git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.MRF
  12   alias Pleroma.Web.ActivityPub.ObjectValidator
  13   alias Pleroma.Web.ActivityPub.SideEffects
  14   alias Pleroma.Web.Federator
  15
  16   @spec common_pipeline(map(), keyword()) ::
  17           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  18   def common_pipeline(object, meta) do
  19     case Repo.transaction(fn -> do_common_pipeline(object, meta) end) do
  20       {:ok, value} ->
  21         value
  22
  23       {:error, e} ->
  24         {:error, e}
  25     end
  26   end
  27
  28   def do_common_pipeline(object, meta) do
  29     with {_, {:ok, validated_object, meta}} <-
  30            {:validate_object, ObjectValidator.validate(object, meta)},
  31          {_, {:ok, mrfd_object}} <- {:mrf_object, MRF.filter(validated_object)},
  32          {_, {:ok, activity, meta}} <-
  33            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  34          {_, {:ok, activity, meta}} <-
  35            {:execute_side_effects, SideEffects.handle(activity, meta)},
  36          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  37       {:ok, activity, meta}
  38     else
  39       {:mrf_object, {:reject, _}} -> {:ok, nil, meta}
  40       e -> {:error, e}
  41     end
  42   end
  43
  44   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  45
  46   defp maybe_federate(%Activity{} = activity, meta) do
  47     with {:ok, local} <- Keyword.fetch(meta, :local) do
  48       do_not_federate = meta[:do_not_federate] || !Config.get([:instance, :federating])
  49
  50       if !do_not_federate && local do
  51         Federator.publish(activity)
  52         {:ok, :federated}
  53       else
  54         {:ok, :not_federated}
  55       end
  56     else
  57       _e -> {:error, :badarg}
  58     end
  59   end
  60 end