git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/like_validator.ex

   1 defmodule Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator do
   2   use Ecto.Schema
   3   import Ecto.Changeset
   4
   5   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
   6   alias Pleroma.Web.ActivityPub.Utils
   7   alias Pleroma.User
   8   alias Pleroma.Object
   9
  10   @primary_key false
  11
  12   embedded_schema do
  13     field(:id, :string, primary_key: true)
  14     field(:type, :string)
  15     field(:object, Types.ObjectID)
  16     field(:actor, Types.ObjectID)
  17     field(:context, :string)
  18     field(:to, {:array, :string})
  19     field(:cc, {:array, :string})
  20   end
  21
  22   def cast_and_validate(data) do
  23     data
  24     |> cast_data()
  25     |> validate_data()
  26   end
  27
  28   def cast_data(data) do
  29     %__MODULE__{}
  30     |> cast(data, [:id, :type, :object, :actor, :context, :to, :cc])
  31   end
  32
  33   def validate_data(data_cng) do
  34     data_cng
  35     |> validate_inclusion(:type, ["Like"])
  36     |> validate_required([:id, :type, :object, :actor, :context])
  37     |> validate_change(:actor, &actor_valid?/2)
  38     |> validate_change(:object, &object_valid?/2)
  39     |> validate_existing_like()
  40   end
  41
  42   def validate_existing_like(%{changes: %{actor: actor, object: object}} = cng) do
  43     if Utils.get_existing_like(actor, %{data: %{"id" => object}}) do
  44       cng
  45       |> add_error(:actor, "already liked this object")
  46       |> add_error(:object, "already liked by this actor")
  47     else
  48       cng
  49     end
  50   end
  51
  52   def validate_existing_like(cng), do: cng
  53
  54   def actor_valid?(field_name, actor) do
  55     if User.get_cached_by_ap_id(actor) do
  56       []
  57     else
  58       [{field_name, "can't find user"}]
  59     end
  60   end
  61
  62   def object_valid?(field_name, object) do
  63     if Object.get_cached_by_ap_id(object) do
  64       []
  65     else
  66       [{field_name, "can't find object"}]
  67     end
  68   end
  69 end