git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/like_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Object
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, ObjectValidators.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:object, ObjectValidators.ObjectID)
  21     field(:actor, ObjectValidators.ObjectID)
  22     field(:context, :string)
  23     field(:to, ObjectValidators.Recipients, default: [])
  24     field(:cc, ObjectValidators.Recipients, default: [])
  25   end
  26
  27   def cast_and_validate(data) do
  28     data
  29     |> cast_data()
  30     |> validate_data()
  31   end
  32
  33   def cast_data(data) do
  34     %__MODULE__{}
  35     |> changeset(data)
  36   end
  37
  38   def changeset(struct, data) do
  39     struct
  40     |> cast(data, __schema__(:fields))
  41     |> fix_after_cast()
  42   end
  43
  44   def fix_after_cast(cng) do
  45     cng
  46     |> fix_recipients()
  47     |> fix_context()
  48   end
  49
  50   def fix_context(cng) do
  51     object = get_field(cng, :object)
  52
  53     with nil <- get_field(cng, :context),
  54          %Object{data: %{"context" => context}} <- Object.get_cached_by_ap_id(object) do
  55       cng
  56       |> put_change(:context, context)
  57     else
  58       _ ->
  59         cng
  60     end
  61   end
  62
  63   def fix_recipients(cng) do
  64     to = get_field(cng, :to)
  65     cc = get_field(cng, :cc)
  66     object = get_field(cng, :object)
  67
  68     with {[], []} <- {to, cc},
  69          %Object{data: %{"actor" => actor}} <- Object.get_cached_by_ap_id(object),
  70          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
  71       cng
  72       |> put_change(:to, [actor])
  73     else
  74       _ ->
  75         cng
  76     end
  77   end
  78
  79   def validate_data(data_cng) do
  80     data_cng
  81     |> validate_inclusion(:type, ["Like"])
  82     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc])
  83     |> validate_actor_presence()
  84     |> validate_object_presence()
  85     |> validate_existing_like()
  86   end
  87
  88   def validate_existing_like(%{changes: %{actor: actor, object: object}} = cng) do
  89     if Utils.get_existing_like(actor, %{data: %{"id" => object}}) do
  90       cng
  91       |> add_error(:actor, "already liked this object")
  92       |> add_error(:object, "already liked by this actor")
  93     else
  94       cng
  95     end
  96   end
  97
  98   def validate_existing_like(cng), do: cng
  99 end