git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/event_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EventValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.AttachmentValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12
  13   import Ecto.Changeset
  14
  15   @primary_key false
  16   @derive Jason.Encoder
  17
  18   # Extends from NoteValidator
  19   embedded_schema do
  20     field(:id, ObjectValidators.ObjectID, primary_key: true)
  21     field(:to, ObjectValidators.Recipients, default: [])
  22     field(:cc, ObjectValidators.Recipients, default: [])
  23     field(:bto, ObjectValidators.Recipients, default: [])
  24     field(:bcc, ObjectValidators.Recipients, default: [])
  25     # TODO: Write type
  26     field(:tag, {:array, :map}, default: [])
  27     field(:type, :string)
  28
  29     field(:name, :string)
  30     field(:summary, :string)
  31     field(:content, :string)
  32
  33     field(:context, :string)
  34     # short identifier for PleromaFE to group statuses by context
  35     field(:context_id, :integer)
  36
  37     # TODO: Remove actor on objects
  38     field(:actor, ObjectValidators.ObjectID)
  39
  40     field(:attributedTo, ObjectValidators.ObjectID)
  41     field(:published, ObjectValidators.DateTime)
  42     # TODO: Write type
  43     field(:emoji, :map, default: %{})
  44     field(:sensitive, :boolean, default: false)
  45     embeds_many(:attachment, AttachmentValidator)
  46     field(:replies_count, :integer, default: 0)
  47     field(:like_count, :integer, default: 0)
  48     field(:announcement_count, :integer, default: 0)
  49     field(:inReplyTo, ObjectValidators.ObjectID)
  50     field(:url, ObjectValidators.Uri)
  51
  52     field(:likes, {:array, ObjectValidators.ObjectID}, default: [])
  53     field(:announcements, {:array, ObjectValidators.ObjectID}, default: [])
  54   end
  55
  56   def cast_and_apply(data) do
  57     data
  58     |> cast_data
  59     |> apply_action(:insert)
  60   end
  61
  62   def cast_and_validate(data) do
  63     data
  64     |> cast_data()
  65     |> validate_data()
  66   end
  67
  68   def cast_data(data) do
  69     %__MODULE__{}
  70     |> changeset(data)
  71   end
  72
  73   defp fix(data) do
  74     data
  75     |> CommonFixes.fix_defaults()
  76     |> CommonFixes.fix_attribution()
  77   end
  78
  79   def changeset(struct, data) do
  80     data = fix(data)
  81
  82     struct
  83     |> cast(data, __schema__(:fields) -- [:attachment])
  84     |> cast_embed(:attachment)
  85   end
  86
  87   def validate_data(data_cng) do
  88     data_cng
  89     |> validate_inclusion(:type, ["Event"])
  90     |> validate_required([:id, :actor, :attributedTo, :type, :context, :context_id])
  91     |> CommonValidations.validate_any_presence([:cc, :to])
  92     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
  93     |> CommonValidations.validate_actor_presence()
  94     |> CommonValidations.validate_host_match()
  95   end
  96 end