git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15   @emoji_regex ~r/:[A-Za-z_-]+:/
  16
  17   embedded_schema do
  18     quote do
  19       unquote do
  20         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  21         message_fields()
  22         activity_fields()
  23         tag_fields()
  24       end
  25     end
  26
  27     field(:context, :string)
  28     field(:content, :string)
  29   end
  30
  31   def cast_and_validate(data) do
  32     data
  33     |> cast_data()
  34     |> validate_data()
  35   end
  36
  37   def cast_data(data) do
  38     data =
  39       data
  40       |> fix()
  41
  42     %__MODULE__{}
  43     |> changeset(data)
  44   end
  45
  46   def changeset(struct, data) do
  47     struct
  48     |> cast(data, __schema__(:fields) -- [:tag])
  49     |> cast_embed(:tag)
  50   end
  51
  52   defp fix(data) do
  53     data =
  54       data
  55       |> CommonFixes.fix_actor()
  56       |> CommonFixes.fix_activity_addressing()
  57
  58     data =
  59       if Map.has_key?(data, "tag") do
  60         data
  61       else
  62         Map.put(data, "tag", [])
  63       end
  64
  65     with %Object{} = object <- Object.normalize(data["object"]) do
  66       data
  67       |> CommonFixes.fix_activity_context(object)
  68       |> CommonFixes.fix_object_action_recipients(object)
  69     else
  70       _ -> data
  71     end
  72   end
  73
  74   defp validate_emoji(cng) do
  75     content = get_field(cng, :content)
  76
  77     if Pleroma.Emoji.is_unicode_emoji?(content) || Regex.match?(@emoji_regex, content) do
  78       cng
  79     else
  80       cng
  81       |> add_error(:content, "is not a valid emoji")
  82     end
  83   end
  84
  85   defp validate_data(data_cng) do
  86     data_cng
  87     |> validate_inclusion(:type, ["EmojiReact"])
  88     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
  89     |> validate_actor_presence()
  90     |> validate_object_presence()
  91     |> validate_emoji()
  92   end
  93 end