git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/article_note_page_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator do
   6   use Ecto.Schema
   7   alias Pleroma.User
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Web.CommonAPI.Utils
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13
  14   import Ecto.Changeset
  15
  16   require Logger
  17
  18   @primary_key false
  19   @derive Jason.Encoder
  20
  21   embedded_schema do
  22     quote do
  23       unquote do
  24         import Elixir.Pleroma.Web.ActivityPub.ObjectValidators.CommonFields
  25         message_fields()
  26         object_fields()
  27         status_object_fields()
  28       end
  29     end
  30
  31     field(:replies, {:array, ObjectValidators.ObjectID}, default: [])
  32     field(:source, :map)
  33     field(:contentMap, :map)
  34   end
  35
  36   def cast_and_apply(data) do
  37     data
  38     |> cast_data
  39     |> apply_action(:insert)
  40   end
  41
  42   def cast_and_validate(data) do
  43     data
  44     |> cast_data()
  45     |> validate_data()
  46   end
  47
  48   def cast_data(data) do
  49     %__MODULE__{}
  50     |> changeset(data)
  51   end
  52
  53   defp fix_url(%{"url" => url} = data) when is_bitstring(url), do: data
  54   defp fix_url(%{"url" => url} = data) when is_map(url), do: Map.put(data, "url", url["href"])
  55   defp fix_url(data), do: data
  56
  57   defp fix_tag(%{"tag" => tag} = data) when is_list(tag) do
  58     Map.put(data, "tag", Enum.filter(tag, &is_map/1))
  59   end
  60
  61   defp fix_tag(%{"tag" => tag} = data) when is_map(tag), do: Map.put(data, "tag", [tag])
  62   defp fix_tag(data), do: Map.drop(data, ["tag"])
  63
  64   defp fix_replies(%{"replies" => replies} = data) when is_list(replies), do: data
  65
  66   defp fix_replies(%{"replies" => %{"first" => first}} = data) do
  67     with {:ok, replies} <- Akkoma.Collections.Fetcher.fetch_collection(first) do
  68       Map.put(data, "replies", replies)
  69     else
  70       {:error, _} ->
  71         Logger.error("Could not fetch replies for #{first}")
  72         Map.put(data, "replies", [])
  73     end
  74   end
  75
  76   defp fix_replies(%{"replies" => %{"items" => replies}} = data) when is_list(replies),
  77     do: Map.put(data, "replies", replies)
  78
  79   defp fix_replies(data), do: Map.delete(data, "replies")
  80
  81   defp remote_mention_resolver(
  82          %{"id" => ap_id, "tag" => tags},
  83          "@" <> nickname = mention,
  84          buffer,
  85          opts,
  86          acc
  87        ) do
  88     initial_host =
  89       ap_id
  90       |> URI.parse()
  91       |> Map.get(:host)
  92
  93     with mention_tag <-
  94            Enum.find(tags, fn t ->
  95              t["type"] == "Mention" &&
  96                (t["name"] == mention || mention == "#{t["name"]}@#{initial_host}")
  97            end),
  98          false <- is_nil(mention_tag),
  99          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(mention_tag["href"]) do
 100       link = Pleroma.Formatter.mention_tag(user, nickname, opts)
 101       {link, %{acc | mentions: MapSet.put(acc.mentions, {"@" <> nickname, user})}}
 102     else
 103       _ -> {buffer, acc}
 104     end
 105   end
 106
 107   # See https://akkoma.dev/FoundKeyGang/FoundKey/issues/343
 108   # Misskey/Foundkey drops some of the custom formatting when it sends remotely
 109   # So this basically reprocesses the MFM source
 110   defp fix_misskey_content(
 111          %{"source" => %{"mediaType" => "text/x.misskeymarkdown", "content" => content}} = object
 112        )
 113        when is_binary(content) do
 114     mention_handler = fn nick, buffer, opts, acc ->
 115       remote_mention_resolver(object, nick, buffer, opts, acc)
 116     end
 117
 118     {linked, _, _} =
 119       Utils.format_input(content, "text/x.misskeymarkdown", mention_handler: mention_handler)
 120
 121     Map.put(object, "content", linked)
 122   end
 123
 124   # See https://github.com/misskey-dev/misskey/pull/8787
 125   # This is for compatibility with older Misskey instances
 126   defp fix_misskey_content(%{"_misskey_content" => content} = object) when is_binary(content) do
 127     mention_handler = fn nick, buffer, opts, acc ->
 128       remote_mention_resolver(object, nick, buffer, opts, acc)
 129     end
 130
 131     {linked, _, _} =
 132       Utils.format_input(content, "text/x.misskeymarkdown", mention_handler: mention_handler)
 133
 134     object
 135     |> Map.put("source", %{
 136       "content" => content,
 137       "mediaType" => "text/x.misskeymarkdown"
 138     })
 139     |> Map.put("content", linked)
 140     |> Map.delete("_misskey_content")
 141   end
 142
 143   defp fix_misskey_content(data), do: data
 144
 145   defp fix_source(%{"source" => source} = object) when is_binary(source) do
 146     object
 147     |> Map.put("source", %{"content" => source})
 148   end
 149
 150   defp fix_source(object), do: object
 151
 152   defp fix_content_map_languages(%{"contentMap" => content_map} = object)
 153        when is_map(content_map) do
 154     # Only allow valid languages
 155     content_map =
 156       content_map
 157       |> Enum.reject(fn {lang, _content} ->
 158         !Pleroma.ISO639.valid_alpha2?(lang)
 159       end)
 160       |> Enum.into(%{})
 161
 162     Map.put(object, "contentMap", content_map)
 163   end
 164
 165   defp fix_content_map_languages(object), do: object
 166
 167   defp fix(data) do
 168     data
 169     |> CommonFixes.fix_actor()
 170     |> CommonFixes.fix_object_defaults()
 171     |> fix_url()
 172     |> fix_tag()
 173     |> fix_replies()
 174     |> fix_source()
 175     |> fix_misskey_content()
 176     |> Transmogrifier.fix_attachments()
 177     |> Transmogrifier.fix_emoji()
 178     |> Transmogrifier.fix_content_map()
 179     |> fix_content_map_languages()
 180   end
 181
 182   def changeset(struct, data) do
 183     data = fix(data)
 184
 185     struct
 186     |> cast(data, __schema__(:fields) -- [:attachment, :tag])
 187     |> cast_embed(:attachment)
 188     |> cast_embed(:tag)
 189   end
 190
 191   defp validate_data(data_cng) do
 192     data_cng
 193     |> validate_inclusion(:type, ["Article", "Note", "Page"])
 194     |> validate_required([:id, :actor, :attributedTo, :type, :context])
 195     |> CommonValidations.validate_any_presence([:cc, :to])
 196     |> CommonValidations.validate_fields_match([:actor, :attributedTo])
 197     |> CommonValidations.validate_actor_presence()
 198     |> CommonValidations.validate_host_match()
 199   end
 200 end