git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/announce_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
   9   alias Pleroma.Web.ActivityPub.Utils
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15
  16   embedded_schema do
  17     field(:id, Types.ObjectID, primary_key: true)
  18     field(:type, :string)
  19     field(:object, Types.ObjectID)
  20     field(:actor, Types.ObjectID)
  21     field(:context, :string, autogenerate: {Utils, :generate_context_id, []})
  22     field(:to, Types.Recipients, default: [])
  23     field(:cc, Types.Recipients, default: [])
  24     field(:published, Types.DateTime)
  25   end
  26
  27   def cast_and_validate(data) do
  28     data
  29     |> cast_data()
  30     |> validate_data()
  31   end
  32
  33   def cast_data(data) do
  34     %__MODULE__{}
  35     |> changeset(data)
  36   end
  37
  38   def changeset(struct, data) do
  39     struct
  40     |> cast(data, __schema__(:fields))
  41     |> fix_after_cast()
  42   end
  43
  44   def fix_after_cast(cng) do
  45     cng
  46   end
  47
  48   def validate_data(data_cng) do
  49     data_cng
  50     |> validate_inclusion(:type, ["Announce"])
  51     |> validate_required([:id, :type, :object, :actor, :to, :cc])
  52     |> validate_actor_presence()
  53     |> validate_object_presence()
  54     |> validate_existing_announce()
  55   end
  56
  57   def validate_existing_announce(cng) do
  58     actor = get_field(cng, :actor)
  59     object = get_field(cng, :object)
  60
  61     if actor && object && Utils.get_existing_announce(actor, %{data: %{"id" => object}}) do
  62       cng
  63       |> add_error(:actor, "already announced this object")
  64       |> add_error(:object, "already announced by this actor")
  65     else
  66       cng
  67     end
  68   end
  69 end