git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  19
  20   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  21   def validate(object, meta)
  22
  23   def validate(%{"type" => "Delete"} = object, meta) do
  24     with cng <- DeleteValidator.cast_and_validate(object),
  25          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  26          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  27       object = stringify_keys(object)
  28       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  29       {:ok, object, meta}
  30     end
  31   end
  32
  33   def validate(%{"type" => "Like"} = object, meta) do
  34     with {:ok, object} <-
  35            object
  36            |> LikeValidator.cast_and_validate()
  37            |> Ecto.Changeset.apply_action(:insert) do
  38       object = stringify_keys(object)
  39       {:ok, object, meta}
  40     end
  41   end
  42
  43   def validate(%{"type" => "ChatMessage"} = object, meta) do
  44     with {:ok, object} <-
  45            object
  46            |> ChatMessageValidator.cast_and_validate()
  47            |> Ecto.Changeset.apply_action(:insert) do
  48       object = stringify_keys(object)
  49       {:ok, object, meta}
  50     end
  51   end
  52
  53   def validate(%{"type" => "Create", "object" => object} = create_activity, meta) do
  54     with {:ok, object_data} <- cast_and_apply(object),
  55          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  56          {:ok, create_activity} <-
  57            create_activity
  58            |> CreateChatMessageValidator.cast_and_validate(meta)
  59            |> Ecto.Changeset.apply_action(:insert) do
  60       create_activity = stringify_keys(create_activity)
  61       {:ok, create_activity, meta}
  62     end
  63   end
  64
  65   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
  66     ChatMessageValidator.cast_and_apply(object)
  67   end
  68
  69   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
  70
  71   def stringify_keys(%{__struct__: _} = object) do
  72     object
  73     |> Map.from_struct()
  74     |> stringify_keys
  75   end
  76
  77   def stringify_keys(object) when is_map(object) do
  78     object
  79     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
  80   end
  81
  82   def stringify_keys(object) when is_list(object) do
  83     object
  84     |> Enum.map(&stringify_keys/1)
  85   end
  86
  87   def stringify_keys(object), do: object
  88
  89   def fetch_actor(object) do
  90     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  91       User.get_or_fetch_by_ap_id(actor)
  92     end
  93   end
  94
  95   def fetch_actor_and_object(object) do
  96     fetch_actor(object)
  97     Object.normalize(object["object"])
  98     :ok
  99   end
 100 end