git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  21
  22   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  23   def validate(object, meta)
  24
  25   def validate(%{"type" => "Undo"} = object, meta) do
  26     with {:ok, object} <-
  27            object
  28            |> UndoValidator.cast_and_validate()
  29            |> Ecto.Changeset.apply_action(:insert) do
  30       object = stringify_keys(object)
  31       {:ok, object, meta}
  32     end
  33   end
  34
  35   def validate(%{"type" => "Delete"} = object, meta) do
  36     with cng <- DeleteValidator.cast_and_validate(object),
  37          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  38          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  39       object = stringify_keys(object)
  40       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  41       {:ok, object, meta}
  42     end
  43   end
  44
  45   def validate(%{"type" => "Like"} = object, meta) do
  46     with {:ok, object} <-
  47            object
  48            |> LikeValidator.cast_and_validate()
  49            |> Ecto.Changeset.apply_action(:insert) do
  50       object = stringify_keys(object)
  51       {:ok, object, meta}
  52     end
  53   end
  54
  55   def validate(%{"type" => "ChatMessage"} = object, meta) do
  56     with {:ok, object} <-
  57            object
  58            |> ChatMessageValidator.cast_and_validate()
  59            |> Ecto.Changeset.apply_action(:insert) do
  60       object = stringify_keys(object)
  61       {:ok, object, meta}
  62     end
  63   end
  64
  65   def validate(%{"type" => "EmojiReact"} = object, meta) do
  66     with {:ok, object} <-
  67            object
  68            |> EmojiReactValidator.cast_and_validate()
  69            |> Ecto.Changeset.apply_action(:insert) do
  70       object = stringify_keys(object |> Map.from_struct())
  71       {:ok, object, meta}
  72     end
  73   end
  74
  75   def validate(%{"type" => "Create", "object" => object} = create_activity, meta) do
  76     with {:ok, object_data} <- cast_and_apply(object),
  77          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  78          {:ok, create_activity} <-
  79            create_activity
  80            |> CreateChatMessageValidator.cast_and_validate(meta)
  81            |> Ecto.Changeset.apply_action(:insert) do
  82       create_activity = stringify_keys(create_activity)
  83       {:ok, create_activity, meta}
  84     end
  85   end
  86
  87   def cast_and_apply(%{"type" => "ChatMessage"} = object) do
  88     ChatMessageValidator.cast_and_apply(object)
  89   end
  90
  91   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
  92
  93   def stringify_keys(%{__struct__: _} = object) do
  94     object
  95     |> Map.from_struct()
  96     |> stringify_keys
  97   end
  98
  99   def stringify_keys(object) when is_map(object) do
 100     object
 101     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 102   end
 103
 104   def stringify_keys(object) when is_list(object) do
 105     object
 106     |> Enum.map(&stringify_keys/1)
 107   end
 108
 109   def stringify_keys(object), do: object
 110
 111   def fetch_actor(object) do
 112     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
 113       User.get_or_fetch_by_ap_id(actor)
 114     end
 115   end
 116
 117   def fetch_actor_and_object(object) do
 118     fetch_actor(object)
 119     Object.normalize(object["object"])
 120     :ok
 121   end
 122 end