git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  18   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  19
  20   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  21   def validate(object, meta)
  22
  23   def validate(%{"type" => "Undo"} = object, meta) do
  24     with {:ok, object} <-
  25            object
  26            |> UndoValidator.cast_and_validate()
  27            |> Ecto.Changeset.apply_action(:insert) do
  28       object = stringify_keys(object)
  29       {:ok, object, meta}
  30     end
  31   end
  32
  33   def validate(%{"type" => "Delete"} = object, meta) do
  34     with cng <- DeleteValidator.cast_and_validate(object),
  35          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  36          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  37       object = stringify_keys(object)
  38       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  39       {:ok, object, meta}
  40     end
  41   end
  42
  43   def validate(%{"type" => "Like"} = object, meta) do
  44     with {:ok, object} <-
  45            object |> LikeValidator.cast_and_validate() |> Ecto.Changeset.apply_action(:insert) do
  46       object = stringify_keys(object |> Map.from_struct())
  47       {:ok, object, meta}
  48     end
  49   end
  50
  51   def validate(%{"type" => "EmojiReact"} = object, meta) do
  52     with {:ok, object} <-
  53            object
  54            |> EmojiReactValidator.cast_and_validate()
  55            |> Ecto.Changeset.apply_action(:insert) do
  56       object = stringify_keys(object |> Map.from_struct())
  57       {:ok, object, meta}
  58     end
  59   end
  60
  61   def stringify_keys(%{__struct__: _} = object) do
  62     object
  63     |> Map.from_struct()
  64     |> stringify_keys
  65   end
  66
  67   def stringify_keys(object) do
  68     object
  69     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  70   end
  71
  72   def fetch_actor(object) do
  73     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  74       User.get_or_fetch_by_ap_id(actor)
  75     end
  76   end
  77
  78   def fetch_actor_and_object(object) do
  79     fetch_actor(object)
  80     Object.normalize(object["object"])
  81     :ok
  82   end
  83 end