git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.ChatMessageValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateChatMessageValidator
  17
  18   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  19   def validate(object, meta)
  20
  21   def validate(%{"type" => "Like"} = object, meta) do
  22     with {:ok, object} <-
  23            object
  24            |> LikeValidator.cast_and_validate()
  25            |> Ecto.Changeset.apply_action(:insert) do
  26       object = stringify_keys(object |> Map.from_struct())
  27       {:ok, object, meta}
  28     end
  29   end
  30
  31   def validate(%{"type" => "ChatMessage"} = object, meta) do
  32     with {:ok, object} <-
  33            object
  34            |> ChatMessageValidator.cast_and_apply() do
  35       object = stringify_keys(object)
  36       {:ok, object, meta}
  37     end
  38   end
  39
  40   def validate(%{"type" => "Create"} = object, meta) do
  41     with {:ok, object} <-
  42            object
  43            |> CreateChatMessageValidator.cast_and_apply() do
  44       object = stringify_keys(object)
  45       {:ok, object, meta}
  46     end
  47   end
  48
  49   def stringify_keys(%{__struct__: _} = object) do
  50     object
  51     |> Map.from_struct()
  52     |> stringify_keys
  53   end
  54
  55   def stringify_keys(object) do
  56     object
  57     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  58   end
  59
  60   def fetch_actor_and_object(object) do
  61     User.get_or_fetch_by_ap_id(object["actor"])
  62     Object.normalize(object["object"])
  63     :ok
  64   end
  65 end