git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  17
  18   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  19   def validate(object, meta)
  20
  21   def validate(%{"type" => "Delete"} = object, meta) do
  22     with cng <- DeleteValidator.cast_and_validate(object),
  23          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  24          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  25       object = stringify_keys(object)
  26       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  27       {:ok, object, meta}
  28     end
  29   end
  30
  31   def validate(%{"type" => "Like"} = object, meta) do
  32     with {:ok, object} <-
  33            object |> LikeValidator.cast_and_validate() |> Ecto.Changeset.apply_action(:insert) do
  34       object = stringify_keys(object |> Map.from_struct())
  35       {:ok, object, meta}
  36     end
  37   end
  38
  39   def stringify_keys(%{__struct__: _} = object) do
  40     object
  41     |> Map.from_struct()
  42     |> stringify_keys
  43   end
  44
  45   def stringify_keys(object) do
  46     object
  47     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  48   end
  49
  50   def fetch_actor(object) do
  51     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  52       User.get_or_fetch_by_ap_id(actor)
  53     end
  54   end
  55
  56   def fetch_actor_and_object(object) do
  57     fetch_actor(object)
  58     Object.normalize(object["object"])
  59     :ok
  60   end
  61 end