git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   alias Pleroma.Object
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  15   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  16   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  17   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  18
  19   @spec validate(map(), keyword()) :: {:ok, map(), keyword()} | {:error, any()}
  20   def validate(object, meta)
  21
  22   def validate(%{"type" => "Undo"} = object, meta) do
  23     with {:ok, object} <-
  24            object
  25            |> UndoValidator.cast_and_validate()
  26            |> Ecto.Changeset.apply_action(:insert) do
  27       object = stringify_keys(object)
  28       {:ok, object, meta}
  29     end
  30   end
  31
  32   def validate(%{"type" => "Delete"} = object, meta) do
  33     with cng <- DeleteValidator.cast_and_validate(object),
  34          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  35          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  36       object = stringify_keys(object)
  37       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  38       {:ok, object, meta}
  39     end
  40   end
  41
  42   def validate(%{"type" => "Like"} = object, meta) do
  43     with {:ok, object} <-
  44            object |> LikeValidator.cast_and_validate() |> Ecto.Changeset.apply_action(:insert) do
  45       object = stringify_keys(object |> Map.from_struct())
  46       {:ok, object, meta}
  47     end
  48   end
  49
  50   def stringify_keys(%{__struct__: _} = object) do
  51     object
  52     |> Map.from_struct()
  53     |> stringify_keys
  54   end
  55
  56   def stringify_keys(object) do
  57     object
  58     |> Map.new(fn {key, val} -> {to_string(key), val} end)
  59   end
  60
  61   def fetch_actor(object) do
  62     with {:ok, actor} <- Types.ObjectID.cast(object["actor"]) do
  63       User.get_or_fetch_by_ap_id(actor)
  64     end
  65   end
  66
  67   def fetch_actor_and_object(object) do
  68     fetch_actor(object)
  69     Object.normalize(object["object"])
  70     :ok
  71   end
  72 end