git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidator do
   6   @moduledoc """
   7   This module is responsible for validating an object (which can be an activity)
   8   and checking if it is both well formed and also compatible with our view of
   9   the system.
  10   """
  11
  12   @behaviour Pleroma.Web.ActivityPub.ObjectValidator.Validating
  13
  14   alias Pleroma.Activity
  15   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  16   alias Pleroma.Object
  17   alias Pleroma.Object.Containment
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ObjectValidators.AcceptRejectValidator
  20   alias Pleroma.Web.ActivityPub.ObjectValidators.AddRemoveValidator
  21   alias Pleroma.Web.ActivityPub.ObjectValidators.AnnounceValidator
  22   alias Pleroma.Web.ActivityPub.ObjectValidators.AnswerValidator
  23   alias Pleroma.Web.ActivityPub.ObjectValidators.ArticleNotePageValidator
  24   alias Pleroma.Web.ActivityPub.ObjectValidators.AudioVideoValidator
  25   alias Pleroma.Web.ActivityPub.ObjectValidators.BlockValidator
  26   alias Pleroma.Web.ActivityPub.ObjectValidators.CreateGenericValidator
  27   alias Pleroma.Web.ActivityPub.ObjectValidators.DeleteValidator
  28   alias Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator
  29   alias Pleroma.Web.ActivityPub.ObjectValidators.EventValidator
  30   alias Pleroma.Web.ActivityPub.ObjectValidators.FollowValidator
  31   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  32   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator
  33   alias Pleroma.Web.ActivityPub.ObjectValidators.UndoValidator
  34   alias Pleroma.Web.ActivityPub.ObjectValidators.UpdateValidator
  35
  36   @impl true
  37   def validate(object, meta)
  38
  39   def validate(%{"type" => "Block"} = block_activity, meta) do
  40     with {:ok, block_activity} <-
  41            block_activity
  42            |> BlockValidator.cast_and_validate()
  43            |> Ecto.Changeset.apply_action(:insert) do
  44       block_activity = stringify_keys(block_activity)
  45       outgoing_blocks = Pleroma.Config.get([:activitypub, :outgoing_blocks])
  46
  47       meta =
  48         if !outgoing_blocks do
  49           Keyword.put(meta, :do_not_federate, true)
  50         else
  51           meta
  52         end
  53
  54       {:ok, block_activity, meta}
  55     end
  56   end
  57
  58   def validate(%{"type" => "Undo"} = object, meta) do
  59     with {:ok, object} <-
  60            object
  61            |> UndoValidator.cast_and_validate()
  62            |> Ecto.Changeset.apply_action(:insert) do
  63       object = stringify_keys(object)
  64       undone_object = Activity.get_by_ap_id(object["object"])
  65
  66       meta =
  67         meta
  68         |> Keyword.put(:object_data, undone_object.data)
  69
  70       {:ok, object, meta}
  71     end
  72   end
  73
  74   def validate(%{"type" => "Delete"} = object, meta) do
  75     with cng <- DeleteValidator.cast_and_validate(object),
  76          do_not_federate <- DeleteValidator.do_not_federate?(cng),
  77          {:ok, object} <- Ecto.Changeset.apply_action(cng, :insert) do
  78       object = stringify_keys(object)
  79       meta = Keyword.put(meta, :do_not_federate, do_not_federate)
  80       {:ok, object, meta}
  81     end
  82   end
  83
  84   def validate(
  85         %{"type" => "Create", "object" => %{"type" => objtype} = object} = create_activity,
  86         meta
  87       )
  88       when objtype in ~w[Question Answer Audio Video Event Article Note Page] do
  89     with {:ok, object_data} <- cast_and_apply(object),
  90          meta = Keyword.put(meta, :object_data, object_data |> stringify_keys),
  91          {:ok, create_activity} <-
  92            create_activity
  93            |> CreateGenericValidator.cast_and_validate(meta)
  94            |> Ecto.Changeset.apply_action(:insert) do
  95       create_activity = stringify_keys(create_activity)
  96       {:ok, create_activity, meta}
  97     end
  98   end
  99
 100   def validate(%{"type" => type} = object, meta)
 101       when type in ~w[Event Question Audio Video Article Note Page] do
 102     validator =
 103       case type do
 104         "Event" -> EventValidator
 105         "Question" -> QuestionValidator
 106         "Audio" -> AudioVideoValidator
 107         "Video" -> AudioVideoValidator
 108         "Article" -> ArticleNotePageValidator
 109         "Note" -> ArticleNotePageValidator
 110         "Page" -> ArticleNotePageValidator
 111       end
 112
 113     with {:ok, object} <-
 114            object
 115            |> validator.cast_and_validate()
 116            |> Ecto.Changeset.apply_action(:insert) do
 117       object = stringify_keys(object)
 118
 119       # Insert copy of hashtags as strings for the non-hashtag table indexing
 120       tag = (object["tag"] || []) ++ Object.hashtags(%Object{data: object})
 121       object = Map.put(object, "tag", tag)
 122
 123       {:ok, object, meta}
 124     end
 125   end
 126
 127   def validate(%{"type" => type} = object, meta)
 128       when type in ~w[Accept Reject Follow Update Like EmojiReact Announce
 129       Answer] do
 130     validator =
 131       case type do
 132         "Accept" -> AcceptRejectValidator
 133         "Reject" -> AcceptRejectValidator
 134         "Follow" -> FollowValidator
 135         "Update" -> UpdateValidator
 136         "Like" -> LikeValidator
 137         "EmojiReact" -> EmojiReactValidator
 138         "Announce" -> AnnounceValidator
 139         "Answer" -> AnswerValidator
 140       end
 141
 142     with {:ok, object} <-
 143            object
 144            |> validator.cast_and_validate()
 145            |> Ecto.Changeset.apply_action(:insert) do
 146       object = stringify_keys(object)
 147       {:ok, object, meta}
 148     end
 149   end
 150
 151   def validate(%{"type" => type} = object, meta) when type in ~w(Add Remove) do
 152     with {:ok, object} <-
 153            object
 154            |> AddRemoveValidator.cast_and_validate()
 155            |> Ecto.Changeset.apply_action(:insert) do
 156       object = stringify_keys(object)
 157       {:ok, object, meta}
 158     end
 159   end
 160
 161   def validate(o, m), do: {:error, {:validator_not_set, {o, m}}}
 162
 163   def cast_and_apply(%{"type" => "Question"} = object) do
 164     QuestionValidator.cast_and_apply(object)
 165   end
 166
 167   def cast_and_apply(%{"type" => "Answer"} = object) do
 168     AnswerValidator.cast_and_apply(object)
 169   end
 170
 171   def cast_and_apply(%{"type" => type} = object) when type in ~w[Audio Video] do
 172     AudioVideoValidator.cast_and_apply(object)
 173   end
 174
 175   def cast_and_apply(%{"type" => "Event"} = object) do
 176     EventValidator.cast_and_apply(object)
 177   end
 178
 179   def cast_and_apply(%{"type" => type} = object) when type in ~w[Article Note Page] do
 180     ArticleNotePageValidator.cast_and_apply(object)
 181   end
 182
 183   def cast_and_apply(o), do: {:error, {:validator_not_set, o}}
 184
 185   # is_struct/1 appears in Elixir 1.11
 186   def stringify_keys(%{__struct__: _} = object) do
 187     object
 188     |> Map.from_struct()
 189     |> stringify_keys
 190   end
 191
 192   def stringify_keys(object) when is_map(object) do
 193     object
 194     |> Enum.filter(fn {_, v} -> v != nil end)
 195     |> Map.new(fn {key, val} -> {to_string(key), stringify_keys(val)} end)
 196   end
 197
 198   def stringify_keys(object) when is_list(object) do
 199     object
 200     |> Enum.map(&stringify_keys/1)
 201   end
 202
 203   def stringify_keys(object), do: object
 204
 205   def fetch_actor(object) do
 206     with actor <- Containment.get_actor(object),
 207          {:ok, actor} <- ObjectValidators.ObjectID.cast(actor) do
 208       User.get_or_fetch_by_ap_id(actor)
 209     end
 210   end
 211
 212   def fetch_actor_and_object(object) do
 213     fetch_actor(object)
 214     Object.normalize(object["object"], fetch: true)
 215     :ok
 216   end
 217 end