git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF do
   6   @callback filter(Map.t()) :: {:ok | :reject, Map.t()}
   7
   8   def filter(policies, %{} = object) do
   9     policies
  10     |> Enum.reduce({:ok, object}, fn
  11       policy, {:ok, object} ->
  12         policy.filter(object)
  13
  14       _, error ->
  15         error
  16     end)
  17   end
  18
  19   def filter(%{} = object), do: get_policies() |> filter(object)
  20
  21   def get_policies do
  22     Pleroma.Config.get([:instance, :rewrite_policy], []) |> get_policies()
  23   end
  24
  25   defp get_policies(policy) when is_atom(policy), do: [policy]
  26   defp get_policies(policies) when is_list(policies), do: policies
  27   defp get_policies(_), do: []
  28
  29   @spec subdomains_regex([String.t()]) :: [Regex.t()]
  30   def subdomains_regex(domains) when is_list(domains) do
  31     for domain <- domains, do: ~r(^#{String.replace(domain, "*.", "(.*\\.)*")}$)
  32   end
  33
  34   @spec subdomain_match?([Regex.t()], String.t()) :: boolean()
  35   def subdomain_match?(domains, host) do
  36     Enum.any?(domains, fn domain -> Regex.match?(domain, host) end)
  37   end
  38 end