git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF do
   6   require Logger
   7
   8   @behaviour Pleroma.Web.ActivityPub.MRF.PipelineFiltering
   9
  10   @mrf_config_descriptions [
  11     %{
  12       group: :pleroma,
  13       key: :mrf,
  14       tab: :mrf,
  15       label: "MRF",
  16       type: :group,
  17       description: "General MRF settings",
  18       children: [
  19         %{
  20           key: :policies,
  21           type: [:module, {:list, :module}],
  22           description:
  23             "A list of MRF policies enabled. Module names are shortened (removed leading `Pleroma.Web.ActivityPub.MRF.` part), but on adding custom module you need to use full name.",
  24           suggestions: {:list_behaviour_implementations, Pleroma.Web.ActivityPub.MRF}
  25         },
  26         %{
  27           key: :transparency,
  28           label: "MRF transparency",
  29           type: :boolean,
  30           description:
  31             "Make the content of your Message Rewrite Facility settings public (via nodeinfo)"
  32         },
  33         %{
  34           key: :transparency_exclusions,
  35           label: "MRF transparency exclusions",
  36           type: {:list, :string},
  37           description:
  38             "Exclude specific instance names from MRF transparency. The use of the exclusions feature will be disclosed in nodeinfo as a boolean value.",
  39           suggestions: [
  40             "exclusion.com"
  41           ]
  42         }
  43       ]
  44     }
  45   ]
  46
  47   @default_description %{
  48     label: "",
  49     description: ""
  50   }
  51
  52   @required_description_keys [:key, :related_policy]
  53
  54   def filter(policies, %{} = message) do
  55     policies
  56     |> Enum.reduce({:ok, message}, fn
  57       policy, {:ok, message} -> policy.filter(message)
  58       _, error -> error
  59     end)
  60   end
  61
  62   def filter(%{} = object), do: get_policies() |> filter(object)
  63
  64   @impl true
  65   def pipeline_filter(%{} = message, meta) do
  66     object = meta[:object_data]
  67     ap_id = message["object"]
  68
  69     if object && ap_id do
  70       with {:ok, message} <- filter(Map.put(message, "object", object)) do
  71         meta = Keyword.put(meta, :object_data, message["object"])
  72         {:ok, Map.put(message, "object", ap_id), meta}
  73       else
  74         {err, message} -> {err, message, meta}
  75       end
  76     else
  77       {err, message} = filter(message)
  78
  79       {err, message, meta}
  80     end
  81   end
  82
  83   def get_policies do
  84     Pleroma.Config.get([:mrf, :policies], [])
  85     |> get_policies()
  86     |> Enum.concat([Pleroma.Web.ActivityPub.MRF.HashtagPolicy])
  87   end
  88
  89   defp get_policies(policy) when is_atom(policy), do: [policy]
  90   defp get_policies(policies) when is_list(policies), do: policies
  91   defp get_policies(_), do: []
  92
  93   @spec subdomains_regex([String.t()]) :: [Regex.t()]
  94   def subdomains_regex(domains) when is_list(domains) do
  95     for domain <- domains, do: ~r(^#{String.replace(domain, "*.", "(.*\\.)*")}$)i
  96   end
  97
  98   @spec subdomain_match?([Regex.t()], String.t()) :: boolean()
  99   def subdomain_match?(domains, host) do
 100     Enum.any?(domains, fn domain -> Regex.match?(domain, host) end)
 101   end
 102
 103   @spec instance_list_from_tuples([{String.t(), String.t()}]) :: [String.t()]
 104   def instance_list_from_tuples(list) do
 105     Enum.map(list, fn {instance, _} -> instance end)
 106   end
 107
 108   def describe(policies) do
 109     {:ok, policy_configs} =
 110       policies
 111       |> Enum.reduce({:ok, %{}}, fn
 112         policy, {:ok, data} ->
 113           {:ok, policy_data} = policy.describe()
 114           {:ok, Map.merge(data, policy_data)}
 115
 116         _, error ->
 117           error
 118       end)
 119
 120     mrf_policies =
 121       get_policies()
 122       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
 123
 124     exclusions = Pleroma.Config.get([:mrf, :transparency_exclusions])
 125
 126     base =
 127       %{
 128         mrf_policies: mrf_policies,
 129         exclusions: length(exclusions) > 0
 130       }
 131       |> Map.merge(policy_configs)
 132
 133     {:ok, base}
 134   end
 135
 136   def describe, do: get_policies() |> describe()
 137
 138   def config_descriptions do
 139     Pleroma.Web.ActivityPub.MRF.Policy
 140     |> Pleroma.Docs.Generator.list_behaviour_implementations()
 141     |> config_descriptions()
 142   end
 143
 144   def config_descriptions(policies) do
 145     Enum.reduce(policies, @mrf_config_descriptions, fn policy, acc ->
 146       if function_exported?(policy, :config_description, 0) do
 147         description =
 148           @default_description
 149           |> Map.merge(policy.config_description)
 150           |> Map.put(:group, :pleroma)
 151           |> Map.put(:tab, :mrf)
 152           |> Map.put(:type, :group)
 153
 154         if Enum.all?(@required_description_keys, &Map.has_key?(description, &1)) do
 155           [description | acc]
 156         else
 157           Logger.warn(
 158             "#{policy} config description doesn't have one or all required keys #{
 159               inspect(@required_description_keys)
 160             }"
 161           )
 162
 163           acc
 164         end
 165       else
 166         Logger.debug(
 167           "#{policy} is excluded from config descriptions, because does not implement `config_description/0` method."
 168         )
 169
 170         acc
 171       end
 172     end)
 173   end
 174 end