git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/simple_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.SimplePolicy do
   6   @moduledoc "Filter activities depending on their origin instance"
   7   @behaviour Pleroma.Web.ActivityPub.MRF
   8
   9   alias Pleroma.Config
  10   alias Pleroma.FollowingRelationship
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.MRF
  13
  14   require Pleroma.Constants
  15
  16   defp check_accept(%{host: actor_host} = _actor_info, object) do
  17     accepts =
  18       Config.get([:mrf_simple, :accept])
  19       |> MRF.subdomains_regex()
  20
  21     cond do
  22       accepts == [] -> {:ok, object}
  23       actor_host == Config.get([Pleroma.Web.Endpoint, :url, :host]) -> {:ok, object}
  24       MRF.subdomain_match?(accepts, actor_host) -> {:ok, object}
  25       true -> {:reject, "[SimplePolicy] host not in accept list"}
  26     end
  27   end
  28
  29   defp check_reject(%{host: actor_host} = _actor_info, object) do
  30     rejects =
  31       Config.get([:mrf_simple, :reject])
  32       |> MRF.subdomains_regex()
  33
  34     if MRF.subdomain_match?(rejects, actor_host) do
  35       {:reject, "[SimplePolicy] host in reject list"}
  36     else
  37       {:ok, object}
  38     end
  39   end
  40
  41   defp check_media_removal(
  42          %{host: actor_host} = _actor_info,
  43          %{"type" => "Create", "object" => %{"attachment" => child_attachment}} = object
  44        )
  45        when length(child_attachment) > 0 do
  46     media_removal =
  47       Config.get([:mrf_simple, :media_removal])
  48       |> MRF.subdomains_regex()
  49
  50     object =
  51       if MRF.subdomain_match?(media_removal, actor_host) do
  52         child_object = Map.delete(object["object"], "attachment")
  53         Map.put(object, "object", child_object)
  54       else
  55         object
  56       end
  57
  58     {:ok, object}
  59   end
  60
  61   defp check_media_removal(_actor_info, object), do: {:ok, object}
  62
  63   defp check_media_nsfw(
  64          %{host: actor_host} = _actor_info,
  65          %{
  66            "type" => "Create",
  67            "object" => child_object
  68          } = object
  69        ) do
  70     media_nsfw =
  71       Config.get([:mrf_simple, :media_nsfw])
  72       |> MRF.subdomains_regex()
  73
  74     object =
  75       if MRF.subdomain_match?(media_nsfw, actor_host) do
  76         tags = (child_object["tag"] || []) ++ ["nsfw"]
  77         child_object = Map.put(child_object, "tag", tags)
  78         child_object = Map.put(child_object, "sensitive", true)
  79         Map.put(object, "object", child_object)
  80       else
  81         object
  82       end
  83
  84     {:ok, object}
  85   end
  86
  87   defp check_media_nsfw(_actor_info, object), do: {:ok, object}
  88
  89   defp check_ftl_removal(%{host: actor_host} = _actor_info, object) do
  90     timeline_removal =
  91       Config.get([:mrf_simple, :federated_timeline_removal])
  92       |> MRF.subdomains_regex()
  93
  94     object =
  95       with true <- MRF.subdomain_match?(timeline_removal, actor_host),
  96            user <- User.get_cached_by_ap_id(object["actor"]),
  97            true <- Pleroma.Constants.as_public() in object["to"] do
  98         to = List.delete(object["to"], Pleroma.Constants.as_public()) ++ [user.follower_address]
  99
 100         cc = List.delete(object["cc"], user.follower_address) ++ [Pleroma.Constants.as_public()]
 101
 102         object
 103         |> Map.put("to", to)
 104         |> Map.put("cc", cc)
 105       else
 106         _ -> object
 107       end
 108
 109     {:ok, object}
 110   end
 111
 112   defp intersection(list1, list2) do
 113     list1 -- list1 -- list2
 114   end
 115
 116   defp check_followers_only(%{host: actor_host} = _actor_info, object) do
 117     followers_only =
 118       Config.get([:mrf_simple, :followers_only])
 119       |> MRF.subdomains_regex()
 120
 121     object =
 122       with true <- MRF.subdomain_match?(followers_only, actor_host),
 123            user <- User.get_cached_by_ap_id(object["actor"]) do
 124         # Don't use Map.get/3 intentionally, these must not be nil
 125         fixed_to = object["to"] || []
 126         fixed_cc = object["cc"] || []
 127
 128         to = FollowingRelationship.followers_ap_ids(user, fixed_to)
 129         cc = FollowingRelationship.followers_ap_ids(user, fixed_cc)
 130
 131         object
 132         |> Map.put("to", intersection([user.follower_address | to], fixed_to))
 133         |> Map.put("cc", intersection([user.follower_address | cc], fixed_cc))
 134       else
 135         _ -> object
 136       end
 137
 138     {:ok, object}
 139   end
 140
 141   defp check_report_removal(%{host: actor_host} = _actor_info, %{"type" => "Flag"} = object) do
 142     report_removal =
 143       Config.get([:mrf_simple, :report_removal])
 144       |> MRF.subdomains_regex()
 145
 146     if MRF.subdomain_match?(report_removal, actor_host) do
 147       {:reject, "[SimplePolicy] host in report_removal list"}
 148     else
 149       {:ok, object}
 150     end
 151   end
 152
 153   defp check_report_removal(_actor_info, object), do: {:ok, object}
 154
 155   defp check_avatar_removal(%{host: actor_host} = _actor_info, %{"icon" => _icon} = object) do
 156     avatar_removal =
 157       Config.get([:mrf_simple, :avatar_removal])
 158       |> MRF.subdomains_regex()
 159
 160     if MRF.subdomain_match?(avatar_removal, actor_host) do
 161       {:ok, Map.delete(object, "icon")}
 162     else
 163       {:ok, object}
 164     end
 165   end
 166
 167   defp check_avatar_removal(_actor_info, object), do: {:ok, object}
 168
 169   defp check_banner_removal(%{host: actor_host} = _actor_info, %{"image" => _image} = object) do
 170     banner_removal =
 171       Config.get([:mrf_simple, :banner_removal])
 172       |> MRF.subdomains_regex()
 173
 174     if MRF.subdomain_match?(banner_removal, actor_host) do
 175       {:ok, Map.delete(object, "image")}
 176     else
 177       {:ok, object}
 178     end
 179   end
 180
 181   defp check_banner_removal(_actor_info, object), do: {:ok, object}
 182
 183   @impl true
 184   def filter(%{"type" => "Delete", "actor" => actor} = object) do
 185     %{host: actor_host} = URI.parse(actor)
 186
 187     reject_deletes =
 188       Config.get([:mrf_simple, :reject_deletes])
 189       |> MRF.subdomains_regex()
 190
 191     if MRF.subdomain_match?(reject_deletes, actor_host) do
 192       {:reject, "[SimplePolicy] host in reject_deletes list"}
 193     else
 194       {:ok, object}
 195     end
 196   end
 197
 198   @impl true
 199   def filter(%{"actor" => actor} = object) do
 200     actor_info = URI.parse(actor)
 201
 202     with {:ok, object} <- check_accept(actor_info, object),
 203          {:ok, object} <- check_reject(actor_info, object),
 204          {:ok, object} <- check_media_removal(actor_info, object),
 205          {:ok, object} <- check_media_nsfw(actor_info, object),
 206          {:ok, object} <- check_ftl_removal(actor_info, object),
 207          {:ok, object} <- check_followers_only(actor_info, object),
 208          {:ok, object} <- check_report_removal(actor_info, object) do
 209       {:ok, object}
 210     else
 211       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 212       {:reject, _} = e -> e
 213       _ -> {:reject, "[SimplePolicy]"}
 214     end
 215   end
 216
 217   def filter(%{"id" => actor, "type" => obj_type} = object)
 218       when obj_type in ["Application", "Group", "Organization", "Person", "Service"] do
 219     actor_info = URI.parse(actor)
 220
 221     with {:ok, object} <- check_accept(actor_info, object),
 222          {:ok, object} <- check_reject(actor_info, object),
 223          {:ok, object} <- check_avatar_removal(actor_info, object),
 224          {:ok, object} <- check_banner_removal(actor_info, object) do
 225       {:ok, object}
 226     else
 227       {:reject, nil} -> {:reject, "[SimplePolicy]"}
 228       {:reject, _} = e -> e
 229       _ -> {:reject, "[SimplePolicy]"}
 230     end
 231   end
 232
 233   def filter(object), do: {:ok, object}
 234
 235   @impl true
 236   def describe do
 237     exclusions = Config.get([:mrf, :transparency_exclusions])
 238
 239     mrf_simple =
 240       Config.get(:mrf_simple)
 241       |> Enum.map(fn {k, v} -> {k, Enum.reject(v, fn v -> v in exclusions end)} end)
 242       |> Enum.into(%{})
 243
 244     {:ok, %{mrf_simple: mrf_simple}}
 245   end
 246 end