git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/media_proxy_warming_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.MediaProxyWarmingPolicy do
   6   @moduledoc "Preloads any attachments in the MediaProxy cache by prefetching them"
   7   @behaviour Pleroma.Web.ActivityPub.MRF.Policy
   8
   9   alias Pleroma.HTTP
  10   alias Pleroma.Web.MediaProxy
  11
  12   require Logger
  13
  14   @adapter_options [
  15     pool: :media,
  16     recv_timeout: 10_000
  17   ]
  18
  19   defp prefetch(url) do
  20     # Fetching only proxiable resources
  21     if MediaProxy.enabled?() and MediaProxy.url_proxiable?(url) do
  22       # If preview proxy is enabled, it'll also hit media proxy (so we're caching both requests)
  23       prefetch_url = MediaProxy.preview_url(url)
  24
  25       Logger.debug("Prefetching #{inspect(url)} as #{inspect(prefetch_url)}")
  26
  27       if Pleroma.Config.get(:env) == :test do
  28         fetch(prefetch_url)
  29       else
  30         ConcurrentLimiter.limit(__MODULE__, fn ->
  31           Task.start(fn -> fetch(prefetch_url) end)
  32         end)
  33       end
  34     end
  35   end
  36
  37   defp fetch(url), do: HTTP.get(url, [], @adapter_options)
  38
  39   defp preload(%{"object" => %{"attachment" => attachments}} = _message) do
  40     Enum.each(attachments, fn
  41       %{"url" => url} when is_list(url) ->
  42         url
  43         |> Enum.each(fn
  44           %{"href" => href} ->
  45             prefetch(href)
  46
  47           x ->
  48             Logger.debug("Unhandled attachment URL object #{inspect(x)}")
  49         end)
  50
  51       x ->
  52         Logger.debug("Unhandled attachment #{inspect(x)}")
  53     end)
  54   end
  55
  56   @impl true
  57   def filter(
  58         %{"type" => "Create", "object" => %{"attachment" => attachments} = _object} = message
  59       )
  60       when is_list(attachments) and length(attachments) > 0 do
  61     preload(message)
  62
  63     {:ok, message}
  64   end
  65
  66   @impl true
  67   def filter(message), do: {:ok, message}
  68
  69   @impl true
  70   def describe, do: {:ok, %{}}
  71 end