git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/mrf/keyword_policy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.MRF.KeywordPolicy do
   6   @behaviour Pleroma.Web.ActivityPub.MRF
   7   defp string_matches?(string, pattern) when is_binary(pattern) do
   8     String.contains?(string, pattern)
   9   end
  10
  11   defp string_matches?(string, pattern) do
  12     String.match?(string, pattern)
  13   end
  14
  15   defp check_reject(%{"object" => %{"content" => content, "summary" => summary}} = message) do
  16     if Enum.any?(Pleroma.Config.get([:mrf_keyword, :reject]), fn pattern ->
  17          string_matches?(content, pattern) or string_matches?(summary, pattern)
  18        end) do
  19       {:reject, nil}
  20     else
  21       {:ok, message}
  22     end
  23   end
  24
  25   defp check_ftl_removal(
  26          %{"to" => to, "object" => %{"content" => content, "summary" => summary}} = message
  27        ) do
  28     if "https://www.w3.org/ns/activitystreams#Public" in to and
  29          Enum.any?(Pleroma.Config.get([:mrf_keyword, :federated_timeline_removal]), fn pattern ->
  30            string_matches?(content, pattern) or string_matches?(summary, pattern)
  31          end) do
  32       to = List.delete(to, "https://www.w3.org/ns/activitystreams#Public")
  33       cc = ["https://www.w3.org/ns/activitystreams#Public" | message["cc"] || []]
  34
  35       message =
  36         message
  37         |> Map.put("to", to)
  38         |> Map.put("cc", cc)
  39
  40       {:ok, message}
  41     else
  42       {:ok, message}
  43     end
  44   end
  45
  46   defp check_replace(%{"object" => %{"content" => content, "summary" => summary}} = message) do
  47     {content, summary} =
  48       Enum.reduce(Pleroma.Config.get([:mrf_keyword, :replace]), {content, summary}, fn {pattern,
  49                                                                                         replacement},
  50                                                                                        {content_acc,
  51                                                                                         summary_acc} ->
  52         {String.replace(content_acc, pattern, replacement),
  53          String.replace(summary_acc, pattern, replacement)}
  54       end)
  55
  56     {:ok,
  57      message
  58      |> put_in(["object", "content"], content)
  59      |> put_in(["object", "summary"], summary)}
  60   end
  61
  62   @impl true
  63   def filter(%{"object" => %{"content" => nil}} = message) do
  64     {:ok, message}
  65   end
  66
  67   @impl true
  68   def filter(%{"type" => "Create", "object" => %{"content" => _content}} = message) do
  69     with {:ok, message} <- check_reject(message),
  70          {:ok, message} <- check_ftl_removal(message),
  71          {:ok, message} <- check_replace(message) do
  72       {:ok, message}
  73     else
  74       _e ->
  75         {:reject, nil}
  76     end
  77   end
  78
  79   @impl true
  80   def filter(message), do: {:ok, message}
  81 end