git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub_controller.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{User, Object}
   4   alias Pleroma.Object.Fetcher
   5   alias Pleroma.Web.ActivityPub.{ObjectView, UserView}
   6   alias Pleroma.Web.ActivityPub.ActivityPub
   7   alias Pleroma.Web.ActivityPub.Relay
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.Federator
  10
  11   require Logger
  12
  13   action_fallback(:errors)
  14
  15   plug(Pleroma.Web.FederatingPlug when action in [:inbox, :relay])
  16   plug(:relay_active? when action in [:relay])
  17
  18   def relay_active?(conn, _) do
  19     if Keyword.get(Application.get_env(:pleroma, :instance), :allow_relay) do
  20       conn
  21     else
  22       conn
  23       |> put_status(404)
  24       |> json(%{error: "not found"})
  25       |> halt
  26     end
  27   end
  28
  29   def user(conn, %{"nickname" => nickname}) do
  30     with %User{} = user <- User.get_cached_by_nickname(nickname),
  31          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  32       conn
  33       |> put_resp_header("content-type", "application/activity+json")
  34       |> json(UserView.render("user.json", %{user: user}))
  35     else
  36       nil -> {:error, :not_found}
  37     end
  38   end
  39
  40   def object(conn, %{"uuid" => uuid}) do
  41     with ap_id <- o_status_url(conn, :object, uuid),
  42          %Object{} = object <- Object.get_cached_by_ap_id(ap_id),
  43          {_, true} <- {:public?, ActivityPub.is_public?(object)} do
  44       conn
  45       |> put_resp_header("content-type", "application/activity+json")
  46       |> json(ObjectView.render("object.json", %{object: object}))
  47     else
  48       {:public?, false} ->
  49         {:error, :not_found}
  50     end
  51   end
  52
  53   def following(conn, %{"nickname" => nickname, "page" => page}) do
  54     with %User{} = user <- User.get_cached_by_nickname(nickname),
  55          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  56       {page, _} = Integer.parse(page)
  57
  58       conn
  59       |> put_resp_header("content-type", "application/activity+json")
  60       |> json(UserView.render("following.json", %{user: user, page: page}))
  61     end
  62   end
  63
  64   def following(conn, %{"nickname" => nickname}) do
  65     with %User{} = user <- User.get_cached_by_nickname(nickname),
  66          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  67       conn
  68       |> put_resp_header("content-type", "application/activity+json")
  69       |> json(UserView.render("following.json", %{user: user}))
  70     end
  71   end
  72
  73   def followers(conn, %{"nickname" => nickname, "page" => page}) do
  74     with %User{} = user <- User.get_cached_by_nickname(nickname),
  75          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  76       {page, _} = Integer.parse(page)
  77
  78       conn
  79       |> put_resp_header("content-type", "application/activity+json")
  80       |> json(UserView.render("followers.json", %{user: user, page: page}))
  81     end
  82   end
  83
  84   def followers(conn, %{"nickname" => nickname}) do
  85     with %User{} = user <- User.get_cached_by_nickname(nickname),
  86          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  87       conn
  88       |> put_resp_header("content-type", "application/activity+json")
  89       |> json(UserView.render("followers.json", %{user: user}))
  90     end
  91   end
  92
  93   def outbox(conn, %{"nickname" => nickname, "max_id" => max_id}) do
  94     with %User{} = user <- User.get_cached_by_nickname(nickname),
  95          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
  96       conn
  97       |> put_resp_header("content-type", "application/activity+json")
  98       |> json(UserView.render("outbox.json", %{user: user, max_id: max_id}))
  99     end
 100   end
 101
 102   def outbox(conn, %{"nickname" => nickname}) do
 103     outbox(conn, %{"nickname" => nickname, "max_id" => nil})
 104   end
 105
 106   def inbox(%{assigns: %{valid_signature: true}} = conn, %{"nickname" => nickname} = params) do
 107     with %User{} = user <- User.get_cached_by_nickname(nickname),
 108          true <- Utils.recipient_in_message(user.ap_id, params),
 109          params <- Utils.maybe_splice_recipient(user.ap_id, params) do
 110       Federator.enqueue(:incoming_ap_doc, params)
 111       json(conn, "ok")
 112     end
 113   end
 114
 115   def inbox(%{assigns: %{valid_signature: true}} = conn, params) do
 116     Federator.enqueue(:incoming_ap_doc, params)
 117     json(conn, "ok")
 118   end
 119
 120   # only accept relayed Creates
 121   def inbox(conn, %{"type" => "Create"} = params) do
 122     Logger.info(
 123       "Signature missing or not from author, relayed Create message, fetching object from source"
 124     )
 125
 126     Fetcher.fetch_object_from_id(params["object"]["id"])
 127
 128     json(conn, "ok")
 129   end
 130
 131   def inbox(conn, params) do
 132     headers = Enum.into(conn.req_headers, %{})
 133
 134     if String.contains?(headers["signature"], params["actor"]) do
 135       Logger.info(
 136         "Signature validation error for: #{params["actor"]}, make sure you are forwarding the HTTP Host header!"
 137       )
 138
 139       Logger.info(inspect(conn.req_headers))
 140     end
 141
 142     json(conn, "error")
 143   end
 144
 145   def relay(conn, params) do
 146     with %User{} = user <- Relay.get_actor(),
 147          {:ok, user} <- Pleroma.Web.WebFinger.ensure_keys_present(user) do
 148       conn
 149       |> put_resp_header("content-type", "application/activity+json")
 150       |> json(UserView.render("user.json", %{user: user}))
 151     else
 152       nil -> {:error, :not_found}
 153     end
 154   end
 155
 156   def errors(conn, {:error, :not_found}) do
 157     conn
 158     |> put_status(404)
 159     |> json("Not found")
 160   end
 161
 162   def errors(conn, _e) do
 163     conn
 164     |> put_status(500)
 165     |> json("error")
 166   end
 167 end