git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         activity.data["object"]
 107         |> Map.get("tag", [])
 108         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 109         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 110
 111         if activity.data["object"]["attachment"] != [] do
 112           Pleroma.Web.Streamer.stream("public:media", activity)
 113
 114           if activity.local do
 115             Pleroma.Web.Streamer.stream("public:local:media", activity)
 116           end
 117         end
 118       else
 119         if !Enum.member?(activity.data["cc"] || [], public) &&
 120              !Enum.member?(
 121                activity.data["to"],
 122                User.get_by_ap_id(activity.data["actor"]).follower_address
 123              ),
 124            do: Pleroma.Web.Streamer.stream("direct", activity)
 125       end
 126     end
 127   end
 128
 129   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 130     additional = params[:additional] || %{}
 131     # only accept false as false value
 132     local = !(params[:local] == false)
 133     published = params[:published]
 134
 135     with create_data <-
 136            make_create_data(
 137              %{to: to, actor: actor, published: published, context: context, object: object},
 138              additional
 139            ),
 140          {:ok, activity} <- insert(create_data, local),
 141          :ok <- maybe_federate(activity),
 142          {:ok, _actor} <- User.increase_note_count(actor) do
 143       {:ok, activity}
 144     end
 145   end
 146
 147   def accept(%{to: to, actor: actor, object: object} = params) do
 148     # only accept false as false value
 149     local = !(params[:local] == false)
 150
 151     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 152          {:ok, activity} <- insert(data, local),
 153          :ok <- maybe_federate(activity) do
 154       {:ok, activity}
 155     end
 156   end
 157
 158   def reject(%{to: to, actor: actor, object: object} = params) do
 159     # only accept false as false value
 160     local = !(params[:local] == false)
 161
 162     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 163          {:ok, activity} <- insert(data, local),
 164          :ok <- maybe_federate(activity) do
 165       {:ok, activity}
 166     end
 167   end
 168
 169   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 170     # only accept false as false value
 171     local = !(params[:local] == false)
 172
 173     with data <- %{
 174            "to" => to,
 175            "cc" => cc,
 176            "type" => "Update",
 177            "actor" => actor,
 178            "object" => object
 179          },
 180          {:ok, activity} <- insert(data, local),
 181          :ok <- maybe_federate(activity) do
 182       {:ok, activity}
 183     end
 184   end
 185
 186   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 187   def like(
 188         %User{ap_id: ap_id} = user,
 189         %Object{data: %{"id" => _}} = object,
 190         activity_id \\ nil,
 191         local \\ true
 192       ) do
 193     with nil <- get_existing_like(ap_id, object),
 194          like_data <- make_like_data(user, object, activity_id),
 195          {:ok, activity} <- insert(like_data, local),
 196          {:ok, object} <- add_like_to_object(activity, object),
 197          :ok <- maybe_federate(activity) do
 198       {:ok, activity, object}
 199     else
 200       %Activity{} = activity -> {:ok, activity, object}
 201       error -> {:error, error}
 202     end
 203   end
 204
 205   def unlike(
 206         %User{} = actor,
 207         %Object{} = object,
 208         activity_id \\ nil,
 209         local \\ true
 210       ) do
 211     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 212          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 213          {:ok, unlike_activity} <- insert(unlike_data, local),
 214          {:ok, _activity} <- Repo.delete(like_activity),
 215          {:ok, object} <- remove_like_from_object(like_activity, object),
 216          :ok <- maybe_federate(unlike_activity) do
 217       {:ok, unlike_activity, like_activity, object}
 218     else
 219       _e -> {:ok, object}
 220     end
 221   end
 222
 223   def announce(
 224         %User{ap_id: _} = user,
 225         %Object{data: %{"id" => _}} = object,
 226         activity_id \\ nil,
 227         local \\ true
 228       ) do
 229     with true <- is_public?(object),
 230          announce_data <- make_announce_data(user, object, activity_id),
 231          {:ok, activity} <- insert(announce_data, local),
 232          {:ok, object} <- add_announce_to_object(activity, object),
 233          :ok <- maybe_federate(activity) do
 234       {:ok, activity, object}
 235     else
 236       error -> {:error, error}
 237     end
 238   end
 239
 240   def unannounce(
 241         %User{} = actor,
 242         %Object{} = object,
 243         activity_id \\ nil,
 244         local \\ true
 245       ) do
 246     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 247          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 248          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 249          :ok <- maybe_federate(unannounce_activity),
 250          {:ok, _activity} <- Repo.delete(announce_activity),
 251          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 252       {:ok, unannounce_activity, object}
 253     else
 254       _e -> {:ok, object}
 255     end
 256   end
 257
 258   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 259     with data <- make_follow_data(follower, followed, activity_id),
 260          {:ok, activity} <- insert(data, local),
 261          :ok <- maybe_federate(activity) do
 262       {:ok, activity}
 263     end
 264   end
 265
 266   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 267     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 268          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 269          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 270          {:ok, activity} <- insert(unfollow_data, local),
 271          :ok <- maybe_federate(activity) do
 272       {:ok, activity}
 273     end
 274   end
 275
 276   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 277     user = User.get_cached_by_ap_id(actor)
 278
 279     data = %{
 280       "type" => "Delete",
 281       "actor" => actor,
 282       "object" => id,
 283       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 284     }
 285
 286     with {:ok, _} <- Object.delete(object),
 287          {:ok, activity} <- insert(data, local),
 288          :ok <- maybe_federate(activity),
 289          {:ok, _actor} <- User.decrease_note_count(user) do
 290       {:ok, activity}
 291     end
 292   end
 293
 294   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 295     ap_config = Application.get_env(:pleroma, :activitypub)
 296     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 297     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 298
 299     with true <- unfollow_blocked do
 300       follow_activity = fetch_latest_follow(blocker, blocked)
 301
 302       if follow_activity do
 303         unfollow(blocker, blocked, nil, local)
 304       end
 305     end
 306
 307     with true <- outgoing_blocks,
 308          block_data <- make_block_data(blocker, blocked, activity_id),
 309          {:ok, activity} <- insert(block_data, local),
 310          :ok <- maybe_federate(activity) do
 311       {:ok, activity}
 312     else
 313       _e -> {:ok, nil}
 314     end
 315   end
 316
 317   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 318     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 319          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 320          {:ok, activity} <- insert(unblock_data, local),
 321          :ok <- maybe_federate(activity) do
 322       {:ok, activity}
 323     end
 324   end
 325
 326   def fetch_activities_for_context(context, opts \\ %{}) do
 327     public = ["https://www.w3.org/ns/activitystreams#Public"]
 328
 329     recipients =
 330       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 331
 332     query = from(activity in Activity)
 333
 334     query =
 335       query
 336       |> restrict_blocked(opts)
 337       |> restrict_recipients(recipients, opts["user"])
 338
 339     query =
 340       from(
 341         activity in query,
 342         where:
 343           fragment(
 344             "?->>'type' = ? and ?->>'context' = ?",
 345             activity.data,
 346             "Create",
 347             activity.data,
 348             ^context
 349           ),
 350         order_by: [desc: :id]
 351       )
 352
 353     Repo.all(query)
 354   end
 355
 356   def fetch_public_activities(opts \\ %{}) do
 357     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 358
 359     q
 360     |> restrict_unlisted()
 361     |> Repo.all()
 362     |> Enum.reverse()
 363   end
 364
 365   @valid_visibilities ~w[direct unlisted public private]
 366
 367   defp restrict_visibility(query, %{visibility: visibility})
 368        when visibility in @valid_visibilities do
 369     query =
 370       from(
 371         a in query,
 372         where:
 373           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 374       )
 375
 376     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 377
 378     query
 379   end
 380
 381   defp restrict_visibility(_query, %{visibility: visibility})
 382        when visibility not in @valid_visibilities do
 383     Logger.error("Could not restrict visibility to #{visibility}")
 384   end
 385
 386   defp restrict_visibility(query, _visibility), do: query
 387
 388   def fetch_user_activities(user, reading_user, params \\ %{}) do
 389     params =
 390       params
 391       |> Map.put("type", ["Create", "Announce"])
 392       |> Map.put("actor_id", user.ap_id)
 393       |> Map.put("whole_db", true)
 394
 395     recipients =
 396       if reading_user do
 397         ["https://www.w3.org/ns/activitystreams#Public"] ++
 398           [reading_user.ap_id | reading_user.following]
 399       else
 400         ["https://www.w3.org/ns/activitystreams#Public"]
 401       end
 402
 403     fetch_activities(recipients, params)
 404     |> Enum.reverse()
 405   end
 406
 407   defp restrict_since(query, %{"since_id" => since_id}) do
 408     from(activity in query, where: activity.id > ^since_id)
 409   end
 410
 411   defp restrict_since(query, _), do: query
 412
 413   defp restrict_tag(query, %{"tag" => tag}) do
 414     from(
 415       activity in query,
 416       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 417     )
 418   end
 419
 420   defp restrict_tag(query, _), do: query
 421
 422   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 423     from(
 424       activity in query,
 425       where:
 426         fragment(
 427           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 428           activity.data,
 429           ^recipients_to,
 430           activity.data,
 431           ^recipients_cc
 432         )
 433     )
 434   end
 435
 436   defp restrict_recipients(query, [], _user), do: query
 437
 438   defp restrict_recipients(query, recipients, nil) do
 439     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 440   end
 441
 442   defp restrict_recipients(query, recipients, user) do
 443     from(
 444       activity in query,
 445       where: fragment("? && ?", ^recipients, activity.recipients),
 446       or_where: activity.actor == ^user.ap_id
 447     )
 448   end
 449
 450   defp restrict_limit(query, %{"limit" => limit}) do
 451     from(activity in query, limit: ^limit)
 452   end
 453
 454   defp restrict_limit(query, _), do: query
 455
 456   defp restrict_local(query, %{"local_only" => true}) do
 457     from(activity in query, where: activity.local == true)
 458   end
 459
 460   defp restrict_local(query, _), do: query
 461
 462   defp restrict_max(query, %{"max_id" => max_id}) do
 463     from(activity in query, where: activity.id < ^max_id)
 464   end
 465
 466   defp restrict_max(query, _), do: query
 467
 468   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 469     from(activity in query, where: activity.actor == ^actor_id)
 470   end
 471
 472   defp restrict_actor(query, _), do: query
 473
 474   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 475     restrict_type(query, %{"type" => [type]})
 476   end
 477
 478   defp restrict_type(query, %{"type" => type}) do
 479     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 480   end
 481
 482   defp restrict_type(query, _), do: query
 483
 484   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 485     from(
 486       activity in query,
 487       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 488     )
 489   end
 490
 491   defp restrict_favorited_by(query, _), do: query
 492
 493   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 494     from(
 495       activity in query,
 496       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 497     )
 498   end
 499
 500   defp restrict_media(query, _), do: query
 501
 502   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 503     from(
 504       activity in query,
 505       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 506     )
 507   end
 508
 509   defp restrict_replies(query, _), do: query
 510
 511   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 512     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 513   end
 514
 515   defp restrict_reblogs(query, _), do: query
 516
 517   # Only search through last 100_000 activities by default
 518   defp restrict_recent(query, %{"whole_db" => true}), do: query
 519
 520   defp restrict_recent(query, _) do
 521     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 522
 523     from(activity in query, where: activity.id > ^since)
 524   end
 525
 526   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 527     blocks = info.blocks || []
 528     domain_blocks = info.domain_blocks || []
 529
 530     from(
 531       activity in query,
 532       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 533       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 534       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 535     )
 536   end
 537
 538   defp restrict_blocked(query, _), do: query
 539
 540   defp restrict_unlisted(query) do
 541     from(
 542       activity in query,
 543       where:
 544         fragment(
 545           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 546           activity.data,
 547           ^["https://www.w3.org/ns/activitystreams#Public"]
 548         )
 549     )
 550   end
 551
 552   def fetch_activities_query(recipients, opts \\ %{}) do
 553     base_query =
 554       from(
 555         activity in Activity,
 556         limit: 20,
 557         order_by: [fragment("? desc nulls last", activity.id)]
 558       )
 559
 560     base_query
 561     |> restrict_recipients(recipients, opts["user"])
 562     |> restrict_tag(opts)
 563     |> restrict_since(opts)
 564     |> restrict_local(opts)
 565     |> restrict_limit(opts)
 566     |> restrict_max(opts)
 567     |> restrict_actor(opts)
 568     |> restrict_type(opts)
 569     |> restrict_favorited_by(opts)
 570     |> restrict_recent(opts)
 571     |> restrict_blocked(opts)
 572     |> restrict_media(opts)
 573     |> restrict_visibility(opts)
 574     |> restrict_replies(opts)
 575     |> restrict_reblogs(opts)
 576   end
 577
 578   def fetch_activities(recipients, opts \\ %{}) do
 579     fetch_activities_query(recipients, opts)
 580     |> Repo.all()
 581     |> Enum.reverse()
 582   end
 583
 584   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 585     fetch_activities_query([], opts)
 586     |> restrict_to_cc(recipients_to, recipients_cc)
 587     |> Repo.all()
 588     |> Enum.reverse()
 589   end
 590
 591   def upload(file, opts \\ []) do
 592     with {:ok, data} <- Upload.store(file, opts) do
 593       obj_data =
 594         if opts[:actor] do
 595           Map.put(data, "actor", opts[:actor])
 596         else
 597           data
 598         end
 599
 600       Repo.insert(%Object{data: obj_data})
 601     end
 602   end
 603
 604   def user_data_from_user_object(data) do
 605     avatar =
 606       data["icon"]["url"] &&
 607         %{
 608           "type" => "Image",
 609           "url" => [%{"href" => data["icon"]["url"]}]
 610         }
 611
 612     banner =
 613       data["image"]["url"] &&
 614         %{
 615           "type" => "Image",
 616           "url" => [%{"href" => data["image"]["url"]}]
 617         }
 618
 619     locked = data["manuallyApprovesFollowers"] || false
 620     data = Transmogrifier.maybe_fix_user_object(data)
 621
 622     user_data = %{
 623       ap_id: data["id"],
 624       info: %{
 625         "ap_enabled" => true,
 626         "source_data" => data,
 627         "banner" => banner,
 628         "locked" => locked
 629       },
 630       avatar: avatar,
 631       name: data["name"],
 632       follower_address: data["followers"],
 633       bio: data["summary"]
 634     }
 635
 636     # nickname can be nil because of virtual actors
 637     user_data =
 638       if data["preferredUsername"] do
 639         Map.put(
 640           user_data,
 641           :nickname,
 642           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 643         )
 644       else
 645         Map.put(user_data, :nickname, nil)
 646       end
 647
 648     {:ok, user_data}
 649   end
 650
 651   def fetch_and_prepare_user_from_ap_id(ap_id) do
 652     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 653       user_data_from_user_object(data)
 654     else
 655       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 656     end
 657   end
 658
 659   def make_user_from_ap_id(ap_id) do
 660     if _user = User.get_by_ap_id(ap_id) do
 661       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 662     else
 663       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 664         User.insert_or_update_user(data)
 665       else
 666         e -> {:error, e}
 667       end
 668     end
 669   end
 670
 671   def make_user_from_nickname(nickname) do
 672     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 673       make_user_from_ap_id(ap_id)
 674     else
 675       _e -> {:error, "No AP id in WebFinger"}
 676     end
 677   end
 678
 679   def should_federate?(inbox, public) do
 680     if public do
 681       true
 682     else
 683       inbox_info = URI.parse(inbox)
 684       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 685     end
 686   end
 687
 688   def publish(actor, activity) do
 689     followers =
 690       if actor.follower_address in activity.recipients do
 691         {:ok, followers} = User.get_followers(actor)
 692         followers |> Enum.filter(&(!&1.local))
 693       else
 694         []
 695       end
 696
 697     public = is_public?(activity)
 698
 699     remote_inboxes =
 700       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 701       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 702       |> Enum.map(fn %{info: %{source_data: data}} ->
 703         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 704       end)
 705       |> Enum.uniq()
 706       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 707
 708     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 709     json = Jason.encode!(data)
 710
 711     Enum.each(remote_inboxes, fn inbox ->
 712       Federator.enqueue(:publish_single_ap, %{
 713         inbox: inbox,
 714         json: json,
 715         actor: actor,
 716         id: activity.data["id"]
 717       })
 718     end)
 719   end
 720
 721   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 722     Logger.info("Federating #{id} to #{inbox}")
 723     host = URI.parse(inbox).host
 724
 725     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 726
 727     signature =
 728       Pleroma.Web.HTTPSignatures.sign(actor, %{
 729         host: host,
 730         "content-length": byte_size(json),
 731         digest: digest
 732       })
 733
 734     @httpoison.post(
 735       inbox,
 736       json,
 737       [
 738         {"Content-Type", "application/activity+json"},
 739         {"signature", signature},
 740         {"digest", digest}
 741       ]
 742     )
 743   end
 744
 745   # TODO:
 746   # This will create a Create activity, which we need internally at the moment.
 747   def fetch_object_from_id(id) do
 748     if object = Object.get_cached_by_ap_id(id) do
 749       {:ok, object}
 750     else
 751       Logger.info("Fetching #{id} via AP")
 752
 753       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 754            nil <- Object.normalize(data),
 755            params <- %{
 756              "type" => "Create",
 757              "to" => data["to"],
 758              "cc" => data["cc"],
 759              "actor" => data["actor"] || data["attributedTo"],
 760              "object" => data
 761            },
 762            :ok <- Transmogrifier.contain_origin(id, params),
 763            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 764         {:ok, Object.normalize(activity.data["object"])}
 765       else
 766         {:error, {:reject, nil}} ->
 767           {:reject, nil}
 768
 769         object = %Object{} ->
 770           {:ok, object}
 771
 772         _e ->
 773           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 774
 775           case OStatus.fetch_activity_from_url(id) do
 776             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 777             e -> e
 778           end
 779       end
 780     end
 781   end
 782
 783   def fetch_and_contain_remote_object_from_id(id) do
 784     Logger.info("Fetching #{id} via AP")
 785
 786     with true <- String.starts_with?(id, "http"),
 787          {:ok, %{body: body, status: code}} when code in 200..299 <-
 788            @httpoison.get(
 789              id,
 790              [{:Accept, "application/activity+json"}]
 791            ),
 792          {:ok, data} <- Jason.decode(body),
 793          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 794       {:ok, data}
 795     else
 796       e ->
 797         {:error, e}
 798     end
 799   end
 800
 801   def is_public?(%Object{data: %{"type" => "Tombstone"}}) do
 802     false
 803   end
 804
 805   def is_public?(activity) do
 806     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 807                                                          (activity.data["cc"] || []))
 808   end
 809
 810   def visible_for_user?(activity, nil) do
 811     is_public?(activity)
 812   end
 813
 814   def visible_for_user?(activity, user) do
 815     x = [user.ap_id | user.following]
 816     y = activity.data["to"] ++ (activity.data["cc"] || [])
 817     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 818   end
 819
 820   # guard
 821   def entire_thread_visible_for_user?(nil, _user), do: false
 822
 823   # child
 824   def entire_thread_visible_for_user?(
 825         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 826         user
 827       )
 828       when is_binary(parent_id) do
 829     parent = Activity.get_in_reply_to_activity(tail)
 830     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 831   end
 832
 833   # root
 834   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 835
 836   # filter out broken threads
 837   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 838     entire_thread_visible_for_user?(activity, user)
 839   end
 840
 841   # do post-processing on a specific activity
 842   def contain_activity(%Activity{} = activity, %User{} = user) do
 843     contain_broken_threads(activity, user)
 844   end
 845
 846   # do post-processing on a timeline
 847   def contain_timeline(timeline, user) do
 848     timeline
 849     |> Enum.filter(fn activity ->
 850       contain_activity(activity, user)
 851     end)
 852   end
 853 end