git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         activity.data["object"]
 107         |> Map.get("tag", [])
 108         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 109         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 110
 111         if activity.data["object"]["attachment"] != [] do
 112           Pleroma.Web.Streamer.stream("public:media", activity)
 113
 114           if activity.local do
 115             Pleroma.Web.Streamer.stream("public:local:media", activity)
 116           end
 117         end
 118       else
 119         if !Enum.member?(activity.data["cc"] || [], public) &&
 120              !Enum.member?(
 121                activity.data["to"],
 122                User.get_by_ap_id(activity.data["actor"]).follower_address
 123              ),
 124            do: Pleroma.Web.Streamer.stream("direct", activity)
 125       end
 126     end
 127   end
 128
 129   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 130     additional = params[:additional] || %{}
 131     # only accept false as false value
 132     local = !(params[:local] == false)
 133     published = params[:published]
 134
 135     with create_data <-
 136            make_create_data(
 137              %{to: to, actor: actor, published: published, context: context, object: object},
 138              additional
 139            ),
 140          {:ok, activity} <- insert(create_data, local),
 141          :ok <- maybe_federate(activity),
 142          {:ok, _actor} <- User.increase_note_count(actor) do
 143       {:ok, activity}
 144     end
 145   end
 146
 147   def accept(%{to: to, actor: actor, object: object} = params) do
 148     # only accept false as false value
 149     local = !(params[:local] == false)
 150
 151     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 152          {:ok, activity} <- insert(data, local),
 153          :ok <- maybe_federate(activity) do
 154       {:ok, activity}
 155     end
 156   end
 157
 158   def reject(%{to: to, actor: actor, object: object} = params) do
 159     # only accept false as false value
 160     local = !(params[:local] == false)
 161
 162     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 163          {:ok, activity} <- insert(data, local),
 164          :ok <- maybe_federate(activity) do
 165       {:ok, activity}
 166     end
 167   end
 168
 169   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 170     # only accept false as false value
 171     local = !(params[:local] == false)
 172
 173     with data <- %{
 174            "to" => to,
 175            "cc" => cc,
 176            "type" => "Update",
 177            "actor" => actor,
 178            "object" => object
 179          },
 180          {:ok, activity} <- insert(data, local),
 181          :ok <- maybe_federate(activity) do
 182       {:ok, activity}
 183     end
 184   end
 185
 186   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 187   def like(
 188         %User{ap_id: ap_id} = user,
 189         %Object{data: %{"id" => _}} = object,
 190         activity_id \\ nil,
 191         local \\ true
 192       ) do
 193     with nil <- get_existing_like(ap_id, object),
 194          like_data <- make_like_data(user, object, activity_id),
 195          {:ok, activity} <- insert(like_data, local),
 196          {:ok, object} <- add_like_to_object(activity, object),
 197          :ok <- maybe_federate(activity) do
 198       {:ok, activity, object}
 199     else
 200       %Activity{} = activity -> {:ok, activity, object}
 201       error -> {:error, error}
 202     end
 203   end
 204
 205   def unlike(
 206         %User{} = actor,
 207         %Object{} = object,
 208         activity_id \\ nil,
 209         local \\ true
 210       ) do
 211     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 212          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 213          {:ok, unlike_activity} <- insert(unlike_data, local),
 214          {:ok, _activity} <- Repo.delete(like_activity),
 215          {:ok, object} <- remove_like_from_object(like_activity, object),
 216          :ok <- maybe_federate(unlike_activity) do
 217       {:ok, unlike_activity, like_activity, object}
 218     else
 219       _e -> {:ok, object}
 220     end
 221   end
 222
 223   def announce(
 224         %User{ap_id: _} = user,
 225         %Object{data: %{"id" => _}} = object,
 226         activity_id \\ nil,
 227         local \\ true
 228       ) do
 229     with true <- is_public?(object),
 230          announce_data <- make_announce_data(user, object, activity_id),
 231          {:ok, activity} <- insert(announce_data, local),
 232          {:ok, object} <- add_announce_to_object(activity, object),
 233          :ok <- maybe_federate(activity) do
 234       {:ok, activity, object}
 235     else
 236       error -> {:error, error}
 237     end
 238   end
 239
 240   def unannounce(
 241         %User{} = actor,
 242         %Object{} = object,
 243         activity_id \\ nil,
 244         local \\ true
 245       ) do
 246     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 247          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 248          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 249          :ok <- maybe_federate(unannounce_activity),
 250          {:ok, _activity} <- Repo.delete(announce_activity),
 251          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 252       {:ok, unannounce_activity, object}
 253     else
 254       _e -> {:ok, object}
 255     end
 256   end
 257
 258   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 259     with data <- make_follow_data(follower, followed, activity_id),
 260          {:ok, activity} <- insert(data, local),
 261          :ok <- maybe_federate(activity) do
 262       {:ok, activity}
 263     end
 264   end
 265
 266   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 267     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 268          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 269          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 270          {:ok, activity} <- insert(unfollow_data, local),
 271          :ok <- maybe_federate(activity) do
 272       {:ok, activity}
 273     end
 274   end
 275
 276   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 277     user = User.get_cached_by_ap_id(actor)
 278
 279     data = %{
 280       "type" => "Delete",
 281       "actor" => actor,
 282       "object" => id,
 283       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 284     }
 285
 286     with {:ok, _} <- Object.delete(object),
 287          {:ok, activity} <- insert(data, local),
 288          :ok <- maybe_federate(activity),
 289          {:ok, _actor} <- User.decrease_note_count(user) do
 290       {:ok, activity}
 291     end
 292   end
 293
 294   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 295     ap_config = Application.get_env(:pleroma, :activitypub)
 296     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 297     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 298
 299     with true <- unfollow_blocked do
 300       follow_activity = fetch_latest_follow(blocker, blocked)
 301
 302       if follow_activity do
 303         unfollow(blocker, blocked, nil, local)
 304       end
 305     end
 306
 307     with true <- outgoing_blocks,
 308          block_data <- make_block_data(blocker, blocked, activity_id),
 309          {:ok, activity} <- insert(block_data, local),
 310          :ok <- maybe_federate(activity) do
 311       {:ok, activity}
 312     else
 313       _e -> {:ok, nil}
 314     end
 315   end
 316
 317   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 318     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 319          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 320          {:ok, activity} <- insert(unblock_data, local),
 321          :ok <- maybe_federate(activity) do
 322       {:ok, activity}
 323     end
 324   end
 325
 326   def fetch_activities_for_context(context, opts \\ %{}) do
 327     public = ["https://www.w3.org/ns/activitystreams#Public"]
 328
 329     recipients =
 330       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 331
 332     query = from(activity in Activity)
 333
 334     query =
 335       query
 336       |> restrict_blocked(opts)
 337       |> restrict_recipients(recipients, opts["user"])
 338
 339     query =
 340       from(
 341         activity in query,
 342         where:
 343           fragment(
 344             "?->>'type' = ? and ?->>'context' = ?",
 345             activity.data,
 346             "Create",
 347             activity.data,
 348             ^context
 349           ),
 350         order_by: [desc: :id]
 351       )
 352
 353     Repo.all(query)
 354   end
 355
 356   def fetch_public_activities(opts \\ %{}) do
 357     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 358
 359     q
 360     |> restrict_unlisted()
 361     |> Repo.all()
 362     |> Enum.reverse()
 363   end
 364
 365   @valid_visibilities ~w[direct unlisted public private]
 366
 367   defp restrict_visibility(query, %{visibility: visibility})
 368        when visibility in @valid_visibilities do
 369     query =
 370       from(
 371         a in query,
 372         where:
 373           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 374       )
 375
 376     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 377
 378     query
 379   end
 380
 381   defp restrict_visibility(_query, %{visibility: visibility})
 382        when visibility not in @valid_visibilities do
 383     Logger.error("Could not restrict visibility to #{visibility}")
 384   end
 385
 386   defp restrict_visibility(query, _visibility), do: query
 387
 388   def fetch_user_activities(user, reading_user, params \\ %{}) do
 389     params =
 390       params
 391       |> Map.put("type", ["Create", "Announce"])
 392       |> Map.put("actor_id", user.ap_id)
 393       |> Map.put("whole_db", true)
 394       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 395
 396     recipients =
 397       if reading_user do
 398         ["https://www.w3.org/ns/activitystreams#Public"] ++
 399           [reading_user.ap_id | reading_user.following]
 400       else
 401         ["https://www.w3.org/ns/activitystreams#Public"]
 402       end
 403
 404     fetch_activities(recipients, params)
 405     |> Enum.reverse()
 406   end
 407
 408   defp restrict_since(query, %{"since_id" => since_id}) do
 409     from(activity in query, where: activity.id > ^since_id)
 410   end
 411
 412   defp restrict_since(query, _), do: query
 413
 414   defp restrict_tag(query, %{"tag" => tag}) do
 415     from(
 416       activity in query,
 417       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 418     )
 419   end
 420
 421   defp restrict_tag(query, _), do: query
 422
 423   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 424     from(
 425       activity in query,
 426       where:
 427         fragment(
 428           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 429           activity.data,
 430           ^recipients_to,
 431           activity.data,
 432           ^recipients_cc
 433         )
 434     )
 435   end
 436
 437   defp restrict_recipients(query, [], _user), do: query
 438
 439   defp restrict_recipients(query, recipients, nil) do
 440     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 441   end
 442
 443   defp restrict_recipients(query, recipients, user) do
 444     from(
 445       activity in query,
 446       where: fragment("? && ?", ^recipients, activity.recipients),
 447       or_where: activity.actor == ^user.ap_id
 448     )
 449   end
 450
 451   defp restrict_limit(query, %{"limit" => limit}) do
 452     from(activity in query, limit: ^limit)
 453   end
 454
 455   defp restrict_limit(query, _), do: query
 456
 457   defp restrict_local(query, %{"local_only" => true}) do
 458     from(activity in query, where: activity.local == true)
 459   end
 460
 461   defp restrict_local(query, _), do: query
 462
 463   defp restrict_max(query, %{"max_id" => max_id}) do
 464     from(activity in query, where: activity.id < ^max_id)
 465   end
 466
 467   defp restrict_max(query, _), do: query
 468
 469   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 470     from(activity in query, where: activity.actor == ^actor_id)
 471   end
 472
 473   defp restrict_actor(query, _), do: query
 474
 475   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 476     restrict_type(query, %{"type" => [type]})
 477   end
 478
 479   defp restrict_type(query, %{"type" => type}) do
 480     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 481   end
 482
 483   defp restrict_type(query, _), do: query
 484
 485   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 486     from(
 487       activity in query,
 488       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 489     )
 490   end
 491
 492   defp restrict_favorited_by(query, _), do: query
 493
 494   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 495     from(
 496       activity in query,
 497       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 498     )
 499   end
 500
 501   defp restrict_media(query, _), do: query
 502
 503   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 504     from(
 505       activity in query,
 506       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 507     )
 508   end
 509
 510   defp restrict_replies(query, _), do: query
 511
 512   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 513     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 514   end
 515
 516   defp restrict_reblogs(query, _), do: query
 517
 518   # Only search through last 100_000 activities by default
 519   defp restrict_recent(query, %{"whole_db" => true}), do: query
 520
 521   defp restrict_recent(query, _) do
 522     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 523
 524     from(activity in query, where: activity.id > ^since)
 525   end
 526
 527   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 528     blocks = info.blocks || []
 529     domain_blocks = info.domain_blocks || []
 530
 531     from(
 532       activity in query,
 533       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 534       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 535       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 536     )
 537   end
 538
 539   defp restrict_blocked(query, _), do: query
 540
 541   defp restrict_unlisted(query) do
 542     from(
 543       activity in query,
 544       where:
 545         fragment(
 546           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 547           activity.data,
 548           ^["https://www.w3.org/ns/activitystreams#Public"]
 549         )
 550     )
 551   end
 552
 553   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 554     from(activity in query, where: activity.id in ^ids)
 555   end
 556
 557   defp restrict_pinned(query, _), do: query
 558
 559   def fetch_activities_query(recipients, opts \\ %{}) do
 560     base_query =
 561       from(
 562         activity in Activity,
 563         limit: 20,
 564         order_by: [fragment("? desc nulls last", activity.id)]
 565       )
 566
 567     base_query
 568     |> restrict_recipients(recipients, opts["user"])
 569     |> restrict_tag(opts)
 570     |> restrict_since(opts)
 571     |> restrict_local(opts)
 572     |> restrict_limit(opts)
 573     |> restrict_max(opts)
 574     |> restrict_actor(opts)
 575     |> restrict_type(opts)
 576     |> restrict_favorited_by(opts)
 577     |> restrict_recent(opts)
 578     |> restrict_blocked(opts)
 579     |> restrict_media(opts)
 580     |> restrict_visibility(opts)
 581     |> restrict_replies(opts)
 582     |> restrict_reblogs(opts)
 583     |> restrict_pinned(opts)
 584   end
 585
 586   def fetch_activities(recipients, opts \\ %{}) do
 587     fetch_activities_query(recipients, opts)
 588     |> Repo.all()
 589     |> Enum.reverse()
 590   end
 591
 592   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 593     fetch_activities_query([], opts)
 594     |> restrict_to_cc(recipients_to, recipients_cc)
 595     |> Repo.all()
 596     |> Enum.reverse()
 597   end
 598
 599   def upload(file, opts \\ []) do
 600     with {:ok, data} <- Upload.store(file, opts) do
 601       obj_data =
 602         if opts[:actor] do
 603           Map.put(data, "actor", opts[:actor])
 604         else
 605           data
 606         end
 607
 608       Repo.insert(%Object{data: obj_data})
 609     end
 610   end
 611
 612   def user_data_from_user_object(data) do
 613     avatar =
 614       data["icon"]["url"] &&
 615         %{
 616           "type" => "Image",
 617           "url" => [%{"href" => data["icon"]["url"]}]
 618         }
 619
 620     banner =
 621       data["image"]["url"] &&
 622         %{
 623           "type" => "Image",
 624           "url" => [%{"href" => data["image"]["url"]}]
 625         }
 626
 627     locked = data["manuallyApprovesFollowers"] || false
 628     data = Transmogrifier.maybe_fix_user_object(data)
 629
 630     user_data = %{
 631       ap_id: data["id"],
 632       info: %{
 633         "ap_enabled" => true,
 634         "source_data" => data,
 635         "banner" => banner,
 636         "locked" => locked
 637       },
 638       avatar: avatar,
 639       name: data["name"],
 640       follower_address: data["followers"],
 641       bio: data["summary"]
 642     }
 643
 644     # nickname can be nil because of virtual actors
 645     user_data =
 646       if data["preferredUsername"] do
 647         Map.put(
 648           user_data,
 649           :nickname,
 650           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 651         )
 652       else
 653         Map.put(user_data, :nickname, nil)
 654       end
 655
 656     {:ok, user_data}
 657   end
 658
 659   def fetch_and_prepare_user_from_ap_id(ap_id) do
 660     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 661       user_data_from_user_object(data)
 662     else
 663       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 664     end
 665   end
 666
 667   def make_user_from_ap_id(ap_id) do
 668     if _user = User.get_by_ap_id(ap_id) do
 669       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 670     else
 671       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 672         User.insert_or_update_user(data)
 673       else
 674         e -> {:error, e}
 675       end
 676     end
 677   end
 678
 679   def make_user_from_nickname(nickname) do
 680     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 681       make_user_from_ap_id(ap_id)
 682     else
 683       _e -> {:error, "No AP id in WebFinger"}
 684     end
 685   end
 686
 687   def should_federate?(inbox, public) do
 688     if public do
 689       true
 690     else
 691       inbox_info = URI.parse(inbox)
 692       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 693     end
 694   end
 695
 696   def publish(actor, activity) do
 697     followers =
 698       if actor.follower_address in activity.recipients do
 699         {:ok, followers} = User.get_followers(actor)
 700         followers |> Enum.filter(&(!&1.local))
 701       else
 702         []
 703       end
 704
 705     public = is_public?(activity)
 706
 707     remote_inboxes =
 708       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 709       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 710       |> Enum.map(fn %{info: %{source_data: data}} ->
 711         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 712       end)
 713       |> Enum.uniq()
 714       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 715
 716     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 717     json = Jason.encode!(data)
 718
 719     Enum.each(remote_inboxes, fn inbox ->
 720       Federator.enqueue(:publish_single_ap, %{
 721         inbox: inbox,
 722         json: json,
 723         actor: actor,
 724         id: activity.data["id"]
 725       })
 726     end)
 727   end
 728
 729   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 730     Logger.info("Federating #{id} to #{inbox}")
 731     host = URI.parse(inbox).host
 732
 733     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 734
 735     signature =
 736       Pleroma.Web.HTTPSignatures.sign(actor, %{
 737         host: host,
 738         "content-length": byte_size(json),
 739         digest: digest
 740       })
 741
 742     @httpoison.post(
 743       inbox,
 744       json,
 745       [
 746         {"Content-Type", "application/activity+json"},
 747         {"signature", signature},
 748         {"digest", digest}
 749       ]
 750     )
 751   end
 752
 753   # TODO:
 754   # This will create a Create activity, which we need internally at the moment.
 755   def fetch_object_from_id(id) do
 756     if object = Object.get_cached_by_ap_id(id) do
 757       {:ok, object}
 758     else
 759       Logger.info("Fetching #{id} via AP")
 760
 761       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 762            nil <- Object.normalize(data),
 763            params <- %{
 764              "type" => "Create",
 765              "to" => data["to"],
 766              "cc" => data["cc"],
 767              "actor" => data["actor"] || data["attributedTo"],
 768              "object" => data
 769            },
 770            :ok <- Transmogrifier.contain_origin(id, params),
 771            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 772         {:ok, Object.normalize(activity.data["object"])}
 773       else
 774         {:error, {:reject, nil}} ->
 775           {:reject, nil}
 776
 777         object = %Object{} ->
 778           {:ok, object}
 779
 780         _e ->
 781           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 782
 783           case OStatus.fetch_activity_from_url(id) do
 784             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 785             e -> e
 786           end
 787       end
 788     end
 789   end
 790
 791   def fetch_and_contain_remote_object_from_id(id) do
 792     Logger.info("Fetching #{id} via AP")
 793
 794     with true <- String.starts_with?(id, "http"),
 795          {:ok, %{body: body, status: code}} when code in 200..299 <-
 796            @httpoison.get(
 797              id,
 798              [{:Accept, "application/activity+json"}]
 799            ),
 800          {:ok, data} <- Jason.decode(body),
 801          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 802       {:ok, data}
 803     else
 804       e ->
 805         {:error, e}
 806     end
 807   end
 808
 809   def is_public?(%Object{data: %{"type" => "Tombstone"}}) do
 810     false
 811   end
 812
 813   def is_public?(activity) do
 814     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 815                                                          (activity.data["cc"] || []))
 816   end
 817
 818   def visible_for_user?(activity, nil) do
 819     is_public?(activity)
 820   end
 821
 822   def visible_for_user?(activity, user) do
 823     x = [user.ap_id | user.following]
 824     y = activity.data["to"] ++ (activity.data["cc"] || [])
 825     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 826   end
 827
 828   # guard
 829   def entire_thread_visible_for_user?(nil, _user), do: false
 830
 831   # child
 832   def entire_thread_visible_for_user?(
 833         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 834         user
 835       )
 836       when is_binary(parent_id) do
 837     parent = Activity.get_in_reply_to_activity(tail)
 838     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 839   end
 840
 841   # root
 842   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 843
 844   # filter out broken threads
 845   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 846     entire_thread_visible_for_user?(activity, user)
 847   end
 848
 849   # do post-processing on a specific activity
 850   def contain_activity(%Activity{} = activity, %User{} = user) do
 851     contain_broken_threads(activity, user)
 852   end
 853
 854   # do post-processing on a timeline
 855   def contain_timeline(timeline, user) do
 856     timeline
 857     |> Enum.filter(fn activity ->
 858       contain_activity(activity, user)
 859     end)
 860   end
 861 end