git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(%{"type" => "Create"} = data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     actor = data["actor"] || []
  43     recipients = (to ++ cc ++ [actor]) |> Enum.uniq()
  44     {recipients, to, cc}
  45   end
  46
  47   defp get_recipients(data) do
  48     to = data["to"] || []
  49     cc = data["cc"] || []
  50     recipients = to ++ cc
  51     {recipients, to, cc}
  52   end
  53
  54   defp check_actor_is_active(actor) do
  55     if not is_nil(actor) do
  56       with user <- User.get_cached_by_ap_id(actor),
  57            false <- user.info.deactivated do
  58         :ok
  59       else
  60         _e -> :reject
  61       end
  62     else
  63       :ok
  64     end
  65   end
  66
  67   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  68     limit = Pleroma.Config.get([:instance, :remote_limit])
  69     String.length(content) <= limit
  70   end
  71
  72   defp check_remote_limit(_), do: true
  73
  74   def insert(map, local \\ true) when is_map(map) do
  75     with nil <- Activity.normalize(map),
  76          map <- lazy_put_activity_defaults(map),
  77          :ok <- check_actor_is_active(map["actor"]),
  78          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  79          {:ok, map} <- MRF.filter(map),
  80          :ok <- insert_full_object(map) do
  81       {recipients, _, _} = get_recipients(map)
  82
  83       {:ok, activity} =
  84         Repo.insert(%Activity{
  85           data: map,
  86           local: local,
  87           actor: map["actor"],
  88           recipients: recipients
  89         })
  90
  91       Notification.create_notifications(activity)
  92       stream_out(activity)
  93       {:ok, activity}
  94     else
  95       %Activity{} = activity -> {:ok, activity}
  96       error -> {:error, error}
  97     end
  98   end
  99
 100   def stream_out(activity) do
 101     public = "https://www.w3.org/ns/activitystreams#Public"
 102
 103     if activity.data["type"] in ["Create", "Announce"] do
 104       Pleroma.Web.Streamer.stream("user", activity)
 105       Pleroma.Web.Streamer.stream("list", activity)
 106
 107       if Enum.member?(activity.data["to"], public) do
 108         Pleroma.Web.Streamer.stream("public", activity)
 109
 110         if activity.local do
 111           Pleroma.Web.Streamer.stream("public:local", activity)
 112         end
 113
 114         activity.data["object"]
 115         |> Map.get("tag", [])
 116         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 117         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 118
 119         if activity.data["object"]["attachment"] != [] do
 120           Pleroma.Web.Streamer.stream("public:media", activity)
 121
 122           if activity.local do
 123             Pleroma.Web.Streamer.stream("public:local:media", activity)
 124           end
 125         end
 126       else
 127         if !Enum.member?(activity.data["cc"] || [], public) &&
 128              !Enum.member?(
 129                activity.data["to"],
 130                User.get_by_ap_id(activity.data["actor"]).follower_address
 131              ),
 132            do: Pleroma.Web.Streamer.stream("direct", activity)
 133       end
 134     end
 135   end
 136
 137   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 138     additional = params[:additional] || %{}
 139     # only accept false as false value
 140     local = !(params[:local] == false)
 141     published = params[:published]
 142
 143     with create_data <-
 144            make_create_data(
 145              %{to: to, actor: actor, published: published, context: context, object: object},
 146              additional
 147            ),
 148          {:ok, activity} <- insert(create_data, local),
 149          :ok <- maybe_federate(activity),
 150          {:ok, _actor} <- User.increase_note_count(actor) do
 151       {:ok, activity}
 152     end
 153   end
 154
 155   def accept(%{to: to, actor: actor, object: object} = params) do
 156     # only accept false as false value
 157     local = !(params[:local] == false)
 158
 159     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 160          {:ok, activity} <- insert(data, local),
 161          :ok <- maybe_federate(activity) do
 162       {:ok, activity}
 163     end
 164   end
 165
 166   def reject(%{to: to, actor: actor, object: object} = params) do
 167     # only accept false as false value
 168     local = !(params[:local] == false)
 169
 170     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 171          {:ok, activity} <- insert(data, local),
 172          :ok <- maybe_federate(activity) do
 173       {:ok, activity}
 174     end
 175   end
 176
 177   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 178     # only accept false as false value
 179     local = !(params[:local] == false)
 180
 181     with data <- %{
 182            "to" => to,
 183            "cc" => cc,
 184            "type" => "Update",
 185            "actor" => actor,
 186            "object" => object
 187          },
 188          {:ok, activity} <- insert(data, local),
 189          :ok <- maybe_federate(activity) do
 190       {:ok, activity}
 191     end
 192   end
 193
 194   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 195   def like(
 196         %User{ap_id: ap_id} = user,
 197         %Object{data: %{"id" => _}} = object,
 198         activity_id \\ nil,
 199         local \\ true
 200       ) do
 201     with nil <- get_existing_like(ap_id, object),
 202          like_data <- make_like_data(user, object, activity_id),
 203          {:ok, activity} <- insert(like_data, local),
 204          {:ok, object} <- add_like_to_object(activity, object),
 205          :ok <- maybe_federate(activity) do
 206       {:ok, activity, object}
 207     else
 208       %Activity{} = activity -> {:ok, activity, object}
 209       error -> {:error, error}
 210     end
 211   end
 212
 213   def unlike(
 214         %User{} = actor,
 215         %Object{} = object,
 216         activity_id \\ nil,
 217         local \\ true
 218       ) do
 219     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 220          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 221          {:ok, unlike_activity} <- insert(unlike_data, local),
 222          {:ok, _activity} <- Repo.delete(like_activity),
 223          {:ok, object} <- remove_like_from_object(like_activity, object),
 224          :ok <- maybe_federate(unlike_activity) do
 225       {:ok, unlike_activity, like_activity, object}
 226     else
 227       _e -> {:ok, object}
 228     end
 229   end
 230
 231   def announce(
 232         %User{ap_id: _} = user,
 233         %Object{data: %{"id" => _}} = object,
 234         activity_id \\ nil,
 235         local \\ true
 236       ) do
 237     with true <- is_public?(object),
 238          announce_data <- make_announce_data(user, object, activity_id),
 239          {:ok, activity} <- insert(announce_data, local),
 240          {:ok, object} <- add_announce_to_object(activity, object),
 241          :ok <- maybe_federate(activity) do
 242       {:ok, activity, object}
 243     else
 244       error -> {:error, error}
 245     end
 246   end
 247
 248   def unannounce(
 249         %User{} = actor,
 250         %Object{} = object,
 251         activity_id \\ nil,
 252         local \\ true
 253       ) do
 254     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 255          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 256          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 257          :ok <- maybe_federate(unannounce_activity),
 258          {:ok, _activity} <- Repo.delete(announce_activity),
 259          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 260       {:ok, unannounce_activity, object}
 261     else
 262       _e -> {:ok, object}
 263     end
 264   end
 265
 266   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 267     with data <- make_follow_data(follower, followed, activity_id),
 268          {:ok, activity} <- insert(data, local),
 269          :ok <- maybe_federate(activity) do
 270       {:ok, activity}
 271     end
 272   end
 273
 274   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 275     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 276          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 277          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 278          {:ok, activity} <- insert(unfollow_data, local),
 279          :ok <- maybe_federate(activity) do
 280       {:ok, activity}
 281     end
 282   end
 283
 284   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 285     user = User.get_cached_by_ap_id(actor)
 286
 287     data = %{
 288       "type" => "Delete",
 289       "actor" => actor,
 290       "object" => id,
 291       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 292     }
 293
 294     with {:ok, _} <- Object.delete(object),
 295          {:ok, activity} <- insert(data, local),
 296          :ok <- maybe_federate(activity),
 297          {:ok, _actor} <- User.decrease_note_count(user) do
 298       {:ok, activity}
 299     end
 300   end
 301
 302   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 303     ap_config = Application.get_env(:pleroma, :activitypub)
 304     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 305     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 306
 307     with true <- unfollow_blocked do
 308       follow_activity = fetch_latest_follow(blocker, blocked)
 309
 310       if follow_activity do
 311         unfollow(blocker, blocked, nil, local)
 312       end
 313     end
 314
 315     with true <- outgoing_blocks,
 316          block_data <- make_block_data(blocker, blocked, activity_id),
 317          {:ok, activity} <- insert(block_data, local),
 318          :ok <- maybe_federate(activity) do
 319       {:ok, activity}
 320     else
 321       _e -> {:ok, nil}
 322     end
 323   end
 324
 325   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 326     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 327          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 328          {:ok, activity} <- insert(unblock_data, local),
 329          :ok <- maybe_federate(activity) do
 330       {:ok, activity}
 331     end
 332   end
 333
 334   def fetch_activities_for_context(context, opts \\ %{}) do
 335     public = ["https://www.w3.org/ns/activitystreams#Public"]
 336
 337     recipients =
 338       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 339
 340     query = from(activity in Activity)
 341
 342     query =
 343       query
 344       |> restrict_blocked(opts)
 345       |> restrict_recipients(recipients, opts["user"])
 346
 347     query =
 348       from(
 349         activity in query,
 350         where:
 351           fragment(
 352             "?->>'type' = ? and ?->>'context' = ?",
 353             activity.data,
 354             "Create",
 355             activity.data,
 356             ^context
 357           ),
 358         order_by: [desc: :id]
 359       )
 360
 361     Repo.all(query)
 362   end
 363
 364   def fetch_public_activities(opts \\ %{}) do
 365     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 366
 367     q
 368     |> restrict_unlisted()
 369     |> Repo.all()
 370     |> Enum.reverse()
 371   end
 372
 373   @valid_visibilities ~w[direct unlisted public private]
 374
 375   defp restrict_visibility(query, %{visibility: visibility})
 376        when visibility in @valid_visibilities do
 377     query =
 378       from(
 379         a in query,
 380         where:
 381           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 382       )
 383
 384     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 385
 386     query
 387   end
 388
 389   defp restrict_visibility(_query, %{visibility: visibility})
 390        when visibility not in @valid_visibilities do
 391     Logger.error("Could not restrict visibility to #{visibility}")
 392   end
 393
 394   defp restrict_visibility(query, _visibility), do: query
 395
 396   def fetch_user_activities(user, reading_user, params \\ %{}) do
 397     params =
 398       params
 399       |> Map.put("type", ["Create", "Announce"])
 400       |> Map.put("actor_id", user.ap_id)
 401       |> Map.put("whole_db", true)
 402       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 403
 404     recipients =
 405       if reading_user do
 406         ["https://www.w3.org/ns/activitystreams#Public"] ++
 407           [reading_user.ap_id | reading_user.following]
 408       else
 409         ["https://www.w3.org/ns/activitystreams#Public"]
 410       end
 411
 412     fetch_activities(recipients, params)
 413     |> Enum.reverse()
 414   end
 415
 416   defp restrict_since(query, %{"since_id" => since_id}) do
 417     from(activity in query, where: activity.id > ^since_id)
 418   end
 419
 420   defp restrict_since(query, _), do: query
 421
 422   defp restrict_tag(query, %{"tag" => tag}) do
 423     from(
 424       activity in query,
 425       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 426     )
 427   end
 428
 429   defp restrict_tag(query, _), do: query
 430
 431   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 432     from(
 433       activity in query,
 434       where:
 435         fragment(
 436           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 437           activity.data,
 438           ^recipients_to,
 439           activity.data,
 440           ^recipients_cc
 441         )
 442     )
 443   end
 444
 445   defp restrict_recipients(query, [], _user), do: query
 446
 447   defp restrict_recipients(query, recipients, nil) do
 448     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 449   end
 450
 451   defp restrict_recipients(query, recipients, user) do
 452     from(
 453       activity in query,
 454       where: fragment("? && ?", ^recipients, activity.recipients),
 455       or_where: activity.actor == ^user.ap_id
 456     )
 457   end
 458
 459   defp restrict_limit(query, %{"limit" => limit}) do
 460     from(activity in query, limit: ^limit)
 461   end
 462
 463   defp restrict_limit(query, _), do: query
 464
 465   defp restrict_local(query, %{"local_only" => true}) do
 466     from(activity in query, where: activity.local == true)
 467   end
 468
 469   defp restrict_local(query, _), do: query
 470
 471   defp restrict_max(query, %{"max_id" => max_id}) do
 472     from(activity in query, where: activity.id < ^max_id)
 473   end
 474
 475   defp restrict_max(query, _), do: query
 476
 477   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 478     from(activity in query, where: activity.actor == ^actor_id)
 479   end
 480
 481   defp restrict_actor(query, _), do: query
 482
 483   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 484     restrict_type(query, %{"type" => [type]})
 485   end
 486
 487   defp restrict_type(query, %{"type" => type}) do
 488     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 489   end
 490
 491   defp restrict_type(query, _), do: query
 492
 493   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 494     from(
 495       activity in query,
 496       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 497     )
 498   end
 499
 500   defp restrict_favorited_by(query, _), do: query
 501
 502   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 503     from(
 504       activity in query,
 505       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 506     )
 507   end
 508
 509   defp restrict_media(query, _), do: query
 510
 511   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 512     from(
 513       activity in query,
 514       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 515     )
 516   end
 517
 518   defp restrict_replies(query, _), do: query
 519
 520   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 521     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 522   end
 523
 524   defp restrict_reblogs(query, _), do: query
 525
 526   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 527     blocks = info.blocks || []
 528     domain_blocks = info.domain_blocks || []
 529
 530     from(
 531       activity in query,
 532       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 533       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 534       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 535     )
 536   end
 537
 538   defp restrict_blocked(query, _), do: query
 539
 540   defp restrict_unlisted(query) do
 541     from(
 542       activity in query,
 543       where:
 544         fragment(
 545           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 546           activity.data,
 547           ^["https://www.w3.org/ns/activitystreams#Public"]
 548         )
 549     )
 550   end
 551
 552   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 553     from(activity in query, where: activity.id in ^ids)
 554   end
 555
 556   defp restrict_pinned(query, _), do: query
 557
 558   def fetch_activities_query(recipients, opts \\ %{}) do
 559     base_query =
 560       from(
 561         activity in Activity,
 562         limit: 20,
 563         order_by: [fragment("? desc nulls last", activity.id)]
 564       )
 565
 566     base_query
 567     |> restrict_recipients(recipients, opts["user"])
 568     |> restrict_tag(opts)
 569     |> restrict_since(opts)
 570     |> restrict_local(opts)
 571     |> restrict_limit(opts)
 572     |> restrict_max(opts)
 573     |> restrict_actor(opts)
 574     |> restrict_type(opts)
 575     |> restrict_favorited_by(opts)
 576     |> restrict_blocked(opts)
 577     |> restrict_media(opts)
 578     |> restrict_visibility(opts)
 579     |> restrict_replies(opts)
 580     |> restrict_reblogs(opts)
 581     |> restrict_pinned(opts)
 582   end
 583
 584   def fetch_activities(recipients, opts \\ %{}) do
 585     fetch_activities_query(recipients, opts)
 586     |> Repo.all()
 587     |> Enum.reverse()
 588   end
 589
 590   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 591     fetch_activities_query([], opts)
 592     |> restrict_to_cc(recipients_to, recipients_cc)
 593     |> Repo.all()
 594     |> Enum.reverse()
 595   end
 596
 597   def upload(file, opts \\ []) do
 598     with {:ok, data} <- Upload.store(file, opts) do
 599       obj_data =
 600         if opts[:actor] do
 601           Map.put(data, "actor", opts[:actor])
 602         else
 603           data
 604         end
 605
 606       Repo.insert(%Object{data: obj_data})
 607     end
 608   end
 609
 610   def user_data_from_user_object(data) do
 611     avatar =
 612       data["icon"]["url"] &&
 613         %{
 614           "type" => "Image",
 615           "url" => [%{"href" => data["icon"]["url"]}]
 616         }
 617
 618     banner =
 619       data["image"]["url"] &&
 620         %{
 621           "type" => "Image",
 622           "url" => [%{"href" => data["image"]["url"]}]
 623         }
 624
 625     locked = data["manuallyApprovesFollowers"] || false
 626     data = Transmogrifier.maybe_fix_user_object(data)
 627
 628     user_data = %{
 629       ap_id: data["id"],
 630       info: %{
 631         "ap_enabled" => true,
 632         "source_data" => data,
 633         "banner" => banner,
 634         "locked" => locked
 635       },
 636       avatar: avatar,
 637       name: data["name"],
 638       follower_address: data["followers"],
 639       bio: data["summary"]
 640     }
 641
 642     # nickname can be nil because of virtual actors
 643     user_data =
 644       if data["preferredUsername"] do
 645         Map.put(
 646           user_data,
 647           :nickname,
 648           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 649         )
 650       else
 651         Map.put(user_data, :nickname, nil)
 652       end
 653
 654     {:ok, user_data}
 655   end
 656
 657   def fetch_and_prepare_user_from_ap_id(ap_id) do
 658     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 659       user_data_from_user_object(data)
 660     else
 661       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 662     end
 663   end
 664
 665   def make_user_from_ap_id(ap_id) do
 666     if _user = User.get_by_ap_id(ap_id) do
 667       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 668     else
 669       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 670         User.insert_or_update_user(data)
 671       else
 672         e -> {:error, e}
 673       end
 674     end
 675   end
 676
 677   def make_user_from_nickname(nickname) do
 678     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 679       make_user_from_ap_id(ap_id)
 680     else
 681       _e -> {:error, "No AP id in WebFinger"}
 682     end
 683   end
 684
 685   def should_federate?(inbox, public) do
 686     if public do
 687       true
 688     else
 689       inbox_info = URI.parse(inbox)
 690       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 691     end
 692   end
 693
 694   def publish(actor, activity) do
 695     followers =
 696       if actor.follower_address in activity.recipients do
 697         {:ok, followers} = User.get_followers(actor)
 698         followers |> Enum.filter(&(!&1.local))
 699       else
 700         []
 701       end
 702
 703     public = is_public?(activity)
 704
 705     remote_inboxes =
 706       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 707       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 708       |> Enum.map(fn %{info: %{source_data: data}} ->
 709         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 710       end)
 711       |> Enum.uniq()
 712       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 713
 714     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 715     json = Jason.encode!(data)
 716
 717     Enum.each(remote_inboxes, fn inbox ->
 718       Federator.enqueue(:publish_single_ap, %{
 719         inbox: inbox,
 720         json: json,
 721         actor: actor,
 722         id: activity.data["id"]
 723       })
 724     end)
 725   end
 726
 727   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 728     Logger.info("Federating #{id} to #{inbox}")
 729     host = URI.parse(inbox).host
 730
 731     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 732
 733     signature =
 734       Pleroma.Web.HTTPSignatures.sign(actor, %{
 735         host: host,
 736         "content-length": byte_size(json),
 737         digest: digest
 738       })
 739
 740     @httpoison.post(
 741       inbox,
 742       json,
 743       [
 744         {"Content-Type", "application/activity+json"},
 745         {"signature", signature},
 746         {"digest", digest}
 747       ]
 748     )
 749   end
 750
 751   # TODO:
 752   # This will create a Create activity, which we need internally at the moment.
 753   def fetch_object_from_id(id) do
 754     if object = Object.get_cached_by_ap_id(id) do
 755       {:ok, object}
 756     else
 757       Logger.info("Fetching #{id} via AP")
 758
 759       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 760            nil <- Object.normalize(data),
 761            params <- %{
 762              "type" => "Create",
 763              "to" => data["to"],
 764              "cc" => data["cc"],
 765              "actor" => data["actor"] || data["attributedTo"],
 766              "object" => data
 767            },
 768            :ok <- Transmogrifier.contain_origin(id, params),
 769            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 770         {:ok, Object.normalize(activity.data["object"])}
 771       else
 772         {:error, {:reject, nil}} ->
 773           {:reject, nil}
 774
 775         object = %Object{} ->
 776           {:ok, object}
 777
 778         _e ->
 779           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 780
 781           case OStatus.fetch_activity_from_url(id) do
 782             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 783             e -> e
 784           end
 785       end
 786     end
 787   end
 788
 789   def fetch_and_contain_remote_object_from_id(id) do
 790     Logger.info("Fetching #{id} via AP")
 791
 792     with true <- String.starts_with?(id, "http"),
 793          {:ok, %{body: body, status: code}} when code in 200..299 <-
 794            @httpoison.get(
 795              id,
 796              [{:Accept, "application/activity+json"}]
 797            ),
 798          {:ok, data} <- Jason.decode(body),
 799          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 800       {:ok, data}
 801     else
 802       e ->
 803         {:error, e}
 804     end
 805   end
 806
 807   def is_public?(%Object{data: %{"type" => "Tombstone"}}) do
 808     false
 809   end
 810
 811   def is_public?(activity) do
 812     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 813                                                          (activity.data["cc"] || []))
 814   end
 815
 816   def visible_for_user?(activity, nil) do
 817     is_public?(activity)
 818   end
 819
 820   def visible_for_user?(activity, user) do
 821     x = [user.ap_id | user.following]
 822     y = activity.data["to"] ++ (activity.data["cc"] || [])
 823     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 824   end
 825
 826   # guard
 827   def entire_thread_visible_for_user?(nil, _user), do: false
 828
 829   # child
 830   def entire_thread_visible_for_user?(
 831         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 832         user
 833       )
 834       when is_binary(parent_id) do
 835     parent = Activity.get_in_reply_to_activity(tail)
 836     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 837   end
 838
 839   # root
 840   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 841
 842   # filter out broken threads
 843   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 844     entire_thread_visible_for_user?(activity, user)
 845   end
 846
 847   # do post-processing on a specific activity
 848   def contain_activity(%Activity{} = activity, %User{} = user) do
 849     contain_broken_threads(activity, user)
 850   end
 851
 852   # do post-processing on a timeline
 853   def contain_timeline(timeline, user) do
 854     timeline
 855     |> Enum.filter(fn activity ->
 856       contain_activity(activity, user)
 857     end)
 858   end
 859 end