git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   def get_recipients(data) do
  14     (data["to"] || []) ++ (data["cc"] || [])
  15   end
  16
  17   def insert(map, local \\ true) when is_map(map) do
  18     with nil <- Activity.get_by_ap_id(map["id"]),
  19          map <- lazy_put_activity_defaults(map),
  20          :ok <- insert_full_object(map) do
  21       {:ok, activity} = Repo.insert(%Activity{data: map, local: local, actor: map["actor"], recipients: get_recipients(map)})
  22       Notification.create_notifications(activity)
  23       stream_out(activity)
  24       {:ok, activity}
  25     else
  26       %Activity{} = activity -> {:ok, activity}
  27       error -> {:error, error}
  28     end
  29   end
  30
  31   def stream_out(activity) do
  32     if activity.data["type"] in ["Create", "Announce"] do
  33       Pleroma.Web.Streamer.stream("user", activity)
  34       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  35         Pleroma.Web.Streamer.stream("public", activity)
  36         if activity.local do
  37           Pleroma.Web.Streamer.stream("public:local", activity)
  38         end
  39       end
  40     end
  41   end
  42
  43   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  44     additional = params[:additional] || %{}
  45     local = !(params[:local] == false) # only accept false as false value
  46     published = params[:published]
  47
  48     with create_data <- make_create_data(%{to: to, actor: actor, published: published, context: context, object: object}, additional),
  49          {:ok, activity} <- insert(create_data, local),
  50          :ok <- maybe_federate(activity) do
  51       {:ok, activity}
  52     end
  53   end
  54
  55   def accept(%{to: to, actor: actor, object: object} = params) do
  56     local = !(params[:local] == false) # only accept false as false value
  57
  58     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  59          {:ok, activity} <- insert(data, local),
  60          :ok <- maybe_federate(activity) do
  61       {:ok, activity}
  62     end
  63   end
  64
  65   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  66     local = !(params[:local] == false) # only accept false as false value
  67
  68     with data <- %{"to" => to, "cc" => cc, "type" => "Update", "actor" => actor, "object" => object},
  69          {:ok, activity} <- insert(data, local),
  70          :ok <- maybe_federate(activity) do
  71       {:ok, activity}
  72     end
  73   end
  74
  75   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
  76   def like(%User{ap_id: ap_id} = user, %Object{data: %{"id" => _}} = object, activity_id \\ nil, local \\ true) do
  77     with nil <- get_existing_like(ap_id, object),
  78          like_data <- make_like_data(user, object, activity_id),
  79          {:ok, activity} <- insert(like_data, local),
  80          {:ok, object} <- add_like_to_object(activity, object),
  81          :ok <- maybe_federate(activity) do
  82       {:ok, activity, object}
  83     else
  84       %Activity{} = activity -> {:ok, activity, object}
  85       error -> {:error, error}
  86     end
  87   end
  88
  89   def unlike(%User{} = actor, %Object{} = object) do
  90     with %Activity{} = activity <- get_existing_like(actor.ap_id, object),
  91          {:ok, _activity} <- Repo.delete(activity),
  92          {:ok, object} <- remove_like_from_object(activity, object) do
  93       {:ok, object}
  94       else _e -> {:ok, object}
  95     end
  96   end
  97
  98   def announce(%User{ap_id: _} = user, %Object{data: %{"id" => _}} = object, activity_id \\ nil, local \\ true) do
  99     with true <- is_public?(object),
 100          announce_data <- make_announce_data(user, object, activity_id),
 101          {:ok, activity} <- insert(announce_data, local),
 102          {:ok, object} <- add_announce_to_object(activity, object),
 103          :ok <- maybe_federate(activity) do
 104       {:ok, activity, object}
 105     else
 106       error -> {:error, error}
 107     end
 108   end
 109
 110   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 111     with data <- make_follow_data(follower, followed, activity_id),
 112          {:ok, activity} <- insert(data, local),
 113          :ok <- maybe_federate(activity) do
 114       {:ok, activity}
 115     end
 116   end
 117
 118   def unfollow(follower, followed, local \\ true) do
 119     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 120          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
 121          {:ok, activity} <- insert(unfollow_data, local),
 122          :ok, maybe_federate(activity) do
 123       {:ok, activity}
 124     end
 125   end
 126
 127   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 128     user = User.get_cached_by_ap_id(actor)
 129     data = %{
 130       "type" => "Delete",
 131       "actor" => actor,
 132       "object" => id,
 133       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 134     }
 135     with Repo.delete(object),
 136          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 137          {:ok, activity} <- insert(data, local),
 138          :ok <- maybe_federate(activity) do
 139       {:ok, activity}
 140     end
 141   end
 142
 143   def fetch_activities_for_context(context, opts \\ %{}) do
 144     public = ["https://www.w3.org/ns/activitystreams#Public"]
 145     recipients = if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 146
 147     query = from activity in Activity
 148     query = query
 149       |> restrict_blocked(opts)
 150       |> restrict_recipients(recipients, opts["user"])
 151
 152    query = from activity in query,
 153       where: fragment("?->>'type' = ? and ?->>'context' = ?", activity.data, "Create", activity.data, ^context),
 154       order_by: [desc: :id]
 155     Repo.all(query)
 156   end
 157
 158   # TODO: Make this work properly with unlisted.
 159   def fetch_public_activities(opts \\ %{}) do
 160     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 161     q
 162     |> Repo.all
 163     |> Enum.reverse
 164   end
 165
 166   defp restrict_since(query, %{"since_id" => since_id}) do
 167     from activity in query, where: activity.id > ^since_id
 168   end
 169   defp restrict_since(query, _), do: query
 170
 171   defp restrict_tag(query, %{"tag" => tag}) do
 172     from activity in query,
 173       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 174   end
 175   defp restrict_tag(query, _), do: query
 176
 177   defp restrict_recipients(query, [], user), do: query
 178   defp restrict_recipients(query, recipients, nil) do
 179     from activity in query,
 180      where: fragment("? && ?", ^recipients, activity.recipients)
 181   end
 182   defp restrict_recipients(query, recipients, user) do
 183     from activity in query,
 184       where: fragment("? && ?", ^recipients, activity.recipients),
 185       or_where: activity.actor == ^user.ap_id
 186   end
 187
 188   defp restrict_limit(query, %{"limit" => limit}) do
 189     from activity in query,
 190       limit: ^limit
 191   end
 192   defp restrict_limit(query, _), do: query
 193
 194   defp restrict_local(query, %{"local_only" => true}) do
 195     from activity in query, where: activity.local == true
 196   end
 197   defp restrict_local(query, _), do: query
 198
 199   defp restrict_max(query, %{"max_id" => max_id}) do
 200     from activity in query, where: activity.id < ^max_id
 201   end
 202   defp restrict_max(query, _), do: query
 203
 204   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 205     from activity in query,
 206       where: activity.actor == ^actor_id
 207   end
 208   defp restrict_actor(query, _), do: query
 209
 210   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 211     restrict_type(query, %{"type" => [type]})
 212   end
 213   defp restrict_type(query, %{"type" => type}) do
 214     from activity in query,
 215       where: fragment("?->>'type' = ANY(?)", activity.data, ^type)
 216   end
 217   defp restrict_type(query, _), do: query
 218
 219   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 220     from activity in query,
 221       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 222   end
 223   defp restrict_favorited_by(query, _), do: query
 224
 225   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 226     from activity in query,
 227       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 228   end
 229   defp restrict_media(query, _), do: query
 230
 231   # Only search through last 100_000 activities by default
 232   defp restrict_recent(query, %{"whole_db" => true}), do: query
 233   defp restrict_recent(query, _) do
 234     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 235
 236     from activity in query,
 237       where: activity.id > ^since
 238   end
 239
 240   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 241     blocks = info["blocks"] || []
 242     from activity in query,
 243       where: fragment("not (? = ANY(?))", activity.actor, ^blocks)
 244   end
 245   defp restrict_blocked(query, _), do: query
 246
 247   def fetch_activities_query(recipients, opts \\ %{}) do
 248     base_query = from activity in Activity,
 249       limit: 20,
 250       order_by: [fragment("? desc nulls last", activity.id)]
 251
 252     base_query
 253     |> restrict_recipients(recipients, opts["user"])
 254     |> restrict_tag(opts)
 255     |> restrict_since(opts)
 256     |> restrict_local(opts)
 257     |> restrict_limit(opts)
 258     |> restrict_max(opts)
 259     |> restrict_actor(opts)
 260     |> restrict_type(opts)
 261     |> restrict_favorited_by(opts)
 262     |> restrict_recent(opts)
 263     |> restrict_blocked(opts)
 264     |> restrict_media(opts)
 265   end
 266
 267   def fetch_activities(recipients, opts \\ %{}) do
 268     fetch_activities_query(recipients, opts)
 269     |> Repo.all
 270     |> Enum.reverse
 271   end
 272
 273   def upload(file) do
 274     data = Upload.store(file)
 275     Repo.insert(%Object{data: data})
 276   end
 277
 278   def user_data_from_user_object(data) do
 279     avatar = data["icon"]["url"] && %{
 280       "type" => "Image",
 281       "url" => [%{"href" => data["icon"]["url"]}]
 282     }
 283
 284     banner = data["image"]["url"] && %{
 285       "type" => "Image",
 286       "url" => [%{"href" => data["image"]["url"]}]
 287     }
 288
 289     user_data = %{
 290       ap_id: data["id"],
 291       info: %{
 292         "ap_enabled" => true,
 293         "source_data" => data,
 294         "banner" => banner
 295       },
 296       avatar: avatar,
 297       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 298       name: data["name"],
 299       follower_address: data["followers"],
 300       bio: data["summary"]
 301     }
 302
 303     {:ok, user_data}
 304   end
 305
 306   def fetch_and_prepare_user_from_ap_id(ap_id) do
 307     with {:ok, %{status_code: 200, body: body}} <- @httpoison.get(ap_id, ["Accept": "application/activity+json"]),
 308     {:ok, data} <- Jason.decode(body) do
 309       user_data_from_user_object(data)
 310     else
 311       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 312     end
 313   end
 314
 315   def make_user_from_ap_id(ap_id) do
 316     if user = User.get_by_ap_id(ap_id) do
 317       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 318     else
 319       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 320         User.insert_or_update_user(data)
 321       else
 322         e -> {:error, e}
 323       end
 324     end
 325   end
 326
 327   def make_user_from_nickname(nickname) do
 328     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 329       make_user_from_ap_id(ap_id)
 330     else
 331       _e -> {:error, "No AP id in WebFinger"}
 332     end
 333   end
 334
 335   def publish(actor, activity) do
 336     followers = if actor.follower_address in activity.recipients do
 337       {:ok, followers} = User.get_followers(actor)
 338       followers |> Enum.filter(&(!&1.local))
 339     else
 340       []
 341     end
 342
 343     remote_inboxes = (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 344     |> Enum.filter(fn (user) -> User.ap_enabled?(user) end)
 345     |> Enum.map(fn (%{info: %{"source_data" => data}}) ->
 346       (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 347     end)
 348     |> Enum.uniq
 349
 350     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 351     json = Jason.encode!(data)
 352     Enum.each remote_inboxes, fn(inbox) ->
 353       Federator.enqueue(:publish_single_ap, %{inbox: inbox, json: json, actor: actor, id: activity.data["id"]})
 354     end
 355   end
 356
 357   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 358     Logger.info("Federating #{id} to #{inbox}")
 359     host = URI.parse(inbox).host
 360     signature = Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 361     @httpoison.post(inbox, json, [{"Content-Type", "application/activity+json"}, {"signature", signature}], hackney: [pool: :default])
 362   end
 363
 364   # TODO:
 365   # This will create a Create activity, which we need internally at the moment.
 366   def fetch_object_from_id(id) do
 367     if object = Object.get_cached_by_ap_id(id) do
 368       {:ok, object}
 369     else
 370       Logger.info("Fetching #{id} via AP")
 371       with true <- String.starts_with?(id, "http"),
 372            {:ok, %{body: body, status_code: code}} when code in 200..299 <- @httpoison.get(id, [Accept: "application/activity+json"], follow_redirect: true, timeout: 10000, recv_timeout: 20000),
 373            {:ok, data} <- Jason.decode(body),
 374            nil <- Object.get_by_ap_id(data["id"]),
 375            params <- %{"type" => "Create", "to" => data["to"], "cc" => data["cc"], "actor" => data["attributedTo"], "object" => data},
 376            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 377         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 378       else
 379         object = %Object{} -> {:ok, object}
 380         e ->
 381           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 382           case OStatus.fetch_activity_from_url(id) do
 383             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 384             e -> e
 385           end
 386       end
 387     end
 388   end
 389
 390   def is_public?(activity) do
 391     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++ (activity.data["cc"] || []))
 392   end
 393
 394   def visible_for_user?(activity, nil) do
 395     is_public?(activity)
 396   end
 397   def visible_for_user?(activity, user) do
 398     x = [user.ap_id | user.following]
 399     y = (activity.data["to"] ++ (activity.data["cc"] || []))
 400     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 401   end
 402 end