git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce", "Delete"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         if activity.data["type"] in ["Create"] do
 107           activity.data["object"]
 108           |> Map.get("tag", [])
 109           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 110           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 111
 112           if activity.data["object"]["attachment"] != [] do
 113             Pleroma.Web.Streamer.stream("public:media", activity)
 114
 115             if activity.local do
 116               Pleroma.Web.Streamer.stream("public:local:media", activity)
 117             end
 118           end
 119         end
 120       else
 121         if !Enum.member?(activity.data["cc"] || [], public) &&
 122              !Enum.member?(
 123                activity.data["to"],
 124                User.get_by_ap_id(activity.data["actor"]).follower_address
 125              ),
 126            do: Pleroma.Web.Streamer.stream("direct", activity)
 127       end
 128     end
 129   end
 130
 131   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 132     additional = params[:additional] || %{}
 133     # only accept false as false value
 134     local = !(params[:local] == false)
 135     published = params[:published]
 136
 137     with create_data <-
 138            make_create_data(
 139              %{to: to, actor: actor, published: published, context: context, object: object},
 140              additional
 141            ),
 142          {:ok, activity} <- insert(create_data, local),
 143          :ok <- maybe_federate(activity),
 144          {:ok, _actor} <- User.increase_note_count(actor) do
 145       {:ok, activity}
 146     end
 147   end
 148
 149   def accept(%{to: to, actor: actor, object: object} = params) do
 150     # only accept false as false value
 151     local = !(params[:local] == false)
 152
 153     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 154          {:ok, activity} <- insert(data, local),
 155          :ok <- maybe_federate(activity) do
 156       {:ok, activity}
 157     end
 158   end
 159
 160   def reject(%{to: to, actor: actor, object: object} = params) do
 161     # only accept false as false value
 162     local = !(params[:local] == false)
 163
 164     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 165          {:ok, activity} <- insert(data, local),
 166          :ok <- maybe_federate(activity) do
 167       {:ok, activity}
 168     end
 169   end
 170
 171   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 172     # only accept false as false value
 173     local = !(params[:local] == false)
 174
 175     with data <- %{
 176            "to" => to,
 177            "cc" => cc,
 178            "type" => "Update",
 179            "actor" => actor,
 180            "object" => object
 181          },
 182          {:ok, activity} <- insert(data, local),
 183          :ok <- maybe_federate(activity) do
 184       {:ok, activity}
 185     end
 186   end
 187
 188   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 189   def like(
 190         %User{ap_id: ap_id} = user,
 191         %Object{data: %{"id" => _}} = object,
 192         activity_id \\ nil,
 193         local \\ true
 194       ) do
 195     with nil <- get_existing_like(ap_id, object),
 196          like_data <- make_like_data(user, object, activity_id),
 197          {:ok, activity} <- insert(like_data, local),
 198          {:ok, object} <- add_like_to_object(activity, object),
 199          :ok <- maybe_federate(activity) do
 200       {:ok, activity, object}
 201     else
 202       %Activity{} = activity -> {:ok, activity, object}
 203       error -> {:error, error}
 204     end
 205   end
 206
 207   def unlike(
 208         %User{} = actor,
 209         %Object{} = object,
 210         activity_id \\ nil,
 211         local \\ true
 212       ) do
 213     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 214          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 215          {:ok, unlike_activity} <- insert(unlike_data, local),
 216          {:ok, _activity} <- Repo.delete(like_activity),
 217          {:ok, object} <- remove_like_from_object(like_activity, object),
 218          :ok <- maybe_federate(unlike_activity) do
 219       {:ok, unlike_activity, like_activity, object}
 220     else
 221       _e -> {:ok, object}
 222     end
 223   end
 224
 225   def announce(
 226         %User{ap_id: _} = user,
 227         %Object{data: %{"id" => _}} = object,
 228         activity_id \\ nil,
 229         local \\ true,
 230         public \\ true
 231       ) do
 232     with true <- is_public?(object),
 233          announce_data <- make_announce_data(user, object, activity_id, public),
 234          {:ok, activity} <- insert(announce_data, local),
 235          {:ok, object} <- add_announce_to_object(activity, object),
 236          :ok <- maybe_federate(activity) do
 237       {:ok, activity, object}
 238     else
 239       error -> {:error, error}
 240     end
 241   end
 242
 243   def unannounce(
 244         %User{} = actor,
 245         %Object{} = object,
 246         activity_id \\ nil,
 247         local \\ true
 248       ) do
 249     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 250          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 251          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 252          :ok <- maybe_federate(unannounce_activity),
 253          {:ok, _activity} <- Repo.delete(announce_activity),
 254          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 255       {:ok, unannounce_activity, object}
 256     else
 257       _e -> {:ok, object}
 258     end
 259   end
 260
 261   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 262     with data <- make_follow_data(follower, followed, activity_id),
 263          {:ok, activity} <- insert(data, local),
 264          :ok <- maybe_federate(activity) do
 265       {:ok, activity}
 266     end
 267   end
 268
 269   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 270     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 271          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 272          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 273          {:ok, activity} <- insert(unfollow_data, local),
 274          :ok <- maybe_federate(activity) do
 275       {:ok, activity}
 276     end
 277   end
 278
 279   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 280     user = User.get_cached_by_ap_id(actor)
 281
 282     data = %{
 283       "type" => "Delete",
 284       "actor" => actor,
 285       "object" => id,
 286       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 287     }
 288
 289     with {:ok, _} <- Object.delete(object),
 290          {:ok, activity} <- insert(data, local),
 291          :ok <- maybe_federate(activity),
 292          {:ok, _actor} <- User.decrease_note_count(user) do
 293       {:ok, activity}
 294     end
 295   end
 296
 297   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 298     ap_config = Application.get_env(:pleroma, :activitypub)
 299     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 300     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 301
 302     with true <- unfollow_blocked do
 303       follow_activity = fetch_latest_follow(blocker, blocked)
 304
 305       if follow_activity do
 306         unfollow(blocker, blocked, nil, local)
 307       end
 308     end
 309
 310     with true <- outgoing_blocks,
 311          block_data <- make_block_data(blocker, blocked, activity_id),
 312          {:ok, activity} <- insert(block_data, local),
 313          :ok <- maybe_federate(activity) do
 314       {:ok, activity}
 315     else
 316       _e -> {:ok, nil}
 317     end
 318   end
 319
 320   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 321     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 322          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 323          {:ok, activity} <- insert(unblock_data, local),
 324          :ok <- maybe_federate(activity) do
 325       {:ok, activity}
 326     end
 327   end
 328
 329   def fetch_activities_for_context(context, opts \\ %{}) do
 330     public = ["https://www.w3.org/ns/activitystreams#Public"]
 331
 332     recipients =
 333       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 334
 335     query = from(activity in Activity)
 336
 337     query =
 338       query
 339       |> restrict_blocked(opts)
 340       |> restrict_recipients(recipients, opts["user"])
 341
 342     query =
 343       from(
 344         activity in query,
 345         where:
 346           fragment(
 347             "?->>'type' = ? and ?->>'context' = ?",
 348             activity.data,
 349             "Create",
 350             activity.data,
 351             ^context
 352           ),
 353         order_by: [desc: :id]
 354       )
 355
 356     Repo.all(query)
 357   end
 358
 359   def fetch_public_activities(opts \\ %{}) do
 360     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 361
 362     q
 363     |> restrict_unlisted()
 364     |> Repo.all()
 365     |> Enum.reverse()
 366   end
 367
 368   @valid_visibilities ~w[direct unlisted public private]
 369
 370   defp restrict_visibility(query, %{visibility: visibility})
 371        when visibility in @valid_visibilities do
 372     query =
 373       from(
 374         a in query,
 375         where:
 376           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 377       )
 378
 379     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 380
 381     query
 382   end
 383
 384   defp restrict_visibility(_query, %{visibility: visibility})
 385        when visibility not in @valid_visibilities do
 386     Logger.error("Could not restrict visibility to #{visibility}")
 387   end
 388
 389   defp restrict_visibility(query, _visibility), do: query
 390
 391   def fetch_user_activities(user, reading_user, params \\ %{}) do
 392     params =
 393       params
 394       |> Map.put("type", ["Create", "Announce"])
 395       |> Map.put("actor_id", user.ap_id)
 396       |> Map.put("whole_db", true)
 397       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 398
 399     recipients =
 400       if reading_user do
 401         ["https://www.w3.org/ns/activitystreams#Public"] ++
 402           [reading_user.ap_id | reading_user.following]
 403       else
 404         ["https://www.w3.org/ns/activitystreams#Public"]
 405       end
 406
 407     fetch_activities(recipients, params)
 408     |> Enum.reverse()
 409   end
 410
 411   defp restrict_since(query, %{"since_id" => since_id}) do
 412     from(activity in query, where: activity.id > ^since_id)
 413   end
 414
 415   defp restrict_since(query, _), do: query
 416
 417   defp restrict_tag(query, %{"tag" => tag}) do
 418     from(
 419       activity in query,
 420       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 421     )
 422   end
 423
 424   defp restrict_tag(query, _), do: query
 425
 426   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 427     from(
 428       activity in query,
 429       where:
 430         fragment(
 431           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 432           activity.data,
 433           ^recipients_to,
 434           activity.data,
 435           ^recipients_cc
 436         )
 437     )
 438   end
 439
 440   defp restrict_recipients(query, [], _user), do: query
 441
 442   defp restrict_recipients(query, recipients, nil) do
 443     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 444   end
 445
 446   defp restrict_recipients(query, recipients, user) do
 447     from(
 448       activity in query,
 449       where: fragment("? && ?", ^recipients, activity.recipients),
 450       or_where: activity.actor == ^user.ap_id
 451     )
 452   end
 453
 454   defp restrict_limit(query, %{"limit" => limit}) do
 455     from(activity in query, limit: ^limit)
 456   end
 457
 458   defp restrict_limit(query, _), do: query
 459
 460   defp restrict_local(query, %{"local_only" => true}) do
 461     from(activity in query, where: activity.local == true)
 462   end
 463
 464   defp restrict_local(query, _), do: query
 465
 466   defp restrict_max(query, %{"max_id" => max_id}) do
 467     from(activity in query, where: activity.id < ^max_id)
 468   end
 469
 470   defp restrict_max(query, _), do: query
 471
 472   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 473     from(activity in query, where: activity.actor == ^actor_id)
 474   end
 475
 476   defp restrict_actor(query, _), do: query
 477
 478   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 479     restrict_type(query, %{"type" => [type]})
 480   end
 481
 482   defp restrict_type(query, %{"type" => type}) do
 483     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 484   end
 485
 486   defp restrict_type(query, _), do: query
 487
 488   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 489     from(
 490       activity in query,
 491       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 492     )
 493   end
 494
 495   defp restrict_favorited_by(query, _), do: query
 496
 497   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 498     from(
 499       activity in query,
 500       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 501     )
 502   end
 503
 504   defp restrict_media(query, _), do: query
 505
 506   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 507     from(
 508       activity in query,
 509       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 510     )
 511   end
 512
 513   defp restrict_replies(query, _), do: query
 514
 515   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 516     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 517   end
 518
 519   defp restrict_reblogs(query, _), do: query
 520
 521   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 522     blocks = info.blocks || []
 523     domain_blocks = info.domain_blocks || []
 524
 525     from(
 526       activity in query,
 527       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 528       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 529       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 530     )
 531   end
 532
 533   defp restrict_blocked(query, _), do: query
 534
 535   defp restrict_unlisted(query) do
 536     from(
 537       activity in query,
 538       where:
 539         fragment(
 540           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 541           activity.data,
 542           ^["https://www.w3.org/ns/activitystreams#Public"]
 543         )
 544     )
 545   end
 546
 547   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 548     from(activity in query, where: activity.id in ^ids)
 549   end
 550
 551   defp restrict_pinned(query, _), do: query
 552
 553   def fetch_activities_query(recipients, opts \\ %{}) do
 554     base_query =
 555       from(
 556         activity in Activity,
 557         limit: 20,
 558         order_by: [fragment("? desc nulls last", activity.id)]
 559       )
 560
 561     base_query
 562     |> restrict_recipients(recipients, opts["user"])
 563     |> restrict_tag(opts)
 564     |> restrict_since(opts)
 565     |> restrict_local(opts)
 566     |> restrict_limit(opts)
 567     |> restrict_max(opts)
 568     |> restrict_actor(opts)
 569     |> restrict_type(opts)
 570     |> restrict_favorited_by(opts)
 571     |> restrict_blocked(opts)
 572     |> restrict_media(opts)
 573     |> restrict_visibility(opts)
 574     |> restrict_replies(opts)
 575     |> restrict_reblogs(opts)
 576     |> restrict_pinned(opts)
 577   end
 578
 579   def fetch_activities(recipients, opts \\ %{}) do
 580     fetch_activities_query(recipients, opts)
 581     |> Repo.all()
 582     |> Enum.reverse()
 583   end
 584
 585   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 586     fetch_activities_query([], opts)
 587     |> restrict_to_cc(recipients_to, recipients_cc)
 588     |> Repo.all()
 589     |> Enum.reverse()
 590   end
 591
 592   def upload(file, opts \\ []) do
 593     with {:ok, data} <- Upload.store(file, opts) do
 594       obj_data =
 595         if opts[:actor] do
 596           Map.put(data, "actor", opts[:actor])
 597         else
 598           data
 599         end
 600
 601       Repo.insert(%Object{data: obj_data})
 602     end
 603   end
 604
 605   def user_data_from_user_object(data) do
 606     avatar =
 607       data["icon"]["url"] &&
 608         %{
 609           "type" => "Image",
 610           "url" => [%{"href" => data["icon"]["url"]}]
 611         }
 612
 613     banner =
 614       data["image"]["url"] &&
 615         %{
 616           "type" => "Image",
 617           "url" => [%{"href" => data["image"]["url"]}]
 618         }
 619
 620     locked = data["manuallyApprovesFollowers"] || false
 621     data = Transmogrifier.maybe_fix_user_object(data)
 622
 623     user_data = %{
 624       ap_id: data["id"],
 625       info: %{
 626         "ap_enabled" => true,
 627         "source_data" => data,
 628         "banner" => banner,
 629         "locked" => locked
 630       },
 631       avatar: avatar,
 632       name: data["name"],
 633       follower_address: data["followers"],
 634       bio: data["summary"]
 635     }
 636
 637     # nickname can be nil because of virtual actors
 638     user_data =
 639       if data["preferredUsername"] do
 640         Map.put(
 641           user_data,
 642           :nickname,
 643           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 644         )
 645       else
 646         Map.put(user_data, :nickname, nil)
 647       end
 648
 649     {:ok, user_data}
 650   end
 651
 652   def fetch_and_prepare_user_from_ap_id(ap_id) do
 653     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 654       user_data_from_user_object(data)
 655     else
 656       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 657     end
 658   end
 659
 660   def make_user_from_ap_id(ap_id) do
 661     if _user = User.get_by_ap_id(ap_id) do
 662       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 663     else
 664       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 665         User.insert_or_update_user(data)
 666       else
 667         e -> {:error, e}
 668       end
 669     end
 670   end
 671
 672   def make_user_from_nickname(nickname) do
 673     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 674       make_user_from_ap_id(ap_id)
 675     else
 676       _e -> {:error, "No AP id in WebFinger"}
 677     end
 678   end
 679
 680   def should_federate?(inbox, public) do
 681     if public do
 682       true
 683     else
 684       inbox_info = URI.parse(inbox)
 685       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 686     end
 687   end
 688
 689   def publish(actor, activity) do
 690     followers =
 691       if actor.follower_address in activity.recipients do
 692         {:ok, followers} = User.get_followers(actor)
 693         followers |> Enum.filter(&(!&1.local))
 694       else
 695         []
 696       end
 697
 698     public = is_public?(activity)
 699
 700     remote_inboxes =
 701       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 702       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 703       |> Enum.map(fn %{info: %{source_data: data}} ->
 704         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 705       end)
 706       |> Enum.uniq()
 707       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 708
 709     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 710     json = Jason.encode!(data)
 711
 712     Enum.each(remote_inboxes, fn inbox ->
 713       Federator.enqueue(:publish_single_ap, %{
 714         inbox: inbox,
 715         json: json,
 716         actor: actor,
 717         id: activity.data["id"]
 718       })
 719     end)
 720   end
 721
 722   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 723     Logger.info("Federating #{id} to #{inbox}")
 724     host = URI.parse(inbox).host
 725
 726     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 727
 728     signature =
 729       Pleroma.Web.HTTPSignatures.sign(actor, %{
 730         host: host,
 731         "content-length": byte_size(json),
 732         digest: digest
 733       })
 734
 735     @httpoison.post(
 736       inbox,
 737       json,
 738       [
 739         {"Content-Type", "application/activity+json"},
 740         {"signature", signature},
 741         {"digest", digest}
 742       ]
 743     )
 744   end
 745
 746   # TODO:
 747   # This will create a Create activity, which we need internally at the moment.
 748   def fetch_object_from_id(id) do
 749     if object = Object.get_cached_by_ap_id(id) do
 750       {:ok, object}
 751     else
 752       Logger.info("Fetching #{id} via AP")
 753
 754       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 755            nil <- Object.normalize(data),
 756            params <- %{
 757              "type" => "Create",
 758              "to" => data["to"],
 759              "cc" => data["cc"],
 760              "actor" => data["actor"] || data["attributedTo"],
 761              "object" => data
 762            },
 763            :ok <- Transmogrifier.contain_origin(id, params),
 764            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 765         {:ok, Object.normalize(activity.data["object"])}
 766       else
 767         {:error, {:reject, nil}} ->
 768           {:reject, nil}
 769
 770         object = %Object{} ->
 771           {:ok, object}
 772
 773         _e ->
 774           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 775
 776           case OStatus.fetch_activity_from_url(id) do
 777             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 778             e -> e
 779           end
 780       end
 781     end
 782   end
 783
 784   def fetch_and_contain_remote_object_from_id(id) do
 785     Logger.info("Fetching #{id} via AP")
 786
 787     with true <- String.starts_with?(id, "http"),
 788          {:ok, %{body: body, status: code}} when code in 200..299 <-
 789            @httpoison.get(
 790              id,
 791              [{:Accept, "application/activity+json"}]
 792            ),
 793          {:ok, data} <- Jason.decode(body),
 794          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 795       {:ok, data}
 796     else
 797       e ->
 798         {:error, e}
 799     end
 800   end
 801
 802   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 803   def is_public?(%Object{data: data}), do: is_public?(data)
 804   def is_public?(%Activity{data: data}), do: is_public?(data)
 805
 806   def is_public?(data) do
 807     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 808   end
 809
 810   def visible_for_user?(activity, nil) do
 811     is_public?(activity)
 812   end
 813
 814   def visible_for_user?(activity, user) do
 815     x = [user.ap_id | user.following]
 816     y = activity.data["to"] ++ (activity.data["cc"] || [])
 817     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 818   end
 819
 820   # guard
 821   def entire_thread_visible_for_user?(nil, _user), do: false
 822
 823   # child
 824   def entire_thread_visible_for_user?(
 825         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 826         user
 827       )
 828       when is_binary(parent_id) do
 829     parent = Activity.get_in_reply_to_activity(tail)
 830     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 831   end
 832
 833   # root
 834   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 835
 836   # filter out broken threads
 837   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 838     entire_thread_visible_for_user?(activity, user)
 839   end
 840
 841   # do post-processing on a specific activity
 842   def contain_activity(%Activity{} = activity, %User{} = user) do
 843     contain_broken_threads(activity, user)
 844   end
 845
 846   # do post-processing on a timeline
 847   def contain_timeline(timeline, user) do
 848     timeline
 849     |> Enum.filter(fn activity ->
 850       contain_activity(activity, user)
 851     end)
 852   end
 853 end