git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.OStatus
   4   import Ecto.Query
   5   import Pleroma.Web.ActivityPub.Utils
   6   require Logger
   7
   8   @httpoison Application.get_env(:pleroma, :httpoison)
   9
  10   def get_recipients(data) do
  11     (data["to"] || []) ++ (data["cc"] || [])
  12   end
  13
  14   def insert(map, local \\ true) when is_map(map) do
  15     with nil <- Activity.get_by_ap_id(map["id"]),
  16          map <- lazy_put_activity_defaults(map),
  17          :ok <- insert_full_object(map) do
  18       {:ok, activity} = Repo.insert(%Activity{data: map, local: local, actor: map["actor"], recipients: get_recipients(map)})
  19       Notification.create_notifications(activity)
  20       stream_out(activity)
  21       {:ok, activity}
  22     else
  23       %Activity{} = activity -> {:ok, activity}
  24       error -> {:error, error}
  25     end
  26   end
  27
  28   def stream_out(activity) do
  29     if activity.data["type"] in ["Create", "Announce"] do
  30       Pleroma.Web.Streamer.stream("user", activity)
  31       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  32         Pleroma.Web.Streamer.stream("public", activity)
  33         if activity.local do
  34           Pleroma.Web.Streamer.stream("public:local", activity)
  35         end
  36       end
  37     end
  38   end
  39
  40   def create(to, actor, context, object, additional \\ %{}, published \\ nil, local \\ true) do
  41     with create_data <- make_create_data(%{to: to, actor: actor, published: published, context: context, object: object}, additional),
  42          {:ok, activity} <- insert(create_data, local),
  43          :ok <- maybe_federate(activity) do
  44       {:ok, activity}
  45     end
  46   end
  47
  48   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
  49   def like(%User{ap_id: ap_id} = user, %Object{data: %{"id" => _}} = object, activity_id \\ nil, local \\ true) do
  50     with nil <- get_existing_like(ap_id, object),
  51          like_data <- make_like_data(user, object, activity_id),
  52          {:ok, activity} <- insert(like_data, local),
  53          {:ok, object} <- add_like_to_object(activity, object),
  54          :ok <- maybe_federate(activity) do
  55       {:ok, activity, object}
  56     else
  57       %Activity{} = activity -> {:ok, activity, object}
  58       error -> {:error, error}
  59     end
  60   end
  61
  62   def unlike(%User{} = actor, %Object{} = object) do
  63     with %Activity{} = activity <- get_existing_like(actor.ap_id, object),
  64          {:ok, _activity} <- Repo.delete(activity),
  65          {:ok, object} <- remove_like_from_object(activity, object) do
  66       {:ok, object}
  67       else _e -> {:ok, object}
  68     end
  69   end
  70
  71   def announce(%User{ap_id: _} = user, %Object{data: %{"id" => _}} = object, activity_id \\ nil, local \\ true) do
  72     with announce_data <- make_announce_data(user, object, activity_id),
  73          {:ok, activity} <- insert(announce_data, local),
  74          {:ok, object} <- add_announce_to_object(activity, object),
  75          :ok <- maybe_federate(activity) do
  76       {:ok, activity, object}
  77     else
  78       error -> {:error, error}
  79     end
  80   end
  81
  82   def follow(follower, followed, activity_id \\ nil, local \\ true) do
  83     with data <- make_follow_data(follower, followed, activity_id),
  84          {:ok, activity} <- insert(data, local),
  85          :ok <- maybe_federate(activity) do
  86       {:ok, activity}
  87     end
  88   end
  89
  90   def unfollow(follower, followed, local \\ true) do
  91     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
  92          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
  93          {:ok, activity} <- insert(unfollow_data, local),
  94          :ok, maybe_federate(activity) do
  95       {:ok, activity}
  96     end
  97   end
  98
  99   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 100     user = User.get_cached_by_ap_id(actor)
 101     data = %{
 102       "type" => "Delete",
 103       "actor" => actor,
 104       "object" => id,
 105       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 106     }
 107     with Repo.delete(object),
 108          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 109          {:ok, activity} <- insert(data, local),
 110          :ok <- maybe_federate(activity) do
 111       {:ok, activity}
 112     end
 113   end
 114
 115   def fetch_activities_for_context(context, opts \\ %{}) do
 116     query = from activity in Activity,
 117       where: fragment("?->>'type' = ? and ?->>'context' = ?", activity.data, "Create", activity.data, ^context),
 118       order_by: [desc: :id]
 119     query = restrict_blocked(query, opts)
 120     Repo.all(query)
 121   end
 122
 123   def fetch_public_activities(opts \\ %{}) do
 124     public = ["https://www.w3.org/ns/activitystreams#Public"]
 125     fetch_activities(public, opts)
 126   end
 127
 128   defp restrict_since(query, %{"since_id" => since_id}) do
 129     from activity in query, where: activity.id > ^since_id
 130   end
 131   defp restrict_since(query, _), do: query
 132
 133   defp restrict_tag(query, %{"tag" => tag}) do
 134     from activity in query,
 135       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 136   end
 137   defp restrict_tag(query, _), do: query
 138
 139   defp restrict_recipients(query, recipients) do
 140     Enum.reduce(recipients, query, fn (recipient, q) ->
 141       map = %{ to: [recipient] }
 142       from activity in q,
 143       or_where: fragment(~s(? @> ?), activity.data, ^map)
 144     end)
 145   end
 146
 147   defp restrict_local(query, %{"local_only" => true}) do
 148     from activity in query, where: activity.local == true
 149   end
 150   defp restrict_local(query, _), do: query
 151
 152   defp restrict_max(query, %{"max_id" => max_id}) do
 153     from activity in query, where: activity.id < ^max_id
 154   end
 155   defp restrict_max(query, _), do: query
 156
 157   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 158     from activity in query,
 159       where: activity.actor == ^actor_id
 160   end
 161   defp restrict_actor(query, _), do: query
 162
 163   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 164     restrict_type(query, %{"type" => [type]})
 165   end
 166   defp restrict_type(query, %{"type" => type}) do
 167     from activity in query,
 168       where: fragment("?->>'type' = ANY(?)", activity.data, ^type)
 169   end
 170   defp restrict_type(query, _), do: query
 171
 172   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 173     from activity in query,
 174       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 175   end
 176   defp restrict_favorited_by(query, _), do: query
 177
 178   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 179     from activity in query,
 180       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 181   end
 182   defp restrict_media(query, _), do: query
 183
 184   # Only search through last 100_000 activities by default
 185   defp restrict_recent(query, %{"whole_db" => true}), do: query
 186   defp restrict_recent(query, _) do
 187     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 188
 189     from activity in query,
 190       where: activity.id > ^since
 191   end
 192
 193   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 194     blocks = info["blocks"] || []
 195     from activity in query,
 196       where: fragment("not (? = ANY(?))", activity.actor, ^blocks)
 197   end
 198   defp restrict_blocked(query, _), do: query
 199
 200   def fetch_activities(recipients, opts \\ %{}) do
 201     base_query = from activity in Activity,
 202       limit: 20,
 203       order_by: [fragment("? desc nulls last", activity.id)]
 204
 205     base_query
 206     |> restrict_recipients(recipients)
 207     |> restrict_tag(opts)
 208     |> restrict_since(opts)
 209     |> restrict_local(opts)
 210     |> restrict_max(opts)
 211     |> restrict_actor(opts)
 212     |> restrict_type(opts)
 213     |> restrict_favorited_by(opts)
 214     |> restrict_recent(opts)
 215     |> restrict_blocked(opts)
 216     |> restrict_media(opts)
 217     |> Repo.all
 218     |> Enum.reverse
 219   end
 220
 221   def upload(file) do
 222     data = Upload.store(file)
 223     Repo.insert(%Object{data: data})
 224   end
 225
 226   def make_user_from_ap_id(ap_id) do
 227     with {:ok, %{status_code: 200, body: body}} <- @httpoison.get(ap_id, ["Accept": "application/activity+json"]),
 228     {:ok, data} <- Poison.decode(body)
 229       do
 230       user_data = %{
 231         ap_id: data["id"],
 232         info: %{
 233           "ap_enabled" => true,
 234           "source_data" => data
 235         },
 236         nickname: "#{data["preferredUsername"]}@#{URI.parse(ap_id).host}",
 237         name: data["name"]
 238       }
 239
 240       User.insert_or_update_user(user_data)
 241     end
 242   end
 243
 244   # TODO: Extract to own module, align as close to Mastodon format as possible.
 245   def sanitize_outgoing_activity_data(data) do
 246     data
 247     |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 248   end
 249
 250   def prepare_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 251     with {:ok, user} <- OStatus.find_or_make_user(data["actor"]) do
 252       {:ok, data}
 253     else
 254       _e -> :error
 255     end
 256   end
 257
 258   def prepare_incoming(_) do
 259     :error
 260   end
 261
 262   def publish(actor, activity) do
 263     remote_users = Pleroma.Web.Salmon.remote_users(activity)
 264     data = sanitize_outgoing_activity_data(activity.data)
 265     Enum.each remote_users, fn(user) ->
 266       if user.info["ap_enabled"] do
 267         inbox = user.info["source_data"]["inbox"]
 268         Logger.info("Federating #{activity.data["id"]} to #{inbox}")
 269         host = URI.parse(inbox).host
 270         signature = Pleroma.Web.HTTPSignatures.sign(actor, %{host: host})
 271         @httpoison.post(inbox, Poison.encode!(data), [{"Content-Type", "application/activity+json"}, {"signature", signature}])
 272       end
 273     end
 274   end
 275 end