git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   def get_recipients(data) do
  16     (data["to"] || []) ++ (data["cc"] || [])
  17   end
  18
  19   defp check_actor_is_active(actor) do
  20     if not is_nil(actor) do
  21       with user <- User.get_cached_by_ap_id(actor),
  22            nil <- user.info["deactivated"] do
  23         :ok
  24       else
  25         _e -> :reject
  26       end
  27     else
  28       :ok
  29     end
  30   end
  31
  32   def insert(map, local \\ true) when is_map(map) do
  33     with nil <- Activity.get_by_ap_id(map["id"]),
  34          map <- lazy_put_activity_defaults(map),
  35          :ok <- check_actor_is_active(map["actor"]),
  36          {:ok, map} <- MRF.filter(map),
  37          :ok <- insert_full_object(map) do
  38       {:ok, activity} =
  39         Repo.insert(%Activity{
  40           data: map,
  41           local: local,
  42           actor: map["actor"],
  43           recipients: get_recipients(map)
  44         })
  45
  46       Notification.create_notifications(activity)
  47       stream_out(activity)
  48       {:ok, activity}
  49     else
  50       %Activity{} = activity -> {:ok, activity}
  51       error -> {:error, error}
  52     end
  53   end
  54
  55   def stream_out(activity) do
  56     if activity.data["type"] in ["Create", "Announce"] do
  57       Pleroma.Web.Streamer.stream("user", activity)
  58
  59       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  60         Pleroma.Web.Streamer.stream("public", activity)
  61
  62         if activity.local do
  63           Pleroma.Web.Streamer.stream("public:local", activity)
  64         end
  65       end
  66     end
  67   end
  68
  69   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  70     additional = params[:additional] || %{}
  71     # only accept false as false value
  72     local = !(params[:local] == false)
  73     published = params[:published]
  74
  75     with create_data <-
  76            make_create_data(
  77              %{to: to, actor: actor, published: published, context: context, object: object},
  78              additional
  79            ),
  80          {:ok, activity} <- insert(create_data, local),
  81          :ok <- maybe_federate(activity),
  82          {:ok, _actor} <- User.increase_note_count(actor) do
  83       {:ok, activity}
  84     end
  85   end
  86
  87   def accept(%{to: to, actor: actor, object: object} = params) do
  88     # only accept false as false value
  89     local = !(params[:local] == false)
  90
  91     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  92          {:ok, activity} <- insert(data, local),
  93          :ok <- maybe_federate(activity) do
  94       {:ok, activity}
  95     end
  96   end
  97
  98   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  99     # only accept false as false value
 100     local = !(params[:local] == false)
 101
 102     with data <- %{
 103            "to" => to,
 104            "cc" => cc,
 105            "type" => "Update",
 106            "actor" => actor,
 107            "object" => object
 108          },
 109          {:ok, activity} <- insert(data, local),
 110          :ok <- maybe_federate(activity) do
 111       {:ok, activity}
 112     end
 113   end
 114
 115   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 116   def like(
 117         %User{ap_id: ap_id} = user,
 118         %Object{data: %{"id" => _}} = object,
 119         activity_id \\ nil,
 120         local \\ true
 121       ) do
 122     with nil <- get_existing_like(ap_id, object),
 123          like_data <- make_like_data(user, object, activity_id),
 124          {:ok, activity} <- insert(like_data, local),
 125          {:ok, object} <- add_like_to_object(activity, object),
 126          :ok <- maybe_federate(activity) do
 127       {:ok, activity, object}
 128     else
 129       %Activity{} = activity -> {:ok, activity, object}
 130       error -> {:error, error}
 131     end
 132   end
 133
 134   def unlike(
 135         %User{} = actor,
 136         %Object{} = object,
 137         activity_id \\ nil,
 138         local \\ true
 139       ) do
 140     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 141          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 142          {:ok, unlike_activity} <- insert(unlike_data, local),
 143          {:ok, _activity} <- Repo.delete(like_activity),
 144          {:ok, object} <- remove_like_from_object(like_activity, object),
 145          :ok <- maybe_federate(unlike_activity) do
 146       {:ok, unlike_activity, like_activity, object}
 147     else
 148       _e -> {:ok, object}
 149     end
 150   end
 151
 152   def announce(
 153         %User{ap_id: _} = user,
 154         %Object{data: %{"id" => _}} = object,
 155         activity_id \\ nil,
 156         local \\ true
 157       ) do
 158     with true <- is_public?(object),
 159          announce_data <- make_announce_data(user, object, activity_id),
 160          {:ok, activity} <- insert(announce_data, local),
 161          {:ok, object} <- add_announce_to_object(activity, object),
 162          :ok <- maybe_federate(activity) do
 163       {:ok, activity, object}
 164     else
 165       error -> {:error, error}
 166     end
 167   end
 168
 169   def unannounce(
 170         %User{} = actor,
 171         %Object{} = object,
 172         activity_id \\ nil,
 173         local \\ true
 174       ) do
 175     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 176          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 177          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 178          :ok <- maybe_federate(unannounce_activity),
 179          {:ok, _activity} <- Repo.delete(announce_activity),
 180          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 181       {:ok, unannounce_activity, announce_activity, object}
 182     else
 183       _e -> {:ok, object}
 184     end
 185   end
 186
 187   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 188     with data <- make_follow_data(follower, followed, activity_id),
 189          {:ok, activity} <- insert(data, local),
 190          :ok <- maybe_federate(activity) do
 191       {:ok, activity}
 192     end
 193   end
 194
 195   def unfollow(follower, followed, local \\ true) do
 196     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 197          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
 198          {:ok, activity} <- insert(unfollow_data, local),
 199          :ok,
 200          maybe_federate(activity) do
 201       {:ok, activity}
 202     end
 203   end
 204
 205   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 206     user = User.get_cached_by_ap_id(actor)
 207
 208     data = %{
 209       "type" => "Delete",
 210       "actor" => actor,
 211       "object" => id,
 212       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 213     }
 214
 215     with Repo.delete(object),
 216          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 217          {:ok, activity} <- insert(data, local),
 218          :ok <- maybe_federate(activity),
 219          {:ok, _actor} <- User.decrease_note_count(user) do
 220       {:ok, activity}
 221     end
 222   end
 223
 224   def fetch_activities_for_context(context, opts \\ %{}) do
 225     public = ["https://www.w3.org/ns/activitystreams#Public"]
 226
 227     recipients =
 228       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 229
 230     query = from(activity in Activity)
 231
 232     query =
 233       query
 234       |> restrict_blocked(opts)
 235       |> restrict_recipients(recipients, opts["user"])
 236
 237     query =
 238       from(
 239         activity in query,
 240         where:
 241           fragment(
 242             "?->>'type' = ? and ?->>'context' = ?",
 243             activity.data,
 244             "Create",
 245             activity.data,
 246             ^context
 247           ),
 248         order_by: [desc: :id]
 249       )
 250
 251     Repo.all(query)
 252   end
 253
 254   def fetch_public_activities(opts \\ %{}) do
 255     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 256
 257     q
 258     |> restrict_unlisted()
 259     |> Repo.all()
 260     |> Enum.reverse()
 261   end
 262
 263   defp restrict_since(query, %{"since_id" => since_id}) do
 264     from(activity in query, where: activity.id > ^since_id)
 265   end
 266
 267   defp restrict_since(query, _), do: query
 268
 269   defp restrict_tag(query, %{"tag" => tag}) do
 270     from(
 271       activity in query,
 272       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 273     )
 274   end
 275
 276   defp restrict_tag(query, _), do: query
 277
 278   defp restrict_recipients(query, [], _user), do: query
 279
 280   defp restrict_recipients(query, recipients, nil) do
 281     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 282   end
 283
 284   defp restrict_recipients(query, recipients, user) do
 285     from(
 286       activity in query,
 287       where: fragment("? && ?", ^recipients, activity.recipients),
 288       or_where: activity.actor == ^user.ap_id
 289     )
 290   end
 291
 292   defp restrict_limit(query, %{"limit" => limit}) do
 293     from(activity in query, limit: ^limit)
 294   end
 295
 296   defp restrict_limit(query, _), do: query
 297
 298   defp restrict_local(query, %{"local_only" => true}) do
 299     from(activity in query, where: activity.local == true)
 300   end
 301
 302   defp restrict_local(query, _), do: query
 303
 304   defp restrict_max(query, %{"max_id" => max_id}) do
 305     from(activity in query, where: activity.id < ^max_id)
 306   end
 307
 308   defp restrict_max(query, _), do: query
 309
 310   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 311     from(activity in query, where: activity.actor == ^actor_id)
 312   end
 313
 314   defp restrict_actor(query, _), do: query
 315
 316   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 317     restrict_type(query, %{"type" => [type]})
 318   end
 319
 320   defp restrict_type(query, %{"type" => type}) do
 321     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 322   end
 323
 324   defp restrict_type(query, _), do: query
 325
 326   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 327     from(
 328       activity in query,
 329       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 330     )
 331   end
 332
 333   defp restrict_favorited_by(query, _), do: query
 334
 335   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 336     from(
 337       activity in query,
 338       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 339     )
 340   end
 341
 342   defp restrict_media(query, _), do: query
 343
 344   # Only search through last 100_000 activities by default
 345   defp restrict_recent(query, %{"whole_db" => true}), do: query
 346
 347   defp restrict_recent(query, _) do
 348     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 349
 350     from(activity in query, where: activity.id > ^since)
 351   end
 352
 353   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 354     blocks = info["blocks"] || []
 355
 356     from(
 357       activity in query,
 358       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 359       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks)
 360     )
 361   end
 362
 363   defp restrict_blocked(query, _), do: query
 364
 365   defp restrict_unlisted(query) do
 366     from(
 367       activity in query,
 368       where:
 369         fragment(
 370           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 371           activity.data,
 372           ^["https://www.w3.org/ns/activitystreams#Public"]
 373         )
 374     )
 375   end
 376
 377   def fetch_activities_query(recipients, opts \\ %{}) do
 378     base_query =
 379       from(
 380         activity in Activity,
 381         limit: 20,
 382         order_by: [fragment("? desc nulls last", activity.id)]
 383       )
 384
 385     base_query
 386     |> restrict_recipients(recipients, opts["user"])
 387     |> restrict_tag(opts)
 388     |> restrict_since(opts)
 389     |> restrict_local(opts)
 390     |> restrict_limit(opts)
 391     |> restrict_max(opts)
 392     |> restrict_actor(opts)
 393     |> restrict_type(opts)
 394     |> restrict_favorited_by(opts)
 395     |> restrict_recent(opts)
 396     |> restrict_blocked(opts)
 397     |> restrict_media(opts)
 398   end
 399
 400   def fetch_activities(recipients, opts \\ %{}) do
 401     fetch_activities_query(recipients, opts)
 402     |> Repo.all()
 403     |> Enum.reverse()
 404   end
 405
 406   def upload(file) do
 407     data = Upload.store(file)
 408     Repo.insert(%Object{data: data})
 409   end
 410
 411   def user_data_from_user_object(data) do
 412     avatar =
 413       data["icon"]["url"] &&
 414         %{
 415           "type" => "Image",
 416           "url" => [%{"href" => data["icon"]["url"]}]
 417         }
 418
 419     banner =
 420       data["image"]["url"] &&
 421         %{
 422           "type" => "Image",
 423           "url" => [%{"href" => data["image"]["url"]}]
 424         }
 425
 426     data = Transmogrifier.maybe_fix_user_object(data)
 427
 428     user_data = %{
 429       ap_id: data["id"],
 430       info: %{
 431         "ap_enabled" => true,
 432         "source_data" => data,
 433         "banner" => banner
 434       },
 435       avatar: avatar,
 436       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 437       name: data["name"],
 438       follower_address: data["followers"],
 439       bio: data["summary"]
 440     }
 441
 442     {:ok, user_data}
 443   end
 444
 445   def fetch_and_prepare_user_from_ap_id(ap_id) do
 446     with {:ok, %{status_code: 200, body: body}} <-
 447            @httpoison.get(ap_id, Accept: "application/activity+json"),
 448          {:ok, data} <- Jason.decode(body) do
 449       user_data_from_user_object(data)
 450     else
 451       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 452     end
 453   end
 454
 455   def make_user_from_ap_id(ap_id) do
 456     if _user = User.get_by_ap_id(ap_id) do
 457       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 458     else
 459       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 460         User.insert_or_update_user(data)
 461       else
 462         e -> {:error, e}
 463       end
 464     end
 465   end
 466
 467   def make_user_from_nickname(nickname) do
 468     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 469       make_user_from_ap_id(ap_id)
 470     else
 471       _e -> {:error, "No AP id in WebFinger"}
 472     end
 473   end
 474
 475   def publish(actor, activity) do
 476     followers =
 477       if actor.follower_address in activity.recipients do
 478         {:ok, followers} = User.get_followers(actor)
 479         followers |> Enum.filter(&(!&1.local))
 480       else
 481         []
 482       end
 483
 484     remote_inboxes =
 485       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 486       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 487       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 488         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 489       end)
 490       |> Enum.uniq()
 491
 492     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 493     json = Jason.encode!(data)
 494
 495     Enum.each(remote_inboxes, fn inbox ->
 496       Federator.enqueue(:publish_single_ap, %{
 497         inbox: inbox,
 498         json: json,
 499         actor: actor,
 500         id: activity.data["id"]
 501       })
 502     end)
 503   end
 504
 505   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 506     Logger.info("Federating #{id} to #{inbox}")
 507     host = URI.parse(inbox).host
 508
 509     signature =
 510       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 511
 512     @httpoison.post(
 513       inbox,
 514       json,
 515       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 516       hackney: [pool: :default]
 517     )
 518   end
 519
 520   # TODO:
 521   # This will create a Create activity, which we need internally at the moment.
 522   def fetch_object_from_id(id) do
 523     if object = Object.get_cached_by_ap_id(id) do
 524       {:ok, object}
 525     else
 526       Logger.info("Fetching #{id} via AP")
 527
 528       with true <- String.starts_with?(id, "http"),
 529            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 530              @httpoison.get(
 531                id,
 532                [Accept: "application/activity+json"],
 533                follow_redirect: true,
 534                timeout: 10000,
 535                recv_timeout: 20000
 536              ),
 537            {:ok, data} <- Jason.decode(body),
 538            nil <- Object.get_by_ap_id(data["id"]),
 539            params <- %{
 540              "type" => "Create",
 541              "to" => data["to"],
 542              "cc" => data["cc"],
 543              "actor" => data["attributedTo"],
 544              "object" => data
 545            },
 546            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 547         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 548       else
 549         object = %Object{} ->
 550           {:ok, object}
 551
 552         _e ->
 553           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 554
 555           case OStatus.fetch_activity_from_url(id) do
 556             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 557             e -> e
 558           end
 559       end
 560     end
 561   end
 562
 563   def is_public?(activity) do
 564     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 565                                                          (activity.data["cc"] || []))
 566   end
 567
 568   def visible_for_user?(activity, nil) do
 569     is_public?(activity)
 570   end
 571
 572   def visible_for_user?(activity, user) do
 573     x = [user.ap_id | user.following]
 574     y = activity.data["to"] ++ (activity.data["cc"] || [])
 575     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 576   end
 577 end