git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification, Instances}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(%{"type" => "Create"} = data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     actor = data["actor"] || []
  43     recipients = (to ++ cc ++ [actor]) |> Enum.uniq()
  44     {recipients, to, cc}
  45   end
  46
  47   defp get_recipients(data) do
  48     to = data["to"] || []
  49     cc = data["cc"] || []
  50     recipients = to ++ cc
  51     {recipients, to, cc}
  52   end
  53
  54   defp check_actor_is_active(actor) do
  55     if not is_nil(actor) do
  56       with user <- User.get_cached_by_ap_id(actor),
  57            false <- user.info.deactivated do
  58         :ok
  59       else
  60         _e -> :reject
  61       end
  62     else
  63       :ok
  64     end
  65   end
  66
  67   defp check_remote_limit(%{"object" => %{"content" => content}}) when not is_nil(content) do
  68     limit = Pleroma.Config.get([:instance, :remote_limit])
  69     String.length(content) <= limit
  70   end
  71
  72   defp check_remote_limit(_), do: true
  73
  74   def insert(map, local \\ true) when is_map(map) do
  75     with nil <- Activity.normalize(map),
  76          map <- lazy_put_activity_defaults(map),
  77          :ok <- check_actor_is_active(map["actor"]),
  78          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  79          {:ok, map} <- MRF.filter(map),
  80          :ok <- insert_full_object(map) do
  81       {recipients, _, _} = get_recipients(map)
  82
  83       {:ok, activity} =
  84         Repo.insert(%Activity{
  85           data: map,
  86           local: local,
  87           actor: map["actor"],
  88           recipients: recipients
  89         })
  90
  91       Task.start(fn ->
  92         Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity)
  93       end)
  94
  95       Notification.create_notifications(activity)
  96       stream_out(activity)
  97       {:ok, activity}
  98     else
  99       %Activity{} = activity -> {:ok, activity}
 100       error -> {:error, error}
 101     end
 102   end
 103
 104   def stream_out(activity) do
 105     public = "https://www.w3.org/ns/activitystreams#Public"
 106
 107     if activity.data["type"] in ["Create", "Announce", "Delete"] do
 108       Pleroma.Web.Streamer.stream("user", activity)
 109       Pleroma.Web.Streamer.stream("list", activity)
 110
 111       if Enum.member?(activity.data["to"], public) do
 112         Pleroma.Web.Streamer.stream("public", activity)
 113
 114         if activity.local do
 115           Pleroma.Web.Streamer.stream("public:local", activity)
 116         end
 117
 118         if activity.data["type"] in ["Create"] do
 119           activity.data["object"]
 120           |> Map.get("tag", [])
 121           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 122           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 123
 124           if activity.data["object"]["attachment"] != [] do
 125             Pleroma.Web.Streamer.stream("public:media", activity)
 126
 127             if activity.local do
 128               Pleroma.Web.Streamer.stream("public:local:media", activity)
 129             end
 130           end
 131         end
 132       else
 133         if !Enum.member?(activity.data["cc"] || [], public) &&
 134              !Enum.member?(
 135                activity.data["to"],
 136                User.get_by_ap_id(activity.data["actor"]).follower_address
 137              ),
 138            do: Pleroma.Web.Streamer.stream("direct", activity)
 139       end
 140     end
 141   end
 142
 143   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 144     additional = params[:additional] || %{}
 145     # only accept false as false value
 146     local = !(params[:local] == false)
 147     published = params[:published]
 148
 149     with create_data <-
 150            make_create_data(
 151              %{to: to, actor: actor, published: published, context: context, object: object},
 152              additional
 153            ),
 154          {:ok, activity} <- insert(create_data, local),
 155          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 156          {:ok, _actor} <- User.increase_note_count(actor),
 157          :ok <- maybe_federate(activity) do
 158       {:ok, activity}
 159     end
 160   end
 161
 162   def accept(%{to: to, actor: actor, object: object} = params) do
 163     # only accept false as false value
 164     local = !(params[:local] == false)
 165
 166     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 167          {:ok, activity} <- insert(data, local),
 168          :ok <- maybe_federate(activity) do
 169       {:ok, activity}
 170     end
 171   end
 172
 173   def reject(%{to: to, actor: actor, object: object} = params) do
 174     # only accept false as false value
 175     local = !(params[:local] == false)
 176
 177     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 178          {:ok, activity} <- insert(data, local),
 179          :ok <- maybe_federate(activity) do
 180       {:ok, activity}
 181     end
 182   end
 183
 184   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 185     # only accept false as false value
 186     local = !(params[:local] == false)
 187
 188     with data <- %{
 189            "to" => to,
 190            "cc" => cc,
 191            "type" => "Update",
 192            "actor" => actor,
 193            "object" => object
 194          },
 195          {:ok, activity} <- insert(data, local),
 196          :ok <- maybe_federate(activity) do
 197       {:ok, activity}
 198     end
 199   end
 200
 201   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 202   def like(
 203         %User{ap_id: ap_id} = user,
 204         %Object{data: %{"id" => _}} = object,
 205         activity_id \\ nil,
 206         local \\ true
 207       ) do
 208     with nil <- get_existing_like(ap_id, object),
 209          like_data <- make_like_data(user, object, activity_id),
 210          {:ok, activity} <- insert(like_data, local),
 211          {:ok, object} <- add_like_to_object(activity, object),
 212          :ok <- maybe_federate(activity) do
 213       {:ok, activity, object}
 214     else
 215       %Activity{} = activity -> {:ok, activity, object}
 216       error -> {:error, error}
 217     end
 218   end
 219
 220   def unlike(
 221         %User{} = actor,
 222         %Object{} = object,
 223         activity_id \\ nil,
 224         local \\ true
 225       ) do
 226     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 227          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 228          {:ok, unlike_activity} <- insert(unlike_data, local),
 229          {:ok, _activity} <- Repo.delete(like_activity),
 230          {:ok, object} <- remove_like_from_object(like_activity, object),
 231          :ok <- maybe_federate(unlike_activity) do
 232       {:ok, unlike_activity, like_activity, object}
 233     else
 234       _e -> {:ok, object}
 235     end
 236   end
 237
 238   def announce(
 239         %User{ap_id: _} = user,
 240         %Object{data: %{"id" => _}} = object,
 241         activity_id \\ nil,
 242         local \\ true,
 243         public \\ true
 244       ) do
 245     with true <- is_public?(object),
 246          announce_data <- make_announce_data(user, object, activity_id, public),
 247          {:ok, activity} <- insert(announce_data, local),
 248          {:ok, object} <- add_announce_to_object(activity, object),
 249          :ok <- maybe_federate(activity) do
 250       {:ok, activity, object}
 251     else
 252       error -> {:error, error}
 253     end
 254   end
 255
 256   def unannounce(
 257         %User{} = actor,
 258         %Object{} = object,
 259         activity_id \\ nil,
 260         local \\ true
 261       ) do
 262     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 263          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 264          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 265          :ok <- maybe_federate(unannounce_activity),
 266          {:ok, _activity} <- Repo.delete(announce_activity),
 267          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 268       {:ok, unannounce_activity, object}
 269     else
 270       _e -> {:ok, object}
 271     end
 272   end
 273
 274   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 275     with data <- make_follow_data(follower, followed, activity_id),
 276          {:ok, activity} <- insert(data, local),
 277          :ok <- maybe_federate(activity) do
 278       {:ok, activity}
 279     end
 280   end
 281
 282   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 283     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 284          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 285          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 286          {:ok, activity} <- insert(unfollow_data, local),
 287          :ok <- maybe_federate(activity) do
 288       {:ok, activity}
 289     end
 290   end
 291
 292   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 293     user = User.get_cached_by_ap_id(actor)
 294
 295     data = %{
 296       "type" => "Delete",
 297       "actor" => actor,
 298       "object" => id,
 299       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 300     }
 301
 302     with {:ok, _} <- Object.delete(object),
 303          {:ok, activity} <- insert(data, local),
 304          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 305          {:ok, _actor} <- User.decrease_note_count(user),
 306          :ok <- maybe_federate(activity) do
 307       {:ok, activity}
 308     end
 309   end
 310
 311   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 312     ap_config = Application.get_env(:pleroma, :activitypub)
 313     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 314     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 315
 316     with true <- unfollow_blocked do
 317       follow_activity = fetch_latest_follow(blocker, blocked)
 318
 319       if follow_activity do
 320         unfollow(blocker, blocked, nil, local)
 321       end
 322     end
 323
 324     with true <- outgoing_blocks,
 325          block_data <- make_block_data(blocker, blocked, activity_id),
 326          {:ok, activity} <- insert(block_data, local),
 327          :ok <- maybe_federate(activity) do
 328       {:ok, activity}
 329     else
 330       _e -> {:ok, nil}
 331     end
 332   end
 333
 334   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 335     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 336          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 337          {:ok, activity} <- insert(unblock_data, local),
 338          :ok <- maybe_federate(activity) do
 339       {:ok, activity}
 340     end
 341   end
 342
 343   def fetch_activities_for_context(context, opts \\ %{}) do
 344     public = ["https://www.w3.org/ns/activitystreams#Public"]
 345
 346     recipients =
 347       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 348
 349     query = from(activity in Activity)
 350
 351     query =
 352       query
 353       |> restrict_blocked(opts)
 354       |> restrict_recipients(recipients, opts["user"])
 355
 356     query =
 357       from(
 358         activity in query,
 359         where:
 360           fragment(
 361             "?->>'type' = ? and ?->>'context' = ?",
 362             activity.data,
 363             "Create",
 364             activity.data,
 365             ^context
 366           ),
 367         order_by: [desc: :id]
 368       )
 369
 370     Repo.all(query)
 371   end
 372
 373   def fetch_public_activities(opts \\ %{}) do
 374     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 375
 376     q
 377     |> restrict_unlisted()
 378     |> Repo.all()
 379     |> Enum.reverse()
 380   end
 381
 382   @valid_visibilities ~w[direct unlisted public private]
 383
 384   defp restrict_visibility(query, %{visibility: visibility})
 385        when visibility in @valid_visibilities do
 386     query =
 387       from(
 388         a in query,
 389         where:
 390           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 391       )
 392
 393     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 394
 395     query
 396   end
 397
 398   defp restrict_visibility(_query, %{visibility: visibility})
 399        when visibility not in @valid_visibilities do
 400     Logger.error("Could not restrict visibility to #{visibility}")
 401   end
 402
 403   defp restrict_visibility(query, _visibility), do: query
 404
 405   def fetch_user_activities(user, reading_user, params \\ %{}) do
 406     params =
 407       params
 408       |> Map.put("type", ["Create", "Announce"])
 409       |> Map.put("actor_id", user.ap_id)
 410       |> Map.put("whole_db", true)
 411       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 412
 413     recipients =
 414       if reading_user do
 415         ["https://www.w3.org/ns/activitystreams#Public"] ++
 416           [reading_user.ap_id | reading_user.following]
 417       else
 418         ["https://www.w3.org/ns/activitystreams#Public"]
 419       end
 420
 421     fetch_activities(recipients, params)
 422     |> Enum.reverse()
 423   end
 424
 425   defp restrict_since(query, %{"since_id" => ""}), do: query
 426
 427   defp restrict_since(query, %{"since_id" => since_id}) do
 428     from(activity in query, where: activity.id > ^since_id)
 429   end
 430
 431   defp restrict_since(query, _), do: query
 432
 433   defp restrict_tag_reject(query, %{"tag_reject" => tag_reject})
 434        when is_list(tag_reject) and tag_reject != [] do
 435     from(
 436       activity in query,
 437       where: fragment("(not (? #> '{\"object\",\"tag\"}') \\?| ?)", activity.data, ^tag_reject)
 438     )
 439   end
 440
 441   defp restrict_tag_reject(query, _), do: query
 442
 443   defp restrict_tag_all(query, %{"tag_all" => tag_all})
 444        when is_list(tag_all) and tag_all != [] do
 445     from(
 446       activity in query,
 447       where: fragment("(? #> '{\"object\",\"tag\"}') \\?& ?", activity.data, ^tag_all)
 448     )
 449   end
 450
 451   defp restrict_tag_all(query, _), do: query
 452
 453   defp restrict_tag(query, %{"tag" => tag}) when is_list(tag) do
 454     from(
 455       activity in query,
 456       where: fragment("(? #> '{\"object\",\"tag\"}') \\?| ?", activity.data, ^tag)
 457     )
 458   end
 459
 460   defp restrict_tag(query, %{"tag" => tag}) when is_binary(tag) do
 461     from(
 462       activity in query,
 463       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 464     )
 465   end
 466
 467   defp restrict_tag(query, _), do: query
 468
 469   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 470     from(
 471       activity in query,
 472       where:
 473         fragment(
 474           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 475           activity.data,
 476           ^recipients_to,
 477           activity.data,
 478           ^recipients_cc
 479         )
 480     )
 481   end
 482
 483   defp restrict_recipients(query, [], _user), do: query
 484
 485   defp restrict_recipients(query, recipients, nil) do
 486     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 487   end
 488
 489   defp restrict_recipients(query, recipients, user) do
 490     from(
 491       activity in query,
 492       where: fragment("? && ?", ^recipients, activity.recipients),
 493       or_where: activity.actor == ^user.ap_id
 494     )
 495   end
 496
 497   defp restrict_limit(query, %{"limit" => limit}) do
 498     from(activity in query, limit: ^limit)
 499   end
 500
 501   defp restrict_limit(query, _), do: query
 502
 503   defp restrict_local(query, %{"local_only" => true}) do
 504     from(activity in query, where: activity.local == true)
 505   end
 506
 507   defp restrict_local(query, _), do: query
 508
 509   defp restrict_max(query, %{"max_id" => ""}), do: query
 510
 511   defp restrict_max(query, %{"max_id" => max_id}) do
 512     from(activity in query, where: activity.id < ^max_id)
 513   end
 514
 515   defp restrict_max(query, _), do: query
 516
 517   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 518     from(activity in query, where: activity.actor == ^actor_id)
 519   end
 520
 521   defp restrict_actor(query, _), do: query
 522
 523   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 524     restrict_type(query, %{"type" => [type]})
 525   end
 526
 527   defp restrict_type(query, %{"type" => type}) do
 528     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 529   end
 530
 531   defp restrict_type(query, _), do: query
 532
 533   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 534     from(
 535       activity in query,
 536       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 537     )
 538   end
 539
 540   defp restrict_favorited_by(query, _), do: query
 541
 542   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 543     from(
 544       activity in query,
 545       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 546     )
 547   end
 548
 549   defp restrict_media(query, _), do: query
 550
 551   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 552     from(
 553       activity in query,
 554       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 555     )
 556   end
 557
 558   defp restrict_replies(query, _), do: query
 559
 560   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 561     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 562   end
 563
 564   defp restrict_reblogs(query, _), do: query
 565
 566   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 567     blocks = info.blocks || []
 568     domain_blocks = info.domain_blocks || []
 569
 570     from(
 571       activity in query,
 572       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 573       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 574       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 575     )
 576   end
 577
 578   defp restrict_blocked(query, _), do: query
 579
 580   defp restrict_unlisted(query) do
 581     from(
 582       activity in query,
 583       where:
 584         fragment(
 585           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 586           activity.data,
 587           ^["https://www.w3.org/ns/activitystreams#Public"]
 588         )
 589     )
 590   end
 591
 592   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 593     from(activity in query, where: activity.id in ^ids)
 594   end
 595
 596   defp restrict_pinned(query, _), do: query
 597
 598   def fetch_activities_query(recipients, opts \\ %{}) do
 599     base_query =
 600       from(
 601         activity in Activity,
 602         limit: 20,
 603         order_by: [fragment("? desc nulls last", activity.id)]
 604       )
 605
 606     base_query
 607     |> restrict_recipients(recipients, opts["user"])
 608     |> restrict_tag(opts)
 609     |> restrict_tag_reject(opts)
 610     |> restrict_tag_all(opts)
 611     |> restrict_since(opts)
 612     |> restrict_local(opts)
 613     |> restrict_limit(opts)
 614     |> restrict_max(opts)
 615     |> restrict_actor(opts)
 616     |> restrict_type(opts)
 617     |> restrict_favorited_by(opts)
 618     |> restrict_blocked(opts)
 619     |> restrict_media(opts)
 620     |> restrict_visibility(opts)
 621     |> restrict_replies(opts)
 622     |> restrict_reblogs(opts)
 623     |> restrict_pinned(opts)
 624   end
 625
 626   def fetch_activities(recipients, opts \\ %{}) do
 627     fetch_activities_query(recipients, opts)
 628     |> Repo.all()
 629     |> Enum.reverse()
 630   end
 631
 632   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 633     fetch_activities_query([], opts)
 634     |> restrict_to_cc(recipients_to, recipients_cc)
 635     |> Repo.all()
 636     |> Enum.reverse()
 637   end
 638
 639   def upload(file, opts \\ []) do
 640     with {:ok, data} <- Upload.store(file, opts) do
 641       obj_data =
 642         if opts[:actor] do
 643           Map.put(data, "actor", opts[:actor])
 644         else
 645           data
 646         end
 647
 648       Repo.insert(%Object{data: obj_data})
 649     end
 650   end
 651
 652   def user_data_from_user_object(data) do
 653     avatar =
 654       data["icon"]["url"] &&
 655         %{
 656           "type" => "Image",
 657           "url" => [%{"href" => data["icon"]["url"]}]
 658         }
 659
 660     banner =
 661       data["image"]["url"] &&
 662         %{
 663           "type" => "Image",
 664           "url" => [%{"href" => data["image"]["url"]}]
 665         }
 666
 667     locked = data["manuallyApprovesFollowers"] || false
 668     data = Transmogrifier.maybe_fix_user_object(data)
 669
 670     user_data = %{
 671       ap_id: data["id"],
 672       info: %{
 673         "ap_enabled" => true,
 674         "source_data" => data,
 675         "banner" => banner,
 676         "locked" => locked
 677       },
 678       avatar: avatar,
 679       name: data["name"],
 680       follower_address: data["followers"],
 681       bio: data["summary"]
 682     }
 683
 684     # nickname can be nil because of virtual actors
 685     user_data =
 686       if data["preferredUsername"] do
 687         Map.put(
 688           user_data,
 689           :nickname,
 690           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 691         )
 692       else
 693         Map.put(user_data, :nickname, nil)
 694       end
 695
 696     {:ok, user_data}
 697   end
 698
 699   def fetch_and_prepare_user_from_ap_id(ap_id) do
 700     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 701       user_data_from_user_object(data)
 702     else
 703       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 704     end
 705   end
 706
 707   def make_user_from_ap_id(ap_id) do
 708     if _user = User.get_by_ap_id(ap_id) do
 709       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 710     else
 711       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 712         User.insert_or_update_user(data)
 713       else
 714         e -> {:error, e}
 715       end
 716     end
 717   end
 718
 719   def make_user_from_nickname(nickname) do
 720     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 721       make_user_from_ap_id(ap_id)
 722     else
 723       _e -> {:error, "No AP id in WebFinger"}
 724     end
 725   end
 726
 727   def should_federate?(inbox, public) do
 728     if public do
 729       true
 730     else
 731       inbox_info = URI.parse(inbox)
 732       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 733     end
 734   end
 735
 736   def publish(actor, activity) do
 737     remote_followers =
 738       if actor.follower_address in activity.recipients do
 739         {:ok, followers} = User.get_followers(actor)
 740         followers |> Enum.filter(&(!&1.local))
 741       else
 742         []
 743       end
 744
 745     public = is_public?(activity)
 746
 747     reachable_inboxes_metadata =
 748       (Pleroma.Web.Salmon.remote_users(activity) ++ remote_followers)
 749       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 750       |> Enum.map(fn %{info: %{source_data: data}} ->
 751         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 752       end)
 753       |> Enum.uniq()
 754       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 755       |> Instances.filter_reachable()
 756
 757     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 758     json = Jason.encode!(data)
 759
 760     Enum.each(reachable_inboxes_metadata, fn {inbox, unreachable_since} ->
 761       Federator.enqueue(:publish_single_ap, %{
 762         inbox: inbox,
 763         json: json,
 764         actor: actor,
 765         id: activity.data["id"],
 766         unreachable_since: unreachable_since
 767       })
 768     end)
 769   end
 770
 771   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id} = params) do
 772     Logger.info("Federating #{id} to #{inbox}")
 773     host = URI.parse(inbox).host
 774
 775     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 776
 777     signature =
 778       Pleroma.Web.HTTPSignatures.sign(actor, %{
 779         host: host,
 780         "content-length": byte_size(json),
 781         digest: digest
 782       })
 783
 784     with {:ok, %{status: code}} when code in 200..299 <-
 785            result =
 786              @httpoison.post(
 787                inbox,
 788                json,
 789                [
 790                  {"Content-Type", "application/activity+json"},
 791                  {"signature", signature},
 792                  {"digest", digest}
 793                ]
 794              ) do
 795       if !Map.has_key?(params, :unreachable_since) || params[:unreachable_since],
 796         do: Instances.set_reachable(inbox)
 797
 798       result
 799     else
 800       {_post_result, response} ->
 801         unless params[:unreachable_since], do: Instances.set_unreachable(inbox)
 802         {:error, response}
 803     end
 804   end
 805
 806   # TODO:
 807   # This will create a Create activity, which we need internally at the moment.
 808   def fetch_object_from_id(id) do
 809     if object = Object.get_cached_by_ap_id(id) do
 810       {:ok, object}
 811     else
 812       Logger.info("Fetching #{id} via AP")
 813
 814       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 815            nil <- Object.normalize(data),
 816            params <- %{
 817              "type" => "Create",
 818              "to" => data["to"],
 819              "cc" => data["cc"],
 820              "actor" => data["actor"] || data["attributedTo"],
 821              "object" => data
 822            },
 823            :ok <- Transmogrifier.contain_origin(id, params),
 824            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 825         {:ok, Object.normalize(activity.data["object"])}
 826       else
 827         {:error, {:reject, nil}} ->
 828           {:reject, nil}
 829
 830         object = %Object{} ->
 831           {:ok, object}
 832
 833         _e ->
 834           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 835
 836           case OStatus.fetch_activity_from_url(id) do
 837             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 838             e -> e
 839           end
 840       end
 841     end
 842   end
 843
 844   def fetch_and_contain_remote_object_from_id(id) do
 845     Logger.info("Fetching #{id} via AP")
 846
 847     with true <- String.starts_with?(id, "http"),
 848          {:ok, %{body: body, status: code}} when code in 200..299 <-
 849            @httpoison.get(
 850              id,
 851              [{:Accept, "application/activity+json"}]
 852            ),
 853          {:ok, data} <- Jason.decode(body),
 854          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 855       {:ok, data}
 856     else
 857       e ->
 858         {:error, e}
 859     end
 860   end
 861
 862   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 863   def is_public?(%Object{data: data}), do: is_public?(data)
 864   def is_public?(%Activity{data: data}), do: is_public?(data)
 865   def is_public?(%{"directMessage" => true}), do: false
 866
 867   def is_public?(data) do
 868     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 869   end
 870
 871   def is_private?(activity) do
 872     !is_public?(activity) && Enum.any?(activity.data["to"], &String.contains?(&1, "/followers"))
 873   end
 874
 875   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
 876   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
 877
 878   def is_direct?(activity) do
 879     !is_public?(activity) && !is_private?(activity)
 880   end
 881
 882   def visible_for_user?(activity, nil) do
 883     is_public?(activity)
 884   end
 885
 886   def visible_for_user?(activity, user) do
 887     x = [user.ap_id | user.following]
 888     y = activity.data["to"] ++ (activity.data["cc"] || [])
 889     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 890   end
 891
 892   # guard
 893   def entire_thread_visible_for_user?(nil, _user), do: false
 894
 895   # child
 896   def entire_thread_visible_for_user?(
 897         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 898         user
 899       )
 900       when is_binary(parent_id) do
 901     parent = Activity.get_in_reply_to_activity(tail)
 902     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 903   end
 904
 905   # root
 906   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 907
 908   # filter out broken threads
 909   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 910     entire_thread_visible_for_user?(activity, user)
 911   end
 912
 913   # do post-processing on a specific activity
 914   def contain_activity(%Activity{} = activity, %User{} = user) do
 915     contain_broken_threads(activity, user)
 916   end
 917
 918   # do post-processing on a timeline
 919   def contain_timeline(timeline, user) do
 920     timeline
 921     |> Enum.filter(fn activity ->
 922       contain_activity(activity, user)
 923     end)
 924   end
 925 end