git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   # For Announce activities, we filter the recipients based on following status for any actors
  16   # that match actual users.  See issue #164 for more information about why this is necessary.
  17   defp get_recipients(%{"type" => "Announce"} = data) do
  18     to = data["to"] || []
  19     cc = data["cc"] || []
  20     recipients = to ++ cc
  21     actor = User.get_cached_by_ap_id(data["actor"])
  22
  23     recipients
  24     |> Enum.filter(fn recipient ->
  25       case User.get_cached_by_ap_id(recipient) do
  26         nil ->
  27           true
  28
  29         user ->
  30           User.following?(user, actor)
  31       end
  32     end)
  33
  34     {recipients, to, cc}
  35   end
  36
  37   defp get_recipients(data) do
  38     to = data["to"] || []
  39     cc = data["cc"] || []
  40     recipients = to ++ cc
  41     {recipients, to, cc}
  42   end
  43
  44   defp check_actor_is_active(actor) do
  45     if not is_nil(actor) do
  46       with user <- User.get_cached_by_ap_id(actor),
  47            nil <- user.info["deactivated"] do
  48         :ok
  49       else
  50         _e -> :reject
  51       end
  52     else
  53       :ok
  54     end
  55   end
  56
  57   def insert(map, local \\ true) when is_map(map) do
  58     with nil <- Activity.normalize(map),
  59          map <- lazy_put_activity_defaults(map),
  60          :ok <- check_actor_is_active(map["actor"]),
  61          {:ok, map} <- MRF.filter(map),
  62          :ok <- insert_full_object(map) do
  63       {recipients, _, _} = get_recipients(map)
  64
  65       {:ok, activity} =
  66         Repo.insert(%Activity{
  67           data: map,
  68           local: local,
  69           actor: map["actor"],
  70           recipients: recipients
  71         })
  72
  73       Notification.create_notifications(activity)
  74       stream_out(activity)
  75       {:ok, activity}
  76     else
  77       %Activity{} = activity -> {:ok, activity}
  78       error -> {:error, error}
  79     end
  80   end
  81
  82   def stream_out(activity) do
  83     public = "https://www.w3.org/ns/activitystreams#Public"
  84
  85     if activity.data["type"] in ["Create", "Announce"] do
  86       Pleroma.Web.Streamer.stream("user", activity)
  87       Pleroma.Web.Streamer.stream("list", activity)
  88
  89       if Enum.member?(activity.data["to"], public) do
  90         Pleroma.Web.Streamer.stream("public", activity)
  91
  92         if activity.local do
  93           Pleroma.Web.Streamer.stream("public:local", activity)
  94         end
  95
  96         if activity.data["object"]["attachment"] != [] do
  97           Pleroma.Web.Streamer.stream("public:media", activity)
  98
  99           if activity.local do
 100             Pleroma.Web.Streamer.stream("public:local:media", activity)
 101           end
 102         end
 103       else
 104         if !Enum.member?(activity.data["cc"] || [], public) &&
 105              !Enum.member?(
 106                activity.data["to"],
 107                User.get_by_ap_id(activity.data["actor"]).follower_address
 108              ),
 109            do: Pleroma.Web.Streamer.stream("direct", activity)
 110       end
 111     end
 112   end
 113
 114   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 115     additional = params[:additional] || %{}
 116     # only accept false as false value
 117     local = !(params[:local] == false)
 118     published = params[:published]
 119
 120     with create_data <-
 121            make_create_data(
 122              %{to: to, actor: actor, published: published, context: context, object: object},
 123              additional
 124            ),
 125          {:ok, activity} <- insert(create_data, local),
 126          :ok <- maybe_federate(activity),
 127          {:ok, _actor} <- User.increase_note_count(actor) do
 128       {:ok, activity}
 129     end
 130   end
 131
 132   def accept(%{to: to, actor: actor, object: object} = params) do
 133     # only accept false as false value
 134     local = !(params[:local] == false)
 135
 136     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 137          {:ok, activity} <- insert(data, local),
 138          :ok <- maybe_federate(activity) do
 139       {:ok, activity}
 140     end
 141   end
 142
 143   def reject(%{to: to, actor: actor, object: object} = params) do
 144     # only accept false as false value
 145     local = !(params[:local] == false)
 146
 147     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 148          {:ok, activity} <- insert(data, local),
 149          :ok <- maybe_federate(activity) do
 150       {:ok, activity}
 151     end
 152   end
 153
 154   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 155     # only accept false as false value
 156     local = !(params[:local] == false)
 157
 158     with data <- %{
 159            "to" => to,
 160            "cc" => cc,
 161            "type" => "Update",
 162            "actor" => actor,
 163            "object" => object
 164          },
 165          {:ok, activity} <- insert(data, local),
 166          :ok <- maybe_federate(activity) do
 167       {:ok, activity}
 168     end
 169   end
 170
 171   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 172   def like(
 173         %User{ap_id: ap_id} = user,
 174         %Object{data: %{"id" => _}} = object,
 175         activity_id \\ nil,
 176         local \\ true
 177       ) do
 178     with nil <- get_existing_like(ap_id, object),
 179          like_data <- make_like_data(user, object, activity_id),
 180          {:ok, activity} <- insert(like_data, local),
 181          {:ok, object} <- add_like_to_object(activity, object),
 182          :ok <- maybe_federate(activity) do
 183       {:ok, activity, object}
 184     else
 185       %Activity{} = activity -> {:ok, activity, object}
 186       error -> {:error, error}
 187     end
 188   end
 189
 190   def unlike(
 191         %User{} = actor,
 192         %Object{} = object,
 193         activity_id \\ nil,
 194         local \\ true
 195       ) do
 196     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 197          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 198          {:ok, unlike_activity} <- insert(unlike_data, local),
 199          {:ok, _activity} <- Repo.delete(like_activity),
 200          {:ok, object} <- remove_like_from_object(like_activity, object),
 201          :ok <- maybe_federate(unlike_activity) do
 202       {:ok, unlike_activity, like_activity, object}
 203     else
 204       _e -> {:ok, object}
 205     end
 206   end
 207
 208   def announce(
 209         %User{ap_id: _} = user,
 210         %Object{data: %{"id" => _}} = object,
 211         activity_id \\ nil,
 212         local \\ true
 213       ) do
 214     with true <- is_public?(object),
 215          announce_data <- make_announce_data(user, object, activity_id),
 216          {:ok, activity} <- insert(announce_data, local),
 217          {:ok, object} <- add_announce_to_object(activity, object),
 218          :ok <- maybe_federate(activity) do
 219       {:ok, activity, object}
 220     else
 221       error -> {:error, error}
 222     end
 223   end
 224
 225   def unannounce(
 226         %User{} = actor,
 227         %Object{} = object,
 228         activity_id \\ nil,
 229         local \\ true
 230       ) do
 231     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 232          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 233          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 234          :ok <- maybe_federate(unannounce_activity),
 235          {:ok, _activity} <- Repo.delete(announce_activity),
 236          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 237       {:ok, unannounce_activity, object}
 238     else
 239       _e -> {:ok, object}
 240     end
 241   end
 242
 243   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 244     with data <- make_follow_data(follower, followed, activity_id),
 245          {:ok, activity} <- insert(data, local),
 246          :ok <- maybe_federate(activity) do
 247       {:ok, activity}
 248     end
 249   end
 250
 251   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 252     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 253          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 254          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 255          {:ok, activity} <- insert(unfollow_data, local),
 256          :ok <- maybe_federate(activity) do
 257       {:ok, activity}
 258     end
 259   end
 260
 261   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 262     user = User.get_cached_by_ap_id(actor)
 263
 264     data = %{
 265       "type" => "Delete",
 266       "actor" => actor,
 267       "object" => id,
 268       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 269     }
 270
 271     with Repo.delete(object),
 272          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 273          {:ok, activity} <- insert(data, local),
 274          :ok <- maybe_federate(activity),
 275          {:ok, _actor} <- User.decrease_note_count(user) do
 276       {:ok, activity}
 277     end
 278   end
 279
 280   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 281     ap_config = Application.get_env(:pleroma, :activitypub)
 282     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 283     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 284
 285     with true <- unfollow_blocked do
 286       follow_activity = fetch_latest_follow(blocker, blocked)
 287
 288       if follow_activity do
 289         unfollow(blocker, blocked, nil, local)
 290       end
 291     end
 292
 293     with true <- outgoing_blocks,
 294          block_data <- make_block_data(blocker, blocked, activity_id),
 295          {:ok, activity} <- insert(block_data, local),
 296          :ok <- maybe_federate(activity) do
 297       {:ok, activity}
 298     else
 299       _e -> {:ok, nil}
 300     end
 301   end
 302
 303   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 304     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 305          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 306          {:ok, activity} <- insert(unblock_data, local),
 307          :ok <- maybe_federate(activity) do
 308       {:ok, activity}
 309     end
 310   end
 311
 312   def fetch_activities_for_context(context, opts \\ %{}) do
 313     public = ["https://www.w3.org/ns/activitystreams#Public"]
 314
 315     recipients =
 316       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 317
 318     query = from(activity in Activity)
 319
 320     query =
 321       query
 322       |> restrict_blocked(opts)
 323       |> restrict_recipients(recipients, opts["user"])
 324
 325     query =
 326       from(
 327         activity in query,
 328         where:
 329           fragment(
 330             "?->>'type' = ? and ?->>'context' = ?",
 331             activity.data,
 332             "Create",
 333             activity.data,
 334             ^context
 335           ),
 336         order_by: [desc: :id]
 337       )
 338
 339     Repo.all(query)
 340   end
 341
 342   def fetch_public_activities(opts \\ %{}) do
 343     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 344
 345     q
 346     |> restrict_unlisted()
 347     |> Repo.all()
 348     |> Enum.reverse()
 349   end
 350
 351   @valid_visibilities ~w[direct unlisted public private]
 352
 353   defp restrict_visibility(query, %{visibility: "direct"}) do
 354     public = "https://www.w3.org/ns/activitystreams#Public"
 355
 356     from(
 357       activity in query,
 358       join: sender in User,
 359       on: sender.ap_id == activity.actor,
 360       # Are non-direct statuses with no to/cc possible?
 361       where:
 362         fragment(
 363           "not (? && ?)",
 364           [^public, sender.follower_address],
 365           activity.recipients
 366         )
 367     )
 368   end
 369
 370   defp restrict_visibility(_query, %{visibility: visibility})
 371        when visibility not in @valid_visibilities do
 372     Logger.error("Could not restrict visibility to #{visibility}")
 373   end
 374
 375   defp restrict_visibility(query, _visibility), do: query
 376
 377   def fetch_user_activities(user, reading_user, params \\ %{}) do
 378     params =
 379       params
 380       |> Map.put("type", ["Create", "Announce"])
 381       |> Map.put("actor_id", user.ap_id)
 382       |> Map.put("whole_db", true)
 383
 384     recipients =
 385       if reading_user do
 386         ["https://www.w3.org/ns/activitystreams#Public"] ++
 387           [reading_user.ap_id | reading_user.following]
 388       else
 389         ["https://www.w3.org/ns/activitystreams#Public"]
 390       end
 391
 392     fetch_activities(recipients, params)
 393     |> Enum.reverse()
 394   end
 395
 396   defp restrict_since(query, %{"since_id" => since_id}) do
 397     from(activity in query, where: activity.id > ^since_id)
 398   end
 399
 400   defp restrict_since(query, _), do: query
 401
 402   defp restrict_tag(query, %{"tag" => tag}) do
 403     from(
 404       activity in query,
 405       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 406     )
 407   end
 408
 409   defp restrict_tag(query, _), do: query
 410
 411   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 412     from(
 413       activity in query,
 414       where:
 415         fragment(
 416           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 417           activity.data,
 418           ^recipients_to,
 419           activity.data,
 420           ^recipients_cc
 421         )
 422     )
 423   end
 424
 425   defp restrict_recipients(query, [], _user), do: query
 426
 427   defp restrict_recipients(query, recipients, nil) do
 428     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 429   end
 430
 431   defp restrict_recipients(query, recipients, user) do
 432     from(
 433       activity in query,
 434       where: fragment("? && ?", ^recipients, activity.recipients),
 435       or_where: activity.actor == ^user.ap_id
 436     )
 437   end
 438
 439   defp restrict_limit(query, %{"limit" => limit}) do
 440     from(activity in query, limit: ^limit)
 441   end
 442
 443   defp restrict_limit(query, _), do: query
 444
 445   defp restrict_local(query, %{"local_only" => true}) do
 446     from(activity in query, where: activity.local == true)
 447   end
 448
 449   defp restrict_local(query, _), do: query
 450
 451   defp restrict_max(query, %{"max_id" => max_id}) do
 452     from(activity in query, where: activity.id < ^max_id)
 453   end
 454
 455   defp restrict_max(query, _), do: query
 456
 457   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 458     from(activity in query, where: activity.actor == ^actor_id)
 459   end
 460
 461   defp restrict_actor(query, _), do: query
 462
 463   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 464     restrict_type(query, %{"type" => [type]})
 465   end
 466
 467   defp restrict_type(query, %{"type" => type}) do
 468     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 469   end
 470
 471   defp restrict_type(query, _), do: query
 472
 473   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 474     from(
 475       activity in query,
 476       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 477     )
 478   end
 479
 480   defp restrict_favorited_by(query, _), do: query
 481
 482   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 483     from(
 484       activity in query,
 485       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 486     )
 487   end
 488
 489   defp restrict_media(query, _), do: query
 490
 491   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 492     from(
 493       activity in query,
 494       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 495     )
 496   end
 497
 498   defp restrict_replies(query, _), do: query
 499
 500   # Only search through last 100_000 activities by default
 501   defp restrict_recent(query, %{"whole_db" => true}), do: query
 502
 503   defp restrict_recent(query, _) do
 504     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 505
 506     from(activity in query, where: activity.id > ^since)
 507   end
 508
 509   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 510     blocks = info["blocks"] || []
 511     domain_blocks = info["domain_blocks"] || []
 512
 513     from(
 514       activity in query,
 515       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 516       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 517       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 518     )
 519   end
 520
 521   defp restrict_blocked(query, _), do: query
 522
 523   defp restrict_unlisted(query) do
 524     from(
 525       activity in query,
 526       where:
 527         fragment(
 528           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 529           activity.data,
 530           ^["https://www.w3.org/ns/activitystreams#Public"]
 531         )
 532     )
 533   end
 534
 535   def fetch_activities_query(recipients, opts \\ %{}) do
 536     base_query =
 537       from(
 538         activity in Activity,
 539         limit: 20,
 540         order_by: [fragment("? desc nulls last", activity.id)]
 541       )
 542
 543     base_query
 544     |> restrict_recipients(recipients, opts["user"])
 545     |> restrict_tag(opts)
 546     |> restrict_since(opts)
 547     |> restrict_local(opts)
 548     |> restrict_limit(opts)
 549     |> restrict_max(opts)
 550     |> restrict_actor(opts)
 551     |> restrict_type(opts)
 552     |> restrict_favorited_by(opts)
 553     |> restrict_recent(opts)
 554     |> restrict_blocked(opts)
 555     |> restrict_media(opts)
 556     |> restrict_visibility(opts)
 557     |> restrict_replies(opts)
 558   end
 559
 560   def fetch_activities(recipients, opts \\ %{}) do
 561     fetch_activities_query(recipients, opts)
 562     |> Repo.all()
 563     |> Enum.reverse()
 564   end
 565
 566   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 567     fetch_activities_query([], opts)
 568     |> restrict_to_cc(recipients_to, recipients_cc)
 569     |> Repo.all()
 570     |> Enum.reverse()
 571   end
 572
 573   def upload(file) do
 574     data = Upload.store(file, Application.get_env(:pleroma, :instance)[:dedupe_media])
 575     Repo.insert(%Object{data: data})
 576   end
 577
 578   def user_data_from_user_object(data) do
 579     avatar =
 580       data["icon"]["url"] &&
 581         %{
 582           "type" => "Image",
 583           "url" => [%{"href" => data["icon"]["url"]}]
 584         }
 585
 586     banner =
 587       data["image"]["url"] &&
 588         %{
 589           "type" => "Image",
 590           "url" => [%{"href" => data["image"]["url"]}]
 591         }
 592
 593     locked = data["manuallyApprovesFollowers"] || false
 594     data = Transmogrifier.maybe_fix_user_object(data)
 595
 596     user_data = %{
 597       ap_id: data["id"],
 598       info: %{
 599         "ap_enabled" => true,
 600         "source_data" => data,
 601         "banner" => banner,
 602         "locked" => locked
 603       },
 604       avatar: avatar,
 605       name: data["name"],
 606       follower_address: data["followers"],
 607       bio: data["summary"]
 608     }
 609
 610     # nickname can be nil because of virtual actors
 611     user_data =
 612       if data["preferredUsername"] do
 613         Map.put(
 614           user_data,
 615           :nickname,
 616           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 617         )
 618       else
 619         Map.put(user_data, :nickname, nil)
 620       end
 621
 622     {:ok, user_data}
 623   end
 624
 625   def fetch_and_prepare_user_from_ap_id(ap_id) do
 626     with {:ok, %{status_code: 200, body: body}} <-
 627            @httpoison.get(ap_id, [Accept: "application/activity+json"], follow_redirect: true),
 628          {:ok, data} <- Jason.decode(body) do
 629       user_data_from_user_object(data)
 630     else
 631       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 632     end
 633   end
 634
 635   def make_user_from_ap_id(ap_id) do
 636     if _user = User.get_by_ap_id(ap_id) do
 637       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 638     else
 639       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 640         User.insert_or_update_user(data)
 641       else
 642         e -> {:error, e}
 643       end
 644     end
 645   end
 646
 647   def make_user_from_nickname(nickname) do
 648     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 649       make_user_from_ap_id(ap_id)
 650     else
 651       _e -> {:error, "No AP id in WebFinger"}
 652     end
 653   end
 654
 655   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 656
 657   def should_federate?(inbox, public) do
 658     if public do
 659       true
 660     else
 661       inbox_info = URI.parse(inbox)
 662       inbox_info.host not in @quarantined_instances
 663     end
 664   end
 665
 666   def publish(actor, activity) do
 667     followers =
 668       if actor.follower_address in activity.recipients do
 669         {:ok, followers} = User.get_followers(actor)
 670         followers |> Enum.filter(&(!&1.local))
 671       else
 672         []
 673       end
 674
 675     public = is_public?(activity)
 676
 677     remote_inboxes =
 678       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 679       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 680       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 681         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 682       end)
 683       |> Enum.uniq()
 684       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 685
 686     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 687     json = Jason.encode!(data)
 688
 689     Enum.each(remote_inboxes, fn inbox ->
 690       Federator.enqueue(:publish_single_ap, %{
 691         inbox: inbox,
 692         json: json,
 693         actor: actor,
 694         id: activity.data["id"]
 695       })
 696     end)
 697   end
 698
 699   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 700     Logger.info("Federating #{id} to #{inbox}")
 701     host = URI.parse(inbox).host
 702
 703     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 704
 705     signature =
 706       Pleroma.Web.HTTPSignatures.sign(actor, %{
 707         host: host,
 708         "content-length": byte_size(json),
 709         digest: digest
 710       })
 711
 712     @httpoison.post(
 713       inbox,
 714       json,
 715       [
 716         {"Content-Type", "application/activity+json"},
 717         {"signature", signature},
 718         {"digest", digest}
 719       ],
 720       hackney: [pool: :default]
 721     )
 722   end
 723
 724   # TODO:
 725   # This will create a Create activity, which we need internally at the moment.
 726   def fetch_object_from_id(id) do
 727     if object = Object.get_cached_by_ap_id(id) do
 728       {:ok, object}
 729     else
 730       Logger.info("Fetching #{id} via AP")
 731
 732       with true <- String.starts_with?(id, "http"),
 733            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 734              @httpoison.get(
 735                id,
 736                [Accept: "application/activity+json"],
 737                follow_redirect: true,
 738                timeout: 10000,
 739                recv_timeout: 20000
 740              ),
 741            {:ok, data} <- Jason.decode(body),
 742            nil <- Object.normalize(data),
 743            params <- %{
 744              "type" => "Create",
 745              "to" => data["to"],
 746              "cc" => data["cc"],
 747              "actor" => data["attributedTo"],
 748              "object" => data
 749            },
 750            :ok <- Transmogrifier.contain_origin(id, params),
 751            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 752         {:ok, Object.normalize(activity.data["object"])}
 753       else
 754         object = %Object{} ->
 755           {:ok, object}
 756
 757         _e ->
 758           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 759
 760           case OStatus.fetch_activity_from_url(id) do
 761             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 762             e -> e
 763           end
 764       end
 765     end
 766   end
 767
 768   def is_public?(activity) do
 769     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 770                                                          (activity.data["cc"] || []))
 771   end
 772
 773   def visible_for_user?(activity, nil) do
 774     is_public?(activity)
 775   end
 776
 777   def visible_for_user?(activity, user) do
 778     x = [user.ap_id | user.following]
 779     y = activity.data["to"] ++ (activity.data["cc"] || [])
 780     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 781   end
 782 end