git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.Activity
   7   alias Pleroma.Activity.Ir.Topics
   8   alias Pleroma.Config
   9   alias Pleroma.Conversation
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.Notification
  12   alias Pleroma.Object
  13   alias Pleroma.Object.Containment
  14   alias Pleroma.Object.Fetcher
  15   alias Pleroma.Pagination
  16   alias Pleroma.Repo
  17   alias Pleroma.Upload
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.MRF
  20   alias Pleroma.Web.ActivityPub.Transmogrifier
  21   alias Pleroma.Web.ActivityPub.Utils
  22   alias Pleroma.Web.Streamer
  23   alias Pleroma.Web.WebFinger
  24   alias Pleroma.Workers.BackgroundWorker
  25
  26   import Ecto.Query
  27   import Pleroma.Web.ActivityPub.Utils
  28   import Pleroma.Web.ActivityPub.Visibility
  29
  30   require Logger
  31   require Pleroma.Constants
  32
  33   # For Announce activities, we filter the recipients based on following status for any actors
  34   # that match actual users.  See issue #164 for more information about why this is necessary.
  35   defp get_recipients(%{"type" => "Announce"} = data) do
  36     to = Map.get(data, "to", [])
  37     cc = Map.get(data, "cc", [])
  38     bcc = Map.get(data, "bcc", [])
  39     actor = User.get_cached_by_ap_id(data["actor"])
  40
  41     recipients =
  42       Enum.filter(Enum.concat([to, cc, bcc]), fn recipient ->
  43         case User.get_cached_by_ap_id(recipient) do
  44           nil -> true
  45           user -> User.following?(user, actor)
  46         end
  47       end)
  48
  49     {recipients, to, cc}
  50   end
  51
  52   defp get_recipients(%{"type" => "Create"} = data) do
  53     to = Map.get(data, "to", [])
  54     cc = Map.get(data, "cc", [])
  55     bcc = Map.get(data, "bcc", [])
  56     actor = Map.get(data, "actor", [])
  57     recipients = [to, cc, bcc, [actor]] |> Enum.concat() |> Enum.uniq()
  58     {recipients, to, cc}
  59   end
  60
  61   defp get_recipients(data) do
  62     to = Map.get(data, "to", [])
  63     cc = Map.get(data, "cc", [])
  64     bcc = Map.get(data, "bcc", [])
  65     recipients = Enum.concat([to, cc, bcc])
  66     {recipients, to, cc}
  67   end
  68
  69   defp check_actor_is_active(actor) do
  70     if not is_nil(actor) do
  71       with user <- User.get_cached_by_ap_id(actor),
  72            false <- user.deactivated do
  73         true
  74       else
  75         _e -> false
  76       end
  77     else
  78       true
  79     end
  80   end
  81
  82   defp check_remote_limit(%{"object" => %{"content" => content}}) when not is_nil(content) do
  83     limit = Config.get([:instance, :remote_limit])
  84     String.length(content) <= limit
  85   end
  86
  87   defp check_remote_limit(_), do: true
  88
  89   def increase_note_count_if_public(actor, object) do
  90     if is_public?(object), do: User.increase_note_count(actor), else: {:ok, actor}
  91   end
  92
  93   def decrease_note_count_if_public(actor, object) do
  94     if is_public?(object), do: User.decrease_note_count(actor), else: {:ok, actor}
  95   end
  96
  97   def increase_replies_count_if_reply(%{
  98         "object" => %{"inReplyTo" => reply_ap_id} = object,
  99         "type" => "Create"
 100       }) do
 101     if is_public?(object) do
 102       Object.increase_replies_count(reply_ap_id)
 103     end
 104   end
 105
 106   def increase_replies_count_if_reply(_create_data), do: :noop
 107
 108   def decrease_replies_count_if_reply(%Object{
 109         data: %{"inReplyTo" => reply_ap_id} = object
 110       }) do
 111     if is_public?(object) do
 112       Object.decrease_replies_count(reply_ap_id)
 113     end
 114   end
 115
 116   def decrease_replies_count_if_reply(_object), do: :noop
 117
 118   def increase_poll_votes_if_vote(%{
 119         "object" => %{"inReplyTo" => reply_ap_id, "name" => name},
 120         "type" => "Create"
 121       }) do
 122     Object.increase_vote_count(reply_ap_id, name)
 123   end
 124
 125   def increase_poll_votes_if_vote(_create_data), do: :noop
 126
 127   def insert(map, local \\ true, fake \\ false, bypass_actor_check \\ false) when is_map(map) do
 128     with nil <- Activity.normalize(map),
 129          map <- lazy_put_activity_defaults(map, fake),
 130          true <- bypass_actor_check || check_actor_is_active(map["actor"]),
 131          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
 132          {:ok, map} <- MRF.filter(map),
 133          {recipients, _, _} = get_recipients(map),
 134          {:fake, false, map, recipients} <- {:fake, fake, map, recipients},
 135          {:containment, :ok} <- {:containment, Containment.contain_child(map)},
 136          {:ok, map, object} <- insert_full_object(map) do
 137       {:ok, activity} =
 138         Repo.insert(%Activity{
 139           data: map,
 140           local: local,
 141           actor: map["actor"],
 142           recipients: recipients
 143         })
 144
 145       # Splice in the child object if we have one.
 146       activity =
 147         if not is_nil(object) do
 148           Map.put(activity, :object, object)
 149         else
 150           activity
 151         end
 152
 153       BackgroundWorker.enqueue("fetch_data_for_activity", %{"activity_id" => activity.id})
 154
 155       Notification.create_notifications(activity)
 156
 157       conversation = create_or_bump_conversation(activity, map["actor"])
 158       participations = get_participations(conversation)
 159       stream_out(activity)
 160       stream_out_participations(participations)
 161       {:ok, activity}
 162     else
 163       %Activity{} = activity ->
 164         {:ok, activity}
 165
 166       {:fake, true, map, recipients} ->
 167         activity = %Activity{
 168           data: map,
 169           local: local,
 170           actor: map["actor"],
 171           recipients: recipients,
 172           id: "pleroma:fakeid"
 173         }
 174
 175         Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity)
 176         {:ok, activity}
 177
 178       error ->
 179         {:error, error}
 180     end
 181   end
 182
 183   defp create_or_bump_conversation(activity, actor) do
 184     with {:ok, conversation} <- Conversation.create_or_bump_for(activity),
 185          %User{} = user <- User.get_cached_by_ap_id(actor),
 186          Participation.mark_as_read(user, conversation) do
 187       {:ok, conversation}
 188     end
 189   end
 190
 191   defp get_participations({:ok, conversation}) do
 192     conversation
 193     |> Repo.preload(:participations, force: true)
 194     |> Map.get(:participations)
 195   end
 196
 197   defp get_participations(_), do: []
 198
 199   def stream_out_participations(participations) do
 200     participations =
 201       participations
 202       |> Repo.preload(:user)
 203
 204     Streamer.stream("participation", participations)
 205   end
 206
 207   def stream_out_participations(%Object{data: %{"context" => context}}, user) do
 208     with %Conversation{} = conversation <- Conversation.get_for_ap_id(context),
 209          conversation = Repo.preload(conversation, :participations),
 210          last_activity_id =
 211            fetch_latest_activity_id_for_context(conversation.ap_id, %{
 212              "user" => user,
 213              "blocking_user" => user
 214            }) do
 215       if last_activity_id do
 216         stream_out_participations(conversation.participations)
 217       end
 218     end
 219   end
 220
 221   def stream_out_participations(_, _), do: :noop
 222
 223   def stream_out(%Activity{data: %{"type" => data_type}} = activity)
 224       when data_type in ["Create", "Announce", "Delete"] do
 225     activity
 226     |> Topics.get_activity_topics()
 227     |> Streamer.stream(activity)
 228   end
 229
 230   def stream_out(_activity) do
 231     :noop
 232   end
 233
 234   def create(%{to: to, actor: actor, context: context, object: object} = params, fake \\ false) do
 235     additional = params[:additional] || %{}
 236     # only accept false as false value
 237     local = !(params[:local] == false)
 238     published = params[:published]
 239     quick_insert? = Pleroma.Config.get([:env]) == :benchmark
 240
 241     with create_data <-
 242            make_create_data(
 243              %{to: to, actor: actor, published: published, context: context, object: object},
 244              additional
 245            ),
 246          {:ok, activity} <- insert(create_data, local, fake),
 247          {:fake, false, activity} <- {:fake, fake, activity},
 248          _ <- increase_replies_count_if_reply(create_data),
 249          _ <- increase_poll_votes_if_vote(create_data),
 250          {:quick_insert, false, activity} <- {:quick_insert, quick_insert?, activity},
 251          {:ok, _actor} <- increase_note_count_if_public(actor, activity),
 252          :ok <- maybe_federate(activity) do
 253       {:ok, activity}
 254     else
 255       {:quick_insert, true, activity} ->
 256         {:ok, activity}
 257
 258       {:fake, true, activity} ->
 259         {:ok, activity}
 260
 261       {:error, message} ->
 262         {:error, message}
 263     end
 264   end
 265
 266   def listen(%{to: to, actor: actor, context: context, object: object} = params) do
 267     additional = params[:additional] || %{}
 268     # only accept false as false value
 269     local = !(params[:local] == false)
 270     published = params[:published]
 271
 272     with listen_data <-
 273            make_listen_data(
 274              %{to: to, actor: actor, published: published, context: context, object: object},
 275              additional
 276            ),
 277          {:ok, activity} <- insert(listen_data, local),
 278          :ok <- maybe_federate(activity) do
 279       {:ok, activity}
 280     else
 281       {:error, message} ->
 282         {:error, message}
 283     end
 284   end
 285
 286   def accept(params) do
 287     accept_or_reject("Accept", params)
 288   end
 289
 290   def reject(params) do
 291     accept_or_reject("Reject", params)
 292   end
 293
 294   def accept_or_reject(type, %{to: to, actor: actor, object: object} = params) do
 295     local = Map.get(params, :local, true)
 296     activity_id = Map.get(params, :activity_id, nil)
 297
 298     with data <-
 299            %{"to" => to, "type" => type, "actor" => actor.ap_id, "object" => object}
 300            |> Utils.maybe_put("id", activity_id),
 301          {:ok, activity} <- insert(data, local),
 302          :ok <- maybe_federate(activity) do
 303       {:ok, activity}
 304     end
 305   end
 306
 307   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 308     local = !(params[:local] == false)
 309     activity_id = params[:activity_id]
 310
 311     with data <- %{
 312            "to" => to,
 313            "cc" => cc,
 314            "type" => "Update",
 315            "actor" => actor,
 316            "object" => object
 317          },
 318          data <- Utils.maybe_put(data, "id", activity_id),
 319          {:ok, activity} <- insert(data, local),
 320          :ok <- maybe_federate(activity) do
 321       {:ok, activity}
 322     end
 323   end
 324
 325   def react_with_emoji(user, object, emoji, options \\ []) do
 326     with local <- Keyword.get(options, :local, true),
 327          activity_id <- Keyword.get(options, :activity_id, nil),
 328          Pleroma.Emoji.is_unicode_emoji?(emoji),
 329          reaction_data <- make_emoji_reaction_data(user, object, emoji, activity_id),
 330          {:ok, activity} <- insert(reaction_data, local),
 331          {:ok, object} <- add_emoji_reaction_to_object(activity, object),
 332          :ok <- maybe_federate(activity) do
 333       {:ok, activity, object}
 334     end
 335   end
 336
 337   def unreact_with_emoji(user, reaction_id, options \\ []) do
 338     with local <- Keyword.get(options, :local, true),
 339          activity_id <- Keyword.get(options, :activity_id, nil),
 340          user_ap_id <- user.ap_id,
 341          %Activity{actor: ^user_ap_id} = reaction_activity <- Activity.get_by_ap_id(reaction_id),
 342          object <- Object.normalize(reaction_activity),
 343          unreact_data <- make_undo_data(user, reaction_activity, activity_id),
 344          {:ok, activity} <- insert(unreact_data, local),
 345          {:ok, object} <- remove_emoji_reaction_from_object(reaction_activity, object),
 346          :ok <- maybe_federate(activity) do
 347       {:ok, activity, object}
 348     end
 349   end
 350
 351   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 352   def like(
 353         %User{ap_id: ap_id} = user,
 354         %Object{data: %{"id" => _}} = object,
 355         activity_id \\ nil,
 356         local \\ true
 357       ) do
 358     with nil <- get_existing_like(ap_id, object),
 359          like_data <- make_like_data(user, object, activity_id),
 360          {:ok, activity} <- insert(like_data, local),
 361          {:ok, object} <- add_like_to_object(activity, object),
 362          :ok <- maybe_federate(activity) do
 363       {:ok, activity, object}
 364     else
 365       %Activity{} = activity -> {:ok, activity, object}
 366       error -> {:error, error}
 367     end
 368   end
 369
 370   def unlike(%User{} = actor, %Object{} = object, activity_id \\ nil, local \\ true) do
 371     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 372          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 373          {:ok, unlike_activity} <- insert(unlike_data, local),
 374          {:ok, _activity} <- Repo.delete(like_activity),
 375          {:ok, object} <- remove_like_from_object(like_activity, object),
 376          :ok <- maybe_federate(unlike_activity) do
 377       {:ok, unlike_activity, like_activity, object}
 378     else
 379       _e -> {:ok, object}
 380     end
 381   end
 382
 383   def announce(
 384         %User{ap_id: _} = user,
 385         %Object{data: %{"id" => _}} = object,
 386         activity_id \\ nil,
 387         local \\ true,
 388         public \\ true
 389       ) do
 390     with true <- is_announceable?(object, user, public),
 391          announce_data <- make_announce_data(user, object, activity_id, public),
 392          {:ok, activity} <- insert(announce_data, local),
 393          {:ok, object} <- add_announce_to_object(activity, object),
 394          :ok <- maybe_federate(activity) do
 395       {:ok, activity, object}
 396     else
 397       error -> {:error, error}
 398     end
 399   end
 400
 401   def unannounce(
 402         %User{} = actor,
 403         %Object{} = object,
 404         activity_id \\ nil,
 405         local \\ true
 406       ) do
 407     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 408          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 409          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 410          :ok <- maybe_federate(unannounce_activity),
 411          {:ok, _activity} <- Repo.delete(announce_activity),
 412          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 413       {:ok, unannounce_activity, object}
 414     else
 415       _e -> {:ok, object}
 416     end
 417   end
 418
 419   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 420     with data <- make_follow_data(follower, followed, activity_id),
 421          {:ok, activity} <- insert(data, local),
 422          :ok <- maybe_federate(activity),
 423          _ <- User.set_follow_state_cache(follower.ap_id, followed.ap_id, activity.data["state"]) do
 424       {:ok, activity}
 425     end
 426   end
 427
 428   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 429     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 430          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 431          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 432          {:ok, activity} <- insert(unfollow_data, local),
 433          :ok <- maybe_federate(activity) do
 434       {:ok, activity}
 435     end
 436   end
 437
 438   def delete(%User{ap_id: ap_id, follower_address: follower_address} = user) do
 439     with data <- %{
 440            "to" => [follower_address],
 441            "type" => "Delete",
 442            "actor" => ap_id,
 443            "object" => %{"type" => "Person", "id" => ap_id}
 444          },
 445          {:ok, activity} <- insert(data, true, true, true),
 446          :ok <- maybe_federate(activity) do
 447       {:ok, user}
 448     end
 449   end
 450
 451   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, options \\ []) do
 452     local = Keyword.get(options, :local, true)
 453     activity_id = Keyword.get(options, :activity_id, nil)
 454     actor = Keyword.get(options, :actor, actor)
 455
 456     user = User.get_cached_by_ap_id(actor)
 457     to = (object.data["to"] || []) ++ (object.data["cc"] || [])
 458
 459     with create_activity <- Activity.get_create_by_object_ap_id(id),
 460          data <-
 461            %{
 462              "type" => "Delete",
 463              "actor" => actor,
 464              "object" => id,
 465              "to" => to,
 466              "deleted_activity_id" => create_activity && create_activity.id
 467            }
 468            |> maybe_put("id", activity_id),
 469          {:ok, activity} <- insert(data, local, false),
 470          {:ok, object, _create_activity} <- Object.delete(object),
 471          stream_out_participations(object, user),
 472          _ <- decrease_replies_count_if_reply(object),
 473          {:ok, _actor} <- decrease_note_count_if_public(user, object),
 474          :ok <- maybe_federate(activity) do
 475       {:ok, activity}
 476     end
 477   end
 478
 479   @spec block(User.t(), User.t(), String.t() | nil, boolean) :: {:ok, Activity.t() | nil}
 480   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 481     outgoing_blocks = Config.get([:activitypub, :outgoing_blocks])
 482     unfollow_blocked = Config.get([:activitypub, :unfollow_blocked])
 483
 484     if unfollow_blocked do
 485       follow_activity = fetch_latest_follow(blocker, blocked)
 486       if follow_activity, do: unfollow(blocker, blocked, nil, local)
 487     end
 488
 489     with true <- outgoing_blocks,
 490          block_data <- make_block_data(blocker, blocked, activity_id),
 491          {:ok, activity} <- insert(block_data, local),
 492          :ok <- maybe_federate(activity) do
 493       {:ok, activity}
 494     else
 495       _e -> {:ok, nil}
 496     end
 497   end
 498
 499   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 500     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 501          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 502          {:ok, activity} <- insert(unblock_data, local),
 503          :ok <- maybe_federate(activity) do
 504       {:ok, activity}
 505     end
 506   end
 507
 508   @spec flag(map()) :: {:ok, Activity.t()} | any
 509   def flag(
 510         %{
 511           actor: actor,
 512           context: _context,
 513           account: account,
 514           statuses: statuses,
 515           content: content
 516         } = params
 517       ) do
 518     # only accept false as false value
 519     local = !(params[:local] == false)
 520     forward = !(params[:forward] == false)
 521
 522     additional = params[:additional] || %{}
 523
 524     additional =
 525       if forward do
 526         Map.merge(additional, %{"to" => [], "cc" => [account.ap_id]})
 527       else
 528         Map.merge(additional, %{"to" => [], "cc" => []})
 529       end
 530
 531     with flag_data <- make_flag_data(params, additional),
 532          {:ok, activity} <- insert(flag_data, local),
 533          {:ok, stripped_activity} <- strip_report_status_data(activity),
 534          :ok <- maybe_federate(stripped_activity) do
 535       Enum.each(User.all_superusers(), fn superuser ->
 536         superuser
 537         |> Pleroma.Emails.AdminEmail.report(actor, account, statuses, content)
 538         |> Pleroma.Emails.Mailer.deliver_async()
 539       end)
 540
 541       {:ok, activity}
 542     end
 543   end
 544
 545   def move(%User{} = origin, %User{} = target, local \\ true) do
 546     params = %{
 547       "type" => "Move",
 548       "actor" => origin.ap_id,
 549       "object" => origin.ap_id,
 550       "target" => target.ap_id
 551     }
 552
 553     with true <- origin.ap_id in target.also_known_as,
 554          {:ok, activity} <- insert(params, local) do
 555       maybe_federate(activity)
 556
 557       BackgroundWorker.enqueue("move_following", %{
 558         "origin_id" => origin.id,
 559         "target_id" => target.id
 560       })
 561
 562       {:ok, activity}
 563     else
 564       false -> {:error, "Target account must have the origin in `alsoKnownAs`"}
 565       err -> err
 566     end
 567   end
 568
 569   defp fetch_activities_for_context_query(context, opts) do
 570     public = [Pleroma.Constants.as_public()]
 571
 572     recipients =
 573       if opts["user"],
 574         do: [opts["user"].ap_id | User.following(opts["user"])] ++ public,
 575         else: public
 576
 577     from(activity in Activity)
 578     |> maybe_preload_objects(opts)
 579     |> maybe_preload_bookmarks(opts)
 580     |> maybe_set_thread_muted_field(opts)
 581     |> restrict_blocked(opts)
 582     |> restrict_recipients(recipients, opts["user"])
 583     |> where(
 584       [activity],
 585       fragment(
 586         "?->>'type' = ? and ?->>'context' = ?",
 587         activity.data,
 588         "Create",
 589         activity.data,
 590         ^context
 591       )
 592     )
 593     |> exclude_poll_votes(opts)
 594     |> exclude_id(opts)
 595     |> order_by([activity], desc: activity.id)
 596   end
 597
 598   @spec fetch_activities_for_context(String.t(), keyword() | map()) :: [Activity.t()]
 599   def fetch_activities_for_context(context, opts \\ %{}) do
 600     context
 601     |> fetch_activities_for_context_query(opts)
 602     |> Repo.all()
 603   end
 604
 605   @spec fetch_latest_activity_id_for_context(String.t(), keyword() | map()) ::
 606           FlakeId.Ecto.CompatType.t() | nil
 607   def fetch_latest_activity_id_for_context(context, opts \\ %{}) do
 608     context
 609     |> fetch_activities_for_context_query(Map.merge(%{"skip_preload" => true}, opts))
 610     |> limit(1)
 611     |> select([a], a.id)
 612     |> Repo.one()
 613   end
 614
 615   def fetch_public_activities(opts \\ %{}, pagination \\ :keyset) do
 616     opts = Map.drop(opts, ["user"])
 617
 618     [Pleroma.Constants.as_public()]
 619     |> fetch_activities_query(opts)
 620     |> restrict_unlisted()
 621     |> Pagination.fetch_paginated(opts, pagination)
 622   end
 623
 624   @valid_visibilities ~w[direct unlisted public private]
 625
 626   defp restrict_visibility(query, %{visibility: visibility})
 627        when is_list(visibility) do
 628     if Enum.all?(visibility, &(&1 in @valid_visibilities)) do
 629       query =
 630         from(
 631           a in query,
 632           where:
 633             fragment(
 634               "activity_visibility(?, ?, ?) = ANY (?)",
 635               a.actor,
 636               a.recipients,
 637               a.data,
 638               ^visibility
 639             )
 640         )
 641
 642       query
 643     else
 644       Logger.error("Could not restrict visibility to #{visibility}")
 645     end
 646   end
 647
 648   defp restrict_visibility(query, %{visibility: visibility})
 649        when visibility in @valid_visibilities do
 650     from(
 651       a in query,
 652       where:
 653         fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 654     )
 655   end
 656
 657   defp restrict_visibility(_query, %{visibility: visibility})
 658        when visibility not in @valid_visibilities do
 659     Logger.error("Could not restrict visibility to #{visibility}")
 660   end
 661
 662   defp restrict_visibility(query, _visibility), do: query
 663
 664   defp exclude_visibility(query, %{"exclude_visibilities" => visibility})
 665        when is_list(visibility) do
 666     if Enum.all?(visibility, &(&1 in @valid_visibilities)) do
 667       from(
 668         a in query,
 669         where:
 670           not fragment(
 671             "activity_visibility(?, ?, ?) = ANY (?)",
 672             a.actor,
 673             a.recipients,
 674             a.data,
 675             ^visibility
 676           )
 677       )
 678     else
 679       Logger.error("Could not exclude visibility to #{visibility}")
 680       query
 681     end
 682   end
 683
 684   defp exclude_visibility(query, %{"exclude_visibilities" => visibility})
 685        when visibility in @valid_visibilities do
 686     from(
 687       a in query,
 688       where:
 689         not fragment(
 690           "activity_visibility(?, ?, ?) = ?",
 691           a.actor,
 692           a.recipients,
 693           a.data,
 694           ^visibility
 695         )
 696     )
 697   end
 698
 699   defp exclude_visibility(query, %{"exclude_visibilities" => visibility})
 700        when visibility not in @valid_visibilities do
 701     Logger.error("Could not exclude visibility to #{visibility}")
 702     query
 703   end
 704
 705   defp exclude_visibility(query, _visibility), do: query
 706
 707   defp restrict_thread_visibility(query, _, %{skip_thread_containment: true} = _),
 708     do: query
 709
 710   defp restrict_thread_visibility(
 711          query,
 712          %{"user" => %User{skip_thread_containment: true}},
 713          _
 714        ),
 715        do: query
 716
 717   defp restrict_thread_visibility(query, %{"user" => %User{ap_id: ap_id}}, _) do
 718     from(
 719       a in query,
 720       where: fragment("thread_visibility(?, (?)->>'id') = true", ^ap_id, a.data)
 721     )
 722   end
 723
 724   defp restrict_thread_visibility(query, _, _), do: query
 725
 726   def fetch_user_abstract_activities(user, reading_user, params \\ %{}) do
 727     params =
 728       params
 729       |> Map.put("user", reading_user)
 730       |> Map.put("actor_id", user.ap_id)
 731       |> Map.put("whole_db", true)
 732
 733     recipients =
 734       user_activities_recipients(%{
 735         "godmode" => params["godmode"],
 736         "reading_user" => reading_user
 737       })
 738
 739     fetch_activities(recipients, params)
 740     |> Enum.reverse()
 741   end
 742
 743   def fetch_user_activities(user, reading_user, params \\ %{}) do
 744     params =
 745       params
 746       |> Map.put("type", ["Create", "Announce"])
 747       |> Map.put("user", reading_user)
 748       |> Map.put("actor_id", user.ap_id)
 749       |> Map.put("whole_db", true)
 750       |> Map.put("pinned_activity_ids", user.pinned_activities)
 751
 752     recipients =
 753       user_activities_recipients(%{
 754         "godmode" => params["godmode"],
 755         "reading_user" => reading_user
 756       })
 757
 758     fetch_activities(recipients, params)
 759     |> Enum.reverse()
 760   end
 761
 762   def fetch_instance_activities(params) do
 763     params =
 764       params
 765       |> Map.put("type", ["Create", "Announce"])
 766       |> Map.put("instance", params["instance"])
 767       |> Map.put("whole_db", true)
 768
 769     fetch_activities([Pleroma.Constants.as_public()], params, :offset)
 770     |> Enum.reverse()
 771   end
 772
 773   defp user_activities_recipients(%{"godmode" => true}) do
 774     []
 775   end
 776
 777   defp user_activities_recipients(%{"reading_user" => reading_user}) do
 778     if reading_user do
 779       [Pleroma.Constants.as_public()] ++ [reading_user.ap_id | User.following(reading_user)]
 780     else
 781       [Pleroma.Constants.as_public()]
 782     end
 783   end
 784
 785   defp restrict_since(query, %{"since_id" => ""}), do: query
 786
 787   defp restrict_since(query, %{"since_id" => since_id}) do
 788     from(activity in query, where: activity.id > ^since_id)
 789   end
 790
 791   defp restrict_since(query, _), do: query
 792
 793   defp restrict_tag_reject(_query, %{"tag_reject" => _tag_reject, "skip_preload" => true}) do
 794     raise "Can't use the child object without preloading!"
 795   end
 796
 797   defp restrict_tag_reject(query, %{"tag_reject" => tag_reject})
 798        when is_list(tag_reject) and tag_reject != [] do
 799     from(
 800       [_activity, object] in query,
 801       where: fragment("not (?)->'tag' \\?| (?)", object.data, ^tag_reject)
 802     )
 803   end
 804
 805   defp restrict_tag_reject(query, _), do: query
 806
 807   defp restrict_tag_all(_query, %{"tag_all" => _tag_all, "skip_preload" => true}) do
 808     raise "Can't use the child object without preloading!"
 809   end
 810
 811   defp restrict_tag_all(query, %{"tag_all" => tag_all})
 812        when is_list(tag_all) and tag_all != [] do
 813     from(
 814       [_activity, object] in query,
 815       where: fragment("(?)->'tag' \\?& (?)", object.data, ^tag_all)
 816     )
 817   end
 818
 819   defp restrict_tag_all(query, _), do: query
 820
 821   defp restrict_tag(_query, %{"tag" => _tag, "skip_preload" => true}) do
 822     raise "Can't use the child object without preloading!"
 823   end
 824
 825   defp restrict_tag(query, %{"tag" => tag}) when is_list(tag) do
 826     from(
 827       [_activity, object] in query,
 828       where: fragment("(?)->'tag' \\?| (?)", object.data, ^tag)
 829     )
 830   end
 831
 832   defp restrict_tag(query, %{"tag" => tag}) when is_binary(tag) do
 833     from(
 834       [_activity, object] in query,
 835       where: fragment("(?)->'tag' \\? (?)", object.data, ^tag)
 836     )
 837   end
 838
 839   defp restrict_tag(query, _), do: query
 840
 841   defp restrict_recipients(query, [], _user), do: query
 842
 843   defp restrict_recipients(query, recipients, nil) do
 844     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 845   end
 846
 847   defp restrict_recipients(query, recipients, user) do
 848     from(
 849       activity in query,
 850       where: fragment("? && ?", ^recipients, activity.recipients),
 851       or_where: activity.actor == ^user.ap_id
 852     )
 853   end
 854
 855   defp restrict_local(query, %{"local_only" => true}) do
 856     from(activity in query, where: activity.local == true)
 857   end
 858
 859   defp restrict_local(query, _), do: query
 860
 861   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 862     from(activity in query, where: activity.actor == ^actor_id)
 863   end
 864
 865   defp restrict_actor(query, _), do: query
 866
 867   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 868     from(activity in query, where: fragment("?->>'type' = ?", activity.data, ^type))
 869   end
 870
 871   defp restrict_type(query, %{"type" => type}) do
 872     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 873   end
 874
 875   defp restrict_type(query, _), do: query
 876
 877   defp restrict_state(query, %{"state" => state}) do
 878     from(activity in query, where: fragment("?->>'state' = ?", activity.data, ^state))
 879   end
 880
 881   defp restrict_state(query, _), do: query
 882
 883   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 884     from(
 885       [_activity, object] in query,
 886       where: fragment("(?)->'likes' \\? (?)", object.data, ^ap_id)
 887     )
 888   end
 889
 890   defp restrict_favorited_by(query, _), do: query
 891
 892   defp restrict_media(_query, %{"only_media" => _val, "skip_preload" => true}) do
 893     raise "Can't use the child object without preloading!"
 894   end
 895
 896   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 897     from(
 898       [_activity, object] in query,
 899       where: fragment("not (?)->'attachment' = (?)", object.data, ^[])
 900     )
 901   end
 902
 903   defp restrict_media(query, _), do: query
 904
 905   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 906     from(
 907       [_activity, object] in query,
 908       where: fragment("?->>'inReplyTo' is null", object.data)
 909     )
 910   end
 911
 912   defp restrict_replies(query, _), do: query
 913
 914   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 915     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 916   end
 917
 918   defp restrict_reblogs(query, _), do: query
 919
 920   defp restrict_muted(query, %{"with_muted" => val}) when val in [true, "true", "1"], do: query
 921
 922   defp restrict_muted(query, %{"muting_user" => %User{} = user} = opts) do
 923     mutes = opts["muted_users_ap_ids"] || User.muted_users_ap_ids(user)
 924
 925     query =
 926       from([activity] in query,
 927         where: fragment("not (? = ANY(?))", activity.actor, ^mutes),
 928         where: fragment("not (?->'to' \\?| ?)", activity.data, ^mutes)
 929       )
 930
 931     unless opts["skip_preload"] do
 932       from([thread_mute: tm] in query, where: is_nil(tm.user_id))
 933     else
 934       query
 935     end
 936   end
 937
 938   defp restrict_muted(query, _), do: query
 939
 940   defp restrict_blocked(query, %{"blocking_user" => %User{} = user} = opts) do
 941     blocked_ap_ids = opts["blocked_users_ap_ids"] || User.blocked_users_ap_ids(user)
 942     domain_blocks = user.domain_blocks || []
 943
 944     query =
 945       if has_named_binding?(query, :object), do: query, else: Activity.with_joined_object(query)
 946
 947     from(
 948       [activity, object: o] in query,
 949       where: fragment("not (? = ANY(?))", activity.actor, ^blocked_ap_ids),
 950       where: fragment("not (? && ?)", activity.recipients, ^blocked_ap_ids),
 951       where:
 952         fragment(
 953           "not (?->>'type' = 'Announce' and ?->'to' \\?| ?)",
 954           activity.data,
 955           activity.data,
 956           ^blocked_ap_ids
 957         ),
 958       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks),
 959       where: fragment("not (split_part(?->>'actor', '/', 3) = ANY(?))", o.data, ^domain_blocks)
 960     )
 961   end
 962
 963   defp restrict_blocked(query, _), do: query
 964
 965   defp restrict_unlisted(query) do
 966     from(
 967       activity in query,
 968       where:
 969         fragment(
 970           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 971           activity.data,
 972           ^[Pleroma.Constants.as_public()]
 973         )
 974     )
 975   end
 976
 977   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 978     from(activity in query, where: activity.id in ^ids)
 979   end
 980
 981   defp restrict_pinned(query, _), do: query
 982
 983   defp restrict_muted_reblogs(query, %{"muting_user" => %User{} = user} = opts) do
 984     muted_reblogs = opts["reblog_muted_users_ap_ids"] || User.reblog_muted_users_ap_ids(user)
 985
 986     from(
 987       activity in query,
 988       where:
 989         fragment(
 990           "not ( ?->>'type' = 'Announce' and ? = ANY(?))",
 991           activity.data,
 992           activity.actor,
 993           ^muted_reblogs
 994         )
 995     )
 996   end
 997
 998   defp restrict_muted_reblogs(query, _), do: query
 999
1000   defp restrict_instance(query, %{"instance" => instance}) do
1001     users =
1002       from(
1003         u in User,
1004         select: u.ap_id,
1005         where: fragment("? LIKE ?", u.nickname, ^"%@#{instance}")
1006       )
1007       |> Repo.all()
1008
1009     from(activity in query, where: activity.actor in ^users)
1010   end
1011
1012   defp restrict_instance(query, _), do: query
1013
1014   defp exclude_poll_votes(query, %{"include_poll_votes" => true}), do: query
1015
1016   defp exclude_poll_votes(query, _) do
1017     if has_named_binding?(query, :object) do
1018       from([activity, object: o] in query,
1019         where: fragment("not(?->>'type' = ?)", o.data, "Answer")
1020       )
1021     else
1022       query
1023     end
1024   end
1025
1026   defp exclude_id(query, %{"exclude_id" => id}) when is_binary(id) do
1027     from(activity in query, where: activity.id != ^id)
1028   end
1029
1030   defp exclude_id(query, _), do: query
1031
1032   defp maybe_preload_objects(query, %{"skip_preload" => true}), do: query
1033
1034   defp maybe_preload_objects(query, _) do
1035     query
1036     |> Activity.with_preloaded_object()
1037   end
1038
1039   defp maybe_preload_bookmarks(query, %{"skip_preload" => true}), do: query
1040
1041   defp maybe_preload_bookmarks(query, opts) do
1042     query
1043     |> Activity.with_preloaded_bookmark(opts["user"])
1044   end
1045
1046   defp maybe_set_thread_muted_field(query, %{"skip_preload" => true}), do: query
1047
1048   defp maybe_set_thread_muted_field(query, opts) do
1049     query
1050     |> Activity.with_set_thread_muted_field(opts["muting_user"] || opts["user"])
1051   end
1052
1053   defp maybe_order(query, %{order: :desc}) do
1054     query
1055     |> order_by(desc: :id)
1056   end
1057
1058   defp maybe_order(query, %{order: :asc}) do
1059     query
1060     |> order_by(asc: :id)
1061   end
1062
1063   defp maybe_order(query, _), do: query
1064
1065   defp fetch_activities_query_ap_ids_ops(opts) do
1066     source_user = opts["muting_user"]
1067     ap_id_relations = if source_user, do: [:mute, :reblog_mute], else: []
1068
1069     ap_id_relations =
1070       ap_id_relations ++
1071         if opts["blocking_user"] && opts["blocking_user"] == source_user do
1072           [:block]
1073         else
1074           []
1075         end
1076
1077     preloaded_ap_ids = User.outgoing_relations_ap_ids(source_user, ap_id_relations)
1078
1079     restrict_blocked_opts = Map.merge(%{"blocked_users_ap_ids" => preloaded_ap_ids[:block]}, opts)
1080     restrict_muted_opts = Map.merge(%{"muted_users_ap_ids" => preloaded_ap_ids[:mute]}, opts)
1081
1082     restrict_muted_reblogs_opts =
1083       Map.merge(%{"reblog_muted_users_ap_ids" => preloaded_ap_ids[:reblog_mute]}, opts)
1084
1085     {restrict_blocked_opts, restrict_muted_opts, restrict_muted_reblogs_opts}
1086   end
1087
1088   def fetch_activities_query(recipients, opts \\ %{}) do
1089     {restrict_blocked_opts, restrict_muted_opts, restrict_muted_reblogs_opts} =
1090       fetch_activities_query_ap_ids_ops(opts)
1091
1092     config = %{
1093       skip_thread_containment: Config.get([:instance, :skip_thread_containment])
1094     }
1095
1096     Activity
1097     |> maybe_preload_objects(opts)
1098     |> maybe_preload_bookmarks(opts)
1099     |> maybe_set_thread_muted_field(opts)
1100     |> maybe_order(opts)
1101     |> restrict_recipients(recipients, opts["user"])
1102     |> restrict_tag(opts)
1103     |> restrict_tag_reject(opts)
1104     |> restrict_tag_all(opts)
1105     |> restrict_since(opts)
1106     |> restrict_local(opts)
1107     |> restrict_actor(opts)
1108     |> restrict_type(opts)
1109     |> restrict_state(opts)
1110     |> restrict_favorited_by(opts)
1111     |> restrict_blocked(restrict_blocked_opts)
1112     |> restrict_muted(restrict_muted_opts)
1113     |> restrict_media(opts)
1114     |> restrict_visibility(opts)
1115     |> restrict_thread_visibility(opts, config)
1116     |> restrict_replies(opts)
1117     |> restrict_reblogs(opts)
1118     |> restrict_pinned(opts)
1119     |> restrict_muted_reblogs(restrict_muted_reblogs_opts)
1120     |> restrict_instance(opts)
1121     |> Activity.restrict_deactivated_users()
1122     |> exclude_poll_votes(opts)
1123     |> exclude_visibility(opts)
1124   end
1125
1126   def fetch_activities(recipients, opts \\ %{}, pagination \\ :keyset) do
1127     list_memberships = Pleroma.List.memberships(opts["user"])
1128
1129     fetch_activities_query(recipients ++ list_memberships, opts)
1130     |> Pagination.fetch_paginated(opts, pagination)
1131     |> Enum.reverse()
1132     |> maybe_update_cc(list_memberships, opts["user"])
1133   end
1134
1135   defp maybe_update_cc(activities, list_memberships, %User{ap_id: user_ap_id})
1136        when is_list(list_memberships) and length(list_memberships) > 0 do
1137     Enum.map(activities, fn
1138       %{data: %{"bcc" => bcc}} = activity when is_list(bcc) and length(bcc) > 0 ->
1139         if Enum.any?(bcc, &(&1 in list_memberships)) do
1140           update_in(activity.data["cc"], &[user_ap_id | &1])
1141         else
1142           activity
1143         end
1144
1145       activity ->
1146         activity
1147     end)
1148   end
1149
1150   defp maybe_update_cc(activities, _, _), do: activities
1151
1152   def fetch_activities_bounded_query(query, recipients, recipients_with_public) do
1153     from(activity in query,
1154       where:
1155         fragment("? && ?", activity.recipients, ^recipients) or
1156           (fragment("? && ?", activity.recipients, ^recipients_with_public) and
1157              ^Pleroma.Constants.as_public() in activity.recipients)
1158     )
1159   end
1160
1161   def fetch_activities_bounded(
1162         recipients,
1163         recipients_with_public,
1164         opts \\ %{},
1165         pagination \\ :keyset
1166       ) do
1167     fetch_activities_query([], opts)
1168     |> fetch_activities_bounded_query(recipients, recipients_with_public)
1169     |> Pagination.fetch_paginated(opts, pagination)
1170     |> Enum.reverse()
1171   end
1172
1173   def upload(file, opts \\ []) do
1174     with {:ok, data} <- Upload.store(file, opts) do
1175       obj_data =
1176         if opts[:actor] do
1177           Map.put(data, "actor", opts[:actor])
1178         else
1179           data
1180         end
1181
1182       Repo.insert(%Object{data: obj_data})
1183     end
1184   end
1185
1186   defp object_to_user_data(data) do
1187     avatar =
1188       data["icon"]["url"] &&
1189         %{
1190           "type" => "Image",
1191           "url" => [%{"href" => data["icon"]["url"]}]
1192         }
1193
1194     banner =
1195       data["image"]["url"] &&
1196         %{
1197           "type" => "Image",
1198           "url" => [%{"href" => data["image"]["url"]}]
1199         }
1200
1201     fields =
1202       data
1203       |> Map.get("attachment", [])
1204       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
1205       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
1206
1207     locked = data["manuallyApprovesFollowers"] || false
1208     data = Transmogrifier.maybe_fix_user_object(data)
1209     discoverable = data["discoverable"] || false
1210     invisible = data["invisible"] || false
1211
1212     user_data = %{
1213       ap_id: data["id"],
1214       ap_enabled: true,
1215       source_data: data,
1216       banner: banner,
1217       fields: fields,
1218       locked: locked,
1219       discoverable: discoverable,
1220       invisible: invisible,
1221       avatar: avatar,
1222       name: data["name"],
1223       follower_address: data["followers"],
1224       following_address: data["following"],
1225       bio: data["summary"],
1226       also_known_as: Map.get(data, "alsoKnownAs", [])
1227     }
1228
1229     # nickname can be nil because of virtual actors
1230     user_data =
1231       if data["preferredUsername"] do
1232         Map.put(
1233           user_data,
1234           :nickname,
1235           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
1236         )
1237       else
1238         Map.put(user_data, :nickname, nil)
1239       end
1240
1241     {:ok, user_data}
1242   end
1243
1244   def fetch_follow_information_for_user(user) do
1245     with {:ok, following_data} <-
1246            Fetcher.fetch_and_contain_remote_object_from_id(user.following_address),
1247          following_count when is_integer(following_count) <- following_data["totalItems"],
1248          {:ok, hide_follows} <- collection_private(following_data),
1249          {:ok, followers_data} <-
1250            Fetcher.fetch_and_contain_remote_object_from_id(user.follower_address),
1251          followers_count when is_integer(followers_count) <- followers_data["totalItems"],
1252          {:ok, hide_followers} <- collection_private(followers_data) do
1253       {:ok,
1254        %{
1255          hide_follows: hide_follows,
1256          follower_count: followers_count,
1257          following_count: following_count,
1258          hide_followers: hide_followers
1259        }}
1260     else
1261       {:error, _} = e ->
1262         e
1263
1264       e ->
1265         {:error, e}
1266     end
1267   end
1268
1269   defp maybe_update_follow_information(data) do
1270     with {:enabled, true} <-
1271            {:enabled, Pleroma.Config.get([:instance, :external_user_synchronization])},
1272          {:ok, info} <- fetch_follow_information_for_user(data) do
1273       info = Map.merge(data[:info] || %{}, info)
1274       Map.put(data, :info, info)
1275     else
1276       {:enabled, false} ->
1277         data
1278
1279       e ->
1280         Logger.error(
1281           "Follower/Following counter update for #{data.ap_id} failed.\n" <> inspect(e)
1282         )
1283
1284         data
1285     end
1286   end
1287
1288   defp collection_private(%{"first" => first}) do
1289     if is_map(first) and
1290          first["type"] in ["CollectionPage", "OrderedCollectionPage"] do
1291       {:ok, false}
1292     else
1293       with {:ok, %{"type" => type}} when type in ["CollectionPage", "OrderedCollectionPage"] <-
1294              Fetcher.fetch_and_contain_remote_object_from_id(first) do
1295         {:ok, false}
1296       else
1297         {:error, {:ok, %{status: code}}} when code in [401, 403] ->
1298           {:ok, true}
1299
1300         {:error, _} = e ->
1301           e
1302
1303         e ->
1304           {:error, e}
1305       end
1306     end
1307   end
1308
1309   defp collection_private(_data), do: {:ok, true}
1310
1311   def user_data_from_user_object(data) do
1312     with {:ok, data} <- MRF.filter(data),
1313          {:ok, data} <- object_to_user_data(data) do
1314       {:ok, data}
1315     else
1316       e -> {:error, e}
1317     end
1318   end
1319
1320   def fetch_and_prepare_user_from_ap_id(ap_id) do
1321     with {:ok, data} <- Fetcher.fetch_and_contain_remote_object_from_id(ap_id),
1322          {:ok, data} <- user_data_from_user_object(data),
1323          data <- maybe_update_follow_information(data) do
1324       {:ok, data}
1325     else
1326       e ->
1327         Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
1328         {:error, e}
1329     end
1330   end
1331
1332   def make_user_from_ap_id(ap_id) do
1333     if _user = User.get_cached_by_ap_id(ap_id) do
1334       Transmogrifier.upgrade_user_from_ap_id(ap_id)
1335     else
1336       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
1337         User.insert_or_update_user(data)
1338       else
1339         e -> {:error, e}
1340       end
1341     end
1342   end
1343
1344   def make_user_from_nickname(nickname) do
1345     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
1346       make_user_from_ap_id(ap_id)
1347     else
1348       _e -> {:error, "No AP id in WebFinger"}
1349     end
1350   end
1351
1352   # filter out broken threads
1353   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
1354     entire_thread_visible_for_user?(activity, user)
1355   end
1356
1357   # do post-processing on a specific activity
1358   def contain_activity(%Activity{} = activity, %User{} = user) do
1359     contain_broken_threads(activity, user)
1360   end
1361
1362   def fetch_direct_messages_query do
1363     Activity
1364     |> restrict_type(%{"type" => "Create"})
1365     |> restrict_visibility(%{visibility: "direct"})
1366     |> order_by([activity], asc: activity.id)
1367   end
1368 end