git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14   @rewrite_policy Keyword.get(@instance, :rewrite_policy)
  15
  16   def get_recipients(data) do
  17     (data["to"] || []) ++ (data["cc"] || [])
  18   end
  19
  20   def insert(map, local \\ true) when is_map(map) do
  21     with nil <- Activity.get_by_ap_id(map["id"]),
  22          map <- lazy_put_activity_defaults(map),
  23          {:ok, map} <- @rewrite_policy.filter(map),
  24          :ok <- insert_full_object(map) do
  25       {:ok, activity} =
  26         Repo.insert(%Activity{
  27           data: map,
  28           local: local,
  29           actor: map["actor"],
  30           recipients: get_recipients(map)
  31         })
  32
  33       Notification.create_notifications(activity)
  34       stream_out(activity)
  35       {:ok, activity}
  36     else
  37       %Activity{} = activity -> {:ok, activity}
  38       error -> {:error, error}
  39     end
  40   end
  41
  42   def stream_out(activity) do
  43     public = "https://www.w3.org/ns/activitystreams#Public"
  44
  45     if activity.data["type"] in ["Create", "Announce"] do
  46       Pleroma.Web.Streamer.stream("user", activity)
  47
  48       if Enum.member?(activity.data["to"], public) do
  49         Pleroma.Web.Streamer.stream("public", activity)
  50
  51         if activity.local do
  52           Pleroma.Web.Streamer.stream("public:local", activity)
  53         end
  54       else
  55         if !Enum.member?(activity.data["cc"] || [], public) &&
  56              !Enum.member?(
  57                activity.data["to"],
  58                User.get_by_ap_id(activity.data["actor"]).follower_address
  59              ),
  60            do: Pleroma.Web.Streamer.stream("direct", activity)
  61       end
  62     end
  63   end
  64
  65   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  66     additional = params[:additional] || %{}
  67     # only accept false as false value
  68     local = !(params[:local] == false)
  69     published = params[:published]
  70
  71     with create_data <-
  72            make_create_data(
  73              %{to: to, actor: actor, published: published, context: context, object: object},
  74              additional
  75            ),
  76          {:ok, activity} <- insert(create_data, local),
  77          :ok <- maybe_federate(activity),
  78          {:ok, _actor} <- User.increase_note_count(actor) do
  79       {:ok, activity}
  80     end
  81   end
  82
  83   def accept(%{to: to, actor: actor, object: object} = params) do
  84     # only accept false as false value
  85     local = !(params[:local] == false)
  86
  87     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  88          {:ok, activity} <- insert(data, local),
  89          :ok <- maybe_federate(activity) do
  90       {:ok, activity}
  91     end
  92   end
  93
  94   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  95     # only accept false as false value
  96     local = !(params[:local] == false)
  97
  98     with data <- %{
  99            "to" => to,
 100            "cc" => cc,
 101            "type" => "Update",
 102            "actor" => actor,
 103            "object" => object
 104          },
 105          {:ok, activity} <- insert(data, local),
 106          :ok <- maybe_federate(activity) do
 107       {:ok, activity}
 108     end
 109   end
 110
 111   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 112   def like(
 113         %User{ap_id: ap_id} = user,
 114         %Object{data: %{"id" => _}} = object,
 115         activity_id \\ nil,
 116         local \\ true
 117       ) do
 118     with nil <- get_existing_like(ap_id, object),
 119          like_data <- make_like_data(user, object, activity_id),
 120          {:ok, activity} <- insert(like_data, local),
 121          {:ok, object} <- add_like_to_object(activity, object),
 122          :ok <- maybe_federate(activity) do
 123       {:ok, activity, object}
 124     else
 125       %Activity{} = activity -> {:ok, activity, object}
 126       error -> {:error, error}
 127     end
 128   end
 129
 130   def unlike(%User{} = actor, %Object{} = object) do
 131     with %Activity{} = activity <- get_existing_like(actor.ap_id, object),
 132          {:ok, _activity} <- Repo.delete(activity),
 133          {:ok, object} <- remove_like_from_object(activity, object) do
 134       {:ok, object}
 135     else
 136       _e -> {:ok, object}
 137     end
 138   end
 139
 140   def announce(
 141         %User{ap_id: _} = user,
 142         %Object{data: %{"id" => _}} = object,
 143         activity_id \\ nil,
 144         local \\ true
 145       ) do
 146     with true <- is_public?(object),
 147          announce_data <- make_announce_data(user, object, activity_id),
 148          {:ok, activity} <- insert(announce_data, local),
 149          {:ok, object} <- add_announce_to_object(activity, object),
 150          :ok <- maybe_federate(activity) do
 151       {:ok, activity, object}
 152     else
 153       error -> {:error, error}
 154     end
 155   end
 156
 157   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 158     with data <- make_follow_data(follower, followed, activity_id),
 159          {:ok, activity} <- insert(data, local),
 160          :ok <- maybe_federate(activity) do
 161       {:ok, activity}
 162     end
 163   end
 164
 165   def unfollow(follower, followed, local \\ true) do
 166     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 167          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
 168          {:ok, activity} <- insert(unfollow_data, local),
 169          :ok,
 170          maybe_federate(activity) do
 171       {:ok, activity}
 172     end
 173   end
 174
 175   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 176     user = User.get_cached_by_ap_id(actor)
 177
 178     data = %{
 179       "type" => "Delete",
 180       "actor" => actor,
 181       "object" => id,
 182       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 183     }
 184
 185     with Repo.delete(object),
 186          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 187          {:ok, activity} <- insert(data, local),
 188          :ok <- maybe_federate(activity),
 189          {:ok, _actor} <- User.decrease_note_count(user) do
 190       {:ok, activity}
 191     end
 192   end
 193
 194   def fetch_activities_for_context(context, opts \\ %{}) do
 195     public = ["https://www.w3.org/ns/activitystreams#Public"]
 196
 197     recipients =
 198       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 199
 200     query = from(activity in Activity)
 201
 202     query =
 203       query
 204       |> restrict_blocked(opts)
 205       |> restrict_recipients(recipients, opts["user"])
 206
 207     query =
 208       from(
 209         activity in query,
 210         where:
 211           fragment(
 212             "?->>'type' = ? and ?->>'context' = ?",
 213             activity.data,
 214             "Create",
 215             activity.data,
 216             ^context
 217           ),
 218         order_by: [desc: :id]
 219       )
 220
 221     Repo.all(query)
 222   end
 223
 224   # TODO: Make this work properly with unlisted.
 225   def fetch_public_activities(opts \\ %{}) do
 226     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 227
 228     q
 229     |> Repo.all()
 230     |> Enum.reverse()
 231   end
 232
 233   @valid_visibilities ~w[direct unlisted public private]
 234
 235   defp restrict_visibility(query, %{visibility: "direct"}) do
 236     public = "https://www.w3.org/ns/activitystreams#Public"
 237
 238     from(
 239       activity in query,
 240       join: sender in User,
 241       on: sender.ap_id == activity.actor,
 242       # Are non-direct statuses with no to/cc possible?
 243       where:
 244         fragment("not coalesce(data->'to' \\? ?, false)", ^public) and
 245           fragment("not coalesce(data->'cc' \\? ?, false)", ^public) and
 246           fragment("not coalesce(data->'to' \\? ?, false)", sender.follower_address)
 247     )
 248   end
 249
 250   defp restrict_visibility(_query, %{visibility: visibility})
 251        when visibility not in @valid_visibilities do
 252     Logger.error("Could not restrict visibility to #{visibility}")
 253   end
 254
 255   defp restrict_visibility(query, _visibility), do: query
 256
 257   defp restrict_since(query, %{"since_id" => since_id}) do
 258     from(activity in query, where: activity.id > ^since_id)
 259   end
 260
 261   defp restrict_since(query, _), do: query
 262
 263   defp restrict_tag(query, %{"tag" => tag}) do
 264     from(
 265       activity in query,
 266       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 267     )
 268   end
 269
 270   defp restrict_tag(query, _), do: query
 271
 272   defp restrict_recipients(query, [], _user), do: query
 273
 274   defp restrict_recipients(query, recipients, nil) do
 275     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 276   end
 277
 278   defp restrict_recipients(query, recipients, user) do
 279     from(
 280       activity in query,
 281       where: fragment("? && ?", ^recipients, activity.recipients),
 282       or_where: activity.actor == ^user.ap_id
 283     )
 284   end
 285
 286   defp restrict_limit(query, %{"limit" => limit}) do
 287     from(activity in query, limit: ^limit)
 288   end
 289
 290   defp restrict_limit(query, _), do: query
 291
 292   defp restrict_local(query, %{"local_only" => true}) do
 293     from(activity in query, where: activity.local == true)
 294   end
 295
 296   defp restrict_local(query, _), do: query
 297
 298   defp restrict_max(query, %{"max_id" => max_id}) do
 299     from(activity in query, where: activity.id < ^max_id)
 300   end
 301
 302   defp restrict_max(query, _), do: query
 303
 304   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 305     from(activity in query, where: activity.actor == ^actor_id)
 306   end
 307
 308   defp restrict_actor(query, _), do: query
 309
 310   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 311     restrict_type(query, %{"type" => [type]})
 312   end
 313
 314   defp restrict_type(query, %{"type" => type}) do
 315     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 316   end
 317
 318   defp restrict_type(query, _), do: query
 319
 320   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 321     from(
 322       activity in query,
 323       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 324     )
 325   end
 326
 327   defp restrict_favorited_by(query, _), do: query
 328
 329   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 330     from(
 331       activity in query,
 332       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 333     )
 334   end
 335
 336   defp restrict_media(query, _), do: query
 337
 338   # Only search through last 100_000 activities by default
 339   defp restrict_recent(query, %{"whole_db" => true}), do: query
 340
 341   defp restrict_recent(query, _) do
 342     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 343
 344     from(activity in query, where: activity.id > ^since)
 345   end
 346
 347   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 348     blocks = info["blocks"] || []
 349
 350     from(
 351       activity in query,
 352       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 353       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks)
 354     )
 355   end
 356
 357   defp restrict_blocked(query, _), do: query
 358
 359   def fetch_activities_query(recipients, opts \\ %{}) do
 360     base_query =
 361       from(
 362         activity in Activity,
 363         limit: 20,
 364         order_by: [fragment("? desc nulls last", activity.id)]
 365       )
 366
 367     base_query
 368     |> restrict_recipients(recipients, opts["user"])
 369     |> restrict_tag(opts)
 370     |> restrict_since(opts)
 371     |> restrict_local(opts)
 372     |> restrict_limit(opts)
 373     |> restrict_max(opts)
 374     |> restrict_actor(opts)
 375     |> restrict_type(opts)
 376     |> restrict_favorited_by(opts)
 377     |> restrict_recent(opts)
 378     |> restrict_blocked(opts)
 379     |> restrict_media(opts)
 380     |> restrict_visibility(opts)
 381   end
 382
 383   def fetch_activities(recipients, opts \\ %{}) do
 384     fetch_activities_query(recipients, opts)
 385     |> Repo.all()
 386     |> Enum.reverse()
 387   end
 388
 389   def upload(file) do
 390     data = Upload.store(file)
 391     Repo.insert(%Object{data: data})
 392   end
 393
 394   def user_data_from_user_object(data) do
 395     avatar =
 396       data["icon"]["url"] &&
 397         %{
 398           "type" => "Image",
 399           "url" => [%{"href" => data["icon"]["url"]}]
 400         }
 401
 402     banner =
 403       data["image"]["url"] &&
 404         %{
 405           "type" => "Image",
 406           "url" => [%{"href" => data["image"]["url"]}]
 407         }
 408
 409     user_data = %{
 410       ap_id: data["id"],
 411       info: %{
 412         "ap_enabled" => true,
 413         "source_data" => data,
 414         "banner" => banner
 415       },
 416       avatar: avatar,
 417       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 418       name: data["name"],
 419       follower_address: data["followers"],
 420       bio: data["summary"]
 421     }
 422
 423     {:ok, user_data}
 424   end
 425
 426   def fetch_and_prepare_user_from_ap_id(ap_id) do
 427     with {:ok, %{status_code: 200, body: body}} <-
 428            @httpoison.get(ap_id, Accept: "application/activity+json"),
 429          {:ok, data} <- Jason.decode(body) do
 430       user_data_from_user_object(data)
 431     else
 432       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 433     end
 434   end
 435
 436   def make_user_from_ap_id(ap_id) do
 437     if _user = User.get_by_ap_id(ap_id) do
 438       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 439     else
 440       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 441         User.insert_or_update_user(data)
 442       else
 443         e -> {:error, e}
 444       end
 445     end
 446   end
 447
 448   def make_user_from_nickname(nickname) do
 449     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 450       make_user_from_ap_id(ap_id)
 451     else
 452       _e -> {:error, "No AP id in WebFinger"}
 453     end
 454   end
 455
 456   def publish(actor, activity) do
 457     followers =
 458       if actor.follower_address in activity.recipients do
 459         {:ok, followers} = User.get_followers(actor)
 460         followers |> Enum.filter(&(!&1.local))
 461       else
 462         []
 463       end
 464
 465     remote_inboxes =
 466       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 467       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 468       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 469         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 470       end)
 471       |> Enum.uniq()
 472
 473     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 474     json = Jason.encode!(data)
 475
 476     Enum.each(remote_inboxes, fn inbox ->
 477       Federator.enqueue(:publish_single_ap, %{
 478         inbox: inbox,
 479         json: json,
 480         actor: actor,
 481         id: activity.data["id"]
 482       })
 483     end)
 484   end
 485
 486   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 487     Logger.info("Federating #{id} to #{inbox}")
 488     host = URI.parse(inbox).host
 489
 490     signature =
 491       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 492
 493     @httpoison.post(
 494       inbox,
 495       json,
 496       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 497       hackney: [pool: :default]
 498     )
 499   end
 500
 501   # TODO:
 502   # This will create a Create activity, which we need internally at the moment.
 503   def fetch_object_from_id(id) do
 504     if object = Object.get_cached_by_ap_id(id) do
 505       {:ok, object}
 506     else
 507       Logger.info("Fetching #{id} via AP")
 508
 509       with true <- String.starts_with?(id, "http"),
 510            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 511              @httpoison.get(
 512                id,
 513                [Accept: "application/activity+json"],
 514                follow_redirect: true,
 515                timeout: 10000,
 516                recv_timeout: 20000
 517              ),
 518            {:ok, data} <- Jason.decode(body),
 519            nil <- Object.get_by_ap_id(data["id"]),
 520            params <- %{
 521              "type" => "Create",
 522              "to" => data["to"],
 523              "cc" => data["cc"],
 524              "actor" => data["attributedTo"],
 525              "object" => data
 526            },
 527            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 528         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 529       else
 530         object = %Object{} ->
 531           {:ok, object}
 532
 533         _e ->
 534           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 535
 536           case OStatus.fetch_activity_from_url(id) do
 537             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 538             e -> e
 539           end
 540       end
 541     end
 542   end
 543
 544   def is_public?(activity) do
 545     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 546                                                          (activity.data["cc"] || []))
 547   end
 548
 549   def visible_for_user?(activity, nil) do
 550     is_public?(activity)
 551   end
 552
 553   def visible_for_user?(activity, user) do
 554     x = [user.ap_id | user.following]
 555     y = activity.data["to"] ++ (activity.data["cc"] || [])
 556     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 557   end
 558 end