git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce", "Delete"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         if activity.data["type"] in ["Create"] do
 107           activity.data["object"]
 108           |> Map.get("tag", [])
 109           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 110           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 111
 112           if activity.data["object"]["attachment"] != [] do
 113             Pleroma.Web.Streamer.stream("public:media", activity)
 114
 115             if activity.local do
 116               Pleroma.Web.Streamer.stream("public:local:media", activity)
 117             end
 118           end
 119         end
 120       else
 121         if !Enum.member?(activity.data["cc"] || [], public) &&
 122              !Enum.member?(
 123                activity.data["to"],
 124                User.get_by_ap_id(activity.data["actor"]).follower_address
 125              ),
 126            do: Pleroma.Web.Streamer.stream("direct", activity)
 127       end
 128     end
 129   end
 130
 131   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 132     additional = params[:additional] || %{}
 133     # only accept false as false value
 134     local = !(params[:local] == false)
 135     published = params[:published]
 136
 137     with create_data <-
 138            make_create_data(
 139              %{to: to, actor: actor, published: published, context: context, object: object},
 140              additional
 141            ),
 142          {:ok, activity} <- insert(create_data, local),
 143          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 144          {:ok, _actor} <- User.increase_note_count(actor),
 145          :ok <- maybe_federate(activity) do
 146       {:ok, activity}
 147     end
 148   end
 149
 150   def accept(%{to: to, actor: actor, object: object} = params) do
 151     # only accept false as false value
 152     local = !(params[:local] == false)
 153
 154     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 155          {:ok, activity} <- insert(data, local),
 156          :ok <- maybe_federate(activity) do
 157       {:ok, activity}
 158     end
 159   end
 160
 161   def reject(%{to: to, actor: actor, object: object} = params) do
 162     # only accept false as false value
 163     local = !(params[:local] == false)
 164
 165     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 166          {:ok, activity} <- insert(data, local),
 167          :ok <- maybe_federate(activity) do
 168       {:ok, activity}
 169     end
 170   end
 171
 172   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 173     # only accept false as false value
 174     local = !(params[:local] == false)
 175
 176     with data <- %{
 177            "to" => to,
 178            "cc" => cc,
 179            "type" => "Update",
 180            "actor" => actor,
 181            "object" => object
 182          },
 183          {:ok, activity} <- insert(data, local),
 184          :ok <- maybe_federate(activity) do
 185       {:ok, activity}
 186     end
 187   end
 188
 189   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 190   def like(
 191         %User{ap_id: ap_id} = user,
 192         %Object{data: %{"id" => _}} = object,
 193         activity_id \\ nil,
 194         local \\ true
 195       ) do
 196     with nil <- get_existing_like(ap_id, object),
 197          like_data <- make_like_data(user, object, activity_id),
 198          {:ok, activity} <- insert(like_data, local),
 199          {:ok, object} <- add_like_to_object(activity, object),
 200          :ok <- maybe_federate(activity) do
 201       {:ok, activity, object}
 202     else
 203       %Activity{} = activity -> {:ok, activity, object}
 204       error -> {:error, error}
 205     end
 206   end
 207
 208   def unlike(
 209         %User{} = actor,
 210         %Object{} = object,
 211         activity_id \\ nil,
 212         local \\ true
 213       ) do
 214     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 215          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 216          {:ok, unlike_activity} <- insert(unlike_data, local),
 217          {:ok, _activity} <- Repo.delete(like_activity),
 218          {:ok, object} <- remove_like_from_object(like_activity, object),
 219          :ok <- maybe_federate(unlike_activity) do
 220       {:ok, unlike_activity, like_activity, object}
 221     else
 222       _e -> {:ok, object}
 223     end
 224   end
 225
 226   def announce(
 227         %User{ap_id: _} = user,
 228         %Object{data: %{"id" => _}} = object,
 229         activity_id \\ nil,
 230         local \\ true,
 231         public \\ true
 232       ) do
 233     with true <- is_public?(object),
 234          announce_data <- make_announce_data(user, object, activity_id, public),
 235          {:ok, activity} <- insert(announce_data, local),
 236          {:ok, object} <- add_announce_to_object(activity, object),
 237          :ok <- maybe_federate(activity) do
 238       {:ok, activity, object}
 239     else
 240       error -> {:error, error}
 241     end
 242   end
 243
 244   def unannounce(
 245         %User{} = actor,
 246         %Object{} = object,
 247         activity_id \\ nil,
 248         local \\ true
 249       ) do
 250     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 251          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 252          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 253          :ok <- maybe_federate(unannounce_activity),
 254          {:ok, _activity} <- Repo.delete(announce_activity),
 255          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 256       {:ok, unannounce_activity, object}
 257     else
 258       _e -> {:ok, object}
 259     end
 260   end
 261
 262   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 263     with data <- make_follow_data(follower, followed, activity_id),
 264          {:ok, activity} <- insert(data, local),
 265          :ok <- maybe_federate(activity) do
 266       {:ok, activity}
 267     end
 268   end
 269
 270   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 271     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 272          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 273          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 274          {:ok, activity} <- insert(unfollow_data, local),
 275          :ok <- maybe_federate(activity) do
 276       {:ok, activity}
 277     end
 278   end
 279
 280   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 281     user = User.get_cached_by_ap_id(actor)
 282
 283     data = %{
 284       "type" => "Delete",
 285       "actor" => actor,
 286       "object" => id,
 287       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 288     }
 289
 290     with {:ok, _} <- Object.delete(object),
 291          {:ok, activity} <- insert(data, local),
 292          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 293          {:ok, _actor} <- User.decrease_note_count(user),
 294          :ok <- maybe_federate(activity) do
 295       {:ok, activity}
 296     end
 297   end
 298
 299   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 300     ap_config = Application.get_env(:pleroma, :activitypub)
 301     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 302     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 303
 304     with true <- unfollow_blocked do
 305       follow_activity = fetch_latest_follow(blocker, blocked)
 306
 307       if follow_activity do
 308         unfollow(blocker, blocked, nil, local)
 309       end
 310     end
 311
 312     with true <- outgoing_blocks,
 313          block_data <- make_block_data(blocker, blocked, activity_id),
 314          {:ok, activity} <- insert(block_data, local),
 315          :ok <- maybe_federate(activity) do
 316       {:ok, activity}
 317     else
 318       _e -> {:ok, nil}
 319     end
 320   end
 321
 322   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 323     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 324          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 325          {:ok, activity} <- insert(unblock_data, local),
 326          :ok <- maybe_federate(activity) do
 327       {:ok, activity}
 328     end
 329   end
 330
 331   def fetch_activities_for_context(context, opts \\ %{}) do
 332     public = ["https://www.w3.org/ns/activitystreams#Public"]
 333
 334     recipients =
 335       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 336
 337     query = from(activity in Activity)
 338
 339     query =
 340       query
 341       |> restrict_blocked(opts)
 342       |> restrict_recipients(recipients, opts["user"])
 343
 344     query =
 345       from(
 346         activity in query,
 347         where:
 348           fragment(
 349             "?->>'type' = ? and ?->>'context' = ?",
 350             activity.data,
 351             "Create",
 352             activity.data,
 353             ^context
 354           ),
 355         order_by: [desc: :id]
 356       )
 357
 358     Repo.all(query)
 359   end
 360
 361   def fetch_public_activities(opts \\ %{}) do
 362     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 363
 364     q
 365     |> restrict_unlisted()
 366     |> Repo.all()
 367     |> Enum.reverse()
 368   end
 369
 370   @valid_visibilities ~w[direct unlisted public private]
 371
 372   defp restrict_visibility(query, %{visibility: visibility})
 373        when visibility in @valid_visibilities do
 374     query =
 375       from(
 376         a in query,
 377         where:
 378           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 379       )
 380
 381     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 382
 383     query
 384   end
 385
 386   defp restrict_visibility(_query, %{visibility: visibility})
 387        when visibility not in @valid_visibilities do
 388     Logger.error("Could not restrict visibility to #{visibility}")
 389   end
 390
 391   defp restrict_visibility(query, _visibility), do: query
 392
 393   def fetch_user_activities(user, reading_user, params \\ %{}) do
 394     params =
 395       params
 396       |> Map.put("type", ["Create", "Announce"])
 397       |> Map.put("actor_id", user.ap_id)
 398       |> Map.put("whole_db", true)
 399       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 400
 401     recipients =
 402       if reading_user do
 403         ["https://www.w3.org/ns/activitystreams#Public"] ++
 404           [reading_user.ap_id | reading_user.following]
 405       else
 406         ["https://www.w3.org/ns/activitystreams#Public"]
 407       end
 408
 409     fetch_activities(recipients, params)
 410     |> Enum.reverse()
 411   end
 412
 413   defp restrict_since(query, %{"since_id" => ""}), do: query
 414
 415   defp restrict_since(query, %{"since_id" => since_id}) do
 416     from(activity in query, where: activity.id > ^since_id)
 417   end
 418
 419   defp restrict_since(query, _), do: query
 420
 421   defp restrict_tag(query, %{"tag" => tag}) do
 422     from(
 423       activity in query,
 424       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 425     )
 426   end
 427
 428   defp restrict_tag(query, _), do: query
 429
 430   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 431     from(
 432       activity in query,
 433       where:
 434         fragment(
 435           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 436           activity.data,
 437           ^recipients_to,
 438           activity.data,
 439           ^recipients_cc
 440         )
 441     )
 442   end
 443
 444   defp restrict_recipients(query, [], _user), do: query
 445
 446   defp restrict_recipients(query, recipients, nil) do
 447     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 448   end
 449
 450   defp restrict_recipients(query, recipients, user) do
 451     from(
 452       activity in query,
 453       where: fragment("? && ?", ^recipients, activity.recipients),
 454       or_where: activity.actor == ^user.ap_id
 455     )
 456   end
 457
 458   defp restrict_limit(query, %{"limit" => limit}) do
 459     from(activity in query, limit: ^limit)
 460   end
 461
 462   defp restrict_limit(query, _), do: query
 463
 464   defp restrict_local(query, %{"local_only" => true}) do
 465     from(activity in query, where: activity.local == true)
 466   end
 467
 468   defp restrict_local(query, _), do: query
 469
 470   defp restrict_max(query, %{"max_id" => ""}), do: query
 471
 472   defp restrict_max(query, %{"max_id" => max_id}) do
 473     from(activity in query, where: activity.id < ^max_id)
 474   end
 475
 476   defp restrict_max(query, _), do: query
 477
 478   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 479     from(activity in query, where: activity.actor == ^actor_id)
 480   end
 481
 482   defp restrict_actor(query, _), do: query
 483
 484   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 485     restrict_type(query, %{"type" => [type]})
 486   end
 487
 488   defp restrict_type(query, %{"type" => type}) do
 489     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 490   end
 491
 492   defp restrict_type(query, _), do: query
 493
 494   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 495     from(
 496       activity in query,
 497       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 498     )
 499   end
 500
 501   defp restrict_favorited_by(query, _), do: query
 502
 503   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 504     from(
 505       activity in query,
 506       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 507     )
 508   end
 509
 510   defp restrict_media(query, _), do: query
 511
 512   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 513     from(
 514       activity in query,
 515       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 516     )
 517   end
 518
 519   defp restrict_replies(query, _), do: query
 520
 521   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 522     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 523   end
 524
 525   defp restrict_reblogs(query, _), do: query
 526
 527   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 528     blocks = info.blocks || []
 529     domain_blocks = info.domain_blocks || []
 530
 531     from(
 532       activity in query,
 533       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 534       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 535       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 536     )
 537   end
 538
 539   defp restrict_blocked(query, _), do: query
 540
 541   defp restrict_unlisted(query) do
 542     from(
 543       activity in query,
 544       where:
 545         fragment(
 546           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 547           activity.data,
 548           ^["https://www.w3.org/ns/activitystreams#Public"]
 549         )
 550     )
 551   end
 552
 553   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 554     from(activity in query, where: activity.id in ^ids)
 555   end
 556
 557   defp restrict_pinned(query, _), do: query
 558
 559   def fetch_activities_query(recipients, opts \\ %{}) do
 560     base_query =
 561       from(
 562         activity in Activity,
 563         limit: 20,
 564         order_by: [fragment("? desc nulls last", activity.id)]
 565       )
 566
 567     base_query
 568     |> restrict_recipients(recipients, opts["user"])
 569     |> restrict_tag(opts)
 570     |> restrict_since(opts)
 571     |> restrict_local(opts)
 572     |> restrict_limit(opts)
 573     |> restrict_max(opts)
 574     |> restrict_actor(opts)
 575     |> restrict_type(opts)
 576     |> restrict_favorited_by(opts)
 577     |> restrict_blocked(opts)
 578     |> restrict_media(opts)
 579     |> restrict_visibility(opts)
 580     |> restrict_replies(opts)
 581     |> restrict_reblogs(opts)
 582     |> restrict_pinned(opts)
 583   end
 584
 585   def fetch_activities(recipients, opts \\ %{}) do
 586     fetch_activities_query(recipients, opts)
 587     |> Repo.all()
 588     |> Enum.reverse()
 589   end
 590
 591   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 592     fetch_activities_query([], opts)
 593     |> restrict_to_cc(recipients_to, recipients_cc)
 594     |> Repo.all()
 595     |> Enum.reverse()
 596   end
 597
 598   def upload(file, opts \\ []) do
 599     with {:ok, data} <- Upload.store(file, opts) do
 600       obj_data =
 601         if opts[:actor] do
 602           Map.put(data, "actor", opts[:actor])
 603         else
 604           data
 605         end
 606
 607       Repo.insert(%Object{data: obj_data})
 608     end
 609   end
 610
 611   def user_data_from_user_object(data) do
 612     avatar =
 613       data["icon"]["url"] &&
 614         %{
 615           "type" => "Image",
 616           "url" => [%{"href" => data["icon"]["url"]}]
 617         }
 618
 619     banner =
 620       data["image"]["url"] &&
 621         %{
 622           "type" => "Image",
 623           "url" => [%{"href" => data["image"]["url"]}]
 624         }
 625
 626     locked = data["manuallyApprovesFollowers"] || false
 627     data = Transmogrifier.maybe_fix_user_object(data)
 628
 629     user_data = %{
 630       ap_id: data["id"],
 631       info: %{
 632         "ap_enabled" => true,
 633         "source_data" => data,
 634         "banner" => banner,
 635         "locked" => locked
 636       },
 637       avatar: avatar,
 638       name: data["name"],
 639       follower_address: data["followers"],
 640       bio: data["summary"]
 641     }
 642
 643     # nickname can be nil because of virtual actors
 644     user_data =
 645       if data["preferredUsername"] do
 646         Map.put(
 647           user_data,
 648           :nickname,
 649           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 650         )
 651       else
 652         Map.put(user_data, :nickname, nil)
 653       end
 654
 655     {:ok, user_data}
 656   end
 657
 658   def fetch_and_prepare_user_from_ap_id(ap_id) do
 659     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 660       user_data_from_user_object(data)
 661     else
 662       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 663     end
 664   end
 665
 666   def make_user_from_ap_id(ap_id) do
 667     if _user = User.get_by_ap_id(ap_id) do
 668       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 669     else
 670       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 671         User.insert_or_update_user(data)
 672       else
 673         e -> {:error, e}
 674       end
 675     end
 676   end
 677
 678   def make_user_from_nickname(nickname) do
 679     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 680       make_user_from_ap_id(ap_id)
 681     else
 682       _e -> {:error, "No AP id in WebFinger"}
 683     end
 684   end
 685
 686   def should_federate?(inbox, public) do
 687     if public do
 688       true
 689     else
 690       inbox_info = URI.parse(inbox)
 691       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 692     end
 693   end
 694
 695   def publish(actor, activity) do
 696     followers =
 697       if actor.follower_address in activity.recipients do
 698         {:ok, followers} = User.get_followers(actor)
 699         followers |> Enum.filter(&(!&1.local))
 700       else
 701         []
 702       end
 703
 704     public = is_public?(activity)
 705
 706     remote_inboxes =
 707       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 708       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 709       |> Enum.map(fn %{info: %{source_data: data}} ->
 710         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 711       end)
 712       |> Enum.uniq()
 713       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 714
 715     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 716     json = Jason.encode!(data)
 717
 718     Enum.each(remote_inboxes, fn inbox ->
 719       Federator.enqueue(:publish_single_ap, %{
 720         inbox: inbox,
 721         json: json,
 722         actor: actor,
 723         id: activity.data["id"]
 724       })
 725     end)
 726   end
 727
 728   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 729     Logger.info("Federating #{id} to #{inbox}")
 730     host = URI.parse(inbox).host
 731
 732     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 733
 734     signature =
 735       Pleroma.Web.HTTPSignatures.sign(actor, %{
 736         host: host,
 737         "content-length": byte_size(json),
 738         digest: digest
 739       })
 740
 741     @httpoison.post(
 742       inbox,
 743       json,
 744       [
 745         {"Content-Type", "application/activity+json"},
 746         {"signature", signature},
 747         {"digest", digest}
 748       ]
 749     )
 750   end
 751
 752   # TODO:
 753   # This will create a Create activity, which we need internally at the moment.
 754   def fetch_object_from_id(id) do
 755     if object = Object.get_cached_by_ap_id(id) do
 756       {:ok, object}
 757     else
 758       Logger.info("Fetching #{id} via AP")
 759
 760       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 761            nil <- Object.normalize(data),
 762            params <- %{
 763              "type" => "Create",
 764              "to" => data["to"],
 765              "cc" => data["cc"],
 766              "actor" => data["actor"] || data["attributedTo"],
 767              "object" => data
 768            },
 769            :ok <- Transmogrifier.contain_origin(id, params),
 770            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 771         {:ok, Object.normalize(activity.data["object"])}
 772       else
 773         {:error, {:reject, nil}} ->
 774           {:reject, nil}
 775
 776         object = %Object{} ->
 777           {:ok, object}
 778
 779         _e ->
 780           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 781
 782           case OStatus.fetch_activity_from_url(id) do
 783             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 784             e -> e
 785           end
 786       end
 787     end
 788   end
 789
 790   def fetch_and_contain_remote_object_from_id(id) do
 791     Logger.info("Fetching #{id} via AP")
 792
 793     with true <- String.starts_with?(id, "http"),
 794          {:ok, %{body: body, status: code}} when code in 200..299 <-
 795            @httpoison.get(
 796              id,
 797              [{:Accept, "application/activity+json"}]
 798            ),
 799          {:ok, data} <- Jason.decode(body),
 800          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 801       {:ok, data}
 802     else
 803       e ->
 804         {:error, e}
 805     end
 806   end
 807
 808   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 809   def is_public?(%Object{data: data}), do: is_public?(data)
 810   def is_public?(%Activity{data: data}), do: is_public?(data)
 811   def is_public?(%{"directMessage" => true}), do: false
 812
 813   def is_public?(data) do
 814     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 815   end
 816
 817   def is_private?(activity) do
 818     !is_public?(activity) && Enum.any?(activity.data["to"], &String.contains?(&1, "/followers"))
 819   end
 820
 821   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
 822   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
 823
 824   def is_direct?(activity) do
 825     !is_public?(activity) && !is_private?(activity)
 826   end
 827
 828   def visible_for_user?(activity, nil) do
 829     is_public?(activity)
 830   end
 831
 832   def visible_for_user?(activity, user) do
 833     x = [user.ap_id | user.following]
 834     y = activity.data["to"] ++ (activity.data["cc"] || [])
 835     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 836   end
 837
 838   # guard
 839   def entire_thread_visible_for_user?(nil, _user), do: false
 840
 841   # child
 842   def entire_thread_visible_for_user?(
 843         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 844         user
 845       )
 846       when is_binary(parent_id) do
 847     parent = Activity.get_in_reply_to_activity(tail)
 848     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 849   end
 850
 851   # root
 852   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 853
 854   # filter out broken threads
 855   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 856     entire_thread_visible_for_user?(activity, user)
 857   end
 858
 859   # do post-processing on a specific activity
 860   def contain_activity(%Activity{} = activity, %User{} = user) do
 861     contain_broken_threads(activity, user)
 862   end
 863
 864   # do post-processing on a timeline
 865   def contain_timeline(timeline, user) do
 866     timeline
 867     |> Enum.filter(fn activity ->
 868       contain_activity(activity, user)
 869     end)
 870   end
 871 end