git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   def insert(map, local \\ true) when is_map(map) do
  60     with nil <- Activity.normalize(map),
  61          map <- lazy_put_activity_defaults(map),
  62          :ok <- check_actor_is_active(map["actor"]),
  63          {:ok, map} <- MRF.filter(map),
  64          :ok <- insert_full_object(map) do
  65       {recipients, _, _} = get_recipients(map)
  66
  67       {:ok, activity} =
  68         Repo.insert(%Activity{
  69           data: map,
  70           local: local,
  71           actor: map["actor"],
  72           recipients: recipients
  73         })
  74
  75       Notification.create_notifications(activity)
  76       stream_out(activity)
  77       {:ok, activity}
  78     else
  79       %Activity{} = activity -> {:ok, activity}
  80       error -> {:error, error}
  81     end
  82   end
  83
  84   def stream_out(activity) do
  85     public = "https://www.w3.org/ns/activitystreams#Public"
  86
  87     if activity.data["type"] in ["Create", "Announce"] do
  88       Pleroma.Web.Streamer.stream("user", activity)
  89       Pleroma.Web.Streamer.stream("list", activity)
  90
  91       if Enum.member?(activity.data["to"], public) do
  92         Pleroma.Web.Streamer.stream("public", activity)
  93
  94         if activity.local do
  95           Pleroma.Web.Streamer.stream("public:local", activity)
  96         end
  97
  98         activity.data["object"]
  99         |> Map.get("tag", [])
 100         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 101         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 102
 103         if activity.data["object"]["attachment"] != [] do
 104           Pleroma.Web.Streamer.stream("public:media", activity)
 105
 106           if activity.local do
 107             Pleroma.Web.Streamer.stream("public:local:media", activity)
 108           end
 109         end
 110       else
 111         if !Enum.member?(activity.data["cc"] || [], public) &&
 112              !Enum.member?(
 113                activity.data["to"],
 114                User.get_by_ap_id(activity.data["actor"]).follower_address
 115              ),
 116            do: Pleroma.Web.Streamer.stream("direct", activity)
 117       end
 118     end
 119   end
 120
 121   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 122     additional = params[:additional] || %{}
 123     # only accept false as false value
 124     local = !(params[:local] == false)
 125     published = params[:published]
 126
 127     with create_data <-
 128            make_create_data(
 129              %{to: to, actor: actor, published: published, context: context, object: object},
 130              additional
 131            ),
 132          {:ok, activity} <- insert(create_data, local),
 133          :ok <- maybe_federate(activity),
 134          {:ok, _actor} <- User.increase_note_count(actor) do
 135       {:ok, activity}
 136     end
 137   end
 138
 139   def accept(%{to: to, actor: actor, object: object} = params) do
 140     # only accept false as false value
 141     local = !(params[:local] == false)
 142
 143     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 144          {:ok, activity} <- insert(data, local),
 145          :ok <- maybe_federate(activity) do
 146       {:ok, activity}
 147     end
 148   end
 149
 150   def reject(%{to: to, actor: actor, object: object} = params) do
 151     # only accept false as false value
 152     local = !(params[:local] == false)
 153
 154     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 155          {:ok, activity} <- insert(data, local),
 156          :ok <- maybe_federate(activity) do
 157       {:ok, activity}
 158     end
 159   end
 160
 161   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 162     # only accept false as false value
 163     local = !(params[:local] == false)
 164
 165     with data <- %{
 166            "to" => to,
 167            "cc" => cc,
 168            "type" => "Update",
 169            "actor" => actor,
 170            "object" => object
 171          },
 172          {:ok, activity} <- insert(data, local),
 173          :ok <- maybe_federate(activity) do
 174       {:ok, activity}
 175     end
 176   end
 177
 178   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 179   def like(
 180         %User{ap_id: ap_id} = user,
 181         %Object{data: %{"id" => _}} = object,
 182         activity_id \\ nil,
 183         local \\ true
 184       ) do
 185     with nil <- get_existing_like(ap_id, object),
 186          like_data <- make_like_data(user, object, activity_id),
 187          {:ok, activity} <- insert(like_data, local),
 188          {:ok, object} <- add_like_to_object(activity, object),
 189          :ok <- maybe_federate(activity) do
 190       {:ok, activity, object}
 191     else
 192       %Activity{} = activity -> {:ok, activity, object}
 193       error -> {:error, error}
 194     end
 195   end
 196
 197   def unlike(
 198         %User{} = actor,
 199         %Object{} = object,
 200         activity_id \\ nil,
 201         local \\ true
 202       ) do
 203     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 204          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 205          {:ok, unlike_activity} <- insert(unlike_data, local),
 206          {:ok, _activity} <- Repo.delete(like_activity),
 207          {:ok, object} <- remove_like_from_object(like_activity, object),
 208          :ok <- maybe_federate(unlike_activity) do
 209       {:ok, unlike_activity, like_activity, object}
 210     else
 211       _e -> {:ok, object}
 212     end
 213   end
 214
 215   def announce(
 216         %User{ap_id: _} = user,
 217         %Object{data: %{"id" => _}} = object,
 218         activity_id \\ nil,
 219         local \\ true
 220       ) do
 221     with true <- is_public?(object),
 222          announce_data <- make_announce_data(user, object, activity_id),
 223          {:ok, activity} <- insert(announce_data, local),
 224          {:ok, object} <- add_announce_to_object(activity, object),
 225          :ok <- maybe_federate(activity) do
 226       {:ok, activity, object}
 227     else
 228       error -> {:error, error}
 229     end
 230   end
 231
 232   def unannounce(
 233         %User{} = actor,
 234         %Object{} = object,
 235         activity_id \\ nil,
 236         local \\ true
 237       ) do
 238     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 239          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 240          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 241          :ok <- maybe_federate(unannounce_activity),
 242          {:ok, _activity} <- Repo.delete(announce_activity),
 243          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 244       {:ok, unannounce_activity, object}
 245     else
 246       _e -> {:ok, object}
 247     end
 248   end
 249
 250   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 251     with data <- make_follow_data(follower, followed, activity_id),
 252          {:ok, activity} <- insert(data, local),
 253          :ok <- maybe_federate(activity) do
 254       {:ok, activity}
 255     end
 256   end
 257
 258   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 259     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 260          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 261          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 262          {:ok, activity} <- insert(unfollow_data, local),
 263          :ok <- maybe_federate(activity) do
 264       {:ok, activity}
 265     end
 266   end
 267
 268   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 269     user = User.get_cached_by_ap_id(actor)
 270
 271     data = %{
 272       "type" => "Delete",
 273       "actor" => actor,
 274       "object" => id,
 275       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 276     }
 277
 278     with {:ok, _} <- Object.delete(object),
 279          {:ok, activity} <- insert(data, local),
 280          :ok <- maybe_federate(activity),
 281          {:ok, _actor} <- User.decrease_note_count(user) do
 282       {:ok, activity}
 283     end
 284   end
 285
 286   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 287     ap_config = Application.get_env(:pleroma, :activitypub)
 288     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 289     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 290
 291     with true <- unfollow_blocked do
 292       follow_activity = fetch_latest_follow(blocker, blocked)
 293
 294       if follow_activity do
 295         unfollow(blocker, blocked, nil, local)
 296       end
 297     end
 298
 299     with true <- outgoing_blocks,
 300          block_data <- make_block_data(blocker, blocked, activity_id),
 301          {:ok, activity} <- insert(block_data, local),
 302          :ok <- maybe_federate(activity) do
 303       {:ok, activity}
 304     else
 305       _e -> {:ok, nil}
 306     end
 307   end
 308
 309   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 310     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 311          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 312          {:ok, activity} <- insert(unblock_data, local),
 313          :ok <- maybe_federate(activity) do
 314       {:ok, activity}
 315     end
 316   end
 317
 318   def fetch_activities_for_context(context, opts \\ %{}) do
 319     public = ["https://www.w3.org/ns/activitystreams#Public"]
 320
 321     recipients =
 322       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 323
 324     query = from(activity in Activity)
 325
 326     query =
 327       query
 328       |> restrict_blocked(opts)
 329       |> restrict_recipients(recipients, opts["user"])
 330
 331     query =
 332       from(
 333         activity in query,
 334         where:
 335           fragment(
 336             "?->>'type' = ? and ?->>'context' = ?",
 337             activity.data,
 338             "Create",
 339             activity.data,
 340             ^context
 341           ),
 342         order_by: [desc: :id]
 343       )
 344
 345     Repo.all(query)
 346   end
 347
 348   def fetch_public_activities(opts \\ %{}) do
 349     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 350
 351     q
 352     |> restrict_unlisted()
 353     |> Repo.all()
 354     |> Enum.reverse()
 355   end
 356
 357   @valid_visibilities ~w[direct unlisted public private]
 358
 359   defp restrict_visibility(query, %{visibility: "direct"}) do
 360     public = "https://www.w3.org/ns/activitystreams#Public"
 361
 362     from(
 363       activity in query,
 364       join: sender in User,
 365       on: sender.ap_id == activity.actor,
 366       # Are non-direct statuses with no to/cc possible?
 367       where:
 368         fragment(
 369           "not (? && ?)",
 370           [^public, sender.follower_address],
 371           activity.recipients
 372         )
 373     )
 374   end
 375
 376   defp restrict_visibility(_query, %{visibility: visibility})
 377        when visibility not in @valid_visibilities do
 378     Logger.error("Could not restrict visibility to #{visibility}")
 379   end
 380
 381   defp restrict_visibility(query, _visibility), do: query
 382
 383   def fetch_user_activities(user, reading_user, params \\ %{}) do
 384     params =
 385       params
 386       |> Map.put("type", ["Create", "Announce"])
 387       |> Map.put("actor_id", user.ap_id)
 388       |> Map.put("whole_db", true)
 389
 390     recipients =
 391       if reading_user do
 392         ["https://www.w3.org/ns/activitystreams#Public"] ++
 393           [reading_user.ap_id | reading_user.following]
 394       else
 395         ["https://www.w3.org/ns/activitystreams#Public"]
 396       end
 397
 398     fetch_activities(recipients, params)
 399     |> Enum.reverse()
 400   end
 401
 402   defp restrict_since(query, %{"since_id" => since_id}) do
 403     from(activity in query, where: activity.id > ^since_id)
 404   end
 405
 406   defp restrict_since(query, _), do: query
 407
 408   defp restrict_tag(query, %{"tag" => tag}) do
 409     from(
 410       activity in query,
 411       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 412     )
 413   end
 414
 415   defp restrict_tag(query, _), do: query
 416
 417   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 418     from(
 419       activity in query,
 420       where:
 421         fragment(
 422           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 423           activity.data,
 424           ^recipients_to,
 425           activity.data,
 426           ^recipients_cc
 427         )
 428     )
 429   end
 430
 431   defp restrict_recipients(query, [], _user), do: query
 432
 433   defp restrict_recipients(query, recipients, nil) do
 434     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 435   end
 436
 437   defp restrict_recipients(query, recipients, user) do
 438     from(
 439       activity in query,
 440       where: fragment("? && ?", ^recipients, activity.recipients),
 441       or_where: activity.actor == ^user.ap_id
 442     )
 443   end
 444
 445   defp restrict_limit(query, %{"limit" => limit}) do
 446     from(activity in query, limit: ^limit)
 447   end
 448
 449   defp restrict_limit(query, _), do: query
 450
 451   defp restrict_local(query, %{"local_only" => true}) do
 452     from(activity in query, where: activity.local == true)
 453   end
 454
 455   defp restrict_local(query, _), do: query
 456
 457   defp restrict_max(query, %{"max_id" => max_id}) do
 458     from(activity in query, where: activity.id < ^max_id)
 459   end
 460
 461   defp restrict_max(query, _), do: query
 462
 463   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 464     from(activity in query, where: activity.actor == ^actor_id)
 465   end
 466
 467   defp restrict_actor(query, _), do: query
 468
 469   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 470     restrict_type(query, %{"type" => [type]})
 471   end
 472
 473   defp restrict_type(query, %{"type" => type}) do
 474     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 475   end
 476
 477   defp restrict_type(query, _), do: query
 478
 479   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 480     from(
 481       activity in query,
 482       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 483     )
 484   end
 485
 486   defp restrict_favorited_by(query, _), do: query
 487
 488   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 489     from(
 490       activity in query,
 491       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 492     )
 493   end
 494
 495   defp restrict_media(query, _), do: query
 496
 497   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 498     from(
 499       activity in query,
 500       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 501     )
 502   end
 503
 504   defp restrict_replies(query, _), do: query
 505
 506   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 507     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 508   end
 509
 510   defp restrict_reblogs(query, _), do: query
 511
 512   # Only search through last 100_000 activities by default
 513   defp restrict_recent(query, %{"whole_db" => true}), do: query
 514
 515   defp restrict_recent(query, _) do
 516     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 517
 518     from(activity in query, where: activity.id > ^since)
 519   end
 520
 521   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 522     blocks = info.blocks || []
 523     domain_blocks = info.domain_blocks || []
 524
 525     from(
 526       activity in query,
 527       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 528       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 529       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 530     )
 531   end
 532
 533   defp restrict_blocked(query, _), do: query
 534
 535   defp restrict_unlisted(query) do
 536     from(
 537       activity in query,
 538       where:
 539         fragment(
 540           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 541           activity.data,
 542           ^["https://www.w3.org/ns/activitystreams#Public"]
 543         )
 544     )
 545   end
 546
 547   def fetch_activities_query(recipients, opts \\ %{}) do
 548     base_query =
 549       from(
 550         activity in Activity,
 551         limit: 20,
 552         order_by: [fragment("? desc nulls last", activity.id)]
 553       )
 554
 555     base_query
 556     |> restrict_recipients(recipients, opts["user"])
 557     |> restrict_tag(opts)
 558     |> restrict_since(opts)
 559     |> restrict_local(opts)
 560     |> restrict_limit(opts)
 561     |> restrict_max(opts)
 562     |> restrict_actor(opts)
 563     |> restrict_type(opts)
 564     |> restrict_favorited_by(opts)
 565     |> restrict_recent(opts)
 566     |> restrict_blocked(opts)
 567     |> restrict_media(opts)
 568     |> restrict_visibility(opts)
 569     |> restrict_replies(opts)
 570     |> restrict_reblogs(opts)
 571   end
 572
 573   def fetch_activities(recipients, opts \\ %{}) do
 574     fetch_activities_query(recipients, opts)
 575     |> Repo.all()
 576     |> Enum.reverse()
 577   end
 578
 579   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 580     fetch_activities_query([], opts)
 581     |> restrict_to_cc(recipients_to, recipients_cc)
 582     |> Repo.all()
 583     |> Enum.reverse()
 584   end
 585
 586   def upload(file, opts \\ []) do
 587     with {:ok, data} <- Upload.store(file, opts) do
 588       obj_data =
 589         if opts[:actor] do
 590           Map.put(data, "actor", opts[:actor])
 591         else
 592           data
 593         end
 594
 595       Repo.insert(%Object{data: obj_data})
 596     end
 597   end
 598
 599   def user_data_from_user_object(data) do
 600     avatar =
 601       data["icon"]["url"] &&
 602         %{
 603           "type" => "Image",
 604           "url" => [%{"href" => data["icon"]["url"]}]
 605         }
 606
 607     banner =
 608       data["image"]["url"] &&
 609         %{
 610           "type" => "Image",
 611           "url" => [%{"href" => data["image"]["url"]}]
 612         }
 613
 614     locked = data["manuallyApprovesFollowers"] || false
 615     data = Transmogrifier.maybe_fix_user_object(data)
 616
 617     user_data = %{
 618       ap_id: data["id"],
 619       info: %{
 620         "ap_enabled" => true,
 621         "source_data" => data,
 622         "banner" => banner,
 623         "locked" => locked
 624       },
 625       avatar: avatar,
 626       name: data["name"],
 627       follower_address: data["followers"],
 628       bio: data["summary"]
 629     }
 630
 631     # nickname can be nil because of virtual actors
 632     user_data =
 633       if data["preferredUsername"] do
 634         Map.put(
 635           user_data,
 636           :nickname,
 637           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 638         )
 639       else
 640         Map.put(user_data, :nickname, nil)
 641       end
 642
 643     {:ok, user_data}
 644   end
 645
 646   def fetch_and_prepare_user_from_ap_id(ap_id) do
 647     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 648       user_data_from_user_object(data)
 649     else
 650       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 651     end
 652   end
 653
 654   def make_user_from_ap_id(ap_id) do
 655     if _user = User.get_by_ap_id(ap_id) do
 656       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 657     else
 658       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 659         User.insert_or_update_user(data)
 660       else
 661         e -> {:error, e}
 662       end
 663     end
 664   end
 665
 666   def make_user_from_nickname(nickname) do
 667     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 668       make_user_from_ap_id(ap_id)
 669     else
 670       _e -> {:error, "No AP id in WebFinger"}
 671     end
 672   end
 673
 674   def should_federate?(inbox, public) do
 675     if public do
 676       true
 677     else
 678       inbox_info = URI.parse(inbox)
 679       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 680     end
 681   end
 682
 683   def publish(actor, activity) do
 684     followers =
 685       if actor.follower_address in activity.recipients do
 686         {:ok, followers} = User.get_followers(actor)
 687         followers |> Enum.filter(&(!&1.local))
 688       else
 689         []
 690       end
 691
 692     public = is_public?(activity)
 693
 694     remote_inboxes =
 695       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 696       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 697       |> Enum.map(fn %{info: %{source_data: data}} ->
 698         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 699       end)
 700       |> Enum.uniq()
 701       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 702
 703     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 704     json = Jason.encode!(data)
 705
 706     Enum.each(remote_inboxes, fn inbox ->
 707       Federator.enqueue(:publish_single_ap, %{
 708         inbox: inbox,
 709         json: json,
 710         actor: actor,
 711         id: activity.data["id"]
 712       })
 713     end)
 714   end
 715
 716   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 717     Logger.info("Federating #{id} to #{inbox}")
 718     host = URI.parse(inbox).host
 719
 720     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 721
 722     signature =
 723       Pleroma.Web.HTTPSignatures.sign(actor, %{
 724         host: host,
 725         "content-length": byte_size(json),
 726         digest: digest
 727       })
 728
 729     @httpoison.post(
 730       inbox,
 731       json,
 732       [
 733         {"Content-Type", "application/activity+json"},
 734         {"signature", signature},
 735         {"digest", digest}
 736       ],
 737       hackney: [pool: :default]
 738     )
 739   end
 740
 741   # TODO:
 742   # This will create a Create activity, which we need internally at the moment.
 743   def fetch_object_from_id(id) do
 744     if object = Object.get_cached_by_ap_id(id) do
 745       {:ok, object}
 746     else
 747       Logger.info("Fetching #{id} via AP")
 748
 749       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 750            nil <- Object.normalize(data),
 751            params <- %{
 752              "type" => "Create",
 753              "to" => data["to"],
 754              "cc" => data["cc"],
 755              "actor" => data["actor"] || data["attributedTo"],
 756              "object" => data
 757            },
 758            :ok <- Transmogrifier.contain_origin(id, params),
 759            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 760         {:ok, Object.normalize(activity.data["object"])}
 761       else
 762         {:error, {:reject, nil}} ->
 763           {:reject, nil}
 764
 765         object = %Object{} ->
 766           {:ok, object}
 767
 768         _e ->
 769           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 770
 771           case OStatus.fetch_activity_from_url(id) do
 772             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 773             e -> e
 774           end
 775       end
 776     end
 777   end
 778
 779   def fetch_and_contain_remote_object_from_id(id) do
 780     Logger.info("Fetching #{id} via AP")
 781
 782     with true <- String.starts_with?(id, "http"),
 783          {:ok, %{body: body, status: code}} when code in 200..299 <-
 784            @httpoison.get(
 785              id,
 786              [{:Accept, "application/activity+json"}]
 787            ),
 788          {:ok, data} <- Jason.decode(body),
 789          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 790       {:ok, data}
 791     else
 792       e ->
 793         {:error, e}
 794     end
 795   end
 796
 797   def is_public?(activity) do
 798     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 799                                                          (activity.data["cc"] || []))
 800   end
 801
 802   def visible_for_user?(activity, nil) do
 803     is_public?(activity)
 804   end
 805
 806   def visible_for_user?(activity, user) do
 807     x = [user.ap_id | user.following]
 808     y = activity.data["to"] ++ (activity.data["cc"] || [])
 809     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 810   end
 811
 812   # guard
 813   def entire_thread_visible_for_user?(nil, _user), do: false
 814
 815   # child
 816   def entire_thread_visible_for_user?(
 817         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 818         user
 819       )
 820       when is_binary(parent_id) do
 821     parent = Activity.get_in_reply_to_activity(tail)
 822     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 823   end
 824
 825   # root
 826   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 827
 828   # filter out broken threads
 829   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 830     entire_thread_visible_for_user?(activity, user)
 831   end
 832
 833   # do post-processing on a specific activity
 834   def contain_activity(%Activity{} = activity, %User{} = user) do
 835     contain_broken_threads(activity, user)
 836   end
 837
 838   # do post-processing on a timeline
 839   def contain_timeline(timeline, user) do
 840     timeline
 841     |> Enum.filter(fn activity ->
 842       contain_activity(activity, user)
 843     end)
 844   end
 845 end