git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification, Instances}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce", "Delete"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         if activity.data["type"] in ["Create"] do
 107           activity.data["object"]
 108           |> Map.get("tag", [])
 109           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 110           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 111
 112           if activity.data["object"]["attachment"] != [] do
 113             Pleroma.Web.Streamer.stream("public:media", activity)
 114
 115             if activity.local do
 116               Pleroma.Web.Streamer.stream("public:local:media", activity)
 117             end
 118           end
 119         end
 120       else
 121         if !Enum.member?(activity.data["cc"] || [], public) &&
 122              !Enum.member?(
 123                activity.data["to"],
 124                User.get_by_ap_id(activity.data["actor"]).follower_address
 125              ),
 126            do: Pleroma.Web.Streamer.stream("direct", activity)
 127       end
 128     end
 129   end
 130
 131   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 132     additional = params[:additional] || %{}
 133     # only accept false as false value
 134     local = !(params[:local] == false)
 135     published = params[:published]
 136
 137     with create_data <-
 138            make_create_data(
 139              %{to: to, actor: actor, published: published, context: context, object: object},
 140              additional
 141            ),
 142          {:ok, activity} <- insert(create_data, local),
 143          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 144          {:ok, _actor} <- User.increase_note_count(actor),
 145          :ok <- maybe_federate(activity) do
 146       {:ok, activity}
 147     end
 148   end
 149
 150   def accept(%{to: to, actor: actor, object: object} = params) do
 151     # only accept false as false value
 152     local = !(params[:local] == false)
 153
 154     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 155          {:ok, activity} <- insert(data, local),
 156          :ok <- maybe_federate(activity) do
 157       {:ok, activity}
 158     end
 159   end
 160
 161   def reject(%{to: to, actor: actor, object: object} = params) do
 162     # only accept false as false value
 163     local = !(params[:local] == false)
 164
 165     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 166          {:ok, activity} <- insert(data, local),
 167          :ok <- maybe_federate(activity) do
 168       {:ok, activity}
 169     end
 170   end
 171
 172   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 173     # only accept false as false value
 174     local = !(params[:local] == false)
 175
 176     with data <- %{
 177            "to" => to,
 178            "cc" => cc,
 179            "type" => "Update",
 180            "actor" => actor,
 181            "object" => object
 182          },
 183          {:ok, activity} <- insert(data, local),
 184          :ok <- maybe_federate(activity) do
 185       {:ok, activity}
 186     end
 187   end
 188
 189   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 190   def like(
 191         %User{ap_id: ap_id} = user,
 192         %Object{data: %{"id" => _}} = object,
 193         activity_id \\ nil,
 194         local \\ true
 195       ) do
 196     with nil <- get_existing_like(ap_id, object),
 197          like_data <- make_like_data(user, object, activity_id),
 198          {:ok, activity} <- insert(like_data, local),
 199          {:ok, object} <- add_like_to_object(activity, object),
 200          :ok <- maybe_federate(activity) do
 201       {:ok, activity, object}
 202     else
 203       %Activity{} = activity -> {:ok, activity, object}
 204       error -> {:error, error}
 205     end
 206   end
 207
 208   def unlike(
 209         %User{} = actor,
 210         %Object{} = object,
 211         activity_id \\ nil,
 212         local \\ true
 213       ) do
 214     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 215          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 216          {:ok, unlike_activity} <- insert(unlike_data, local),
 217          {:ok, _activity} <- Repo.delete(like_activity),
 218          {:ok, object} <- remove_like_from_object(like_activity, object),
 219          :ok <- maybe_federate(unlike_activity) do
 220       {:ok, unlike_activity, like_activity, object}
 221     else
 222       _e -> {:ok, object}
 223     end
 224   end
 225
 226   def announce(
 227         %User{ap_id: _} = user,
 228         %Object{data: %{"id" => _}} = object,
 229         activity_id \\ nil,
 230         local \\ true,
 231         public \\ true
 232       ) do
 233     with true <- is_public?(object),
 234          announce_data <- make_announce_data(user, object, activity_id, public),
 235          {:ok, activity} <- insert(announce_data, local),
 236          {:ok, object} <- add_announce_to_object(activity, object),
 237          :ok <- maybe_federate(activity) do
 238       {:ok, activity, object}
 239     else
 240       error -> {:error, error}
 241     end
 242   end
 243
 244   def unannounce(
 245         %User{} = actor,
 246         %Object{} = object,
 247         activity_id \\ nil,
 248         local \\ true
 249       ) do
 250     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 251          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 252          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 253          :ok <- maybe_federate(unannounce_activity),
 254          {:ok, _activity} <- Repo.delete(announce_activity),
 255          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 256       {:ok, unannounce_activity, object}
 257     else
 258       _e -> {:ok, object}
 259     end
 260   end
 261
 262   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 263     with data <- make_follow_data(follower, followed, activity_id),
 264          {:ok, activity} <- insert(data, local),
 265          :ok <- maybe_federate(activity) do
 266       {:ok, activity}
 267     end
 268   end
 269
 270   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 271     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 272          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 273          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 274          {:ok, activity} <- insert(unfollow_data, local),
 275          :ok <- maybe_federate(activity) do
 276       {:ok, activity}
 277     end
 278   end
 279
 280   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 281     user = User.get_cached_by_ap_id(actor)
 282
 283     data = %{
 284       "type" => "Delete",
 285       "actor" => actor,
 286       "object" => id,
 287       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 288     }
 289
 290     with {:ok, _} <- Object.delete(object),
 291          {:ok, activity} <- insert(data, local),
 292          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 293          {:ok, _actor} <- User.decrease_note_count(user),
 294          :ok <- maybe_federate(activity) do
 295       {:ok, activity}
 296     end
 297   end
 298
 299   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 300     ap_config = Application.get_env(:pleroma, :activitypub)
 301     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 302     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 303
 304     with true <- unfollow_blocked do
 305       follow_activity = fetch_latest_follow(blocker, blocked)
 306
 307       if follow_activity do
 308         unfollow(blocker, blocked, nil, local)
 309       end
 310     end
 311
 312     with true <- outgoing_blocks,
 313          block_data <- make_block_data(blocker, blocked, activity_id),
 314          {:ok, activity} <- insert(block_data, local),
 315          :ok <- maybe_federate(activity) do
 316       {:ok, activity}
 317     else
 318       _e -> {:ok, nil}
 319     end
 320   end
 321
 322   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 323     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 324          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 325          {:ok, activity} <- insert(unblock_data, local),
 326          :ok <- maybe_federate(activity) do
 327       {:ok, activity}
 328     end
 329   end
 330
 331   def fetch_activities_for_context(context, opts \\ %{}) do
 332     public = ["https://www.w3.org/ns/activitystreams#Public"]
 333
 334     recipients =
 335       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 336
 337     query = from(activity in Activity)
 338
 339     query =
 340       query
 341       |> restrict_blocked(opts)
 342       |> restrict_recipients(recipients, opts["user"])
 343
 344     query =
 345       from(
 346         activity in query,
 347         where:
 348           fragment(
 349             "?->>'type' = ? and ?->>'context' = ?",
 350             activity.data,
 351             "Create",
 352             activity.data,
 353             ^context
 354           ),
 355         order_by: [desc: :id]
 356       )
 357
 358     Repo.all(query)
 359   end
 360
 361   def fetch_public_activities(opts \\ %{}) do
 362     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 363
 364     q
 365     |> restrict_unlisted()
 366     |> Repo.all()
 367     |> Enum.reverse()
 368   end
 369
 370   @valid_visibilities ~w[direct unlisted public private]
 371
 372   defp restrict_visibility(query, %{visibility: visibility})
 373        when visibility in @valid_visibilities do
 374     query =
 375       from(
 376         a in query,
 377         where:
 378           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 379       )
 380
 381     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 382
 383     query
 384   end
 385
 386   defp restrict_visibility(_query, %{visibility: visibility})
 387        when visibility not in @valid_visibilities do
 388     Logger.error("Could not restrict visibility to #{visibility}")
 389   end
 390
 391   defp restrict_visibility(query, _visibility), do: query
 392
 393   def fetch_user_activities(user, reading_user, params \\ %{}) do
 394     params =
 395       params
 396       |> Map.put("type", ["Create", "Announce"])
 397       |> Map.put("actor_id", user.ap_id)
 398       |> Map.put("whole_db", true)
 399       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 400
 401     recipients =
 402       if reading_user do
 403         ["https://www.w3.org/ns/activitystreams#Public"] ++
 404           [reading_user.ap_id | reading_user.following]
 405       else
 406         ["https://www.w3.org/ns/activitystreams#Public"]
 407       end
 408
 409     fetch_activities(recipients, params)
 410     |> Enum.reverse()
 411   end
 412
 413   defp restrict_since(query, %{"since_id" => since_id}) do
 414     from(activity in query, where: activity.id > ^since_id)
 415   end
 416
 417   defp restrict_since(query, _), do: query
 418
 419   defp restrict_tag(query, %{"tag" => tag}) do
 420     from(
 421       activity in query,
 422       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 423     )
 424   end
 425
 426   defp restrict_tag(query, _), do: query
 427
 428   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 429     from(
 430       activity in query,
 431       where:
 432         fragment(
 433           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 434           activity.data,
 435           ^recipients_to,
 436           activity.data,
 437           ^recipients_cc
 438         )
 439     )
 440   end
 441
 442   defp restrict_recipients(query, [], _user), do: query
 443
 444   defp restrict_recipients(query, recipients, nil) do
 445     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 446   end
 447
 448   defp restrict_recipients(query, recipients, user) do
 449     from(
 450       activity in query,
 451       where: fragment("? && ?", ^recipients, activity.recipients),
 452       or_where: activity.actor == ^user.ap_id
 453     )
 454   end
 455
 456   defp restrict_limit(query, %{"limit" => limit}) do
 457     from(activity in query, limit: ^limit)
 458   end
 459
 460   defp restrict_limit(query, _), do: query
 461
 462   defp restrict_local(query, %{"local_only" => true}) do
 463     from(activity in query, where: activity.local == true)
 464   end
 465
 466   defp restrict_local(query, _), do: query
 467
 468   defp restrict_max(query, %{"max_id" => max_id}) do
 469     from(activity in query, where: activity.id < ^max_id)
 470   end
 471
 472   defp restrict_max(query, _), do: query
 473
 474   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 475     from(activity in query, where: activity.actor == ^actor_id)
 476   end
 477
 478   defp restrict_actor(query, _), do: query
 479
 480   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 481     restrict_type(query, %{"type" => [type]})
 482   end
 483
 484   defp restrict_type(query, %{"type" => type}) do
 485     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 486   end
 487
 488   defp restrict_type(query, _), do: query
 489
 490   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 491     from(
 492       activity in query,
 493       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 494     )
 495   end
 496
 497   defp restrict_favorited_by(query, _), do: query
 498
 499   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 500     from(
 501       activity in query,
 502       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 503     )
 504   end
 505
 506   defp restrict_media(query, _), do: query
 507
 508   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 509     from(
 510       activity in query,
 511       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 512     )
 513   end
 514
 515   defp restrict_replies(query, _), do: query
 516
 517   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 518     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 519   end
 520
 521   defp restrict_reblogs(query, _), do: query
 522
 523   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 524     blocks = info.blocks || []
 525     domain_blocks = info.domain_blocks || []
 526
 527     from(
 528       activity in query,
 529       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 530       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 531       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 532     )
 533   end
 534
 535   defp restrict_blocked(query, _), do: query
 536
 537   defp restrict_unlisted(query) do
 538     from(
 539       activity in query,
 540       where:
 541         fragment(
 542           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 543           activity.data,
 544           ^["https://www.w3.org/ns/activitystreams#Public"]
 545         )
 546     )
 547   end
 548
 549   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 550     from(activity in query, where: activity.id in ^ids)
 551   end
 552
 553   defp restrict_pinned(query, _), do: query
 554
 555   def fetch_activities_query(recipients, opts \\ %{}) do
 556     base_query =
 557       from(
 558         activity in Activity,
 559         limit: 20,
 560         order_by: [fragment("? desc nulls last", activity.id)]
 561       )
 562
 563     base_query
 564     |> restrict_recipients(recipients, opts["user"])
 565     |> restrict_tag(opts)
 566     |> restrict_since(opts)
 567     |> restrict_local(opts)
 568     |> restrict_limit(opts)
 569     |> restrict_max(opts)
 570     |> restrict_actor(opts)
 571     |> restrict_type(opts)
 572     |> restrict_favorited_by(opts)
 573     |> restrict_blocked(opts)
 574     |> restrict_media(opts)
 575     |> restrict_visibility(opts)
 576     |> restrict_replies(opts)
 577     |> restrict_reblogs(opts)
 578     |> restrict_pinned(opts)
 579   end
 580
 581   def fetch_activities(recipients, opts \\ %{}) do
 582     fetch_activities_query(recipients, opts)
 583     |> Repo.all()
 584     |> Enum.reverse()
 585   end
 586
 587   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 588     fetch_activities_query([], opts)
 589     |> restrict_to_cc(recipients_to, recipients_cc)
 590     |> Repo.all()
 591     |> Enum.reverse()
 592   end
 593
 594   def upload(file, opts \\ []) do
 595     with {:ok, data} <- Upload.store(file, opts) do
 596       obj_data =
 597         if opts[:actor] do
 598           Map.put(data, "actor", opts[:actor])
 599         else
 600           data
 601         end
 602
 603       Repo.insert(%Object{data: obj_data})
 604     end
 605   end
 606
 607   def user_data_from_user_object(data) do
 608     avatar =
 609       data["icon"]["url"] &&
 610         %{
 611           "type" => "Image",
 612           "url" => [%{"href" => data["icon"]["url"]}]
 613         }
 614
 615     banner =
 616       data["image"]["url"] &&
 617         %{
 618           "type" => "Image",
 619           "url" => [%{"href" => data["image"]["url"]}]
 620         }
 621
 622     locked = data["manuallyApprovesFollowers"] || false
 623     data = Transmogrifier.maybe_fix_user_object(data)
 624
 625     user_data = %{
 626       ap_id: data["id"],
 627       info: %{
 628         "ap_enabled" => true,
 629         "source_data" => data,
 630         "banner" => banner,
 631         "locked" => locked
 632       },
 633       avatar: avatar,
 634       name: data["name"],
 635       follower_address: data["followers"],
 636       bio: data["summary"]
 637     }
 638
 639     # nickname can be nil because of virtual actors
 640     user_data =
 641       if data["preferredUsername"] do
 642         Map.put(
 643           user_data,
 644           :nickname,
 645           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 646         )
 647       else
 648         Map.put(user_data, :nickname, nil)
 649       end
 650
 651     {:ok, user_data}
 652   end
 653
 654   def fetch_and_prepare_user_from_ap_id(ap_id) do
 655     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 656       user_data_from_user_object(data)
 657     else
 658       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 659     end
 660   end
 661
 662   def make_user_from_ap_id(ap_id) do
 663     if _user = User.get_by_ap_id(ap_id) do
 664       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 665     else
 666       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 667         User.insert_or_update_user(data)
 668       else
 669         e -> {:error, e}
 670       end
 671     end
 672   end
 673
 674   def make_user_from_nickname(nickname) do
 675     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 676       make_user_from_ap_id(ap_id)
 677     else
 678       _e -> {:error, "No AP id in WebFinger"}
 679     end
 680   end
 681
 682   def should_federate?(inbox, public) do
 683     if public do
 684       true
 685     else
 686       inbox_info = URI.parse(inbox)
 687       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 688     end
 689   end
 690
 691   def publish(actor, activity) do
 692     remote_followers =
 693       if actor.follower_address in activity.recipients do
 694         {:ok, followers} = User.get_followers(actor)
 695         followers |> Enum.filter(&(!&1.local))
 696       else
 697         []
 698       end
 699
 700     public = is_public?(activity)
 701
 702     remote_inboxes =
 703       (Pleroma.Web.Salmon.remote_users(activity) ++ remote_followers)
 704       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 705       |> Enum.map(fn %{info: %{source_data: data}} ->
 706         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 707       end)
 708       |> Enum.uniq()
 709       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 710       |> Instances.filter_reachable()
 711
 712     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 713     json = Jason.encode!(data)
 714
 715     Enum.each(remote_inboxes, fn inbox ->
 716       Federator.enqueue(:publish_single_ap, %{
 717         inbox: inbox,
 718         json: json,
 719         actor: actor,
 720         id: activity.data["id"]
 721       })
 722     end)
 723   end
 724
 725   def publish_one(%{inbox: inbox} = activity) do
 726     if Instances.reachable?(inbox) do
 727       do_publish_one(activity)
 728     else
 729       {:error, :noop}
 730     end
 731   end
 732
 733   defp do_publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 734     Logger.info("Federating #{id} to #{inbox}")
 735     host = URI.parse(inbox).host
 736
 737     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 738
 739     signature =
 740       Pleroma.Web.HTTPSignatures.sign(actor, %{
 741         host: host,
 742         "content-length": byte_size(json),
 743         digest: digest
 744       })
 745
 746     with {:ok, %{status: code}} when code in 200..299 <-
 747            result =
 748              @httpoison.post(
 749                inbox,
 750                json,
 751                [
 752                  {"Content-Type", "application/activity+json"},
 753                  {"signature", signature},
 754                  {"digest", digest},
 755                  {"referer", Pleroma.Web.Endpoint.url()}
 756                ]
 757              ) do
 758       Instances.set_reachable(inbox)
 759       result
 760     else
 761       e ->
 762         Instances.set_unreachable(inbox)
 763         e
 764     end
 765   end
 766
 767   # TODO:
 768   # This will create a Create activity, which we need internally at the moment.
 769   def fetch_object_from_id(id) do
 770     if object = Object.get_cached_by_ap_id(id) do
 771       {:ok, object}
 772     else
 773       Logger.info("Fetching #{id} via AP")
 774
 775       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 776            nil <- Object.normalize(data),
 777            params <- %{
 778              "type" => "Create",
 779              "to" => data["to"],
 780              "cc" => data["cc"],
 781              "actor" => data["actor"] || data["attributedTo"],
 782              "object" => data
 783            },
 784            :ok <- Transmogrifier.contain_origin(id, params),
 785            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 786         {:ok, Object.normalize(activity.data["object"])}
 787       else
 788         {:error, {:reject, nil}} ->
 789           {:reject, nil}
 790
 791         object = %Object{} ->
 792           {:ok, object}
 793
 794         _e ->
 795           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 796
 797           case OStatus.fetch_activity_from_url(id) do
 798             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 799             e -> e
 800           end
 801       end
 802     end
 803   end
 804
 805   def fetch_and_contain_remote_object_from_id(id) do
 806     Logger.info("Fetching #{id} via AP")
 807
 808     with true <- String.starts_with?(id, "http"),
 809          {:ok, %{body: body, status: code}} when code in 200..299 <-
 810            @httpoison.get(
 811              id,
 812              [{:Accept, "application/activity+json"}]
 813            ),
 814          {:ok, data} <- Jason.decode(body),
 815          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 816       {:ok, data}
 817     else
 818       e ->
 819         {:error, e}
 820     end
 821   end
 822
 823   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 824   def is_public?(%Object{data: data}), do: is_public?(data)
 825   def is_public?(%Activity{data: data}), do: is_public?(data)
 826   def is_public?(%{"directMessage" => true}), do: false
 827
 828   def is_public?(data) do
 829     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 830   end
 831
 832   def is_private?(activity) do
 833     !is_public?(activity) && Enum.any?(activity.data["to"], &String.contains?(&1, "/followers"))
 834   end
 835
 836   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
 837   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
 838
 839   def is_direct?(activity) do
 840     !is_public?(activity) && !is_private?(activity)
 841   end
 842
 843   def visible_for_user?(activity, nil) do
 844     is_public?(activity)
 845   end
 846
 847   def visible_for_user?(activity, user) do
 848     x = [user.ap_id | user.following]
 849     y = activity.data["to"] ++ (activity.data["cc"] || [])
 850     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 851   end
 852
 853   # guard
 854   def entire_thread_visible_for_user?(nil, _user), do: false
 855
 856   # child
 857   def entire_thread_visible_for_user?(
 858         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 859         user
 860       )
 861       when is_binary(parent_id) do
 862     parent = Activity.get_in_reply_to_activity(tail)
 863     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 864   end
 865
 866   # root
 867   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 868
 869   # filter out broken threads
 870   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 871     entire_thread_visible_for_user?(activity, user)
 872   end
 873
 874   # do post-processing on a specific activity
 875   def contain_activity(%Activity{} = activity, %User{} = user) do
 876     contain_broken_threads(activity, user)
 877   end
 878
 879   # do post-processing on a timeline
 880   def contain_timeline(timeline, user) do
 881     timeline
 882     |> Enum.filter(fn activity ->
 883       contain_activity(activity, user)
 884     end)
 885   end
 886 end