git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(%{"type" => "Create"} = data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     actor = data["actor"] || []
  43     recipients = (to ++ cc ++ [actor]) |> Enum.uniq()
  44     {recipients, to, cc}
  45   end
  46
  47   defp get_recipients(data) do
  48     to = data["to"] || []
  49     cc = data["cc"] || []
  50     recipients = to ++ cc
  51     {recipients, to, cc}
  52   end
  53
  54   defp check_actor_is_active(actor) do
  55     if not is_nil(actor) do
  56       with user <- User.get_cached_by_ap_id(actor),
  57            false <- user.info.deactivated do
  58         :ok
  59       else
  60         _e -> :reject
  61       end
  62     else
  63       :ok
  64     end
  65   end
  66
  67   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  68     limit = Pleroma.Config.get([:instance, :remote_limit])
  69     String.length(content) <= limit
  70   end
  71
  72   defp check_remote_limit(_), do: true
  73
  74   def insert(map, local \\ true) when is_map(map) do
  75     with nil <- Activity.normalize(map),
  76          map <- lazy_put_activity_defaults(map),
  77          :ok <- check_actor_is_active(map["actor"]),
  78          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  79          {:ok, map} <- MRF.filter(map),
  80          :ok <- insert_full_object(map) do
  81       {recipients, _, _} = get_recipients(map)
  82
  83       {:ok, activity} =
  84         Repo.insert(%Activity{
  85           data: map,
  86           local: local,
  87           actor: map["actor"],
  88           recipients: recipients
  89         })
  90
  91       Notification.create_notifications(activity)
  92       stream_out(activity)
  93       {:ok, activity}
  94     else
  95       %Activity{} = activity -> {:ok, activity}
  96       error -> {:error, error}
  97     end
  98   end
  99
 100   def stream_out(activity) do
 101     public = "https://www.w3.org/ns/activitystreams#Public"
 102
 103     if activity.data["type"] in ["Create", "Announce", "Delete"] do
 104       Pleroma.Web.Streamer.stream("user", activity)
 105       Pleroma.Web.Streamer.stream("list", activity)
 106
 107       if Enum.member?(activity.data["to"], public) do
 108         Pleroma.Web.Streamer.stream("public", activity)
 109
 110         if activity.local do
 111           Pleroma.Web.Streamer.stream("public:local", activity)
 112         end
 113
 114         if activity.data["type"] in ["Create"] do
 115           activity.data["object"]
 116           |> Map.get("tag", [])
 117           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 118           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 119
 120           if activity.data["object"]["attachment"] != [] do
 121             Pleroma.Web.Streamer.stream("public:media", activity)
 122
 123             if activity.local do
 124               Pleroma.Web.Streamer.stream("public:local:media", activity)
 125             end
 126           end
 127         end
 128       else
 129         if !Enum.member?(activity.data["cc"] || [], public) &&
 130              !Enum.member?(
 131                activity.data["to"],
 132                User.get_by_ap_id(activity.data["actor"]).follower_address
 133              ),
 134            do: Pleroma.Web.Streamer.stream("direct", activity)
 135       end
 136     end
 137   end
 138
 139   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 140     additional = params[:additional] || %{}
 141     # only accept false as false value
 142     local = !(params[:local] == false)
 143     published = params[:published]
 144
 145     with create_data <-
 146            make_create_data(
 147              %{to: to, actor: actor, published: published, context: context, object: object},
 148              additional
 149            ),
 150          {:ok, activity} <- insert(create_data, local),
 151          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 152          {:ok, _actor} <- User.increase_note_count(actor),
 153          :ok <- maybe_federate(activity) do
 154       {:ok, activity}
 155     end
 156   end
 157
 158   def accept(%{to: to, actor: actor, object: object} = params) do
 159     # only accept false as false value
 160     local = !(params[:local] == false)
 161
 162     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 163          {:ok, activity} <- insert(data, local),
 164          :ok <- maybe_federate(activity) do
 165       {:ok, activity}
 166     end
 167   end
 168
 169   def reject(%{to: to, actor: actor, object: object} = params) do
 170     # only accept false as false value
 171     local = !(params[:local] == false)
 172
 173     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 174          {:ok, activity} <- insert(data, local),
 175          :ok <- maybe_federate(activity) do
 176       {:ok, activity}
 177     end
 178   end
 179
 180   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 181     # only accept false as false value
 182     local = !(params[:local] == false)
 183
 184     with data <- %{
 185            "to" => to,
 186            "cc" => cc,
 187            "type" => "Update",
 188            "actor" => actor,
 189            "object" => object
 190          },
 191          {:ok, activity} <- insert(data, local),
 192          :ok <- maybe_federate(activity) do
 193       {:ok, activity}
 194     end
 195   end
 196
 197   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 198   def like(
 199         %User{ap_id: ap_id} = user,
 200         %Object{data: %{"id" => _}} = object,
 201         activity_id \\ nil,
 202         local \\ true
 203       ) do
 204     with nil <- get_existing_like(ap_id, object),
 205          like_data <- make_like_data(user, object, activity_id),
 206          {:ok, activity} <- insert(like_data, local),
 207          {:ok, object} <- add_like_to_object(activity, object),
 208          :ok <- maybe_federate(activity) do
 209       {:ok, activity, object}
 210     else
 211       %Activity{} = activity -> {:ok, activity, object}
 212       error -> {:error, error}
 213     end
 214   end
 215
 216   def unlike(
 217         %User{} = actor,
 218         %Object{} = object,
 219         activity_id \\ nil,
 220         local \\ true
 221       ) do
 222     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 223          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 224          {:ok, unlike_activity} <- insert(unlike_data, local),
 225          {:ok, _activity} <- Repo.delete(like_activity),
 226          {:ok, object} <- remove_like_from_object(like_activity, object),
 227          :ok <- maybe_federate(unlike_activity) do
 228       {:ok, unlike_activity, like_activity, object}
 229     else
 230       _e -> {:ok, object}
 231     end
 232   end
 233
 234   def announce(
 235         %User{ap_id: _} = user,
 236         %Object{data: %{"id" => _}} = object,
 237         activity_id \\ nil,
 238         local \\ true,
 239         public \\ true
 240       ) do
 241     with true <- is_public?(object),
 242          announce_data <- make_announce_data(user, object, activity_id, public),
 243          {:ok, activity} <- insert(announce_data, local),
 244          {:ok, object} <- add_announce_to_object(activity, object),
 245          :ok <- maybe_federate(activity) do
 246       {:ok, activity, object}
 247     else
 248       error -> {:error, error}
 249     end
 250   end
 251
 252   def unannounce(
 253         %User{} = actor,
 254         %Object{} = object,
 255         activity_id \\ nil,
 256         local \\ true
 257       ) do
 258     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 259          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 260          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 261          :ok <- maybe_federate(unannounce_activity),
 262          {:ok, _activity} <- Repo.delete(announce_activity),
 263          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 264       {:ok, unannounce_activity, object}
 265     else
 266       _e -> {:ok, object}
 267     end
 268   end
 269
 270   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 271     with data <- make_follow_data(follower, followed, activity_id),
 272          {:ok, activity} <- insert(data, local),
 273          :ok <- maybe_federate(activity) do
 274       {:ok, activity}
 275     end
 276   end
 277
 278   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 279     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 280          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 281          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 282          {:ok, activity} <- insert(unfollow_data, local),
 283          :ok <- maybe_federate(activity) do
 284       {:ok, activity}
 285     end
 286   end
 287
 288   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 289     user = User.get_cached_by_ap_id(actor)
 290
 291     data = %{
 292       "type" => "Delete",
 293       "actor" => actor,
 294       "object" => id,
 295       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 296     }
 297
 298     with {:ok, _} <- Object.delete(object),
 299          {:ok, activity} <- insert(data, local),
 300          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 301          {:ok, _actor} <- User.decrease_note_count(user),
 302          :ok <- maybe_federate(activity) do
 303       {:ok, activity}
 304     end
 305   end
 306
 307   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 308     ap_config = Application.get_env(:pleroma, :activitypub)
 309     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 310     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 311
 312     with true <- unfollow_blocked do
 313       follow_activity = fetch_latest_follow(blocker, blocked)
 314
 315       if follow_activity do
 316         unfollow(blocker, blocked, nil, local)
 317       end
 318     end
 319
 320     with true <- outgoing_blocks,
 321          block_data <- make_block_data(blocker, blocked, activity_id),
 322          {:ok, activity} <- insert(block_data, local),
 323          :ok <- maybe_federate(activity) do
 324       {:ok, activity}
 325     else
 326       _e -> {:ok, nil}
 327     end
 328   end
 329
 330   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 331     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 332          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 333          {:ok, activity} <- insert(unblock_data, local),
 334          :ok <- maybe_federate(activity) do
 335       {:ok, activity}
 336     end
 337   end
 338
 339   def fetch_activities_for_context(context, opts \\ %{}) do
 340     public = ["https://www.w3.org/ns/activitystreams#Public"]
 341
 342     recipients =
 343       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 344
 345     query = from(activity in Activity)
 346
 347     query =
 348       query
 349       |> restrict_blocked(opts)
 350       |> restrict_recipients(recipients, opts["user"])
 351
 352     query =
 353       from(
 354         activity in query,
 355         where:
 356           fragment(
 357             "?->>'type' = ? and ?->>'context' = ?",
 358             activity.data,
 359             "Create",
 360             activity.data,
 361             ^context
 362           ),
 363         order_by: [desc: :id]
 364       )
 365
 366     Repo.all(query)
 367   end
 368
 369   def fetch_public_activities(opts \\ %{}) do
 370     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 371
 372     q
 373     |> restrict_unlisted()
 374     |> Repo.all()
 375     |> Enum.reverse()
 376   end
 377
 378   @valid_visibilities ~w[direct unlisted public private]
 379
 380   defp restrict_visibility(query, %{visibility: visibility})
 381        when visibility in @valid_visibilities do
 382     query =
 383       from(
 384         a in query,
 385         where:
 386           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 387       )
 388
 389     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 390
 391     query
 392   end
 393
 394   defp restrict_visibility(_query, %{visibility: visibility})
 395        when visibility not in @valid_visibilities do
 396     Logger.error("Could not restrict visibility to #{visibility}")
 397   end
 398
 399   defp restrict_visibility(query, _visibility), do: query
 400
 401   def fetch_user_activities(user, reading_user, params \\ %{}) do
 402     params =
 403       params
 404       |> Map.put("type", ["Create", "Announce"])
 405       |> Map.put("actor_id", user.ap_id)
 406       |> Map.put("whole_db", true)
 407       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 408
 409     recipients =
 410       if reading_user do
 411         ["https://www.w3.org/ns/activitystreams#Public"] ++
 412           [reading_user.ap_id | reading_user.following]
 413       else
 414         ["https://www.w3.org/ns/activitystreams#Public"]
 415       end
 416
 417     fetch_activities(recipients, params)
 418     |> Enum.reverse()
 419   end
 420
 421   defp restrict_since(query, %{"since_id" => ""}), do: query
 422
 423   defp restrict_since(query, %{"since_id" => since_id}) do
 424     from(activity in query, where: activity.id > ^since_id)
 425   end
 426
 427   defp restrict_since(query, _), do: query
 428
 429   defp restrict_tag(query, %{"tag" => tag}) do
 430     from(
 431       activity in query,
 432       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 433     )
 434   end
 435
 436   defp restrict_tag(query, _), do: query
 437
 438   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 439     from(
 440       activity in query,
 441       where:
 442         fragment(
 443           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 444           activity.data,
 445           ^recipients_to,
 446           activity.data,
 447           ^recipients_cc
 448         )
 449     )
 450   end
 451
 452   defp restrict_recipients(query, [], _user), do: query
 453
 454   defp restrict_recipients(query, recipients, nil) do
 455     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 456   end
 457
 458   defp restrict_recipients(query, recipients, user) do
 459     from(
 460       activity in query,
 461       where: fragment("? && ?", ^recipients, activity.recipients),
 462       or_where: activity.actor == ^user.ap_id
 463     )
 464   end
 465
 466   defp restrict_limit(query, %{"limit" => limit}) do
 467     from(activity in query, limit: ^limit)
 468   end
 469
 470   defp restrict_limit(query, _), do: query
 471
 472   defp restrict_local(query, %{"local_only" => true}) do
 473     from(activity in query, where: activity.local == true)
 474   end
 475
 476   defp restrict_local(query, _), do: query
 477
 478   defp restrict_max(query, %{"max_id" => ""}), do: query
 479
 480   defp restrict_max(query, %{"max_id" => max_id}) do
 481     from(activity in query, where: activity.id < ^max_id)
 482   end
 483
 484   defp restrict_max(query, _), do: query
 485
 486   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 487     from(activity in query, where: activity.actor == ^actor_id)
 488   end
 489
 490   defp restrict_actor(query, _), do: query
 491
 492   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 493     restrict_type(query, %{"type" => [type]})
 494   end
 495
 496   defp restrict_type(query, %{"type" => type}) do
 497     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 498   end
 499
 500   defp restrict_type(query, _), do: query
 501
 502   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 503     from(
 504       activity in query,
 505       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 506     )
 507   end
 508
 509   defp restrict_favorited_by(query, _), do: query
 510
 511   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 512     from(
 513       activity in query,
 514       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 515     )
 516   end
 517
 518   defp restrict_media(query, _), do: query
 519
 520   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 521     from(
 522       activity in query,
 523       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 524     )
 525   end
 526
 527   defp restrict_replies(query, _), do: query
 528
 529   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 530     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 531   end
 532
 533   defp restrict_reblogs(query, _), do: query
 534
 535   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 536     blocks = info.blocks || []
 537     domain_blocks = info.domain_blocks || []
 538
 539     from(
 540       activity in query,
 541       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 542       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 543       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 544     )
 545   end
 546
 547   defp restrict_blocked(query, _), do: query
 548
 549   defp restrict_unlisted(query) do
 550     from(
 551       activity in query,
 552       where:
 553         fragment(
 554           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 555           activity.data,
 556           ^["https://www.w3.org/ns/activitystreams#Public"]
 557         )
 558     )
 559   end
 560
 561   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 562     from(activity in query, where: activity.id in ^ids)
 563   end
 564
 565   defp restrict_pinned(query, _), do: query
 566
 567   def fetch_activities_query(recipients, opts \\ %{}) do
 568     base_query =
 569       from(
 570         activity in Activity,
 571         limit: 20,
 572         order_by: [fragment("? desc nulls last", activity.id)]
 573       )
 574
 575     base_query
 576     |> restrict_recipients(recipients, opts["user"])
 577     |> restrict_tag(opts)
 578     |> restrict_since(opts)
 579     |> restrict_local(opts)
 580     |> restrict_limit(opts)
 581     |> restrict_max(opts)
 582     |> restrict_actor(opts)
 583     |> restrict_type(opts)
 584     |> restrict_favorited_by(opts)
 585     |> restrict_blocked(opts)
 586     |> restrict_media(opts)
 587     |> restrict_visibility(opts)
 588     |> restrict_replies(opts)
 589     |> restrict_reblogs(opts)
 590     |> restrict_pinned(opts)
 591   end
 592
 593   def fetch_activities(recipients, opts \\ %{}) do
 594     fetch_activities_query(recipients, opts)
 595     |> Repo.all()
 596     |> Enum.reverse()
 597   end
 598
 599   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 600     fetch_activities_query([], opts)
 601     |> restrict_to_cc(recipients_to, recipients_cc)
 602     |> Repo.all()
 603     |> Enum.reverse()
 604   end
 605
 606   def upload(file, opts \\ []) do
 607     with {:ok, data} <- Upload.store(file, opts) do
 608       obj_data =
 609         if opts[:actor] do
 610           Map.put(data, "actor", opts[:actor])
 611         else
 612           data
 613         end
 614
 615       Repo.insert(%Object{data: obj_data})
 616     end
 617   end
 618
 619   def user_data_from_user_object(data) do
 620     avatar =
 621       data["icon"]["url"] &&
 622         %{
 623           "type" => "Image",
 624           "url" => [%{"href" => data["icon"]["url"]}]
 625         }
 626
 627     banner =
 628       data["image"]["url"] &&
 629         %{
 630           "type" => "Image",
 631           "url" => [%{"href" => data["image"]["url"]}]
 632         }
 633
 634     locked = data["manuallyApprovesFollowers"] || false
 635     data = Transmogrifier.maybe_fix_user_object(data)
 636
 637     user_data = %{
 638       ap_id: data["id"],
 639       info: %{
 640         "ap_enabled" => true,
 641         "source_data" => data,
 642         "banner" => banner,
 643         "locked" => locked
 644       },
 645       avatar: avatar,
 646       name: data["name"],
 647       follower_address: data["followers"],
 648       bio: data["summary"]
 649     }
 650
 651     # nickname can be nil because of virtual actors
 652     user_data =
 653       if data["preferredUsername"] do
 654         Map.put(
 655           user_data,
 656           :nickname,
 657           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 658         )
 659       else
 660         Map.put(user_data, :nickname, nil)
 661       end
 662
 663     {:ok, user_data}
 664   end
 665
 666   def fetch_and_prepare_user_from_ap_id(ap_id) do
 667     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 668       user_data_from_user_object(data)
 669     else
 670       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 671     end
 672   end
 673
 674   def make_user_from_ap_id(ap_id) do
 675     if _user = User.get_by_ap_id(ap_id) do
 676       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 677     else
 678       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 679         User.insert_or_update_user(data)
 680       else
 681         e -> {:error, e}
 682       end
 683     end
 684   end
 685
 686   def make_user_from_nickname(nickname) do
 687     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 688       make_user_from_ap_id(ap_id)
 689     else
 690       _e -> {:error, "No AP id in WebFinger"}
 691     end
 692   end
 693
 694   def should_federate?(inbox, public) do
 695     if public do
 696       true
 697     else
 698       inbox_info = URI.parse(inbox)
 699       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 700     end
 701   end
 702
 703   def publish(actor, activity) do
 704     followers =
 705       if actor.follower_address in activity.recipients do
 706         {:ok, followers} = User.get_followers(actor)
 707         followers |> Enum.filter(&(!&1.local))
 708       else
 709         []
 710       end
 711
 712     public = is_public?(activity)
 713
 714     remote_inboxes =
 715       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 716       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 717       |> Enum.map(fn %{info: %{source_data: data}} ->
 718         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 719       end)
 720       |> Enum.uniq()
 721       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 722
 723     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 724     json = Jason.encode!(data)
 725
 726     Enum.each(remote_inboxes, fn inbox ->
 727       Federator.enqueue(:publish_single_ap, %{
 728         inbox: inbox,
 729         json: json,
 730         actor: actor,
 731         id: activity.data["id"]
 732       })
 733     end)
 734   end
 735
 736   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 737     Logger.info("Federating #{id} to #{inbox}")
 738     host = URI.parse(inbox).host
 739
 740     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 741
 742     signature =
 743       Pleroma.Web.HTTPSignatures.sign(actor, %{
 744         host: host,
 745         "content-length": byte_size(json),
 746         digest: digest
 747       })
 748
 749     @httpoison.post(
 750       inbox,
 751       json,
 752       [
 753         {"Content-Type", "application/activity+json"},
 754         {"signature", signature},
 755         {"digest", digest}
 756       ]
 757     )
 758   end
 759
 760   # TODO:
 761   # This will create a Create activity, which we need internally at the moment.
 762   def fetch_object_from_id(id) do
 763     if object = Object.get_cached_by_ap_id(id) do
 764       {:ok, object}
 765     else
 766       Logger.info("Fetching #{id} via AP")
 767
 768       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 769            nil <- Object.normalize(data),
 770            params <- %{
 771              "type" => "Create",
 772              "to" => data["to"],
 773              "cc" => data["cc"],
 774              "actor" => data["actor"] || data["attributedTo"],
 775              "object" => data
 776            },
 777            :ok <- Transmogrifier.contain_origin(id, params),
 778            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 779         {:ok, Object.normalize(activity.data["object"])}
 780       else
 781         {:error, {:reject, nil}} ->
 782           {:reject, nil}
 783
 784         object = %Object{} ->
 785           {:ok, object}
 786
 787         _e ->
 788           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 789
 790           case OStatus.fetch_activity_from_url(id) do
 791             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 792             e -> e
 793           end
 794       end
 795     end
 796   end
 797
 798   def fetch_and_contain_remote_object_from_id(id) do
 799     Logger.info("Fetching #{id} via AP")
 800
 801     with true <- String.starts_with?(id, "http"),
 802          {:ok, %{body: body, status: code}} when code in 200..299 <-
 803            @httpoison.get(
 804              id,
 805              [{:Accept, "application/activity+json"}]
 806            ),
 807          {:ok, data} <- Jason.decode(body),
 808          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 809       {:ok, data}
 810     else
 811       e ->
 812         {:error, e}
 813     end
 814   end
 815
 816   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 817   def is_public?(%Object{data: data}), do: is_public?(data)
 818   def is_public?(%Activity{data: data}), do: is_public?(data)
 819   def is_public?(%{"directMessage" => true}), do: false
 820
 821   def is_public?(data) do
 822     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 823   end
 824
 825   def is_private?(activity) do
 826     !is_public?(activity) && Enum.any?(activity.data["to"], &String.contains?(&1, "/followers"))
 827   end
 828
 829   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
 830   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
 831
 832   def is_direct?(activity) do
 833     !is_public?(activity) && !is_private?(activity)
 834   end
 835
 836   def visible_for_user?(activity, nil) do
 837     is_public?(activity)
 838   end
 839
 840   def visible_for_user?(activity, user) do
 841     x = [user.ap_id | user.following]
 842     y = activity.data["to"] ++ (activity.data["cc"] || [])
 843     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 844   end
 845
 846   # guard
 847   def entire_thread_visible_for_user?(nil, _user), do: false
 848
 849   # child
 850   def entire_thread_visible_for_user?(
 851         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 852         user
 853       )
 854       when is_binary(parent_id) do
 855     parent = Activity.get_in_reply_to_activity(tail)
 856     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 857   end
 858
 859   # root
 860   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 861
 862   # filter out broken threads
 863   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 864     entire_thread_visible_for_user?(activity, user)
 865   end
 866
 867   # do post-processing on a specific activity
 868   def contain_activity(%Activity{} = activity, %User{} = user) do
 869     contain_broken_threads(activity, user)
 870   end
 871
 872   # do post-processing on a timeline
 873   def contain_timeline(timeline, user) do
 874     timeline
 875     |> Enum.filter(fn activity ->
 876       contain_activity(activity, user)
 877     end)
 878   end
 879 end