git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   # For Announce activities, we filter the recipients based on following status for any actors
  16   # that match actual users.  See issue #164 for more information about why this is necessary.
  17   defp get_recipients(%{"type" => "Announce"} = data) do
  18     to = data["to"] || []
  19     cc = data["cc"] || []
  20     recipients = to ++ cc
  21     actor = User.get_cached_by_ap_id(data["actor"])
  22
  23     recipients
  24     |> Enum.filter(fn recipient ->
  25       case User.get_cached_by_ap_id(recipient) do
  26         nil ->
  27           true
  28
  29         user ->
  30           User.following?(user, actor)
  31       end
  32     end)
  33
  34     {recipients, to, cc}
  35   end
  36
  37   defp get_recipients(data) do
  38     to = data["to"] || []
  39     cc = data["cc"] || []
  40     recipients = to ++ cc
  41     {recipients, to, cc}
  42   end
  43
  44   defp check_actor_is_active(actor) do
  45     if not is_nil(actor) do
  46       with user <- User.get_cached_by_ap_id(actor),
  47            nil <- user.info["deactivated"] do
  48         :ok
  49       else
  50         _e -> :reject
  51       end
  52     else
  53       :ok
  54     end
  55   end
  56
  57   def insert(map, local \\ true) when is_map(map) do
  58     with nil <- Activity.normalize(map),
  59          map <- lazy_put_activity_defaults(map),
  60          :ok <- check_actor_is_active(map["actor"]),
  61          {:ok, map} <- MRF.filter(map),
  62          :ok <- insert_full_object(map) do
  63       {recipients, _, _} = get_recipients(map)
  64
  65       {:ok, activity} =
  66         Repo.insert(%Activity{
  67           data: map,
  68           local: local,
  69           actor: map["actor"],
  70           recipients: recipients
  71         })
  72
  73       Notification.create_notifications(activity)
  74       stream_out(activity)
  75       {:ok, activity}
  76     else
  77       %Activity{} = activity -> {:ok, activity}
  78       error -> {:error, error}
  79     end
  80   end
  81
  82   def stream_out(activity) do
  83     public = "https://www.w3.org/ns/activitystreams#Public"
  84
  85     if activity.data["type"] in ["Create", "Announce"] do
  86       Pleroma.Web.Streamer.stream("user", activity)
  87       Pleroma.Web.Streamer.stream("list", activity)
  88
  89       if Enum.member?(activity.data["to"], public) do
  90         Pleroma.Web.Streamer.stream("public", activity)
  91
  92         if activity.local do
  93           Pleroma.Web.Streamer.stream("public:local", activity)
  94         end
  95
  96         activity.data["object"]
  97         |> Map.get("tag", [])
  98         |> Enum.filter(fn tag -> is_bitstring(tag) end)
  99         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 100
 101         if activity.data["object"]["attachment"] != [] do
 102           Pleroma.Web.Streamer.stream("public:media", activity)
 103
 104           if activity.local do
 105             Pleroma.Web.Streamer.stream("public:local:media", activity)
 106           end
 107         end
 108       else
 109         if !Enum.member?(activity.data["cc"] || [], public) &&
 110              !Enum.member?(
 111                activity.data["to"],
 112                User.get_by_ap_id(activity.data["actor"]).follower_address
 113              ),
 114            do: Pleroma.Web.Streamer.stream("direct", activity)
 115       end
 116     end
 117   end
 118
 119   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 120     additional = params[:additional] || %{}
 121     # only accept false as false value
 122     local = !(params[:local] == false)
 123     published = params[:published]
 124
 125     with create_data <-
 126            make_create_data(
 127              %{to: to, actor: actor, published: published, context: context, object: object},
 128              additional
 129            ),
 130          {:ok, activity} <- insert(create_data, local),
 131          :ok <- maybe_federate(activity),
 132          {:ok, _actor} <- User.increase_note_count(actor) do
 133       {:ok, activity}
 134     end
 135   end
 136
 137   def accept(%{to: to, actor: actor, object: object} = params) do
 138     # only accept false as false value
 139     local = !(params[:local] == false)
 140
 141     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 142          {:ok, activity} <- insert(data, local),
 143          :ok <- maybe_federate(activity) do
 144       {:ok, activity}
 145     end
 146   end
 147
 148   def reject(%{to: to, actor: actor, object: object} = params) do
 149     # only accept false as false value
 150     local = !(params[:local] == false)
 151
 152     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 153          {:ok, activity} <- insert(data, local),
 154          :ok <- maybe_federate(activity) do
 155       {:ok, activity}
 156     end
 157   end
 158
 159   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 160     # only accept false as false value
 161     local = !(params[:local] == false)
 162
 163     with data <- %{
 164            "to" => to,
 165            "cc" => cc,
 166            "type" => "Update",
 167            "actor" => actor,
 168            "object" => object
 169          },
 170          {:ok, activity} <- insert(data, local),
 171          :ok <- maybe_federate(activity) do
 172       {:ok, activity}
 173     end
 174   end
 175
 176   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 177   def like(
 178         %User{ap_id: ap_id} = user,
 179         %Object{data: %{"id" => _}} = object,
 180         activity_id \\ nil,
 181         local \\ true
 182       ) do
 183     with nil <- get_existing_like(ap_id, object),
 184          like_data <- make_like_data(user, object, activity_id),
 185          {:ok, activity} <- insert(like_data, local),
 186          {:ok, object} <- add_like_to_object(activity, object),
 187          :ok <- maybe_federate(activity) do
 188       {:ok, activity, object}
 189     else
 190       %Activity{} = activity -> {:ok, activity, object}
 191       error -> {:error, error}
 192     end
 193   end
 194
 195   def unlike(
 196         %User{} = actor,
 197         %Object{} = object,
 198         activity_id \\ nil,
 199         local \\ true
 200       ) do
 201     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 202          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 203          {:ok, unlike_activity} <- insert(unlike_data, local),
 204          {:ok, _activity} <- Repo.delete(like_activity),
 205          {:ok, object} <- remove_like_from_object(like_activity, object),
 206          :ok <- maybe_federate(unlike_activity) do
 207       {:ok, unlike_activity, like_activity, object}
 208     else
 209       _e -> {:ok, object}
 210     end
 211   end
 212
 213   def announce(
 214         %User{ap_id: _} = user,
 215         %Object{data: %{"id" => _}} = object,
 216         activity_id \\ nil,
 217         local \\ true
 218       ) do
 219     with true <- is_public?(object),
 220          announce_data <- make_announce_data(user, object, activity_id),
 221          {:ok, activity} <- insert(announce_data, local),
 222          {:ok, object} <- add_announce_to_object(activity, object),
 223          :ok <- maybe_federate(activity) do
 224       {:ok, activity, object}
 225     else
 226       error -> {:error, error}
 227     end
 228   end
 229
 230   def unannounce(
 231         %User{} = actor,
 232         %Object{} = object,
 233         activity_id \\ nil,
 234         local \\ true
 235       ) do
 236     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 237          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 238          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 239          :ok <- maybe_federate(unannounce_activity),
 240          {:ok, _activity} <- Repo.delete(announce_activity),
 241          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 242       {:ok, unannounce_activity, object}
 243     else
 244       _e -> {:ok, object}
 245     end
 246   end
 247
 248   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 249     with data <- make_follow_data(follower, followed, activity_id),
 250          {:ok, activity} <- insert(data, local),
 251          :ok <- maybe_federate(activity) do
 252       {:ok, activity}
 253     end
 254   end
 255
 256   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 257     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 258          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 259          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 260          {:ok, activity} <- insert(unfollow_data, local),
 261          :ok <- maybe_federate(activity) do
 262       {:ok, activity}
 263     end
 264   end
 265
 266   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 267     user = User.get_cached_by_ap_id(actor)
 268
 269     data = %{
 270       "type" => "Delete",
 271       "actor" => actor,
 272       "object" => id,
 273       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 274     }
 275
 276     with Repo.delete(object),
 277          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 278          {:ok, activity} <- insert(data, local),
 279          :ok <- maybe_federate(activity),
 280          {:ok, _actor} <- User.decrease_note_count(user) do
 281       {:ok, activity}
 282     end
 283   end
 284
 285   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 286     ap_config = Application.get_env(:pleroma, :activitypub)
 287     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 288     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 289
 290     with true <- unfollow_blocked do
 291       follow_activity = fetch_latest_follow(blocker, blocked)
 292
 293       if follow_activity do
 294         unfollow(blocker, blocked, nil, local)
 295       end
 296     end
 297
 298     with true <- outgoing_blocks,
 299          block_data <- make_block_data(blocker, blocked, activity_id),
 300          {:ok, activity} <- insert(block_data, local),
 301          :ok <- maybe_federate(activity) do
 302       {:ok, activity}
 303     else
 304       _e -> {:ok, nil}
 305     end
 306   end
 307
 308   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 309     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 310          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 311          {:ok, activity} <- insert(unblock_data, local),
 312          :ok <- maybe_federate(activity) do
 313       {:ok, activity}
 314     end
 315   end
 316
 317   def fetch_activities_for_context(context, opts \\ %{}) do
 318     public = ["https://www.w3.org/ns/activitystreams#Public"]
 319
 320     recipients =
 321       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 322
 323     query = from(activity in Activity)
 324
 325     query =
 326       query
 327       |> restrict_blocked(opts)
 328       |> restrict_recipients(recipients, opts["user"])
 329
 330     query =
 331       from(
 332         activity in query,
 333         where:
 334           fragment(
 335             "?->>'type' = ? and ?->>'context' = ?",
 336             activity.data,
 337             "Create",
 338             activity.data,
 339             ^context
 340           ),
 341         order_by: [desc: :id]
 342       )
 343
 344     Repo.all(query)
 345   end
 346
 347   def fetch_public_activities(opts \\ %{}) do
 348     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 349
 350     q
 351     |> restrict_unlisted()
 352     |> Repo.all()
 353     |> Enum.reverse()
 354   end
 355
 356   @valid_visibilities ~w[direct unlisted public private]
 357
 358   defp restrict_visibility(query, %{visibility: "direct"}) do
 359     public = "https://www.w3.org/ns/activitystreams#Public"
 360
 361     from(
 362       activity in query,
 363       join: sender in User,
 364       on: sender.ap_id == activity.actor,
 365       # Are non-direct statuses with no to/cc possible?
 366       where:
 367         fragment(
 368           "not (? && ?)",
 369           [^public, sender.follower_address],
 370           activity.recipients
 371         )
 372     )
 373   end
 374
 375   defp restrict_visibility(_query, %{visibility: visibility})
 376        when visibility not in @valid_visibilities do
 377     Logger.error("Could not restrict visibility to #{visibility}")
 378   end
 379
 380   defp restrict_visibility(query, _visibility), do: query
 381
 382   def fetch_user_activities(user, reading_user, params \\ %{}) do
 383     params =
 384       params
 385       |> Map.put("type", ["Create", "Announce"])
 386       |> Map.put("actor_id", user.ap_id)
 387       |> Map.put("whole_db", true)
 388
 389     recipients =
 390       if reading_user do
 391         ["https://www.w3.org/ns/activitystreams#Public"] ++
 392           [reading_user.ap_id | reading_user.following]
 393       else
 394         ["https://www.w3.org/ns/activitystreams#Public"]
 395       end
 396
 397     fetch_activities(recipients, params)
 398     |> Enum.reverse()
 399   end
 400
 401   defp restrict_since(query, %{"since_id" => since_id}) do
 402     from(activity in query, where: activity.id > ^since_id)
 403   end
 404
 405   defp restrict_since(query, _), do: query
 406
 407   defp restrict_tag(query, %{"tag" => tag}) do
 408     from(
 409       activity in query,
 410       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 411     )
 412   end
 413
 414   defp restrict_tag(query, _), do: query
 415
 416   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 417     from(
 418       activity in query,
 419       where:
 420         fragment(
 421           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 422           activity.data,
 423           ^recipients_to,
 424           activity.data,
 425           ^recipients_cc
 426         )
 427     )
 428   end
 429
 430   defp restrict_recipients(query, [], _user), do: query
 431
 432   defp restrict_recipients(query, recipients, nil) do
 433     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 434   end
 435
 436   defp restrict_recipients(query, recipients, user) do
 437     from(
 438       activity in query,
 439       where: fragment("? && ?", ^recipients, activity.recipients),
 440       or_where: activity.actor == ^user.ap_id
 441     )
 442   end
 443
 444   defp restrict_limit(query, %{"limit" => limit}) do
 445     from(activity in query, limit: ^limit)
 446   end
 447
 448   defp restrict_limit(query, _), do: query
 449
 450   defp restrict_local(query, %{"local_only" => true}) do
 451     from(activity in query, where: activity.local == true)
 452   end
 453
 454   defp restrict_local(query, _), do: query
 455
 456   defp restrict_max(query, %{"max_id" => max_id}) do
 457     from(activity in query, where: activity.id < ^max_id)
 458   end
 459
 460   defp restrict_max(query, _), do: query
 461
 462   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 463     from(activity in query, where: activity.actor == ^actor_id)
 464   end
 465
 466   defp restrict_actor(query, _), do: query
 467
 468   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 469     restrict_type(query, %{"type" => [type]})
 470   end
 471
 472   defp restrict_type(query, %{"type" => type}) do
 473     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 474   end
 475
 476   defp restrict_type(query, _), do: query
 477
 478   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 479     from(
 480       activity in query,
 481       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 482     )
 483   end
 484
 485   defp restrict_favorited_by(query, _), do: query
 486
 487   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 488     from(
 489       activity in query,
 490       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 491     )
 492   end
 493
 494   defp restrict_media(query, _), do: query
 495
 496   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 497     from(
 498       activity in query,
 499       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 500     )
 501   end
 502
 503   defp restrict_replies(query, _), do: query
 504
 505   # Only search through last 100_000 activities by default
 506   defp restrict_recent(query, %{"whole_db" => true}), do: query
 507
 508   defp restrict_recent(query, _) do
 509     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 510
 511     from(activity in query, where: activity.id > ^since)
 512   end
 513
 514   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 515     blocks = info["blocks"] || []
 516     domain_blocks = info["domain_blocks"] || []
 517
 518     from(
 519       activity in query,
 520       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 521       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 522       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 523     )
 524   end
 525
 526   defp restrict_blocked(query, _), do: query
 527
 528   defp restrict_unlisted(query) do
 529     from(
 530       activity in query,
 531       where:
 532         fragment(
 533           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 534           activity.data,
 535           ^["https://www.w3.org/ns/activitystreams#Public"]
 536         )
 537     )
 538   end
 539
 540   def fetch_activities_query(recipients, opts \\ %{}) do
 541     base_query =
 542       from(
 543         activity in Activity,
 544         limit: 20,
 545         order_by: [fragment("? desc nulls last", activity.id)]
 546       )
 547
 548     base_query
 549     |> restrict_recipients(recipients, opts["user"])
 550     |> restrict_tag(opts)
 551     |> restrict_since(opts)
 552     |> restrict_local(opts)
 553     |> restrict_limit(opts)
 554     |> restrict_max(opts)
 555     |> restrict_actor(opts)
 556     |> restrict_type(opts)
 557     |> restrict_favorited_by(opts)
 558     |> restrict_recent(opts)
 559     |> restrict_blocked(opts)
 560     |> restrict_media(opts)
 561     |> restrict_visibility(opts)
 562     |> restrict_replies(opts)
 563   end
 564
 565   def fetch_activities(recipients, opts \\ %{}) do
 566     fetch_activities_query(recipients, opts)
 567     |> Repo.all()
 568     |> Enum.reverse()
 569   end
 570
 571   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 572     fetch_activities_query([], opts)
 573     |> restrict_to_cc(recipients_to, recipients_cc)
 574     |> Repo.all()
 575     |> Enum.reverse()
 576   end
 577
 578   def upload(file) do
 579     data = Upload.store(file, Application.get_env(:pleroma, :instance)[:dedupe_media])
 580     Repo.insert(%Object{data: data})
 581   end
 582
 583   def user_data_from_user_object(data) do
 584     avatar =
 585       data["icon"]["url"] &&
 586         %{
 587           "type" => "Image",
 588           "url" => [%{"href" => data["icon"]["url"]}]
 589         }
 590
 591     banner =
 592       data["image"]["url"] &&
 593         %{
 594           "type" => "Image",
 595           "url" => [%{"href" => data["image"]["url"]}]
 596         }
 597
 598     locked = data["manuallyApprovesFollowers"] || false
 599     data = Transmogrifier.maybe_fix_user_object(data)
 600
 601     user_data = %{
 602       ap_id: data["id"],
 603       info: %{
 604         "ap_enabled" => true,
 605         "source_data" => data,
 606         "banner" => banner,
 607         "locked" => locked
 608       },
 609       avatar: avatar,
 610       name: data["name"],
 611       follower_address: data["followers"],
 612       bio: data["summary"]
 613     }
 614
 615     # nickname can be nil because of virtual actors
 616     user_data =
 617       if data["preferredUsername"] do
 618         Map.put(
 619           user_data,
 620           :nickname,
 621           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 622         )
 623       else
 624         Map.put(user_data, :nickname, nil)
 625       end
 626
 627     {:ok, user_data}
 628   end
 629
 630   def fetch_and_prepare_user_from_ap_id(ap_id) do
 631     with {:ok, %{status_code: 200, body: body}} <-
 632            @httpoison.get(ap_id, [Accept: "application/activity+json"], follow_redirect: true),
 633          {:ok, data} <- Jason.decode(body) do
 634       user_data_from_user_object(data)
 635     else
 636       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 637     end
 638   end
 639
 640   def make_user_from_ap_id(ap_id) do
 641     if _user = User.get_by_ap_id(ap_id) do
 642       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 643     else
 644       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 645         User.insert_or_update_user(data)
 646       else
 647         e -> {:error, e}
 648       end
 649     end
 650   end
 651
 652   def make_user_from_nickname(nickname) do
 653     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 654       make_user_from_ap_id(ap_id)
 655     else
 656       _e -> {:error, "No AP id in WebFinger"}
 657     end
 658   end
 659
 660   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 661
 662   def should_federate?(inbox, public) do
 663     if public do
 664       true
 665     else
 666       inbox_info = URI.parse(inbox)
 667       inbox_info.host not in @quarantined_instances
 668     end
 669   end
 670
 671   def publish(actor, activity) do
 672     followers =
 673       if actor.follower_address in activity.recipients do
 674         {:ok, followers} = User.get_followers(actor)
 675         followers |> Enum.filter(&(!&1.local))
 676       else
 677         []
 678       end
 679
 680     public = is_public?(activity)
 681
 682     remote_inboxes =
 683       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 684       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 685       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 686         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 687       end)
 688       |> Enum.uniq()
 689       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 690
 691     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 692     json = Jason.encode!(data)
 693
 694     Enum.each(remote_inboxes, fn inbox ->
 695       Federator.enqueue(:publish_single_ap, %{
 696         inbox: inbox,
 697         json: json,
 698         actor: actor,
 699         id: activity.data["id"]
 700       })
 701     end)
 702   end
 703
 704   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 705     Logger.info("Federating #{id} to #{inbox}")
 706     host = URI.parse(inbox).host
 707
 708     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 709
 710     signature =
 711       Pleroma.Web.HTTPSignatures.sign(actor, %{
 712         host: host,
 713         "content-length": byte_size(json),
 714         digest: digest
 715       })
 716
 717     @httpoison.post(
 718       inbox,
 719       json,
 720       [
 721         {"Content-Type", "application/activity+json"},
 722         {"signature", signature},
 723         {"digest", digest}
 724       ],
 725       hackney: [pool: :default]
 726     )
 727   end
 728
 729   # TODO:
 730   # This will create a Create activity, which we need internally at the moment.
 731   def fetch_object_from_id(id) do
 732     if object = Object.get_cached_by_ap_id(id) do
 733       {:ok, object}
 734     else
 735       Logger.info("Fetching #{id} via AP")
 736
 737       with true <- String.starts_with?(id, "http"),
 738            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 739              @httpoison.get(
 740                id,
 741                [Accept: "application/activity+json"],
 742                follow_redirect: true,
 743                timeout: 10000,
 744                recv_timeout: 20000
 745              ),
 746            {:ok, data} <- Jason.decode(body),
 747            nil <- Object.normalize(data),
 748            params <- %{
 749              "type" => "Create",
 750              "to" => data["to"],
 751              "cc" => data["cc"],
 752              "actor" => data["attributedTo"],
 753              "object" => data
 754            },
 755            :ok <- Transmogrifier.contain_origin(id, params),
 756            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 757         {:ok, Object.normalize(activity.data["object"])}
 758       else
 759         {:error, {:reject, nil}} ->
 760           {:reject, nil}
 761
 762         object = %Object{} ->
 763           {:ok, object}
 764
 765         _e ->
 766           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 767
 768           case OStatus.fetch_activity_from_url(id) do
 769             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 770             e -> e
 771           end
 772       end
 773     end
 774   end
 775
 776   def is_public?(activity) do
 777     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 778                                                          (activity.data["cc"] || []))
 779   end
 780
 781   def visible_for_user?(activity, nil) do
 782     is_public?(activity)
 783   end
 784
 785   def visible_for_user?(activity, user) do
 786     x = [user.ap_id | user.following]
 787     y = activity.data["to"] ++ (activity.data["cc"] || [])
 788     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 789   end
 790
 791   # guard
 792   def entire_thread_visible_for_user?(nil, user), do: false
 793
 794   # child
 795   def entire_thread_visible_for_user?(
 796         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 797         user
 798       )
 799       when is_binary(parent_id) do
 800     parent = Activity.get_in_reply_to_activity(tail)
 801     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 802   end
 803
 804   # root
 805   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 806
 807   # filter out broken threads
 808   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 809     entire_thread_visible_for_user?(activity, user)
 810   end
 811
 812   # do post-processing on a specific activity
 813   def contain_activity(%Activity{} = activity, %User{} = user) do
 814     contain_broken_threads(activity, user)
 815   end
 816
 817   # do post-processing on a timeline
 818   def contain_timeline(timeline, user) do
 819     timeline
 820     |> Enum.filter(fn activity ->
 821       contain_activity(activity, user)
 822     end)
 823   end
 824 end