git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  60     limit = Pleroma.Config.get([:instance, :remote_limit])
  61     String.length(content) <= limit
  62   end
  63
  64   defp check_remote_limit(_), do: true
  65
  66   def insert(map, local \\ true) when is_map(map) do
  67     with nil <- Activity.normalize(map),
  68          map <- lazy_put_activity_defaults(map),
  69          :ok <- check_actor_is_active(map["actor"]),
  70          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  71          {:ok, map} <- MRF.filter(map),
  72          :ok <- insert_full_object(map) do
  73       {recipients, _, _} = get_recipients(map)
  74
  75       {:ok, activity} =
  76         Repo.insert(%Activity{
  77           data: map,
  78           local: local,
  79           actor: map["actor"],
  80           recipients: recipients
  81         })
  82
  83       Notification.create_notifications(activity)
  84       stream_out(activity)
  85       {:ok, activity}
  86     else
  87       %Activity{} = activity -> {:ok, activity}
  88       error -> {:error, error}
  89     end
  90   end
  91
  92   def stream_out(activity) do
  93     public = "https://www.w3.org/ns/activitystreams#Public"
  94
  95     if activity.data["type"] in ["Create", "Announce"] do
  96       Pleroma.Web.Streamer.stream("user", activity)
  97       Pleroma.Web.Streamer.stream("list", activity)
  98
  99       if Enum.member?(activity.data["to"], public) do
 100         Pleroma.Web.Streamer.stream("public", activity)
 101
 102         if activity.local do
 103           Pleroma.Web.Streamer.stream("public:local", activity)
 104         end
 105
 106         activity.data["object"]
 107         |> Map.get("tag", [])
 108         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 109         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 110
 111         if activity.data["object"]["attachment"] != [] do
 112           Pleroma.Web.Streamer.stream("public:media", activity)
 113
 114           if activity.local do
 115             Pleroma.Web.Streamer.stream("public:local:media", activity)
 116           end
 117         end
 118       else
 119         if !Enum.member?(activity.data["cc"] || [], public) &&
 120              !Enum.member?(
 121                activity.data["to"],
 122                User.get_by_ap_id(activity.data["actor"]).follower_address
 123              ),
 124            do: Pleroma.Web.Streamer.stream("direct", activity)
 125       end
 126     end
 127   end
 128
 129   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 130     additional = params[:additional] || %{}
 131     # only accept false as false value
 132     local = !(params[:local] == false)
 133     published = params[:published]
 134
 135     with create_data <-
 136            make_create_data(
 137              %{to: to, actor: actor, published: published, context: context, object: object},
 138              additional
 139            ),
 140          {:ok, activity} <- insert(create_data, local),
 141          :ok <- maybe_federate(activity),
 142          {:ok, _actor} <- User.increase_note_count(actor) do
 143       {:ok, activity}
 144     end
 145   end
 146
 147   def accept(%{to: to, actor: actor, object: object} = params) do
 148     # only accept false as false value
 149     local = !(params[:local] == false)
 150
 151     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 152          {:ok, activity} <- insert(data, local),
 153          :ok <- maybe_federate(activity) do
 154       {:ok, activity}
 155     end
 156   end
 157
 158   def reject(%{to: to, actor: actor, object: object} = params) do
 159     # only accept false as false value
 160     local = !(params[:local] == false)
 161
 162     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 163          {:ok, activity} <- insert(data, local),
 164          :ok <- maybe_federate(activity) do
 165       {:ok, activity}
 166     end
 167   end
 168
 169   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 170     # only accept false as false value
 171     local = !(params[:local] == false)
 172
 173     with data <- %{
 174            "to" => to,
 175            "cc" => cc,
 176            "type" => "Update",
 177            "actor" => actor,
 178            "object" => object
 179          },
 180          {:ok, activity} <- insert(data, local),
 181          :ok <- maybe_federate(activity) do
 182       {:ok, activity}
 183     end
 184   end
 185
 186   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 187   def like(
 188         %User{ap_id: ap_id} = user,
 189         %Object{data: %{"id" => _}} = object,
 190         activity_id \\ nil,
 191         local \\ true
 192       ) do
 193     with nil <- get_existing_like(ap_id, object),
 194          like_data <- make_like_data(user, object, activity_id),
 195          {:ok, activity} <- insert(like_data, local),
 196          {:ok, object} <- add_like_to_object(activity, object),
 197          :ok <- maybe_federate(activity) do
 198       {:ok, activity, object}
 199     else
 200       %Activity{} = activity -> {:ok, activity, object}
 201       error -> {:error, error}
 202     end
 203   end
 204
 205   def unlike(
 206         %User{} = actor,
 207         %Object{} = object,
 208         activity_id \\ nil,
 209         local \\ true
 210       ) do
 211     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 212          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 213          {:ok, unlike_activity} <- insert(unlike_data, local),
 214          {:ok, _activity} <- Repo.delete(like_activity),
 215          {:ok, object} <- remove_like_from_object(like_activity, object),
 216          :ok <- maybe_federate(unlike_activity) do
 217       {:ok, unlike_activity, like_activity, object}
 218     else
 219       _e -> {:ok, object}
 220     end
 221   end
 222
 223   def announce(
 224         %User{ap_id: _} = user,
 225         %Object{data: %{"id" => _}} = object,
 226         activity_id \\ nil,
 227         local \\ true,
 228         public \\ true
 229       ) do
 230     with true <- is_public?(object),
 231          announce_data <- make_announce_data(user, object, activity_id, public),
 232          {:ok, activity} <- insert(announce_data, local),
 233          {:ok, object} <- add_announce_to_object(activity, object),
 234          :ok <- maybe_federate(activity) do
 235       {:ok, activity, object}
 236     else
 237       error -> {:error, error}
 238     end
 239   end
 240
 241   def unannounce(
 242         %User{} = actor,
 243         %Object{} = object,
 244         activity_id \\ nil,
 245         local \\ true
 246       ) do
 247     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 248          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 249          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 250          :ok <- maybe_federate(unannounce_activity),
 251          {:ok, _activity} <- Repo.delete(announce_activity),
 252          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 253       {:ok, unannounce_activity, object}
 254     else
 255       _e -> {:ok, object}
 256     end
 257   end
 258
 259   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 260     with data <- make_follow_data(follower, followed, activity_id),
 261          {:ok, activity} <- insert(data, local),
 262          :ok <- maybe_federate(activity) do
 263       {:ok, activity}
 264     end
 265   end
 266
 267   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 268     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 269          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 270          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 271          {:ok, activity} <- insert(unfollow_data, local),
 272          :ok <- maybe_federate(activity) do
 273       {:ok, activity}
 274     end
 275   end
 276
 277   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 278     user = User.get_cached_by_ap_id(actor)
 279
 280     data = %{
 281       "type" => "Delete",
 282       "actor" => actor,
 283       "object" => id,
 284       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 285     }
 286
 287     with {:ok, _} <- Object.delete(object),
 288          {:ok, activity} <- insert(data, local),
 289          :ok <- maybe_federate(activity),
 290          {:ok, _actor} <- User.decrease_note_count(user) do
 291       {:ok, activity}
 292     end
 293   end
 294
 295   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 296     ap_config = Application.get_env(:pleroma, :activitypub)
 297     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 298     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 299
 300     with true <- unfollow_blocked do
 301       follow_activity = fetch_latest_follow(blocker, blocked)
 302
 303       if follow_activity do
 304         unfollow(blocker, blocked, nil, local)
 305       end
 306     end
 307
 308     with true <- outgoing_blocks,
 309          block_data <- make_block_data(blocker, blocked, activity_id),
 310          {:ok, activity} <- insert(block_data, local),
 311          :ok <- maybe_federate(activity) do
 312       {:ok, activity}
 313     else
 314       _e -> {:ok, nil}
 315     end
 316   end
 317
 318   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 319     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 320          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 321          {:ok, activity} <- insert(unblock_data, local),
 322          :ok <- maybe_federate(activity) do
 323       {:ok, activity}
 324     end
 325   end
 326
 327   def fetch_activities_for_context(context, opts \\ %{}) do
 328     public = ["https://www.w3.org/ns/activitystreams#Public"]
 329
 330     recipients =
 331       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 332
 333     query = from(activity in Activity)
 334
 335     query =
 336       query
 337       |> restrict_blocked(opts)
 338       |> restrict_recipients(recipients, opts["user"])
 339
 340     query =
 341       from(
 342         activity in query,
 343         where:
 344           fragment(
 345             "?->>'type' = ? and ?->>'context' = ?",
 346             activity.data,
 347             "Create",
 348             activity.data,
 349             ^context
 350           ),
 351         order_by: [desc: :id]
 352       )
 353
 354     Repo.all(query)
 355   end
 356
 357   def fetch_public_activities(opts \\ %{}) do
 358     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 359
 360     q
 361     |> restrict_unlisted()
 362     |> Repo.all()
 363     |> Enum.reverse()
 364   end
 365
 366   @valid_visibilities ~w[direct unlisted public private]
 367
 368   defp restrict_visibility(query, %{visibility: visibility})
 369        when visibility in @valid_visibilities do
 370     query =
 371       from(
 372         a in query,
 373         where:
 374           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 375       )
 376
 377     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 378
 379     query
 380   end
 381
 382   defp restrict_visibility(_query, %{visibility: visibility})
 383        when visibility not in @valid_visibilities do
 384     Logger.error("Could not restrict visibility to #{visibility}")
 385   end
 386
 387   defp restrict_visibility(query, _visibility), do: query
 388
 389   def fetch_user_activities(user, reading_user, params \\ %{}) do
 390     params =
 391       params
 392       |> Map.put("type", ["Create", "Announce"])
 393       |> Map.put("actor_id", user.ap_id)
 394       |> Map.put("whole_db", true)
 395       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 396
 397     recipients =
 398       if reading_user do
 399         ["https://www.w3.org/ns/activitystreams#Public"] ++
 400           [reading_user.ap_id | reading_user.following]
 401       else
 402         ["https://www.w3.org/ns/activitystreams#Public"]
 403       end
 404
 405     fetch_activities(recipients, params)
 406     |> Enum.reverse()
 407   end
 408
 409   defp restrict_since(query, %{"since_id" => since_id}) do
 410     from(activity in query, where: activity.id > ^since_id)
 411   end
 412
 413   defp restrict_since(query, _), do: query
 414
 415   defp restrict_tag(query, %{"tag" => tag}) do
 416     from(
 417       activity in query,
 418       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 419     )
 420   end
 421
 422   defp restrict_tag(query, _), do: query
 423
 424   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 425     from(
 426       activity in query,
 427       where:
 428         fragment(
 429           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 430           activity.data,
 431           ^recipients_to,
 432           activity.data,
 433           ^recipients_cc
 434         )
 435     )
 436   end
 437
 438   defp restrict_recipients(query, [], _user), do: query
 439
 440   defp restrict_recipients(query, recipients, nil) do
 441     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 442   end
 443
 444   defp restrict_recipients(query, recipients, user) do
 445     from(
 446       activity in query,
 447       where: fragment("? && ?", ^recipients, activity.recipients),
 448       or_where: activity.actor == ^user.ap_id
 449     )
 450   end
 451
 452   defp restrict_limit(query, %{"limit" => limit}) do
 453     from(activity in query, limit: ^limit)
 454   end
 455
 456   defp restrict_limit(query, _), do: query
 457
 458   defp restrict_local(query, %{"local_only" => true}) do
 459     from(activity in query, where: activity.local == true)
 460   end
 461
 462   defp restrict_local(query, _), do: query
 463
 464   defp restrict_max(query, %{"max_id" => max_id}) do
 465     from(activity in query, where: activity.id < ^max_id)
 466   end
 467
 468   defp restrict_max(query, _), do: query
 469
 470   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 471     from(activity in query, where: activity.actor == ^actor_id)
 472   end
 473
 474   defp restrict_actor(query, _), do: query
 475
 476   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 477     restrict_type(query, %{"type" => [type]})
 478   end
 479
 480   defp restrict_type(query, %{"type" => type}) do
 481     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 482   end
 483
 484   defp restrict_type(query, _), do: query
 485
 486   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 487     from(
 488       activity in query,
 489       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 490     )
 491   end
 492
 493   defp restrict_favorited_by(query, _), do: query
 494
 495   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 496     from(
 497       activity in query,
 498       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 499     )
 500   end
 501
 502   defp restrict_media(query, _), do: query
 503
 504   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 505     from(
 506       activity in query,
 507       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 508     )
 509   end
 510
 511   defp restrict_replies(query, _), do: query
 512
 513   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 514     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 515   end
 516
 517   defp restrict_reblogs(query, _), do: query
 518
 519   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 520     blocks = info.blocks || []
 521     domain_blocks = info.domain_blocks || []
 522
 523     from(
 524       activity in query,
 525       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 526       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 527       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 528     )
 529   end
 530
 531   defp restrict_blocked(query, _), do: query
 532
 533   defp restrict_unlisted(query) do
 534     from(
 535       activity in query,
 536       where:
 537         fragment(
 538           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 539           activity.data,
 540           ^["https://www.w3.org/ns/activitystreams#Public"]
 541         )
 542     )
 543   end
 544
 545   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 546     from(activity in query, where: activity.id in ^ids)
 547   end
 548
 549   defp restrict_pinned(query, _), do: query
 550
 551   def fetch_activities_query(recipients, opts \\ %{}) do
 552     base_query =
 553       from(
 554         activity in Activity,
 555         limit: 20,
 556         order_by: [fragment("? desc nulls last", activity.id)]
 557       )
 558
 559     base_query
 560     |> restrict_recipients(recipients, opts["user"])
 561     |> restrict_tag(opts)
 562     |> restrict_since(opts)
 563     |> restrict_local(opts)
 564     |> restrict_limit(opts)
 565     |> restrict_max(opts)
 566     |> restrict_actor(opts)
 567     |> restrict_type(opts)
 568     |> restrict_favorited_by(opts)
 569     |> restrict_blocked(opts)
 570     |> restrict_media(opts)
 571     |> restrict_visibility(opts)
 572     |> restrict_replies(opts)
 573     |> restrict_reblogs(opts)
 574     |> restrict_pinned(opts)
 575   end
 576
 577   def fetch_activities(recipients, opts \\ %{}) do
 578     fetch_activities_query(recipients, opts)
 579     |> Repo.all()
 580     |> Enum.reverse()
 581   end
 582
 583   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 584     fetch_activities_query([], opts)
 585     |> restrict_to_cc(recipients_to, recipients_cc)
 586     |> Repo.all()
 587     |> Enum.reverse()
 588   end
 589
 590   def upload(file, opts \\ []) do
 591     with {:ok, data} <- Upload.store(file, opts) do
 592       obj_data =
 593         if opts[:actor] do
 594           Map.put(data, "actor", opts[:actor])
 595         else
 596           data
 597         end
 598
 599       Repo.insert(%Object{data: obj_data})
 600     end
 601   end
 602
 603   def user_data_from_user_object(data) do
 604     avatar =
 605       data["icon"]["url"] &&
 606         %{
 607           "type" => "Image",
 608           "url" => [%{"href" => data["icon"]["url"]}]
 609         }
 610
 611     banner =
 612       data["image"]["url"] &&
 613         %{
 614           "type" => "Image",
 615           "url" => [%{"href" => data["image"]["url"]}]
 616         }
 617
 618     locked = data["manuallyApprovesFollowers"] || false
 619     data = Transmogrifier.maybe_fix_user_object(data)
 620
 621     user_data = %{
 622       ap_id: data["id"],
 623       info: %{
 624         "ap_enabled" => true,
 625         "source_data" => data,
 626         "banner" => banner,
 627         "locked" => locked
 628       },
 629       avatar: avatar,
 630       name: data["name"],
 631       follower_address: data["followers"],
 632       bio: data["summary"]
 633     }
 634
 635     # nickname can be nil because of virtual actors
 636     user_data =
 637       if data["preferredUsername"] do
 638         Map.put(
 639           user_data,
 640           :nickname,
 641           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 642         )
 643       else
 644         Map.put(user_data, :nickname, nil)
 645       end
 646
 647     {:ok, user_data}
 648   end
 649
 650   def fetch_and_prepare_user_from_ap_id(ap_id) do
 651     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 652       user_data_from_user_object(data)
 653     else
 654       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 655     end
 656   end
 657
 658   def make_user_from_ap_id(ap_id) do
 659     if _user = User.get_by_ap_id(ap_id) do
 660       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 661     else
 662       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 663         User.insert_or_update_user(data)
 664       else
 665         e -> {:error, e}
 666       end
 667     end
 668   end
 669
 670   def make_user_from_nickname(nickname) do
 671     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 672       make_user_from_ap_id(ap_id)
 673     else
 674       _e -> {:error, "No AP id in WebFinger"}
 675     end
 676   end
 677
 678   def should_federate?(inbox, public) do
 679     if public do
 680       true
 681     else
 682       inbox_info = URI.parse(inbox)
 683       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 684     end
 685   end
 686
 687   def publish(actor, activity) do
 688     followers =
 689       if actor.follower_address in activity.recipients do
 690         {:ok, followers} = User.get_followers(actor)
 691         followers |> Enum.filter(&(!&1.local))
 692       else
 693         []
 694       end
 695
 696     public = is_public?(activity)
 697
 698     remote_inboxes =
 699       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 700       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 701       |> Enum.map(fn %{info: %{source_data: data}} ->
 702         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 703       end)
 704       |> Enum.uniq()
 705       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 706
 707     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 708     json = Jason.encode!(data)
 709
 710     Enum.each(remote_inboxes, fn inbox ->
 711       Federator.enqueue(:publish_single_ap, %{
 712         inbox: inbox,
 713         json: json,
 714         actor: actor,
 715         id: activity.data["id"]
 716       })
 717     end)
 718   end
 719
 720   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 721     Logger.info("Federating #{id} to #{inbox}")
 722     host = URI.parse(inbox).host
 723
 724     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 725
 726     signature =
 727       Pleroma.Web.HTTPSignatures.sign(actor, %{
 728         host: host,
 729         "content-length": byte_size(json),
 730         digest: digest
 731       })
 732
 733     @httpoison.post(
 734       inbox,
 735       json,
 736       [
 737         {"Content-Type", "application/activity+json"},
 738         {"signature", signature},
 739         {"digest", digest}
 740       ]
 741     )
 742   end
 743
 744   # TODO:
 745   # This will create a Create activity, which we need internally at the moment.
 746   def fetch_object_from_id(id) do
 747     if object = Object.get_cached_by_ap_id(id) do
 748       {:ok, object}
 749     else
 750       Logger.info("Fetching #{id} via AP")
 751
 752       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 753            nil <- Object.normalize(data),
 754            params <- %{
 755              "type" => "Create",
 756              "to" => data["to"],
 757              "cc" => data["cc"],
 758              "actor" => data["actor"] || data["attributedTo"],
 759              "object" => data
 760            },
 761            :ok <- Transmogrifier.contain_origin(id, params),
 762            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 763         {:ok, Object.normalize(activity.data["object"])}
 764       else
 765         {:error, {:reject, nil}} ->
 766           {:reject, nil}
 767
 768         object = %Object{} ->
 769           {:ok, object}
 770
 771         _e ->
 772           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 773
 774           case OStatus.fetch_activity_from_url(id) do
 775             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 776             e -> e
 777           end
 778       end
 779     end
 780   end
 781
 782   def fetch_and_contain_remote_object_from_id(id) do
 783     Logger.info("Fetching #{id} via AP")
 784
 785     with true <- String.starts_with?(id, "http"),
 786          {:ok, %{body: body, status: code}} when code in 200..299 <-
 787            @httpoison.get(
 788              id,
 789              [{:Accept, "application/activity+json"}]
 790            ),
 791          {:ok, data} <- Jason.decode(body),
 792          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 793       {:ok, data}
 794     else
 795       e ->
 796         {:error, e}
 797     end
 798   end
 799
 800   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 801   def is_public?(%Activity{data: data}), do: is_public?(data)
 802
 803   def is_public?(data) do
 804     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 805   end
 806
 807   def visible_for_user?(activity, nil) do
 808     is_public?(activity)
 809   end
 810
 811   def visible_for_user?(activity, user) do
 812     x = [user.ap_id | user.following]
 813     y = activity.data["to"] ++ (activity.data["cc"] || [])
 814     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 815   end
 816
 817   # guard
 818   def entire_thread_visible_for_user?(nil, _user), do: false
 819
 820   # child
 821   def entire_thread_visible_for_user?(
 822         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 823         user
 824       )
 825       when is_binary(parent_id) do
 826     parent = Activity.get_in_reply_to_activity(tail)
 827     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 828   end
 829
 830   # root
 831   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 832
 833   # filter out broken threads
 834   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 835     entire_thread_visible_for_user?(activity, user)
 836   end
 837
 838   # do post-processing on a specific activity
 839   def contain_activity(%Activity{} = activity, %User{} = user) do
 840     contain_broken_threads(activity, user)
 841   end
 842
 843   # do post-processing on a timeline
 844   def contain_timeline(timeline, user) do
 845     timeline
 846     |> Enum.filter(fn activity ->
 847       contain_activity(activity, user)
 848     end)
 849   end
 850 end