git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     recipients = to ++ cc
  43     {recipients, to, cc}
  44   end
  45
  46   defp check_actor_is_active(actor) do
  47     if not is_nil(actor) do
  48       with user <- User.get_cached_by_ap_id(actor),
  49            false <- user.info.deactivated do
  50         :ok
  51       else
  52         _e -> :reject
  53       end
  54     else
  55       :ok
  56     end
  57   end
  58
  59   def insert(map, local \\ true) when is_map(map) do
  60     with nil <- Activity.normalize(map),
  61          map <- lazy_put_activity_defaults(map),
  62          :ok <- check_actor_is_active(map["actor"]),
  63          {:ok, map} <- MRF.filter(map),
  64          :ok <- insert_full_object(map) do
  65       {recipients, _, _} = get_recipients(map)
  66
  67       {:ok, activity} =
  68         Repo.insert(%Activity{
  69           data: map,
  70           local: local,
  71           actor: map["actor"],
  72           recipients: recipients
  73         })
  74
  75       Notification.create_notifications(activity)
  76       stream_out(activity)
  77       {:ok, activity}
  78     else
  79       %Activity{} = activity -> {:ok, activity}
  80       error -> {:error, error}
  81     end
  82   end
  83
  84   def stream_out(activity) do
  85     public = "https://www.w3.org/ns/activitystreams#Public"
  86
  87     if activity.data["type"] in ["Create", "Announce"] do
  88       Pleroma.Web.Streamer.stream("user", activity)
  89       Pleroma.Web.Streamer.stream("list", activity)
  90
  91       if Enum.member?(activity.data["to"], public) do
  92         Pleroma.Web.Streamer.stream("public", activity)
  93
  94         if activity.local do
  95           Pleroma.Web.Streamer.stream("public:local", activity)
  96         end
  97
  98         activity.data["object"]
  99         |> Map.get("tag", [])
 100         |> Enum.filter(fn tag -> is_bitstring(tag) end)
 101         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 102
 103         if activity.data["object"]["attachment"] != [] do
 104           Pleroma.Web.Streamer.stream("public:media", activity)
 105
 106           if activity.local do
 107             Pleroma.Web.Streamer.stream("public:local:media", activity)
 108           end
 109         end
 110       else
 111         if !Enum.member?(activity.data["cc"] || [], public) &&
 112              !Enum.member?(
 113                activity.data["to"],
 114                User.get_by_ap_id(activity.data["actor"]).follower_address
 115              ),
 116            do: Pleroma.Web.Streamer.stream("direct", activity)
 117       end
 118     end
 119   end
 120
 121   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 122     additional = params[:additional] || %{}
 123     # only accept false as false value
 124     local = !(params[:local] == false)
 125     published = params[:published]
 126
 127     with create_data <-
 128            make_create_data(
 129              %{to: to, actor: actor, published: published, context: context, object: object},
 130              additional
 131            ),
 132          {:ok, activity} <- insert(create_data, local),
 133          :ok <- maybe_federate(activity),
 134          {:ok, _actor} <- User.increase_note_count(actor) do
 135       {:ok, activity}
 136     end
 137   end
 138
 139   def accept(%{to: to, actor: actor, object: object} = params) do
 140     # only accept false as false value
 141     local = !(params[:local] == false)
 142
 143     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 144          {:ok, activity} <- insert(data, local),
 145          :ok <- maybe_federate(activity) do
 146       {:ok, activity}
 147     end
 148   end
 149
 150   def reject(%{to: to, actor: actor, object: object} = params) do
 151     # only accept false as false value
 152     local = !(params[:local] == false)
 153
 154     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 155          {:ok, activity} <- insert(data, local),
 156          :ok <- maybe_federate(activity) do
 157       {:ok, activity}
 158     end
 159   end
 160
 161   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 162     # only accept false as false value
 163     local = !(params[:local] == false)
 164
 165     with data <- %{
 166            "to" => to,
 167            "cc" => cc,
 168            "type" => "Update",
 169            "actor" => actor,
 170            "object" => object
 171          },
 172          {:ok, activity} <- insert(data, local),
 173          :ok <- maybe_federate(activity) do
 174       {:ok, activity}
 175     end
 176   end
 177
 178   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 179   def like(
 180         %User{ap_id: ap_id} = user,
 181         %Object{data: %{"id" => _}} = object,
 182         activity_id \\ nil,
 183         local \\ true
 184       ) do
 185     with nil <- get_existing_like(ap_id, object),
 186          like_data <- make_like_data(user, object, activity_id),
 187          {:ok, activity} <- insert(like_data, local),
 188          {:ok, object} <- add_like_to_object(activity, object),
 189          :ok <- maybe_federate(activity) do
 190       {:ok, activity, object}
 191     else
 192       %Activity{} = activity -> {:ok, activity, object}
 193       error -> {:error, error}
 194     end
 195   end
 196
 197   def unlike(
 198         %User{} = actor,
 199         %Object{} = object,
 200         activity_id \\ nil,
 201         local \\ true
 202       ) do
 203     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 204          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 205          {:ok, unlike_activity} <- insert(unlike_data, local),
 206          {:ok, _activity} <- Repo.delete(like_activity),
 207          {:ok, object} <- remove_like_from_object(like_activity, object),
 208          :ok <- maybe_federate(unlike_activity) do
 209       {:ok, unlike_activity, like_activity, object}
 210     else
 211       _e -> {:ok, object}
 212     end
 213   end
 214
 215   def announce(
 216         %User{ap_id: _} = user,
 217         %Object{data: %{"id" => _}} = object,
 218         activity_id \\ nil,
 219         local \\ true
 220       ) do
 221     with true <- is_public?(object),
 222          announce_data <- make_announce_data(user, object, activity_id),
 223          {:ok, activity} <- insert(announce_data, local),
 224          {:ok, object} <- add_announce_to_object(activity, object),
 225          :ok <- maybe_federate(activity) do
 226       {:ok, activity, object}
 227     else
 228       error -> {:error, error}
 229     end
 230   end
 231
 232   def unannounce(
 233         %User{} = actor,
 234         %Object{} = object,
 235         activity_id \\ nil,
 236         local \\ true
 237       ) do
 238     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 239          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 240          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 241          :ok <- maybe_federate(unannounce_activity),
 242          {:ok, _activity} <- Repo.delete(announce_activity),
 243          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 244       {:ok, unannounce_activity, object}
 245     else
 246       _e -> {:ok, object}
 247     end
 248   end
 249
 250   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 251     with data <- make_follow_data(follower, followed, activity_id),
 252          {:ok, activity} <- insert(data, local),
 253          :ok <- maybe_federate(activity) do
 254       {:ok, activity}
 255     end
 256   end
 257
 258   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 259     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 260          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 261          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 262          {:ok, activity} <- insert(unfollow_data, local),
 263          :ok <- maybe_federate(activity) do
 264       {:ok, activity}
 265     end
 266   end
 267
 268   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 269     user = User.get_cached_by_ap_id(actor)
 270
 271     data = %{
 272       "type" => "Delete",
 273       "actor" => actor,
 274       "object" => id,
 275       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 276     }
 277
 278     with {:ok, _} <- Object.delete(object),
 279          {:ok, activity} <- insert(data, local),
 280          :ok <- maybe_federate(activity),
 281          {:ok, _actor} <- User.decrease_note_count(user) do
 282       {:ok, activity}
 283     end
 284   end
 285
 286   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 287     ap_config = Application.get_env(:pleroma, :activitypub)
 288     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 289     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 290
 291     with true <- unfollow_blocked do
 292       follow_activity = fetch_latest_follow(blocker, blocked)
 293
 294       if follow_activity do
 295         unfollow(blocker, blocked, nil, local)
 296       end
 297     end
 298
 299     with true <- outgoing_blocks,
 300          block_data <- make_block_data(blocker, blocked, activity_id),
 301          {:ok, activity} <- insert(block_data, local),
 302          :ok <- maybe_federate(activity) do
 303       {:ok, activity}
 304     else
 305       _e -> {:ok, nil}
 306     end
 307   end
 308
 309   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 310     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 311          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 312          {:ok, activity} <- insert(unblock_data, local),
 313          :ok <- maybe_federate(activity) do
 314       {:ok, activity}
 315     end
 316   end
 317
 318   def fetch_activities_for_context(context, opts \\ %{}) do
 319     public = ["https://www.w3.org/ns/activitystreams#Public"]
 320
 321     recipients =
 322       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 323
 324     query = from(activity in Activity)
 325
 326     query =
 327       query
 328       |> restrict_blocked(opts)
 329       |> restrict_recipients(recipients, opts["user"])
 330
 331     query =
 332       from(
 333         activity in query,
 334         where:
 335           fragment(
 336             "?->>'type' = ? and ?->>'context' = ?",
 337             activity.data,
 338             "Create",
 339             activity.data,
 340             ^context
 341           ),
 342         order_by: [desc: :id]
 343       )
 344
 345     Repo.all(query)
 346   end
 347
 348   def fetch_public_activities(opts \\ %{}) do
 349     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 350
 351     q
 352     |> restrict_unlisted()
 353     |> Repo.all()
 354     |> Enum.reverse()
 355   end
 356
 357   @valid_visibilities ~w[direct unlisted public private]
 358
 359   defp restrict_visibility(query, %{visibility: "direct"}) do
 360     public = "https://www.w3.org/ns/activitystreams#Public"
 361
 362     from(
 363       activity in query,
 364       join: sender in User,
 365       on: sender.ap_id == activity.actor,
 366       # Are non-direct statuses with no to/cc possible?
 367       where:
 368         fragment(
 369           "not (? && ?)",
 370           [^public, sender.follower_address],
 371           activity.recipients
 372         )
 373     )
 374   end
 375
 376   defp restrict_visibility(_query, %{visibility: visibility})
 377        when visibility not in @valid_visibilities do
 378     Logger.error("Could not restrict visibility to #{visibility}")
 379   end
 380
 381   defp restrict_visibility(query, _visibility), do: query
 382
 383   def fetch_user_activities(user, reading_user, params \\ %{}) do
 384     params =
 385       params
 386       |> Map.put("type", ["Create", "Announce"])
 387       |> Map.put("actor_id", user.ap_id)
 388       |> Map.put("whole_db", true)
 389
 390     recipients =
 391       if reading_user do
 392         ["https://www.w3.org/ns/activitystreams#Public"] ++
 393           [reading_user.ap_id | reading_user.following]
 394       else
 395         ["https://www.w3.org/ns/activitystreams#Public"]
 396       end
 397
 398     fetch_activities(recipients, params)
 399     |> Enum.reverse()
 400   end
 401
 402   defp restrict_since(query, %{"since_id" => since_id}) do
 403     from(activity in query, where: activity.id > ^since_id)
 404   end
 405
 406   defp restrict_since(query, _), do: query
 407
 408   defp restrict_tag(query, %{"tag" => tag}) do
 409     from(
 410       activity in query,
 411       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 412     )
 413   end
 414
 415   defp restrict_tag(query, _), do: query
 416
 417   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 418     from(
 419       activity in query,
 420       where:
 421         fragment(
 422           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 423           activity.data,
 424           ^recipients_to,
 425           activity.data,
 426           ^recipients_cc
 427         )
 428     )
 429   end
 430
 431   defp restrict_recipients(query, [], _user), do: query
 432
 433   defp restrict_recipients(query, recipients, nil) do
 434     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 435   end
 436
 437   defp restrict_recipients(query, recipients, user) do
 438     from(
 439       activity in query,
 440       where: fragment("? && ?", ^recipients, activity.recipients),
 441       or_where: activity.actor == ^user.ap_id
 442     )
 443   end
 444
 445   defp restrict_limit(query, %{"limit" => limit}) do
 446     from(activity in query, limit: ^limit)
 447   end
 448
 449   defp restrict_limit(query, _), do: query
 450
 451   defp restrict_local(query, %{"local_only" => true}) do
 452     from(activity in query, where: activity.local == true)
 453   end
 454
 455   defp restrict_local(query, _), do: query
 456
 457   defp restrict_max(query, %{"max_id" => max_id}) do
 458     from(activity in query, where: activity.id < ^max_id)
 459   end
 460
 461   defp restrict_max(query, _), do: query
 462
 463   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 464     from(activity in query, where: activity.actor == ^actor_id)
 465   end
 466
 467   defp restrict_actor(query, _), do: query
 468
 469   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 470     restrict_type(query, %{"type" => [type]})
 471   end
 472
 473   defp restrict_type(query, %{"type" => type}) do
 474     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 475   end
 476
 477   defp restrict_type(query, _), do: query
 478
 479   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 480     from(
 481       activity in query,
 482       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 483     )
 484   end
 485
 486   defp restrict_favorited_by(query, _), do: query
 487
 488   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 489     from(
 490       activity in query,
 491       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 492     )
 493   end
 494
 495   defp restrict_media(query, _), do: query
 496
 497   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 498     from(
 499       activity in query,
 500       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 501     )
 502   end
 503
 504   defp restrict_replies(query, _), do: query
 505
 506   # Only search through last 100_000 activities by default
 507   defp restrict_recent(query, %{"whole_db" => true}), do: query
 508
 509   defp restrict_recent(query, _) do
 510     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 511
 512     from(activity in query, where: activity.id > ^since)
 513   end
 514
 515   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 516     blocks = info.blocks || []
 517     domain_blocks = info.domain_blocks || []
 518
 519     from(
 520       activity in query,
 521       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 522       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 523       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 524     )
 525   end
 526
 527   defp restrict_blocked(query, _), do: query
 528
 529   defp restrict_unlisted(query) do
 530     from(
 531       activity in query,
 532       where:
 533         fragment(
 534           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 535           activity.data,
 536           ^["https://www.w3.org/ns/activitystreams#Public"]
 537         )
 538     )
 539   end
 540
 541   def fetch_activities_query(recipients, opts \\ %{}) do
 542     base_query =
 543       from(
 544         activity in Activity,
 545         limit: 20,
 546         order_by: [fragment("? desc nulls last", activity.id)]
 547       )
 548
 549     base_query
 550     |> restrict_recipients(recipients, opts["user"])
 551     |> restrict_tag(opts)
 552     |> restrict_since(opts)
 553     |> restrict_local(opts)
 554     |> restrict_limit(opts)
 555     |> restrict_max(opts)
 556     |> restrict_actor(opts)
 557     |> restrict_type(opts)
 558     |> restrict_favorited_by(opts)
 559     |> restrict_recent(opts)
 560     |> restrict_blocked(opts)
 561     |> restrict_media(opts)
 562     |> restrict_visibility(opts)
 563     |> restrict_replies(opts)
 564   end
 565
 566   def fetch_activities(recipients, opts \\ %{}) do
 567     fetch_activities_query(recipients, opts)
 568     |> Repo.all()
 569     |> Enum.reverse()
 570   end
 571
 572   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 573     fetch_activities_query([], opts)
 574     |> restrict_to_cc(recipients_to, recipients_cc)
 575     |> Repo.all()
 576     |> Enum.reverse()
 577   end
 578
 579   def upload(file, opts \\ []) do
 580     with {:ok, data} <- Upload.store(file, opts) do
 581       obj_data =
 582         if opts[:actor] do
 583           Map.put(data, "actor", opts[:actor])
 584         else
 585           data
 586         end
 587
 588       Repo.insert(%Object{data: obj_data})
 589     end
 590   end
 591
 592   def user_data_from_user_object(data) do
 593     avatar =
 594       data["icon"]["url"] &&
 595         %{
 596           "type" => "Image",
 597           "url" => [%{"href" => data["icon"]["url"]}]
 598         }
 599
 600     banner =
 601       data["image"]["url"] &&
 602         %{
 603           "type" => "Image",
 604           "url" => [%{"href" => data["image"]["url"]}]
 605         }
 606
 607     locked = data["manuallyApprovesFollowers"] || false
 608     data = Transmogrifier.maybe_fix_user_object(data)
 609
 610     user_data = %{
 611       ap_id: data["id"],
 612       info: %{
 613         "ap_enabled" => true,
 614         "source_data" => data,
 615         "banner" => banner,
 616         "locked" => locked
 617       },
 618       avatar: avatar,
 619       name: data["name"],
 620       follower_address: data["followers"],
 621       bio: data["summary"]
 622     }
 623
 624     # nickname can be nil because of virtual actors
 625     user_data =
 626       if data["preferredUsername"] do
 627         Map.put(
 628           user_data,
 629           :nickname,
 630           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 631         )
 632       else
 633         Map.put(user_data, :nickname, nil)
 634       end
 635
 636     {:ok, user_data}
 637   end
 638
 639   def fetch_and_prepare_user_from_ap_id(ap_id) do
 640     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 641       user_data_from_user_object(data)
 642     else
 643       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 644     end
 645   end
 646
 647   def make_user_from_ap_id(ap_id) do
 648     if _user = User.get_by_ap_id(ap_id) do
 649       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 650     else
 651       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 652         User.insert_or_update_user(data)
 653       else
 654         e -> {:error, e}
 655       end
 656     end
 657   end
 658
 659   def make_user_from_nickname(nickname) do
 660     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 661       make_user_from_ap_id(ap_id)
 662     else
 663       _e -> {:error, "No AP id in WebFinger"}
 664     end
 665   end
 666
 667   def should_federate?(inbox, public) do
 668     if public do
 669       true
 670     else
 671       inbox_info = URI.parse(inbox)
 672       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 673     end
 674   end
 675
 676   def publish(actor, activity) do
 677     followers =
 678       if actor.follower_address in activity.recipients do
 679         {:ok, followers} = User.get_followers(actor)
 680         followers |> Enum.filter(&(!&1.local))
 681       else
 682         []
 683       end
 684
 685     public = is_public?(activity)
 686
 687     remote_inboxes =
 688       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 689       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 690       |> Enum.map(fn %{info: %{source_data: data}} ->
 691         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 692       end)
 693       |> Enum.uniq()
 694       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 695
 696     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 697     json = Jason.encode!(data)
 698
 699     Enum.each(remote_inboxes, fn inbox ->
 700       Federator.enqueue(:publish_single_ap, %{
 701         inbox: inbox,
 702         json: json,
 703         actor: actor,
 704         id: activity.data["id"]
 705       })
 706     end)
 707   end
 708
 709   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 710     Logger.info("Federating #{id} to #{inbox}")
 711     host = URI.parse(inbox).host
 712
 713     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 714
 715     signature =
 716       Pleroma.Web.HTTPSignatures.sign(actor, %{
 717         host: host,
 718         "content-length": byte_size(json),
 719         digest: digest
 720       })
 721
 722     @httpoison.post(
 723       inbox,
 724       json,
 725       [
 726         {"Content-Type", "application/activity+json"},
 727         {"signature", signature},
 728         {"digest", digest}
 729       ],
 730       hackney: [pool: :default]
 731     )
 732   end
 733
 734   # TODO:
 735   # This will create a Create activity, which we need internally at the moment.
 736   def fetch_object_from_id(id) do
 737     if object = Object.get_cached_by_ap_id(id) do
 738       {:ok, object}
 739     else
 740       Logger.info("Fetching #{id} via AP")
 741
 742       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 743            nil <- Object.normalize(data),
 744            params <- %{
 745              "type" => "Create",
 746              "to" => data["to"],
 747              "cc" => data["cc"],
 748              "actor" => data["actor"] || data["attributedTo"],
 749              "object" => data
 750            },
 751            :ok <- Transmogrifier.contain_origin(id, params),
 752            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 753         {:ok, Object.normalize(activity.data["object"])}
 754       else
 755         {:error, {:reject, nil}} ->
 756           {:reject, nil}
 757
 758         object = %Object{} ->
 759           {:ok, object}
 760
 761         _e ->
 762           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 763
 764           case OStatus.fetch_activity_from_url(id) do
 765             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 766             e -> e
 767           end
 768       end
 769     end
 770   end
 771
 772   def fetch_and_contain_remote_object_from_id(id) do
 773     Logger.info("Fetching #{id} via AP")
 774
 775     with true <- String.starts_with?(id, "http"),
 776          {:ok, %{body: body, status: code}} when code in 200..299 <-
 777            @httpoison.get(
 778              id,
 779              [{:Accept, "application/activity+json"}]
 780            ),
 781          {:ok, data} <- Jason.decode(body),
 782          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 783       {:ok, data}
 784     else
 785       e ->
 786         {:error, e}
 787     end
 788   end
 789
 790   def is_public?(activity) do
 791     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 792                                                          (activity.data["cc"] || []))
 793   end
 794
 795   def visible_for_user?(activity, nil) do
 796     is_public?(activity)
 797   end
 798
 799   def visible_for_user?(activity, user) do
 800     x = [user.ap_id | user.following]
 801     y = activity.data["to"] ++ (activity.data["cc"] || [])
 802     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 803   end
 804
 805   # guard
 806   def entire_thread_visible_for_user?(nil, _user), do: false
 807
 808   # child
 809   def entire_thread_visible_for_user?(
 810         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 811         user
 812       )
 813       when is_binary(parent_id) do
 814     parent = Activity.get_in_reply_to_activity(tail)
 815     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 816   end
 817
 818   # root
 819   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 820
 821   # filter out broken threads
 822   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 823     entire_thread_visible_for_user?(activity, user)
 824   end
 825
 826   # do post-processing on a specific activity
 827   def contain_activity(%Activity{} = activity, %User{} = user) do
 828     contain_broken_threads(activity, user)
 829   end
 830
 831   # do post-processing on a timeline
 832   def contain_timeline(timeline, user) do
 833     timeline
 834     |> Enum.filter(fn activity ->
 835       contain_activity(activity, user)
 836     end)
 837   end
 838 end