git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   6   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   7   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Web.OStatus
  11   import Ecto.Query
  12   import Pleroma.Web.ActivityPub.Utils
  13   require Logger
  14
  15   @httpoison Application.get_env(:pleroma, :httpoison)
  16
  17   # For Announce activities, we filter the recipients based on following status for any actors
  18   # that match actual users.  See issue #164 for more information about why this is necessary.
  19   defp get_recipients(%{"type" => "Announce"} = data) do
  20     to = data["to"] || []
  21     cc = data["cc"] || []
  22     recipients = to ++ cc
  23     actor = User.get_cached_by_ap_id(data["actor"])
  24
  25     recipients
  26     |> Enum.filter(fn recipient ->
  27       case User.get_cached_by_ap_id(recipient) do
  28         nil ->
  29           true
  30
  31         user ->
  32           User.following?(user, actor)
  33       end
  34     end)
  35
  36     {recipients, to, cc}
  37   end
  38
  39   defp get_recipients(%{"type" => "Create"} = data) do
  40     to = data["to"] || []
  41     cc = data["cc"] || []
  42     actor = data["actor"] || []
  43     recipients = (to ++ cc ++ [actor]) |> Enum.uniq()
  44     {recipients, to, cc}
  45   end
  46
  47   defp get_recipients(data) do
  48     to = data["to"] || []
  49     cc = data["cc"] || []
  50     recipients = to ++ cc
  51     {recipients, to, cc}
  52   end
  53
  54   defp check_actor_is_active(actor) do
  55     if not is_nil(actor) do
  56       with user <- User.get_cached_by_ap_id(actor),
  57            false <- user.info.deactivated do
  58         :ok
  59       else
  60         _e -> :reject
  61       end
  62     else
  63       :ok
  64     end
  65   end
  66
  67   defp check_remote_limit(%{"object" => %{"content" => content}}) do
  68     limit = Pleroma.Config.get([:instance, :remote_limit])
  69     String.length(content) <= limit
  70   end
  71
  72   defp check_remote_limit(_), do: true
  73
  74   def insert(map, local \\ true) when is_map(map) do
  75     with nil <- Activity.normalize(map),
  76          map <- lazy_put_activity_defaults(map),
  77          :ok <- check_actor_is_active(map["actor"]),
  78          {_, true} <- {:remote_limit_error, check_remote_limit(map)},
  79          {:ok, map} <- MRF.filter(map),
  80          :ok <- insert_full_object(map) do
  81       {recipients, _, _} = get_recipients(map)
  82
  83       {:ok, activity} =
  84         Repo.insert(%Activity{
  85           data: map,
  86           local: local,
  87           actor: map["actor"],
  88           recipients: recipients
  89         })
  90
  91       Notification.create_notifications(activity)
  92       stream_out(activity)
  93       {:ok, activity}
  94     else
  95       %Activity{} = activity -> {:ok, activity}
  96       error -> {:error, error}
  97     end
  98   end
  99
 100   def stream_out(activity) do
 101     public = "https://www.w3.org/ns/activitystreams#Public"
 102
 103     if activity.data["type"] in ["Create", "Announce", "Delete"] do
 104       Pleroma.Web.Streamer.stream("user", activity)
 105       Pleroma.Web.Streamer.stream("list", activity)
 106
 107       if Enum.member?(activity.data["to"], public) do
 108         Pleroma.Web.Streamer.stream("public", activity)
 109
 110         if activity.local do
 111           Pleroma.Web.Streamer.stream("public:local", activity)
 112         end
 113
 114         if activity.data["type"] in ["Create"] do
 115           activity.data["object"]
 116           |> Map.get("tag", [])
 117           |> Enum.filter(fn tag -> is_bitstring(tag) end)
 118           |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
 119
 120           if activity.data["object"]["attachment"] != [] do
 121             Pleroma.Web.Streamer.stream("public:media", activity)
 122
 123             if activity.local do
 124               Pleroma.Web.Streamer.stream("public:local:media", activity)
 125             end
 126           end
 127         end
 128       else
 129         if !Enum.member?(activity.data["cc"] || [], public) &&
 130              !Enum.member?(
 131                activity.data["to"],
 132                User.get_by_ap_id(activity.data["actor"]).follower_address
 133              ),
 134            do: Pleroma.Web.Streamer.stream("direct", activity)
 135       end
 136     end
 137   end
 138
 139   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 140     additional = params[:additional] || %{}
 141     # only accept false as false value
 142     local = !(params[:local] == false)
 143     published = params[:published]
 144
 145     with create_data <-
 146            make_create_data(
 147              %{to: to, actor: actor, published: published, context: context, object: object},
 148              additional
 149            ),
 150          {:ok, activity} <- insert(create_data, local),
 151          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 152          {:ok, _actor} <- User.increase_note_count(actor),
 153          :ok <- maybe_federate(activity) do
 154       {:ok, activity}
 155     end
 156   end
 157
 158   def accept(%{to: to, actor: actor, object: object} = params) do
 159     # only accept false as false value
 160     local = !(params[:local] == false)
 161
 162     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 163          {:ok, activity} <- insert(data, local),
 164          :ok <- maybe_federate(activity) do
 165       {:ok, activity}
 166     end
 167   end
 168
 169   def reject(%{to: to, actor: actor, object: object} = params) do
 170     # only accept false as false value
 171     local = !(params[:local] == false)
 172
 173     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 174          {:ok, activity} <- insert(data, local),
 175          :ok <- maybe_federate(activity) do
 176       {:ok, activity}
 177     end
 178   end
 179
 180   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 181     # only accept false as false value
 182     local = !(params[:local] == false)
 183
 184     with data <- %{
 185            "to" => to,
 186            "cc" => cc,
 187            "type" => "Update",
 188            "actor" => actor,
 189            "object" => object
 190          },
 191          {:ok, activity} <- insert(data, local),
 192          :ok <- maybe_federate(activity) do
 193       {:ok, activity}
 194     end
 195   end
 196
 197   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 198   def like(
 199         %User{ap_id: ap_id} = user,
 200         %Object{data: %{"id" => _}} = object,
 201         activity_id \\ nil,
 202         local \\ true
 203       ) do
 204     with nil <- get_existing_like(ap_id, object),
 205          like_data <- make_like_data(user, object, activity_id),
 206          {:ok, activity} <- insert(like_data, local),
 207          {:ok, object} <- add_like_to_object(activity, object),
 208          :ok <- maybe_federate(activity) do
 209       {:ok, activity, object}
 210     else
 211       %Activity{} = activity -> {:ok, activity, object}
 212       error -> {:error, error}
 213     end
 214   end
 215
 216   def unlike(
 217         %User{} = actor,
 218         %Object{} = object,
 219         activity_id \\ nil,
 220         local \\ true
 221       ) do
 222     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 223          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 224          {:ok, unlike_activity} <- insert(unlike_data, local),
 225          {:ok, _activity} <- Repo.delete(like_activity),
 226          {:ok, object} <- remove_like_from_object(like_activity, object),
 227          :ok <- maybe_federate(unlike_activity) do
 228       {:ok, unlike_activity, like_activity, object}
 229     else
 230       _e -> {:ok, object}
 231     end
 232   end
 233
 234   def announce(
 235         %User{ap_id: _} = user,
 236         %Object{data: %{"id" => _}} = object,
 237         activity_id \\ nil,
 238         local \\ true,
 239         public \\ true
 240       ) do
 241     with true <- is_public?(object),
 242          announce_data <- make_announce_data(user, object, activity_id, public),
 243          {:ok, activity} <- insert(announce_data, local),
 244          {:ok, object} <- add_announce_to_object(activity, object),
 245          :ok <- maybe_federate(activity) do
 246       {:ok, activity, object}
 247     else
 248       error -> {:error, error}
 249     end
 250   end
 251
 252   def unannounce(
 253         %User{} = actor,
 254         %Object{} = object,
 255         activity_id \\ nil,
 256         local \\ true
 257       ) do
 258     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 259          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 260          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 261          :ok <- maybe_federate(unannounce_activity),
 262          {:ok, _activity} <- Repo.delete(announce_activity),
 263          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 264       {:ok, unannounce_activity, object}
 265     else
 266       _e -> {:ok, object}
 267     end
 268   end
 269
 270   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 271     with data <- make_follow_data(follower, followed, activity_id),
 272          {:ok, activity} <- insert(data, local),
 273          :ok <- maybe_federate(activity) do
 274       {:ok, activity}
 275     end
 276   end
 277
 278   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 279     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 280          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 281          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 282          {:ok, activity} <- insert(unfollow_data, local),
 283          :ok <- maybe_federate(activity) do
 284       {:ok, activity}
 285     end
 286   end
 287
 288   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 289     user = User.get_cached_by_ap_id(actor)
 290
 291     data = %{
 292       "type" => "Delete",
 293       "actor" => actor,
 294       "object" => id,
 295       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 296     }
 297
 298     with {:ok, _} <- Object.delete(object),
 299          {:ok, activity} <- insert(data, local),
 300          # Changing note count prior to enqueuing federation task in order to avoid race conditions on updating user.info
 301          {:ok, _actor} <- User.decrease_note_count(user),
 302          :ok <- maybe_federate(activity) do
 303       {:ok, activity}
 304     end
 305   end
 306
 307   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 308     ap_config = Application.get_env(:pleroma, :activitypub)
 309     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 310     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 311
 312     with true <- unfollow_blocked do
 313       follow_activity = fetch_latest_follow(blocker, blocked)
 314
 315       if follow_activity do
 316         unfollow(blocker, blocked, nil, local)
 317       end
 318     end
 319
 320     with true <- outgoing_blocks,
 321          block_data <- make_block_data(blocker, blocked, activity_id),
 322          {:ok, activity} <- insert(block_data, local),
 323          :ok <- maybe_federate(activity) do
 324       {:ok, activity}
 325     else
 326       _e -> {:ok, nil}
 327     end
 328   end
 329
 330   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 331     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 332          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 333          {:ok, activity} <- insert(unblock_data, local),
 334          :ok <- maybe_federate(activity) do
 335       {:ok, activity}
 336     end
 337   end
 338
 339   def fetch_activities_for_context(context, opts \\ %{}) do
 340     public = ["https://www.w3.org/ns/activitystreams#Public"]
 341
 342     recipients =
 343       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 344
 345     query = from(activity in Activity)
 346
 347     query =
 348       query
 349       |> restrict_blocked(opts)
 350       |> restrict_recipients(recipients, opts["user"])
 351
 352     query =
 353       from(
 354         activity in query,
 355         where:
 356           fragment(
 357             "?->>'type' = ? and ?->>'context' = ?",
 358             activity.data,
 359             "Create",
 360             activity.data,
 361             ^context
 362           ),
 363         order_by: [desc: :id]
 364       )
 365
 366     Repo.all(query)
 367   end
 368
 369   def fetch_public_activities(opts \\ %{}) do
 370     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 371
 372     q
 373     |> restrict_unlisted()
 374     |> Repo.all()
 375     |> Enum.reverse()
 376   end
 377
 378   @valid_visibilities ~w[direct unlisted public private]
 379
 380   defp restrict_visibility(query, %{visibility: visibility})
 381        when visibility in @valid_visibilities do
 382     query =
 383       from(
 384         a in query,
 385         where:
 386           fragment("activity_visibility(?, ?, ?) = ?", a.actor, a.recipients, a.data, ^visibility)
 387       )
 388
 389     Ecto.Adapters.SQL.to_sql(:all, Repo, query)
 390
 391     query
 392   end
 393
 394   defp restrict_visibility(_query, %{visibility: visibility})
 395        when visibility not in @valid_visibilities do
 396     Logger.error("Could not restrict visibility to #{visibility}")
 397   end
 398
 399   defp restrict_visibility(query, _visibility), do: query
 400
 401   def fetch_user_activities(user, reading_user, params \\ %{}) do
 402     params =
 403       params
 404       |> Map.put("type", ["Create", "Announce"])
 405       |> Map.put("actor_id", user.ap_id)
 406       |> Map.put("whole_db", true)
 407       |> Map.put("pinned_activity_ids", user.info.pinned_activities)
 408
 409     recipients =
 410       if reading_user do
 411         ["https://www.w3.org/ns/activitystreams#Public"] ++
 412           [reading_user.ap_id | reading_user.following]
 413       else
 414         ["https://www.w3.org/ns/activitystreams#Public"]
 415       end
 416
 417     fetch_activities(recipients, params)
 418     |> Enum.reverse()
 419   end
 420
 421   defp restrict_since(query, %{"since_id" => ""}), do: query
 422
 423   defp restrict_since(query, %{"since_id" => since_id}) do
 424     from(activity in query, where: activity.id > ^since_id)
 425   end
 426
 427   defp restrict_since(query, _), do: query
 428
 429   defp restrict_tag(query, %{"tag" => tag, "tag_reject" => tag_reject})
 430        when is_list(tag) and tag_reject != [] do
 431     from(
 432       activity in query,
 433       where:
 434         fragment(
 435           "? && ARRAY(SELECT jsonb_array_elements_text((? #> '{\"object\",\"tag\"}')))",
 436           ^tag,
 437           activity.data
 438         ),
 439       where:
 440         fragment(
 441           "(not ? && ARRAY(SELECT jsonb_array_elements_text((? #> '{\"object\",\"tag\"}'))))",
 442           ^tag_reject,
 443           activity.data
 444         )
 445     )
 446   end
 447
 448   defp restrict_tag(query, %{"tag" => tag}) when is_list(tag) do
 449     from(
 450       activity in query,
 451       where:
 452         fragment(
 453           "? && ARRAY(SELECT jsonb_array_elements_text((? #> '{\"object\",\"tag\"}')))",
 454           ^tag,
 455           activity.data
 456         )
 457     )
 458   end
 459
 460   defp restrict_tag(query, %{"tag" => tag}) when is_binary(tag) do
 461     from(
 462       activity in query,
 463       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 464     )
 465   end
 466
 467   defp restrict_tag(query, _), do: query
 468
 469   defp restrict_to_cc(query, recipients_to, recipients_cc) do
 470     from(
 471       activity in query,
 472       where:
 473         fragment(
 474           "(?->'to' \\?| ?) or (?->'cc' \\?| ?)",
 475           activity.data,
 476           ^recipients_to,
 477           activity.data,
 478           ^recipients_cc
 479         )
 480     )
 481   end
 482
 483   defp restrict_recipients(query, [], _user), do: query
 484
 485   defp restrict_recipients(query, recipients, nil) do
 486     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 487   end
 488
 489   defp restrict_recipients(query, recipients, user) do
 490     from(
 491       activity in query,
 492       where: fragment("? && ?", ^recipients, activity.recipients),
 493       or_where: activity.actor == ^user.ap_id
 494     )
 495   end
 496
 497   defp restrict_limit(query, %{"limit" => limit}) do
 498     from(activity in query, limit: ^limit)
 499   end
 500
 501   defp restrict_limit(query, _), do: query
 502
 503   defp restrict_local(query, %{"local_only" => true}) do
 504     from(activity in query, where: activity.local == true)
 505   end
 506
 507   defp restrict_local(query, _), do: query
 508
 509   defp restrict_max(query, %{"max_id" => ""}), do: query
 510
 511   defp restrict_max(query, %{"max_id" => max_id}) do
 512     from(activity in query, where: activity.id < ^max_id)
 513   end
 514
 515   defp restrict_max(query, _), do: query
 516
 517   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 518     from(activity in query, where: activity.actor == ^actor_id)
 519   end
 520
 521   defp restrict_actor(query, _), do: query
 522
 523   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 524     restrict_type(query, %{"type" => [type]})
 525   end
 526
 527   defp restrict_type(query, %{"type" => type}) do
 528     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 529   end
 530
 531   defp restrict_type(query, _), do: query
 532
 533   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 534     from(
 535       activity in query,
 536       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 537     )
 538   end
 539
 540   defp restrict_favorited_by(query, _), do: query
 541
 542   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 543     from(
 544       activity in query,
 545       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 546     )
 547   end
 548
 549   defp restrict_media(query, _), do: query
 550
 551   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 552     from(
 553       activity in query,
 554       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 555     )
 556   end
 557
 558   defp restrict_replies(query, _), do: query
 559
 560   defp restrict_reblogs(query, %{"exclude_reblogs" => val}) when val == "true" or val == "1" do
 561     from(activity in query, where: fragment("?->>'type' != 'Announce'", activity.data))
 562   end
 563
 564   defp restrict_reblogs(query, _), do: query
 565
 566   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 567     blocks = info.blocks || []
 568     domain_blocks = info.domain_blocks || []
 569
 570     from(
 571       activity in query,
 572       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 573       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 574       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 575     )
 576   end
 577
 578   defp restrict_blocked(query, _), do: query
 579
 580   defp restrict_unlisted(query) do
 581     from(
 582       activity in query,
 583       where:
 584         fragment(
 585           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 586           activity.data,
 587           ^["https://www.w3.org/ns/activitystreams#Public"]
 588         )
 589     )
 590   end
 591
 592   defp restrict_pinned(query, %{"pinned" => "true", "pinned_activity_ids" => ids}) do
 593     from(activity in query, where: activity.id in ^ids)
 594   end
 595
 596   defp restrict_pinned(query, _), do: query
 597
 598   def fetch_activities_query(recipients, opts \\ %{}) do
 599     base_query =
 600       from(
 601         activity in Activity,
 602         limit: 20,
 603         order_by: [fragment("? desc nulls last", activity.id)]
 604       )
 605
 606     base_query
 607     |> restrict_recipients(recipients, opts["user"])
 608     |> restrict_tag(opts)
 609     |> restrict_since(opts)
 610     |> restrict_local(opts)
 611     |> restrict_limit(opts)
 612     |> restrict_max(opts)
 613     |> restrict_actor(opts)
 614     |> restrict_type(opts)
 615     |> restrict_favorited_by(opts)
 616     |> restrict_blocked(opts)
 617     |> restrict_media(opts)
 618     |> restrict_visibility(opts)
 619     |> restrict_replies(opts)
 620     |> restrict_reblogs(opts)
 621     |> restrict_pinned(opts)
 622   end
 623
 624   def fetch_activities(recipients, opts \\ %{}) do
 625     fetch_activities_query(recipients, opts)
 626     |> Repo.all()
 627     |> Enum.reverse()
 628   end
 629
 630   def fetch_activities_bounded(recipients_to, recipients_cc, opts \\ %{}) do
 631     fetch_activities_query([], opts)
 632     |> restrict_to_cc(recipients_to, recipients_cc)
 633     |> Repo.all()
 634     |> Enum.reverse()
 635   end
 636
 637   def upload(file, opts \\ []) do
 638     with {:ok, data} <- Upload.store(file, opts) do
 639       obj_data =
 640         if opts[:actor] do
 641           Map.put(data, "actor", opts[:actor])
 642         else
 643           data
 644         end
 645
 646       Repo.insert(%Object{data: obj_data})
 647     end
 648   end
 649
 650   def user_data_from_user_object(data) do
 651     avatar =
 652       data["icon"]["url"] &&
 653         %{
 654           "type" => "Image",
 655           "url" => [%{"href" => data["icon"]["url"]}]
 656         }
 657
 658     banner =
 659       data["image"]["url"] &&
 660         %{
 661           "type" => "Image",
 662           "url" => [%{"href" => data["image"]["url"]}]
 663         }
 664
 665     locked = data["manuallyApprovesFollowers"] || false
 666     data = Transmogrifier.maybe_fix_user_object(data)
 667
 668     user_data = %{
 669       ap_id: data["id"],
 670       info: %{
 671         "ap_enabled" => true,
 672         "source_data" => data,
 673         "banner" => banner,
 674         "locked" => locked
 675       },
 676       avatar: avatar,
 677       name: data["name"],
 678       follower_address: data["followers"],
 679       bio: data["summary"]
 680     }
 681
 682     # nickname can be nil because of virtual actors
 683     user_data =
 684       if data["preferredUsername"] do
 685         Map.put(
 686           user_data,
 687           :nickname,
 688           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 689         )
 690       else
 691         Map.put(user_data, :nickname, nil)
 692       end
 693
 694     {:ok, user_data}
 695   end
 696
 697   def fetch_and_prepare_user_from_ap_id(ap_id) do
 698     with {:ok, data} <- fetch_and_contain_remote_object_from_id(ap_id) do
 699       user_data_from_user_object(data)
 700     else
 701       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 702     end
 703   end
 704
 705   def make_user_from_ap_id(ap_id) do
 706     if _user = User.get_by_ap_id(ap_id) do
 707       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 708     else
 709       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 710         User.insert_or_update_user(data)
 711       else
 712         e -> {:error, e}
 713       end
 714     end
 715   end
 716
 717   def make_user_from_nickname(nickname) do
 718     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 719       make_user_from_ap_id(ap_id)
 720     else
 721       _e -> {:error, "No AP id in WebFinger"}
 722     end
 723   end
 724
 725   def should_federate?(inbox, public) do
 726     if public do
 727       true
 728     else
 729       inbox_info = URI.parse(inbox)
 730       !Enum.member?(Pleroma.Config.get([:instance, :quarantined_instances], []), inbox_info.host)
 731     end
 732   end
 733
 734   def publish(actor, activity) do
 735     followers =
 736       if actor.follower_address in activity.recipients do
 737         {:ok, followers} = User.get_followers(actor)
 738         followers |> Enum.filter(&(!&1.local))
 739       else
 740         []
 741       end
 742
 743     public = is_public?(activity)
 744
 745     remote_inboxes =
 746       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 747       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 748       |> Enum.map(fn %{info: %{source_data: data}} ->
 749         (is_map(data["endpoints"]) && Map.get(data["endpoints"], "sharedInbox")) || data["inbox"]
 750       end)
 751       |> Enum.uniq()
 752       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 753
 754     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 755     json = Jason.encode!(data)
 756
 757     Enum.each(remote_inboxes, fn inbox ->
 758       Federator.enqueue(:publish_single_ap, %{
 759         inbox: inbox,
 760         json: json,
 761         actor: actor,
 762         id: activity.data["id"]
 763       })
 764     end)
 765   end
 766
 767   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 768     Logger.info("Federating #{id} to #{inbox}")
 769     host = URI.parse(inbox).host
 770
 771     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 772
 773     signature =
 774       Pleroma.Web.HTTPSignatures.sign(actor, %{
 775         host: host,
 776         "content-length": byte_size(json),
 777         digest: digest
 778       })
 779
 780     @httpoison.post(
 781       inbox,
 782       json,
 783       [
 784         {"Content-Type", "application/activity+json"},
 785         {"signature", signature},
 786         {"digest", digest}
 787       ]
 788     )
 789   end
 790
 791   # TODO:
 792   # This will create a Create activity, which we need internally at the moment.
 793   def fetch_object_from_id(id) do
 794     if object = Object.get_cached_by_ap_id(id) do
 795       {:ok, object}
 796     else
 797       Logger.info("Fetching #{id} via AP")
 798
 799       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
 800            nil <- Object.normalize(data),
 801            params <- %{
 802              "type" => "Create",
 803              "to" => data["to"],
 804              "cc" => data["cc"],
 805              "actor" => data["actor"] || data["attributedTo"],
 806              "object" => data
 807            },
 808            :ok <- Transmogrifier.contain_origin(id, params),
 809            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 810         {:ok, Object.normalize(activity.data["object"])}
 811       else
 812         {:error, {:reject, nil}} ->
 813           {:reject, nil}
 814
 815         object = %Object{} ->
 816           {:ok, object}
 817
 818         _e ->
 819           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 820
 821           case OStatus.fetch_activity_from_url(id) do
 822             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 823             e -> e
 824           end
 825       end
 826     end
 827   end
 828
 829   def fetch_and_contain_remote_object_from_id(id) do
 830     Logger.info("Fetching #{id} via AP")
 831
 832     with true <- String.starts_with?(id, "http"),
 833          {:ok, %{body: body, status: code}} when code in 200..299 <-
 834            @httpoison.get(
 835              id,
 836              [{:Accept, "application/activity+json"}]
 837            ),
 838          {:ok, data} <- Jason.decode(body),
 839          :ok <- Transmogrifier.contain_origin_from_id(id, data) do
 840       {:ok, data}
 841     else
 842       e ->
 843         {:error, e}
 844     end
 845   end
 846
 847   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
 848   def is_public?(%Object{data: data}), do: is_public?(data)
 849   def is_public?(%Activity{data: data}), do: is_public?(data)
 850   def is_public?(%{"directMessage" => true}), do: false
 851
 852   def is_public?(data) do
 853     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
 854   end
 855
 856   def is_private?(activity) do
 857     !is_public?(activity) && Enum.any?(activity.data["to"], &String.contains?(&1, "/followers"))
 858   end
 859
 860   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
 861   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
 862
 863   def is_direct?(activity) do
 864     !is_public?(activity) && !is_private?(activity)
 865   end
 866
 867   def visible_for_user?(activity, nil) do
 868     is_public?(activity)
 869   end
 870
 871   def visible_for_user?(activity, user) do
 872     x = [user.ap_id | user.following]
 873     y = activity.data["to"] ++ (activity.data["cc"] || [])
 874     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 875   end
 876
 877   # guard
 878   def entire_thread_visible_for_user?(nil, _user), do: false
 879
 880   # child
 881   def entire_thread_visible_for_user?(
 882         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
 883         user
 884       )
 885       when is_binary(parent_id) do
 886     parent = Activity.get_in_reply_to_activity(tail)
 887     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
 888   end
 889
 890   # root
 891   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
 892
 893   # filter out broken threads
 894   def contain_broken_threads(%Activity{} = activity, %User{} = user) do
 895     entire_thread_visible_for_user?(activity, user)
 896   end
 897
 898   # do post-processing on a specific activity
 899   def contain_activity(%Activity{} = activity, %User{} = user) do
 900     contain_broken_threads(activity, user)
 901   end
 902
 903   # do post-processing on a timeline
 904   def contain_timeline(timeline, user) do
 905     timeline
 906     |> Enum.filter(fn activity ->
 907       contain_activity(activity, user)
 908     end)
 909   end
 910 end