git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   def get_recipients(data) do
  16     (data["to"] || []) ++ (data["cc"] || [])
  17   end
  18
  19   defp check_actor_is_active(actor) do
  20     if not is_nil(actor) do
  21       with user <- User.get_cached_by_ap_id(actor),
  22            nil <- user.info["deactivated"] do
  23         :ok
  24       else
  25         _e -> :reject
  26       end
  27     else
  28       :ok
  29     end
  30   end
  31
  32   def insert(map, local \\ true) when is_map(map) do
  33     with nil <- Activity.normalize(map),
  34          map <- lazy_put_activity_defaults(map),
  35          :ok <- check_actor_is_active(map["actor"]),
  36          {:ok, map} <- MRF.filter(map),
  37          :ok <- insert_full_object(map) do
  38       {:ok, activity} =
  39         Repo.insert(%Activity{
  40           data: map,
  41           local: local,
  42           actor: map["actor"],
  43           recipients: get_recipients(map)
  44         })
  45
  46       Notification.create_notifications(activity)
  47       stream_out(activity)
  48       {:ok, activity}
  49     else
  50       %Activity{} = activity -> {:ok, activity}
  51       error -> {:error, error}
  52     end
  53   end
  54
  55   def stream_out(activity) do
  56     public = "https://www.w3.org/ns/activitystreams#Public"
  57
  58     if activity.data["type"] in ["Create", "Announce"] do
  59       Pleroma.Web.Streamer.stream("user", activity)
  60       Pleroma.Web.Streamer.stream("list", activity)
  61
  62       if Enum.member?(activity.data["to"], public) do
  63         Pleroma.Web.Streamer.stream("public", activity)
  64
  65         if activity.local do
  66           Pleroma.Web.Streamer.stream("public:local", activity)
  67         end
  68
  69         if activity.data["object"]["attachment"] != [] do
  70           Pleroma.Web.Streamer.stream("public:media", activity)
  71
  72           if activity.local do
  73             Pleroma.Web.Streamer.stream("public:local:media", activity)
  74           end
  75         end
  76       else
  77         if !Enum.member?(activity.data["cc"] || [], public) &&
  78              !Enum.member?(
  79                activity.data["to"],
  80                User.get_by_ap_id(activity.data["actor"]).follower_address
  81              ),
  82            do: Pleroma.Web.Streamer.stream("direct", activity)
  83       end
  84     end
  85   end
  86
  87   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  88     additional = params[:additional] || %{}
  89     # only accept false as false value
  90     local = !(params[:local] == false)
  91     published = params[:published]
  92
  93     with create_data <-
  94            make_create_data(
  95              %{to: to, actor: actor, published: published, context: context, object: object},
  96              additional
  97            ),
  98          {:ok, activity} <- insert(create_data, local),
  99          :ok <- maybe_federate(activity),
 100          {:ok, _actor} <- User.increase_note_count(actor) do
 101       {:ok, activity}
 102     end
 103   end
 104
 105   def accept(%{to: to, actor: actor, object: object} = params) do
 106     # only accept false as false value
 107     local = !(params[:local] == false)
 108
 109     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 110          {:ok, activity} <- insert(data, local),
 111          :ok <- maybe_federate(activity) do
 112       {:ok, activity}
 113     end
 114   end
 115
 116   def reject(%{to: to, actor: actor, object: object} = params) do
 117     # only accept false as false value
 118     local = !(params[:local] == false)
 119
 120     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 121          {:ok, activity} <- insert(data, local),
 122          :ok <- maybe_federate(activity) do
 123       {:ok, activity}
 124     end
 125   end
 126
 127   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 128     # only accept false as false value
 129     local = !(params[:local] == false)
 130
 131     with data <- %{
 132            "to" => to,
 133            "cc" => cc,
 134            "type" => "Update",
 135            "actor" => actor,
 136            "object" => object
 137          },
 138          {:ok, activity} <- insert(data, local),
 139          :ok <- maybe_federate(activity) do
 140       {:ok, activity}
 141     end
 142   end
 143
 144   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 145   def like(
 146         %User{ap_id: ap_id} = user,
 147         %Object{data: %{"id" => _}} = object,
 148         activity_id \\ nil,
 149         local \\ true
 150       ) do
 151     with nil <- get_existing_like(ap_id, object),
 152          like_data <- make_like_data(user, object, activity_id),
 153          {:ok, activity} <- insert(like_data, local),
 154          {:ok, object} <- add_like_to_object(activity, object),
 155          :ok <- maybe_federate(activity) do
 156       {:ok, activity, object}
 157     else
 158       %Activity{} = activity -> {:ok, activity, object}
 159       error -> {:error, error}
 160     end
 161   end
 162
 163   def unlike(
 164         %User{} = actor,
 165         %Object{} = object,
 166         activity_id \\ nil,
 167         local \\ true
 168       ) do
 169     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 170          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 171          {:ok, unlike_activity} <- insert(unlike_data, local),
 172          {:ok, _activity} <- Repo.delete(like_activity),
 173          {:ok, object} <- remove_like_from_object(like_activity, object),
 174          :ok <- maybe_federate(unlike_activity) do
 175       {:ok, unlike_activity, like_activity, object}
 176     else
 177       _e -> {:ok, object}
 178     end
 179   end
 180
 181   def announce(
 182         %User{ap_id: _} = user,
 183         %Object{data: %{"id" => _}} = object,
 184         activity_id \\ nil,
 185         local \\ true
 186       ) do
 187     with true <- is_public?(object),
 188          announce_data <- make_announce_data(user, object, activity_id),
 189          {:ok, activity} <- insert(announce_data, local),
 190          {:ok, object} <- add_announce_to_object(activity, object),
 191          :ok <- maybe_federate(activity) do
 192       {:ok, activity, object}
 193     else
 194       error -> {:error, error}
 195     end
 196   end
 197
 198   def unannounce(
 199         %User{} = actor,
 200         %Object{} = object,
 201         activity_id \\ nil,
 202         local \\ true
 203       ) do
 204     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 205          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 206          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 207          :ok <- maybe_federate(unannounce_activity),
 208          {:ok, _activity} <- Repo.delete(announce_activity),
 209          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 210       {:ok, unannounce_activity, object}
 211     else
 212       _e -> {:ok, object}
 213     end
 214   end
 215
 216   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 217     with data <- make_follow_data(follower, followed, activity_id),
 218          {:ok, activity} <- insert(data, local),
 219          :ok <- maybe_federate(activity) do
 220       {:ok, activity}
 221     end
 222   end
 223
 224   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 225     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 226          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 227          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 228          {:ok, activity} <- insert(unfollow_data, local),
 229          :ok <- maybe_federate(activity) do
 230       {:ok, activity}
 231     end
 232   end
 233
 234   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 235     user = User.get_cached_by_ap_id(actor)
 236
 237     data = %{
 238       "type" => "Delete",
 239       "actor" => actor,
 240       "object" => id,
 241       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 242     }
 243
 244     with Repo.delete(object),
 245          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 246          {:ok, activity} <- insert(data, local),
 247          :ok <- maybe_federate(activity),
 248          {:ok, _actor} <- User.decrease_note_count(user) do
 249       {:ok, activity}
 250     end
 251   end
 252
 253   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 254     ap_config = Application.get_env(:pleroma, :activitypub)
 255     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 256     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 257
 258     with true <- unfollow_blocked do
 259       follow_activity = fetch_latest_follow(blocker, blocked)
 260
 261       if follow_activity do
 262         unfollow(blocker, blocked, nil, local)
 263       end
 264     end
 265
 266     with true <- outgoing_blocks,
 267          block_data <- make_block_data(blocker, blocked, activity_id),
 268          {:ok, activity} <- insert(block_data, local),
 269          :ok <- maybe_federate(activity) do
 270       {:ok, activity}
 271     else
 272       _e -> {:ok, nil}
 273     end
 274   end
 275
 276   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 277     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 278          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 279          {:ok, activity} <- insert(unblock_data, local),
 280          :ok <- maybe_federate(activity) do
 281       {:ok, activity}
 282     end
 283   end
 284
 285   def fetch_activities_for_context(context, opts \\ %{}) do
 286     public = ["https://www.w3.org/ns/activitystreams#Public"]
 287
 288     recipients =
 289       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 290
 291     query = from(activity in Activity)
 292
 293     query =
 294       query
 295       |> restrict_blocked(opts)
 296       |> restrict_recipients(recipients, opts["user"])
 297
 298     query =
 299       from(
 300         activity in query,
 301         where:
 302           fragment(
 303             "?->>'type' = ? and ?->>'context' = ?",
 304             activity.data,
 305             "Create",
 306             activity.data,
 307             ^context
 308           ),
 309         order_by: [desc: :id]
 310       )
 311
 312     Repo.all(query)
 313   end
 314
 315   def fetch_public_activities(opts \\ %{}) do
 316     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 317
 318     q
 319     |> restrict_unlisted()
 320     |> Repo.all()
 321     |> Enum.reverse()
 322   end
 323
 324   @valid_visibilities ~w[direct unlisted public private]
 325
 326   defp restrict_visibility(query, %{visibility: "direct"}) do
 327     public = "https://www.w3.org/ns/activitystreams#Public"
 328
 329     from(
 330       activity in query,
 331       join: sender in User,
 332       on: sender.ap_id == activity.actor,
 333       # Are non-direct statuses with no to/cc possible?
 334       where:
 335         fragment(
 336           "not (? && ?)",
 337           [^public, sender.follower_address],
 338           activity.recipients
 339         )
 340     )
 341   end
 342
 343   defp restrict_visibility(_query, %{visibility: visibility})
 344        when visibility not in @valid_visibilities do
 345     Logger.error("Could not restrict visibility to #{visibility}")
 346   end
 347
 348   defp restrict_visibility(query, _visibility), do: query
 349
 350   def fetch_user_activities(user, reading_user, params \\ %{}) do
 351     params =
 352       params
 353       |> Map.put("type", ["Create", "Announce"])
 354       |> Map.put("actor_id", user.ap_id)
 355       |> Map.put("whole_db", true)
 356
 357     recipients =
 358       if reading_user do
 359         ["https://www.w3.org/ns/activitystreams#Public"] ++
 360           [reading_user.ap_id | reading_user.following]
 361       else
 362         ["https://www.w3.org/ns/activitystreams#Public"]
 363       end
 364
 365     fetch_activities(recipients, params)
 366     |> Enum.reverse()
 367   end
 368
 369   defp restrict_since(query, %{"since_id" => since_id}) do
 370     from(activity in query, where: activity.id > ^since_id)
 371   end
 372
 373   defp restrict_since(query, _), do: query
 374
 375   defp restrict_tag(query, %{"tag" => tag}) do
 376     from(
 377       activity in query,
 378       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 379     )
 380   end
 381
 382   defp restrict_tag(query, _), do: query
 383
 384   defp restrict_recipients(query, [], _user), do: query
 385
 386   defp restrict_recipients(query, recipients, nil) do
 387     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 388   end
 389
 390   defp restrict_recipients(query, recipients, user) do
 391     from(
 392       activity in query,
 393       where: fragment("? && ?", ^recipients, activity.recipients),
 394       or_where: activity.actor == ^user.ap_id
 395     )
 396   end
 397
 398   defp restrict_limit(query, %{"limit" => limit}) do
 399     from(activity in query, limit: ^limit)
 400   end
 401
 402   defp restrict_limit(query, _), do: query
 403
 404   defp restrict_local(query, %{"local_only" => true}) do
 405     from(activity in query, where: activity.local == true)
 406   end
 407
 408   defp restrict_local(query, _), do: query
 409
 410   defp restrict_max(query, %{"max_id" => max_id}) do
 411     from(activity in query, where: activity.id < ^max_id)
 412   end
 413
 414   defp restrict_max(query, _), do: query
 415
 416   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 417     from(activity in query, where: activity.actor == ^actor_id)
 418   end
 419
 420   defp restrict_actor(query, _), do: query
 421
 422   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 423     restrict_type(query, %{"type" => [type]})
 424   end
 425
 426   defp restrict_type(query, %{"type" => type}) do
 427     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 428   end
 429
 430   defp restrict_type(query, _), do: query
 431
 432   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 433     from(
 434       activity in query,
 435       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 436     )
 437   end
 438
 439   defp restrict_favorited_by(query, _), do: query
 440
 441   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 442     from(
 443       activity in query,
 444       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 445     )
 446   end
 447
 448   defp restrict_media(query, _), do: query
 449
 450   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 451     from(
 452       activity in query,
 453       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 454     )
 455   end
 456
 457   defp restrict_replies(query, _), do: query
 458
 459   # Only search through last 100_000 activities by default
 460   defp restrict_recent(query, %{"whole_db" => true}), do: query
 461
 462   defp restrict_recent(query, _) do
 463     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 464
 465     from(activity in query, where: activity.id > ^since)
 466   end
 467
 468   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 469     blocks = info["blocks"] || []
 470     domain_blocks = info["domain_blocks"] || []
 471
 472     from(
 473       activity in query,
 474       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 475       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 476       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 477     )
 478   end
 479
 480   defp restrict_blocked(query, _), do: query
 481
 482   defp restrict_unlisted(query) do
 483     from(
 484       activity in query,
 485       where:
 486         fragment(
 487           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 488           activity.data,
 489           ^["https://www.w3.org/ns/activitystreams#Public"]
 490         )
 491     )
 492   end
 493
 494   def fetch_activities_query(recipients, opts \\ %{}) do
 495     base_query =
 496       from(
 497         activity in Activity,
 498         limit: 20,
 499         order_by: [fragment("? desc nulls last", activity.id)]
 500       )
 501
 502     base_query
 503     |> restrict_recipients(recipients, opts["user"])
 504     |> restrict_tag(opts)
 505     |> restrict_since(opts)
 506     |> restrict_local(opts)
 507     |> restrict_limit(opts)
 508     |> restrict_max(opts)
 509     |> restrict_actor(opts)
 510     |> restrict_type(opts)
 511     |> restrict_favorited_by(opts)
 512     |> restrict_recent(opts)
 513     |> restrict_blocked(opts)
 514     |> restrict_media(opts)
 515     |> restrict_visibility(opts)
 516     |> restrict_replies(opts)
 517   end
 518
 519   def fetch_activities(recipients, opts \\ %{}) do
 520     fetch_activities_query(recipients, opts)
 521     |> Repo.all()
 522     |> Enum.reverse()
 523   end
 524
 525   def upload(file) do
 526     data = Upload.store(file, Application.get_env(:pleroma, :instance)[:dedupe_media])
 527     Repo.insert(%Object{data: data})
 528   end
 529
 530   def user_data_from_user_object(data) do
 531     avatar =
 532       data["icon"]["url"] &&
 533         %{
 534           "type" => "Image",
 535           "url" => [%{"href" => data["icon"]["url"]}]
 536         }
 537
 538     banner =
 539       data["image"]["url"] &&
 540         %{
 541           "type" => "Image",
 542           "url" => [%{"href" => data["image"]["url"]}]
 543         }
 544
 545     locked = data["manuallyApprovesFollowers"] || false
 546     data = Transmogrifier.maybe_fix_user_object(data)
 547
 548     user_data = %{
 549       ap_id: data["id"],
 550       info: %{
 551         "ap_enabled" => true,
 552         "source_data" => data,
 553         "banner" => banner,
 554         "locked" => locked
 555       },
 556       avatar: avatar,
 557       name: data["name"],
 558       follower_address: data["followers"],
 559       bio: data["summary"]
 560     }
 561
 562     # nickname can be nil because of virtual actors
 563     user_data =
 564       if data["preferredUsername"] do
 565         Map.put(
 566           user_data,
 567           :nickname,
 568           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 569         )
 570       else
 571         Map.put(user_data, :nickname, nil)
 572       end
 573
 574     {:ok, user_data}
 575   end
 576
 577   def fetch_and_prepare_user_from_ap_id(ap_id) do
 578     with {:ok, %{status_code: 200, body: body}} <-
 579            @httpoison.get(ap_id, Accept: "application/activity+json"),
 580          {:ok, data} <- Jason.decode(body) do
 581       user_data_from_user_object(data)
 582     else
 583       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 584     end
 585   end
 586
 587   def make_user_from_ap_id(ap_id) do
 588     if _user = User.get_by_ap_id(ap_id) do
 589       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 590     else
 591       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 592         User.insert_or_update_user(data)
 593       else
 594         e -> {:error, e}
 595       end
 596     end
 597   end
 598
 599   def make_user_from_nickname(nickname) do
 600     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 601       make_user_from_ap_id(ap_id)
 602     else
 603       _e -> {:error, "No AP id in WebFinger"}
 604     end
 605   end
 606
 607   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 608
 609   def should_federate?(inbox, public) do
 610     if public do
 611       true
 612     else
 613       inbox_info = URI.parse(inbox)
 614       inbox_info.host not in @quarantined_instances
 615     end
 616   end
 617
 618   def publish(actor, activity) do
 619     followers =
 620       if actor.follower_address in activity.recipients do
 621         {:ok, followers} = User.get_followers(actor)
 622         followers |> Enum.filter(&(!&1.local))
 623       else
 624         []
 625       end
 626
 627     public = is_public?(activity)
 628
 629     remote_inboxes =
 630       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 631       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 632       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 633         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 634       end)
 635       |> Enum.uniq()
 636       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 637
 638     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 639     json = Jason.encode!(data)
 640
 641     Enum.each(remote_inboxes, fn inbox ->
 642       Federator.enqueue(:publish_single_ap, %{
 643         inbox: inbox,
 644         json: json,
 645         actor: actor,
 646         id: activity.data["id"]
 647       })
 648     end)
 649   end
 650
 651   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 652     Logger.info("Federating #{id} to #{inbox}")
 653     host = URI.parse(inbox).host
 654
 655     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 656
 657     signature =
 658       Pleroma.Web.HTTPSignatures.sign(actor, %{
 659         host: host,
 660         "content-length": byte_size(json),
 661         digest: digest
 662       })
 663
 664     @httpoison.post(
 665       inbox,
 666       json,
 667       [
 668         {"Content-Type", "application/activity+json"},
 669         {"signature", signature},
 670         {"digest", digest}
 671       ],
 672       hackney: [pool: :default]
 673     )
 674   end
 675
 676   # TODO:
 677   # This will create a Create activity, which we need internally at the moment.
 678   def fetch_object_from_id(id) do
 679     if object = Object.get_cached_by_ap_id(id) do
 680       {:ok, object}
 681     else
 682       Logger.info("Fetching #{id} via AP")
 683
 684       with true <- String.starts_with?(id, "http"),
 685            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 686              @httpoison.get(
 687                id,
 688                [Accept: "application/activity+json"],
 689                follow_redirect: true,
 690                timeout: 10000,
 691                recv_timeout: 20000
 692              ),
 693            {:ok, data} <- Jason.decode(body),
 694            nil <- Object.normalize(data),
 695            params <- %{
 696              "type" => "Create",
 697              "to" => data["to"],
 698              "cc" => data["cc"],
 699              "actor" => data["attributedTo"],
 700              "object" => data
 701            },
 702            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 703         {:ok, Object.normalize(activity.data["object"])}
 704       else
 705         object = %Object{} ->
 706           {:ok, object}
 707
 708         _e ->
 709           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 710
 711           case OStatus.fetch_activity_from_url(id) do
 712             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 713             e -> e
 714           end
 715       end
 716     end
 717   end
 718
 719   def is_public?(activity) do
 720     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 721                                                          (activity.data["cc"] || []))
 722   end
 723
 724   def visible_for_user?(activity, nil) do
 725     is_public?(activity)
 726   end
 727
 728   def visible_for_user?(activity, user) do
 729     x = [user.ap_id | user.following]
 730     y = activity.data["to"] ++ (activity.data["cc"] || [])
 731     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 732   end
 733 end