git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.Repo
   3   alias Pleroma.{Activity, Object, Upload}
   4   import Ecto.Query
   5
   6   def insert(map) when is_map(map) do
   7     map = Map.put_new_lazy(map, "id", &generate_activity_id/0)
   8
   9     map = if map["object"] do
  10       object = Map.put_new_lazy(map["object"], "id", &generate_object_id/0)
  11       Map.put(map, "object", object)
  12     else
  13       map
  14     end
  15
  16     Repo.insert(%Activity{data: map})
  17   end
  18
  19   def generate_activity_id do
  20     generate_id("activities")
  21   end
  22
  23   def generate_context_id do
  24     generate_id("contexts")
  25   end
  26
  27   def generate_object_id do
  28     generate_id("objects")
  29   end
  30
  31   def generate_id(type) do
  32     host =
  33       Application.get_env(:pleroma, Pleroma.Web.Endpoint)
  34       |> Keyword.fetch!(:url)
  35       |> Keyword.fetch!(:host)
  36
  37     protocol = Application.get_env(:pleroma, Pleroma.Web.Endpoint) |> Keyword.fetch!(:protocol)
  38     "#{protocol}://#{host}/#{type}/#{Ecto.UUID.generate}"
  39   end
  40
  41   def fetch_public_activities(opts \\ %{}) do
  42     public = ["https://www.w3.org/ns/activitystreams#Public"]
  43     fetch_activities(public, opts)
  44   end
  45
  46   def fetch_activities(recipients, opts \\ %{}) do
  47     since_id = opts["since_id"] || 0
  48
  49     query = from activity in Activity,
  50       limit: 20,
  51       order_by: [desc: :inserted_at]
  52
  53     query = Enum.reduce(recipients, query, fn (recipient, q) ->
  54       map = %{ to: [recipient] }
  55       from activity in q,
  56       or_where: fragment(~s(? @> ?), activity.data, ^map)
  57     end)
  58
  59     query = from activity in query,
  60       where: activity.id > ^since_id
  61
  62     Repo.all(query)
  63     |> Enum.reverse
  64   end
  65
  66   def fetch_activities_for_context(context) do
  67     query = from activity in Activity,
  68       where: fragment("? @> ?", activity.data, ^%{ context: context })
  69     Repo.all(query)
  70   end
  71
  72   def upload(%Plug.Upload{} = file) do
  73     data = Upload.store(file)
  74     Repo.insert(%Object{data: data})
  75   end
  76 end