git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   def get_recipients(data) do
  16     (data["to"] || []) ++ (data["cc"] || [])
  17   end
  18
  19   defp check_actor_is_active(actor) do
  20     if not is_nil(actor) do
  21       with user <- User.get_cached_by_ap_id(actor),
  22            nil <- user.info["deactivated"] do
  23         :ok
  24       else
  25         _e -> :reject
  26       end
  27     else
  28       :ok
  29     end
  30   end
  31
  32   def insert(map, local \\ true) when is_map(map) do
  33     with nil <- Activity.get_by_ap_id(map["id"]),
  34          map <- lazy_put_activity_defaults(map),
  35          :ok <- check_actor_is_active(map["actor"]),
  36          {:ok, map} <- MRF.filter(map),
  37          :ok <- insert_full_object(map) do
  38       {:ok, activity} =
  39         Repo.insert(%Activity{
  40           data: map,
  41           local: local,
  42           actor: map["actor"],
  43           recipients: get_recipients(map)
  44         })
  45
  46       Notification.create_notifications(activity)
  47       stream_out(activity)
  48       {:ok, activity}
  49     else
  50       %Activity{} = activity -> {:ok, activity}
  51       error -> {:error, error}
  52     end
  53   end
  54
  55   def stream_out(activity) do
  56     if activity.data["type"] in ["Create", "Announce"] do
  57       Pleroma.Web.Streamer.stream("user", activity)
  58
  59       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  60         Pleroma.Web.Streamer.stream("public", activity)
  61
  62         if activity.local do
  63           Pleroma.Web.Streamer.stream("public:local", activity)
  64         end
  65       end
  66     end
  67   end
  68
  69   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  70     additional = params[:additional] || %{}
  71     # only accept false as false value
  72     local = !(params[:local] == false)
  73     published = params[:published]
  74
  75     with create_data <-
  76            make_create_data(
  77              %{to: to, actor: actor, published: published, context: context, object: object},
  78              additional
  79            ),
  80          {:ok, activity} <- insert(create_data, local),
  81          :ok <- maybe_federate(activity),
  82          {:ok, _actor} <- User.increase_note_count(actor) do
  83       {:ok, activity}
  84     end
  85   end
  86
  87   def accept(%{to: to, actor: actor, object: object} = params) do
  88     # only accept false as false value
  89     local = !(params[:local] == false)
  90
  91     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  92          {:ok, activity} <- insert(data, local),
  93          :ok <- maybe_federate(activity) do
  94       {:ok, activity}
  95     end
  96   end
  97
  98   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  99     # only accept false as false value
 100     local = !(params[:local] == false)
 101
 102     with data <- %{
 103            "to" => to,
 104            "cc" => cc,
 105            "type" => "Update",
 106            "actor" => actor,
 107            "object" => object
 108          },
 109          {:ok, activity} <- insert(data, local),
 110          :ok <- maybe_federate(activity) do
 111       {:ok, activity}
 112     end
 113   end
 114
 115   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 116   def like(
 117         %User{ap_id: ap_id} = user,
 118         %Object{data: %{"id" => _}} = object,
 119         activity_id \\ nil,
 120         local \\ true
 121       ) do
 122     with nil <- get_existing_like(ap_id, object),
 123          like_data <- make_like_data(user, object, activity_id),
 124          {:ok, activity} <- insert(like_data, local),
 125          {:ok, object} <- add_like_to_object(activity, object),
 126          :ok <- maybe_federate(activity) do
 127       {:ok, activity, object}
 128     else
 129       %Activity{} = activity -> {:ok, activity, object}
 130       error -> {:error, error}
 131     end
 132   end
 133
 134   def unlike(
 135         %User{} = actor,
 136         %Object{} = object,
 137         activity_id \\ nil,
 138         local \\ true
 139       ) do
 140     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 141          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 142          {:ok, unlike_activity} <- insert(unlike_data, local),
 143          {:ok, _activity} <- Repo.delete(like_activity),
 144          {:ok, object} <- remove_like_from_object(like_activity, object),
 145          :ok <- maybe_federate(unlike_activity) do
 146       {:ok, unlike_activity, like_activity, object}
 147     else
 148       _e -> {:ok, object}
 149     end
 150   end
 151
 152   def announce(
 153         %User{ap_id: _} = user,
 154         %Object{data: %{"id" => _}} = object,
 155         activity_id \\ nil,
 156         local \\ true
 157       ) do
 158     with true <- is_public?(object),
 159          announce_data <- make_announce_data(user, object, activity_id),
 160          {:ok, activity} <- insert(announce_data, local),
 161          {:ok, object} <- add_announce_to_object(activity, object),
 162          :ok <- maybe_federate(activity) do
 163       {:ok, activity, object}
 164     else
 165       error -> {:error, error}
 166     end
 167   end
 168
 169   def unannounce(
 170         %User{} = actor,
 171         %Object{} = object,
 172         activity_id \\ nil,
 173         local \\ true
 174       ) do
 175     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 176          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 177          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 178          :ok <- maybe_federate(unannounce_activity),
 179          {:ok, _activity} <- Repo.delete(announce_activity),
 180          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 181       {:ok, unannounce_activity, announce_activity, object}
 182     else
 183       _e -> {:ok, object}
 184     end
 185   end
 186
 187   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 188     with data <- make_follow_data(follower, followed, activity_id),
 189          {:ok, activity} <- insert(data, local),
 190          :ok <- maybe_federate(activity) do
 191       {:ok, activity}
 192     end
 193   end
 194
 195   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 196     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 197          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 198          {:ok, activity} <- insert(unfollow_data, local),
 199          :ok <- maybe_federate(activity) do
 200       {:ok, activity}
 201     end
 202   end
 203
 204   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 205     user = User.get_cached_by_ap_id(actor)
 206
 207     data = %{
 208       "type" => "Delete",
 209       "actor" => actor,
 210       "object" => id,
 211       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 212     }
 213
 214     with Repo.delete(object),
 215          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 216          {:ok, activity} <- insert(data, local),
 217          :ok <- maybe_federate(activity),
 218          {:ok, _actor} <- User.decrease_note_count(user) do
 219       {:ok, activity}
 220     end
 221   end
 222
 223   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 224     follow_activity = fetch_latest_follow(blocker, blocked)
 225
 226     if follow_activity do
 227       unfollow(blocker, blocked, local)
 228     end
 229
 230     with block_data <- make_block_data(blocker, blocked, activity_id),
 231          {:ok, activity} <- insert(block_data, local),
 232          :ok <- maybe_federate(activity) do
 233       {:ok, activity}
 234     end
 235   end
 236
 237   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 238     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 239          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 240          {:ok, activity} <- insert(unblock_data, local),
 241          :ok <- maybe_federate(activity) do
 242       {:ok, activity}
 243     end
 244   end
 245
 246   def fetch_activities_for_context(context, opts \\ %{}) do
 247     public = ["https://www.w3.org/ns/activitystreams#Public"]
 248
 249     recipients =
 250       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 251
 252     query = from(activity in Activity)
 253
 254     query =
 255       query
 256       |> restrict_blocked(opts)
 257       |> restrict_recipients(recipients, opts["user"])
 258
 259     query =
 260       from(
 261         activity in query,
 262         where:
 263           fragment(
 264             "?->>'type' = ? and ?->>'context' = ?",
 265             activity.data,
 266             "Create",
 267             activity.data,
 268             ^context
 269           ),
 270         order_by: [desc: :id]
 271       )
 272
 273     Repo.all(query)
 274   end
 275
 276   def fetch_public_activities(opts \\ %{}) do
 277     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 278
 279     q
 280     |> restrict_unlisted()
 281     |> Repo.all()
 282     |> Enum.reverse()
 283   end
 284
 285   def fetch_user_activities(user, reading_user, params \\ %{}) do
 286     params =
 287       params
 288       |> Map.put("type", ["Create", "Announce"])
 289       |> Map.put("actor_id", user.ap_id)
 290       |> Map.put("whole_db", true)
 291
 292     recipients =
 293       if reading_user do
 294         ["https://www.w3.org/ns/activitystreams#Public"] ++
 295           [reading_user.ap_id | reading_user.following]
 296       else
 297         ["https://www.w3.org/ns/activitystreams#Public"]
 298       end
 299
 300     fetch_activities(recipients, params)
 301     |> Enum.reverse()
 302   end
 303
 304   defp restrict_since(query, %{"since_id" => since_id}) do
 305     from(activity in query, where: activity.id > ^since_id)
 306   end
 307
 308   defp restrict_since(query, _), do: query
 309
 310   defp restrict_tag(query, %{"tag" => tag}) do
 311     from(
 312       activity in query,
 313       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 314     )
 315   end
 316
 317   defp restrict_tag(query, _), do: query
 318
 319   defp restrict_recipients(query, [], _user), do: query
 320
 321   defp restrict_recipients(query, recipients, nil) do
 322     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 323   end
 324
 325   defp restrict_recipients(query, recipients, user) do
 326     from(
 327       activity in query,
 328       where: fragment("? && ?", ^recipients, activity.recipients),
 329       or_where: activity.actor == ^user.ap_id
 330     )
 331   end
 332
 333   defp restrict_limit(query, %{"limit" => limit}) do
 334     from(activity in query, limit: ^limit)
 335   end
 336
 337   defp restrict_limit(query, _), do: query
 338
 339   defp restrict_local(query, %{"local_only" => true}) do
 340     from(activity in query, where: activity.local == true)
 341   end
 342
 343   defp restrict_local(query, _), do: query
 344
 345   defp restrict_max(query, %{"max_id" => max_id}) do
 346     from(activity in query, where: activity.id < ^max_id)
 347   end
 348
 349   defp restrict_max(query, _), do: query
 350
 351   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 352     from(activity in query, where: activity.actor == ^actor_id)
 353   end
 354
 355   defp restrict_actor(query, _), do: query
 356
 357   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 358     restrict_type(query, %{"type" => [type]})
 359   end
 360
 361   defp restrict_type(query, %{"type" => type}) do
 362     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 363   end
 364
 365   defp restrict_type(query, _), do: query
 366
 367   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 368     from(
 369       activity in query,
 370       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 371     )
 372   end
 373
 374   defp restrict_favorited_by(query, _), do: query
 375
 376   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 377     from(
 378       activity in query,
 379       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 380     )
 381   end
 382
 383   defp restrict_media(query, _), do: query
 384
 385   # Only search through last 100_000 activities by default
 386   defp restrict_recent(query, %{"whole_db" => true}), do: query
 387
 388   defp restrict_recent(query, _) do
 389     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 390
 391     from(activity in query, where: activity.id > ^since)
 392   end
 393
 394   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 395     blocks = info["blocks"] || []
 396
 397     from(
 398       activity in query,
 399       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 400       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks)
 401     )
 402   end
 403
 404   defp restrict_blocked(query, _), do: query
 405
 406   defp restrict_unlisted(query) do
 407     from(
 408       activity in query,
 409       where:
 410         fragment(
 411           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 412           activity.data,
 413           ^["https://www.w3.org/ns/activitystreams#Public"]
 414         )
 415     )
 416   end
 417
 418   def fetch_activities_query(recipients, opts \\ %{}) do
 419     base_query =
 420       from(
 421         activity in Activity,
 422         limit: 20,
 423         order_by: [fragment("? desc nulls last", activity.id)]
 424       )
 425
 426     base_query
 427     |> restrict_recipients(recipients, opts["user"])
 428     |> restrict_tag(opts)
 429     |> restrict_since(opts)
 430     |> restrict_local(opts)
 431     |> restrict_limit(opts)
 432     |> restrict_max(opts)
 433     |> restrict_actor(opts)
 434     |> restrict_type(opts)
 435     |> restrict_favorited_by(opts)
 436     |> restrict_recent(opts)
 437     |> restrict_blocked(opts)
 438     |> restrict_media(opts)
 439   end
 440
 441   def fetch_activities(recipients, opts \\ %{}) do
 442     fetch_activities_query(recipients, opts)
 443     |> Repo.all()
 444     |> Enum.reverse()
 445   end
 446
 447   def upload(file) do
 448     data = Upload.store(file)
 449     Repo.insert(%Object{data: data})
 450   end
 451
 452   def user_data_from_user_object(data) do
 453     avatar =
 454       data["icon"]["url"] &&
 455         %{
 456           "type" => "Image",
 457           "url" => [%{"href" => data["icon"]["url"]}]
 458         }
 459
 460     banner =
 461       data["image"]["url"] &&
 462         %{
 463           "type" => "Image",
 464           "url" => [%{"href" => data["image"]["url"]}]
 465         }
 466
 467     data = Transmogrifier.maybe_fix_user_object(data)
 468
 469     user_data = %{
 470       ap_id: data["id"],
 471       info: %{
 472         "ap_enabled" => true,
 473         "source_data" => data,
 474         "banner" => banner
 475       },
 476       avatar: avatar,
 477       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 478       name: data["name"],
 479       follower_address: data["followers"],
 480       bio: data["summary"]
 481     }
 482
 483     {:ok, user_data}
 484   end
 485
 486   def fetch_and_prepare_user_from_ap_id(ap_id) do
 487     with {:ok, %{status_code: 200, body: body}} <-
 488            @httpoison.get(ap_id, Accept: "application/activity+json"),
 489          {:ok, data} <- Jason.decode(body) do
 490       user_data_from_user_object(data)
 491     else
 492       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 493     end
 494   end
 495
 496   def make_user_from_ap_id(ap_id) do
 497     if _user = User.get_by_ap_id(ap_id) do
 498       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 499     else
 500       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 501         User.insert_or_update_user(data)
 502       else
 503         e -> {:error, e}
 504       end
 505     end
 506   end
 507
 508   def make_user_from_nickname(nickname) do
 509     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 510       make_user_from_ap_id(ap_id)
 511     else
 512       _e -> {:error, "No AP id in WebFinger"}
 513     end
 514   end
 515
 516   def publish(actor, activity) do
 517     followers =
 518       if actor.follower_address in activity.recipients do
 519         {:ok, followers} = User.get_followers(actor)
 520         followers |> Enum.filter(&(!&1.local))
 521       else
 522         []
 523       end
 524
 525     remote_inboxes =
 526       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 527       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 528       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 529         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 530       end)
 531       |> Enum.uniq()
 532
 533     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 534     json = Jason.encode!(data)
 535
 536     Enum.each(remote_inboxes, fn inbox ->
 537       Federator.enqueue(:publish_single_ap, %{
 538         inbox: inbox,
 539         json: json,
 540         actor: actor,
 541         id: activity.data["id"]
 542       })
 543     end)
 544   end
 545
 546   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 547     Logger.info("Federating #{id} to #{inbox}")
 548     host = URI.parse(inbox).host
 549
 550     signature =
 551       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 552
 553     @httpoison.post(
 554       inbox,
 555       json,
 556       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 557       hackney: [pool: :default]
 558     )
 559   end
 560
 561   # TODO:
 562   # This will create a Create activity, which we need internally at the moment.
 563   def fetch_object_from_id(id) do
 564     if object = Object.get_cached_by_ap_id(id) do
 565       {:ok, object}
 566     else
 567       Logger.info("Fetching #{id} via AP")
 568
 569       with true <- String.starts_with?(id, "http"),
 570            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 571              @httpoison.get(
 572                id,
 573                [Accept: "application/activity+json"],
 574                follow_redirect: true,
 575                timeout: 10000,
 576                recv_timeout: 20000
 577              ),
 578            {:ok, data} <- Jason.decode(body),
 579            nil <- Object.get_by_ap_id(data["id"]),
 580            params <- %{
 581              "type" => "Create",
 582              "to" => data["to"],
 583              "cc" => data["cc"],
 584              "actor" => data["attributedTo"],
 585              "object" => data
 586            },
 587            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 588         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 589       else
 590         object = %Object{} ->
 591           {:ok, object}
 592
 593         _e ->
 594           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 595
 596           case OStatus.fetch_activity_from_url(id) do
 597             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 598             e -> e
 599           end
 600       end
 601     end
 602   end
 603
 604   def is_public?(activity) do
 605     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 606                                                          (activity.data["cc"] || []))
 607   end
 608
 609   def visible_for_user?(activity, nil) do
 610     is_public?(activity)
 611   end
 612
 613   def visible_for_user?(activity, user) do
 614     x = [user.ap_id | user.following]
 615     y = activity.data["to"] ++ (activity.data["cc"] || [])
 616     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 617   end
 618 end