git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   def get_recipients(data) do
  14     (data["to"] || []) ++ (data["cc"] || [])
  15   end
  16
  17   def insert(map, local \\ true) when is_map(map) do
  18     with nil <- Activity.get_by_ap_id(map["id"]),
  19          map <- lazy_put_activity_defaults(map),
  20          :ok <- insert_full_object(map) do
  21       {:ok, activity} =
  22         Repo.insert(%Activity{
  23           data: map,
  24           local: local,
  25           actor: map["actor"],
  26           recipients: get_recipients(map)
  27         })
  28
  29       Notification.create_notifications(activity)
  30       stream_out(activity)
  31       {:ok, activity}
  32     else
  33       %Activity{} = activity -> {:ok, activity}
  34       error -> {:error, error}
  35     end
  36   end
  37
  38   def stream_out(activity) do
  39     if activity.data["type"] in ["Create", "Announce"] do
  40       Pleroma.Web.Streamer.stream("user", activity)
  41
  42       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  43         Pleroma.Web.Streamer.stream("public", activity)
  44
  45         if activity.local do
  46           Pleroma.Web.Streamer.stream("public:local", activity)
  47         end
  48       end
  49     end
  50   end
  51
  52   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  53     additional = params[:additional] || %{}
  54     # only accept false as false value
  55     local = !(params[:local] == false)
  56     published = params[:published]
  57
  58     with create_data <-
  59            make_create_data(
  60              %{to: to, actor: actor, published: published, context: context, object: object},
  61              additional
  62            ),
  63          {:ok, activity} <- insert(create_data, local),
  64          :ok <- maybe_federate(activity) do
  65       {:ok, activity}
  66     end
  67   end
  68
  69   def accept(%{to: to, actor: actor, object: object} = params) do
  70     # only accept false as false value
  71     local = !(params[:local] == false)
  72
  73     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  74          {:ok, activity} <- insert(data, local),
  75          :ok <- maybe_federate(activity) do
  76       {:ok, activity}
  77     end
  78   end
  79
  80   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  81     # only accept false as false value
  82     local = !(params[:local] == false)
  83
  84     with data <- %{
  85            "to" => to,
  86            "cc" => cc,
  87            "type" => "Update",
  88            "actor" => actor,
  89            "object" => object
  90          },
  91          {:ok, activity} <- insert(data, local),
  92          :ok <- maybe_federate(activity) do
  93       {:ok, activity}
  94     end
  95   end
  96
  97   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
  98   def like(
  99         %User{ap_id: ap_id} = user,
 100         %Object{data: %{"id" => _}} = object,
 101         activity_id \\ nil,
 102         local \\ true
 103       ) do
 104     with nil <- get_existing_like(ap_id, object),
 105          like_data <- make_like_data(user, object, activity_id),
 106          {:ok, activity} <- insert(like_data, local),
 107          {:ok, object} <- add_like_to_object(activity, object),
 108          :ok <- maybe_federate(activity) do
 109       {:ok, activity, object}
 110     else
 111       %Activity{} = activity -> {:ok, activity, object}
 112       error -> {:error, error}
 113     end
 114   end
 115
 116   def unlike(%User{} = actor, %Object{} = object) do
 117     with %Activity{} = activity <- get_existing_like(actor.ap_id, object),
 118          {:ok, _activity} <- Repo.delete(activity),
 119          {:ok, object} <- remove_like_from_object(activity, object) do
 120       {:ok, object}
 121     else
 122       _e -> {:ok, object}
 123     end
 124   end
 125
 126   def announce(
 127         %User{ap_id: _} = user,
 128         %Object{data: %{"id" => _}} = object,
 129         activity_id \\ nil,
 130         local \\ true
 131       ) do
 132     with true <- is_public?(object),
 133          announce_data <- make_announce_data(user, object, activity_id),
 134          {:ok, activity} <- insert(announce_data, local),
 135          {:ok, object} <- add_announce_to_object(activity, object),
 136          :ok <- maybe_federate(activity) do
 137       {:ok, activity, object}
 138     else
 139       error -> {:error, error}
 140     end
 141   end
 142
 143   def unannounce(%User{} = actor, %Object{} = object) do
 144     with %Activity{} = activity <- get_existing_announce(actor.ap_id, object),
 145          {:ok, _activity} <- Repo.delete(activity),
 146          {:ok, object} <- remove_announce_from_object(activity, object) do
 147       {:ok, object}
 148     else
 149       _e -> {:ok, object}
 150     end
 151   end
 152
 153   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 154     with data <- make_follow_data(follower, followed, activity_id),
 155          {:ok, activity} <- insert(data, local),
 156          :ok <- maybe_federate(activity) do
 157       {:ok, activity}
 158     end
 159   end
 160
 161   def unfollow(follower, followed, local \\ true) do
 162     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 163          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
 164          {:ok, activity} <- insert(unfollow_data, local),
 165          :ok,
 166          maybe_federate(activity) do
 167       {:ok, activity}
 168     end
 169   end
 170
 171   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 172     user = User.get_cached_by_ap_id(actor)
 173
 174     data = %{
 175       "type" => "Delete",
 176       "actor" => actor,
 177       "object" => id,
 178       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 179     }
 180
 181     with Repo.delete(object),
 182          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 183          {:ok, activity} <- insert(data, local),
 184          :ok <- maybe_federate(activity) do
 185       {:ok, activity}
 186     end
 187   end
 188
 189   def fetch_activities_for_context(context, opts \\ %{}) do
 190     public = ["https://www.w3.org/ns/activitystreams#Public"]
 191
 192     recipients =
 193       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 194
 195     query = from(activity in Activity)
 196
 197     query =
 198       query
 199       |> restrict_blocked(opts)
 200       |> restrict_recipients(recipients, opts["user"])
 201
 202     query =
 203       from(
 204         activity in query,
 205         where:
 206           fragment(
 207             "?->>'type' = ? and ?->>'context' = ?",
 208             activity.data,
 209             "Create",
 210             activity.data,
 211             ^context
 212           ),
 213         order_by: [desc: :id]
 214       )
 215
 216     Repo.all(query)
 217   end
 218
 219   # TODO: Make this work properly with unlisted.
 220   def fetch_public_activities(opts \\ %{}) do
 221     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 222
 223     q
 224     |> Repo.all()
 225     |> Enum.reverse()
 226   end
 227
 228   defp restrict_since(query, %{"since_id" => since_id}) do
 229     from(activity in query, where: activity.id > ^since_id)
 230   end
 231
 232   defp restrict_since(query, _), do: query
 233
 234   defp restrict_tag(query, %{"tag" => tag}) do
 235     from(
 236       activity in query,
 237       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 238     )
 239   end
 240
 241   defp restrict_tag(query, _), do: query
 242
 243   defp restrict_recipients(query, [], user), do: query
 244
 245   defp restrict_recipients(query, recipients, nil) do
 246     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 247   end
 248
 249   defp restrict_recipients(query, recipients, user) do
 250     from(
 251       activity in query,
 252       where: fragment("? && ?", ^recipients, activity.recipients),
 253       or_where: activity.actor == ^user.ap_id
 254     )
 255   end
 256
 257   defp restrict_limit(query, %{"limit" => limit}) do
 258     from(activity in query, limit: ^limit)
 259   end
 260
 261   defp restrict_limit(query, _), do: query
 262
 263   defp restrict_local(query, %{"local_only" => true}) do
 264     from(activity in query, where: activity.local == true)
 265   end
 266
 267   defp restrict_local(query, _), do: query
 268
 269   defp restrict_max(query, %{"max_id" => max_id}) do
 270     from(activity in query, where: activity.id < ^max_id)
 271   end
 272
 273   defp restrict_max(query, _), do: query
 274
 275   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 276     from(activity in query, where: activity.actor == ^actor_id)
 277   end
 278
 279   defp restrict_actor(query, _), do: query
 280
 281   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 282     restrict_type(query, %{"type" => [type]})
 283   end
 284
 285   defp restrict_type(query, %{"type" => type}) do
 286     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 287   end
 288
 289   defp restrict_type(query, _), do: query
 290
 291   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 292     from(
 293       activity in query,
 294       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 295     )
 296   end
 297
 298   defp restrict_favorited_by(query, _), do: query
 299
 300   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 301     from(
 302       activity in query,
 303       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 304     )
 305   end
 306
 307   defp restrict_media(query, _), do: query
 308
 309   # Only search through last 100_000 activities by default
 310   defp restrict_recent(query, %{"whole_db" => true}), do: query
 311
 312   defp restrict_recent(query, _) do
 313     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 314
 315     from(activity in query, where: activity.id > ^since)
 316   end
 317
 318   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 319     blocks = info["blocks"] || []
 320     from(activity in query, where: fragment("not (? = ANY(?))", activity.actor, ^blocks))
 321   end
 322
 323   defp restrict_blocked(query, _), do: query
 324
 325   def fetch_activities_query(recipients, opts \\ %{}) do
 326     base_query =
 327       from(
 328         activity in Activity,
 329         limit: 20,
 330         order_by: [fragment("? desc nulls last", activity.id)]
 331       )
 332
 333     base_query
 334     |> restrict_recipients(recipients, opts["user"])
 335     |> restrict_tag(opts)
 336     |> restrict_since(opts)
 337     |> restrict_local(opts)
 338     |> restrict_limit(opts)
 339     |> restrict_max(opts)
 340     |> restrict_actor(opts)
 341     |> restrict_type(opts)
 342     |> restrict_favorited_by(opts)
 343     |> restrict_recent(opts)
 344     |> restrict_blocked(opts)
 345     |> restrict_media(opts)
 346   end
 347
 348   def fetch_activities(recipients, opts \\ %{}) do
 349     fetch_activities_query(recipients, opts)
 350     |> Repo.all()
 351     |> Enum.reverse()
 352   end
 353
 354   def upload(file) do
 355     data = Upload.store(file)
 356     Repo.insert(%Object{data: data})
 357   end
 358
 359   def user_data_from_user_object(data) do
 360     avatar =
 361       data["icon"]["url"] &&
 362         %{
 363           "type" => "Image",
 364           "url" => [%{"href" => data["icon"]["url"]}]
 365         }
 366
 367     banner =
 368       data["image"]["url"] &&
 369         %{
 370           "type" => "Image",
 371           "url" => [%{"href" => data["image"]["url"]}]
 372         }
 373
 374     user_data = %{
 375       ap_id: data["id"],
 376       info: %{
 377         "ap_enabled" => true,
 378         "source_data" => data,
 379         "banner" => banner
 380       },
 381       avatar: avatar,
 382       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 383       name: data["name"],
 384       follower_address: data["followers"],
 385       bio: data["summary"]
 386     }
 387
 388     {:ok, user_data}
 389   end
 390
 391   def fetch_and_prepare_user_from_ap_id(ap_id) do
 392     with {:ok, %{status_code: 200, body: body}} <-
 393            @httpoison.get(ap_id, Accept: "application/activity+json"),
 394          {:ok, data} <- Jason.decode(body) do
 395       user_data_from_user_object(data)
 396     else
 397       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 398     end
 399   end
 400
 401   def make_user_from_ap_id(ap_id) do
 402     if user = User.get_by_ap_id(ap_id) do
 403       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 404     else
 405       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 406         User.insert_or_update_user(data)
 407       else
 408         e -> {:error, e}
 409       end
 410     end
 411   end
 412
 413   def make_user_from_nickname(nickname) do
 414     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 415       make_user_from_ap_id(ap_id)
 416     else
 417       _e -> {:error, "No AP id in WebFinger"}
 418     end
 419   end
 420
 421   def publish(actor, activity) do
 422     followers =
 423       if actor.follower_address in activity.recipients do
 424         {:ok, followers} = User.get_followers(actor)
 425         followers |> Enum.filter(&(!&1.local))
 426       else
 427         []
 428       end
 429
 430     remote_inboxes =
 431       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 432       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 433       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 434         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 435       end)
 436       |> Enum.uniq()
 437
 438     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 439     json = Jason.encode!(data)
 440
 441     Enum.each(remote_inboxes, fn inbox ->
 442       Federator.enqueue(:publish_single_ap, %{
 443         inbox: inbox,
 444         json: json,
 445         actor: actor,
 446         id: activity.data["id"]
 447       })
 448     end)
 449   end
 450
 451   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 452     Logger.info("Federating #{id} to #{inbox}")
 453     host = URI.parse(inbox).host
 454
 455     signature =
 456       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 457
 458     @httpoison.post(
 459       inbox,
 460       json,
 461       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 462       hackney: [pool: :default]
 463     )
 464   end
 465
 466   # TODO:
 467   # This will create a Create activity, which we need internally at the moment.
 468   def fetch_object_from_id(id) do
 469     if object = Object.get_cached_by_ap_id(id) do
 470       {:ok, object}
 471     else
 472       Logger.info("Fetching #{id} via AP")
 473
 474       with true <- String.starts_with?(id, "http"),
 475            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 476              @httpoison.get(
 477                id,
 478                [Accept: "application/activity+json"],
 479                follow_redirect: true,
 480                timeout: 10000,
 481                recv_timeout: 20000
 482              ),
 483            {:ok, data} <- Jason.decode(body),
 484            nil <- Object.get_by_ap_id(data["id"]),
 485            params <- %{
 486              "type" => "Create",
 487              "to" => data["to"],
 488              "cc" => data["cc"],
 489              "actor" => data["attributedTo"],
 490              "object" => data
 491            },
 492            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 493         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 494       else
 495         object = %Object{} ->
 496           {:ok, object}
 497
 498         e ->
 499           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 500
 501           case OStatus.fetch_activity_from_url(id) do
 502             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 503             e -> e
 504           end
 505       end
 506     end
 507   end
 508
 509   def is_public?(activity) do
 510     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 511                                                          (activity.data["cc"] || []))
 512   end
 513
 514   def visible_for_user?(activity, nil) do
 515     is_public?(activity)
 516   end
 517
 518   def visible_for_user?(activity, user) do
 519     x = [user.ap_id | user.following]
 520     y = activity.data["to"] ++ (activity.data["cc"] || [])
 521     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 522   end
 523 end