git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   # For Announce activities, we filter the recipients based on following status for any actors
  16   # that match actual users.  See issue #164 for more information about why this is necessary.
  17   def get_recipients(%{"type" => "Announce"} = data) do
  18     recipients = (data["to"] || []) ++ (data["cc"] || [])
  19     actor = User.get_cached_by_ap_id(data["actor"])
  20
  21     recipients
  22     |> Enum.filter(fn recipient ->
  23       case User.get_cached_by_ap_id(recipient) do
  24         nil ->
  25           true
  26
  27         user ->
  28           User.following?(user, actor)
  29       end
  30     end)
  31   end
  32
  33   def get_recipients(data) do
  34     (data["to"] || []) ++ (data["cc"] || [])
  35   end
  36
  37   defp check_actor_is_active(actor) do
  38     if not is_nil(actor) do
  39       with user <- User.get_cached_by_ap_id(actor),
  40            nil <- user.info["deactivated"] do
  41         :ok
  42       else
  43         _e -> :reject
  44       end
  45     else
  46       :ok
  47     end
  48   end
  49
  50   def insert(map, local \\ true) when is_map(map) do
  51     with nil <- Activity.normalize(map),
  52          map <- lazy_put_activity_defaults(map),
  53          :ok <- check_actor_is_active(map["actor"]),
  54          {:ok, map} <- MRF.filter(map),
  55          :ok <- insert_full_object(map) do
  56       {:ok, activity} =
  57         Repo.insert(%Activity{
  58           data: map,
  59           local: local,
  60           actor: map["actor"],
  61           recipients: get_recipients(map)
  62         })
  63
  64       Notification.create_notifications(activity)
  65       stream_out(activity)
  66       {:ok, activity}
  67     else
  68       %Activity{} = activity -> {:ok, activity}
  69       error -> {:error, error}
  70     end
  71   end
  72
  73   def stream_out(activity) do
  74     public = "https://www.w3.org/ns/activitystreams#Public"
  75
  76     if activity.data["type"] in ["Create", "Announce"] do
  77       Pleroma.Web.Streamer.stream("user", activity)
  78       Pleroma.Web.Streamer.stream("list", activity)
  79
  80       if Enum.member?(activity.data["to"], public) do
  81         Pleroma.Web.Streamer.stream("public", activity)
  82
  83         if activity.local do
  84           Pleroma.Web.Streamer.stream("public:local", activity)
  85         end
  86
  87         activity.data["object"]["tag"]
  88         |> Enum.map(fn tag -> Pleroma.Web.Streamer.stream("hashtag:" <> tag, activity) end)
  89
  90         if activity.data["object"]["attachment"] != [] do
  91           Pleroma.Web.Streamer.stream("public:media", activity)
  92
  93           if activity.local do
  94             Pleroma.Web.Streamer.stream("public:local:media", activity)
  95           end
  96         end
  97       else
  98         if !Enum.member?(activity.data["cc"] || [], public) &&
  99              !Enum.member?(
 100                activity.data["to"],
 101                User.get_by_ap_id(activity.data["actor"]).follower_address
 102              ),
 103            do: Pleroma.Web.Streamer.stream("direct", activity)
 104       end
 105     end
 106   end
 107
 108   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 109     additional = params[:additional] || %{}
 110     # only accept false as false value
 111     local = !(params[:local] == false)
 112     published = params[:published]
 113
 114     with create_data <-
 115            make_create_data(
 116              %{to: to, actor: actor, published: published, context: context, object: object},
 117              additional
 118            ),
 119          {:ok, activity} <- insert(create_data, local),
 120          :ok <- maybe_federate(activity),
 121          {:ok, _actor} <- User.increase_note_count(actor) do
 122       {:ok, activity}
 123     end
 124   end
 125
 126   def accept(%{to: to, actor: actor, object: object} = params) do
 127     # only accept false as false value
 128     local = !(params[:local] == false)
 129
 130     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 131          {:ok, activity} <- insert(data, local),
 132          :ok <- maybe_federate(activity) do
 133       {:ok, activity}
 134     end
 135   end
 136
 137   def reject(%{to: to, actor: actor, object: object} = params) do
 138     # only accept false as false value
 139     local = !(params[:local] == false)
 140
 141     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 142          {:ok, activity} <- insert(data, local),
 143          :ok <- maybe_federate(activity) do
 144       {:ok, activity}
 145     end
 146   end
 147
 148   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 149     # only accept false as false value
 150     local = !(params[:local] == false)
 151
 152     with data <- %{
 153            "to" => to,
 154            "cc" => cc,
 155            "type" => "Update",
 156            "actor" => actor,
 157            "object" => object
 158          },
 159          {:ok, activity} <- insert(data, local),
 160          :ok <- maybe_federate(activity) do
 161       {:ok, activity}
 162     end
 163   end
 164
 165   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 166   def like(
 167         %User{ap_id: ap_id} = user,
 168         %Object{data: %{"id" => _}} = object,
 169         activity_id \\ nil,
 170         local \\ true
 171       ) do
 172     with nil <- get_existing_like(ap_id, object),
 173          like_data <- make_like_data(user, object, activity_id),
 174          {:ok, activity} <- insert(like_data, local),
 175          {:ok, object} <- add_like_to_object(activity, object),
 176          :ok <- maybe_federate(activity) do
 177       {:ok, activity, object}
 178     else
 179       %Activity{} = activity -> {:ok, activity, object}
 180       error -> {:error, error}
 181     end
 182   end
 183
 184   def unlike(
 185         %User{} = actor,
 186         %Object{} = object,
 187         activity_id \\ nil,
 188         local \\ true
 189       ) do
 190     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 191          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 192          {:ok, unlike_activity} <- insert(unlike_data, local),
 193          {:ok, _activity} <- Repo.delete(like_activity),
 194          {:ok, object} <- remove_like_from_object(like_activity, object),
 195          :ok <- maybe_federate(unlike_activity) do
 196       {:ok, unlike_activity, like_activity, object}
 197     else
 198       _e -> {:ok, object}
 199     end
 200   end
 201
 202   def announce(
 203         %User{ap_id: _} = user,
 204         %Object{data: %{"id" => _}} = object,
 205         activity_id \\ nil,
 206         local \\ true
 207       ) do
 208     with true <- is_public?(object),
 209          announce_data <- make_announce_data(user, object, activity_id),
 210          {:ok, activity} <- insert(announce_data, local),
 211          {:ok, object} <- add_announce_to_object(activity, object),
 212          :ok <- maybe_federate(activity) do
 213       {:ok, activity, object}
 214     else
 215       error -> {:error, error}
 216     end
 217   end
 218
 219   def unannounce(
 220         %User{} = actor,
 221         %Object{} = object,
 222         activity_id \\ nil,
 223         local \\ true
 224       ) do
 225     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 226          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 227          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 228          :ok <- maybe_federate(unannounce_activity),
 229          {:ok, _activity} <- Repo.delete(announce_activity),
 230          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 231       {:ok, unannounce_activity, object}
 232     else
 233       _e -> {:ok, object}
 234     end
 235   end
 236
 237   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 238     with data <- make_follow_data(follower, followed, activity_id),
 239          {:ok, activity} <- insert(data, local),
 240          :ok <- maybe_federate(activity) do
 241       {:ok, activity}
 242     end
 243   end
 244
 245   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 246     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 247          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 248          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 249          {:ok, activity} <- insert(unfollow_data, local),
 250          :ok <- maybe_federate(activity) do
 251       {:ok, activity}
 252     end
 253   end
 254
 255   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 256     user = User.get_cached_by_ap_id(actor)
 257
 258     data = %{
 259       "type" => "Delete",
 260       "actor" => actor,
 261       "object" => id,
 262       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 263     }
 264
 265     with Repo.delete(object),
 266          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 267          {:ok, activity} <- insert(data, local),
 268          :ok <- maybe_federate(activity),
 269          {:ok, _actor} <- User.decrease_note_count(user) do
 270       {:ok, activity}
 271     end
 272   end
 273
 274   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 275     ap_config = Application.get_env(:pleroma, :activitypub)
 276     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 277     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 278
 279     with true <- unfollow_blocked do
 280       follow_activity = fetch_latest_follow(blocker, blocked)
 281
 282       if follow_activity do
 283         unfollow(blocker, blocked, nil, local)
 284       end
 285     end
 286
 287     with true <- outgoing_blocks,
 288          block_data <- make_block_data(blocker, blocked, activity_id),
 289          {:ok, activity} <- insert(block_data, local),
 290          :ok <- maybe_federate(activity) do
 291       {:ok, activity}
 292     else
 293       _e -> {:ok, nil}
 294     end
 295   end
 296
 297   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 298     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 299          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 300          {:ok, activity} <- insert(unblock_data, local),
 301          :ok <- maybe_federate(activity) do
 302       {:ok, activity}
 303     end
 304   end
 305
 306   def fetch_activities_for_context(context, opts \\ %{}) do
 307     public = ["https://www.w3.org/ns/activitystreams#Public"]
 308
 309     recipients =
 310       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 311
 312     query = from(activity in Activity)
 313
 314     query =
 315       query
 316       |> restrict_blocked(opts)
 317       |> restrict_recipients(recipients, opts["user"])
 318
 319     query =
 320       from(
 321         activity in query,
 322         where:
 323           fragment(
 324             "?->>'type' = ? and ?->>'context' = ?",
 325             activity.data,
 326             "Create",
 327             activity.data,
 328             ^context
 329           ),
 330         order_by: [desc: :id]
 331       )
 332
 333     Repo.all(query)
 334   end
 335
 336   def fetch_public_activities(opts \\ %{}) do
 337     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 338
 339     q
 340     |> restrict_unlisted()
 341     |> Repo.all()
 342     |> Enum.reverse()
 343   end
 344
 345   @valid_visibilities ~w[direct unlisted public private]
 346
 347   defp restrict_visibility(query, %{visibility: "direct"}) do
 348     public = "https://www.w3.org/ns/activitystreams#Public"
 349
 350     from(
 351       activity in query,
 352       join: sender in User,
 353       on: sender.ap_id == activity.actor,
 354       # Are non-direct statuses with no to/cc possible?
 355       where:
 356         fragment(
 357           "not (? && ?)",
 358           [^public, sender.follower_address],
 359           activity.recipients
 360         )
 361     )
 362   end
 363
 364   defp restrict_visibility(_query, %{visibility: visibility})
 365        when visibility not in @valid_visibilities do
 366     Logger.error("Could not restrict visibility to #{visibility}")
 367   end
 368
 369   defp restrict_visibility(query, _visibility), do: query
 370
 371   def fetch_user_activities(user, reading_user, params \\ %{}) do
 372     params =
 373       params
 374       |> Map.put("type", ["Create", "Announce"])
 375       |> Map.put("actor_id", user.ap_id)
 376       |> Map.put("whole_db", true)
 377
 378     recipients =
 379       if reading_user do
 380         ["https://www.w3.org/ns/activitystreams#Public"] ++
 381           [reading_user.ap_id | reading_user.following]
 382       else
 383         ["https://www.w3.org/ns/activitystreams#Public"]
 384       end
 385
 386     fetch_activities(recipients, params)
 387     |> Enum.reverse()
 388   end
 389
 390   defp restrict_since(query, %{"since_id" => since_id}) do
 391     from(activity in query, where: activity.id > ^since_id)
 392   end
 393
 394   defp restrict_since(query, _), do: query
 395
 396   defp restrict_tag(query, %{"tag" => tag}) do
 397     from(
 398       activity in query,
 399       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 400     )
 401   end
 402
 403   defp restrict_tag(query, _), do: query
 404
 405   defp restrict_recipients(query, [], _user), do: query
 406
 407   defp restrict_recipients(query, recipients, nil) do
 408     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 409   end
 410
 411   defp restrict_recipients(query, recipients, user) do
 412     from(
 413       activity in query,
 414       where: fragment("? && ?", ^recipients, activity.recipients),
 415       or_where: activity.actor == ^user.ap_id
 416     )
 417   end
 418
 419   defp restrict_limit(query, %{"limit" => limit}) do
 420     from(activity in query, limit: ^limit)
 421   end
 422
 423   defp restrict_limit(query, _), do: query
 424
 425   defp restrict_local(query, %{"local_only" => true}) do
 426     from(activity in query, where: activity.local == true)
 427   end
 428
 429   defp restrict_local(query, _), do: query
 430
 431   defp restrict_max(query, %{"max_id" => max_id}) do
 432     from(activity in query, where: activity.id < ^max_id)
 433   end
 434
 435   defp restrict_max(query, _), do: query
 436
 437   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 438     from(activity in query, where: activity.actor == ^actor_id)
 439   end
 440
 441   defp restrict_actor(query, _), do: query
 442
 443   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 444     restrict_type(query, %{"type" => [type]})
 445   end
 446
 447   defp restrict_type(query, %{"type" => type}) do
 448     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 449   end
 450
 451   defp restrict_type(query, _), do: query
 452
 453   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 454     from(
 455       activity in query,
 456       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 457     )
 458   end
 459
 460   defp restrict_favorited_by(query, _), do: query
 461
 462   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 463     from(
 464       activity in query,
 465       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 466     )
 467   end
 468
 469   defp restrict_media(query, _), do: query
 470
 471   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 472     from(
 473       activity in query,
 474       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 475     )
 476   end
 477
 478   defp restrict_replies(query, _), do: query
 479
 480   # Only search through last 100_000 activities by default
 481   defp restrict_recent(query, %{"whole_db" => true}), do: query
 482
 483   defp restrict_recent(query, _) do
 484     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 485
 486     from(activity in query, where: activity.id > ^since)
 487   end
 488
 489   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 490     blocks = info["blocks"] || []
 491     domain_blocks = info["domain_blocks"] || []
 492
 493     from(
 494       activity in query,
 495       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 496       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 497       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 498     )
 499   end
 500
 501   defp restrict_blocked(query, _), do: query
 502
 503   defp restrict_unlisted(query) do
 504     from(
 505       activity in query,
 506       where:
 507         fragment(
 508           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 509           activity.data,
 510           ^["https://www.w3.org/ns/activitystreams#Public"]
 511         )
 512     )
 513   end
 514
 515   def fetch_activities_query(recipients, opts \\ %{}) do
 516     base_query =
 517       from(
 518         activity in Activity,
 519         limit: 20,
 520         order_by: [fragment("? desc nulls last", activity.id)]
 521       )
 522
 523     base_query
 524     |> restrict_recipients(recipients, opts["user"])
 525     |> restrict_tag(opts)
 526     |> restrict_since(opts)
 527     |> restrict_local(opts)
 528     |> restrict_limit(opts)
 529     |> restrict_max(opts)
 530     |> restrict_actor(opts)
 531     |> restrict_type(opts)
 532     |> restrict_favorited_by(opts)
 533     |> restrict_recent(opts)
 534     |> restrict_blocked(opts)
 535     |> restrict_media(opts)
 536     |> restrict_visibility(opts)
 537     |> restrict_replies(opts)
 538   end
 539
 540   def fetch_activities(recipients, opts \\ %{}) do
 541     fetch_activities_query(recipients, opts)
 542     |> Repo.all()
 543     |> Enum.reverse()
 544   end
 545
 546   def upload(file) do
 547     data = Upload.store(file, Application.get_env(:pleroma, :instance)[:dedupe_media])
 548     Repo.insert(%Object{data: data})
 549   end
 550
 551   def user_data_from_user_object(data) do
 552     avatar =
 553       data["icon"]["url"] &&
 554         %{
 555           "type" => "Image",
 556           "url" => [%{"href" => data["icon"]["url"]}]
 557         }
 558
 559     banner =
 560       data["image"]["url"] &&
 561         %{
 562           "type" => "Image",
 563           "url" => [%{"href" => data["image"]["url"]}]
 564         }
 565
 566     locked = data["manuallyApprovesFollowers"] || false
 567     data = Transmogrifier.maybe_fix_user_object(data)
 568
 569     user_data = %{
 570       ap_id: data["id"],
 571       info: %{
 572         "ap_enabled" => true,
 573         "source_data" => data,
 574         "banner" => banner,
 575         "locked" => locked
 576       },
 577       avatar: avatar,
 578       name: data["name"],
 579       follower_address: data["followers"],
 580       bio: data["summary"]
 581     }
 582
 583     # nickname can be nil because of virtual actors
 584     user_data =
 585       if data["preferredUsername"] do
 586         Map.put(
 587           user_data,
 588           :nickname,
 589           "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}"
 590         )
 591       else
 592         Map.put(user_data, :nickname, nil)
 593       end
 594
 595     {:ok, user_data}
 596   end
 597
 598   def fetch_and_prepare_user_from_ap_id(ap_id) do
 599     with {:ok, %{status_code: 200, body: body}} <-
 600            @httpoison.get(ap_id, [Accept: "application/activity+json"], follow_redirect: true),
 601          {:ok, data} <- Jason.decode(body) do
 602       user_data_from_user_object(data)
 603     else
 604       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 605     end
 606   end
 607
 608   def make_user_from_ap_id(ap_id) do
 609     if _user = User.get_by_ap_id(ap_id) do
 610       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 611     else
 612       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 613         User.insert_or_update_user(data)
 614       else
 615         e -> {:error, e}
 616       end
 617     end
 618   end
 619
 620   def make_user_from_nickname(nickname) do
 621     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 622       make_user_from_ap_id(ap_id)
 623     else
 624       _e -> {:error, "No AP id in WebFinger"}
 625     end
 626   end
 627
 628   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 629
 630   def should_federate?(inbox, public) do
 631     if public do
 632       true
 633     else
 634       inbox_info = URI.parse(inbox)
 635       inbox_info.host not in @quarantined_instances
 636     end
 637   end
 638
 639   def publish(actor, activity) do
 640     followers =
 641       if actor.follower_address in activity.recipients do
 642         {:ok, followers} = User.get_followers(actor)
 643         followers |> Enum.filter(&(!&1.local))
 644       else
 645         []
 646       end
 647
 648     public = is_public?(activity)
 649
 650     remote_inboxes =
 651       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 652       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 653       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 654         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 655       end)
 656       |> Enum.uniq()
 657       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 658
 659     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 660     json = Jason.encode!(data)
 661
 662     Enum.each(remote_inboxes, fn inbox ->
 663       Federator.enqueue(:publish_single_ap, %{
 664         inbox: inbox,
 665         json: json,
 666         actor: actor,
 667         id: activity.data["id"]
 668       })
 669     end)
 670   end
 671
 672   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 673     Logger.info("Federating #{id} to #{inbox}")
 674     host = URI.parse(inbox).host
 675
 676     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 677
 678     signature =
 679       Pleroma.Web.HTTPSignatures.sign(actor, %{
 680         host: host,
 681         "content-length": byte_size(json),
 682         digest: digest
 683       })
 684
 685     @httpoison.post(
 686       inbox,
 687       json,
 688       [
 689         {"Content-Type", "application/activity+json"},
 690         {"signature", signature},
 691         {"digest", digest}
 692       ],
 693       hackney: [pool: :default]
 694     )
 695   end
 696
 697   # TODO:
 698   # This will create a Create activity, which we need internally at the moment.
 699   def fetch_object_from_id(id) do
 700     if object = Object.get_cached_by_ap_id(id) do
 701       {:ok, object}
 702     else
 703       Logger.info("Fetching #{id} via AP")
 704
 705       with true <- String.starts_with?(id, "http"),
 706            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 707              @httpoison.get(
 708                id,
 709                [Accept: "application/activity+json"],
 710                follow_redirect: true,
 711                timeout: 10000,
 712                recv_timeout: 20000
 713              ),
 714            {:ok, data} <- Jason.decode(body),
 715            nil <- Object.normalize(data),
 716            params <- %{
 717              "type" => "Create",
 718              "to" => data["to"],
 719              "cc" => data["cc"],
 720              "actor" => data["attributedTo"],
 721              "object" => data
 722            },
 723            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 724         {:ok, Object.normalize(activity.data["object"])}
 725       else
 726         object = %Object{} ->
 727           {:ok, object}
 728
 729         _e ->
 730           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 731
 732           case OStatus.fetch_activity_from_url(id) do
 733             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 734             e -> e
 735           end
 736       end
 737     end
 738   end
 739
 740   def is_public?(activity) do
 741     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 742                                                          (activity.data["cc"] || []))
 743   end
 744
 745   def visible_for_user?(activity, nil) do
 746     is_public?(activity)
 747   end
 748
 749   def visible_for_user?(activity, user) do
 750     x = [user.ap_id | user.following]
 751     y = activity.data["to"] ++ (activity.data["cc"] || [])
 752     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 753   end
 754 end