git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   def get_recipients(data) do
  16     (data["to"] || []) ++ (data["cc"] || [])
  17   end
  18
  19   defp check_actor_is_active(actor) do
  20     if not is_nil(actor) do
  21       with user <- User.get_cached_by_ap_id(actor),
  22            nil <- user.info["deactivated"] do
  23         :ok
  24       else
  25         _e -> :reject
  26       end
  27     else
  28       :ok
  29     end
  30   end
  31
  32   def insert(map, local \\ true) when is_map(map) do
  33     with nil <- Activity.get_by_ap_id(map["id"]),
  34          map <- lazy_put_activity_defaults(map),
  35          :ok <- check_actor_is_active(map["actor"]),
  36          {:ok, map} <- MRF.filter(map),
  37          :ok <- insert_full_object(map) do
  38       {:ok, activity} =
  39         Repo.insert(%Activity{
  40           data: map,
  41           local: local,
  42           actor: map["actor"],
  43           recipients: get_recipients(map)
  44         })
  45
  46       Notification.create_notifications(activity)
  47       stream_out(activity)
  48       {:ok, activity}
  49     else
  50       %Activity{} = activity -> {:ok, activity}
  51       error -> {:error, error}
  52     end
  53   end
  54
  55   def stream_out(activity) do
  56     public = "https://www.w3.org/ns/activitystreams#Public"
  57
  58     if activity.data["type"] in ["Create", "Announce"] do
  59       Pleroma.Web.Streamer.stream("user", activity)
  60
  61       if Enum.member?(activity.data["to"], public) do
  62         Pleroma.Web.Streamer.stream("public", activity)
  63
  64         if activity.local do
  65           Pleroma.Web.Streamer.stream("public:local", activity)
  66         end
  67       else
  68         if !Enum.member?(activity.data["cc"] || [], public) &&
  69              !Enum.member?(
  70                activity.data["to"],
  71                User.get_by_ap_id(activity.data["actor"]).follower_address
  72              ),
  73            do: Pleroma.Web.Streamer.stream("direct", activity)
  74       end
  75     end
  76   end
  77
  78   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  79     additional = params[:additional] || %{}
  80     # only accept false as false value
  81     local = !(params[:local] == false)
  82     published = params[:published]
  83
  84     with create_data <-
  85            make_create_data(
  86              %{to: to, actor: actor, published: published, context: context, object: object},
  87              additional
  88            ),
  89          {:ok, activity} <- insert(create_data, local),
  90          :ok <- maybe_federate(activity),
  91          {:ok, _actor} <- User.increase_note_count(actor) do
  92       {:ok, activity}
  93     end
  94   end
  95
  96   def accept(%{to: to, actor: actor, object: object} = params) do
  97     # only accept false as false value
  98     local = !(params[:local] == false)
  99
 100     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 101          {:ok, activity} <- insert(data, local),
 102          :ok <- maybe_federate(activity) do
 103       {:ok, activity}
 104     end
 105   end
 106
 107   def reject(%{to: to, actor: actor, object: object} = params) do
 108     # only accept false as false value
 109     local = !(params[:local] == false)
 110
 111     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 112          {:ok, activity} <- insert(data, local),
 113          :ok <- maybe_federate(activity) do
 114       {:ok, activity}
 115     end
 116   end
 117
 118   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 119     # only accept false as false value
 120     local = !(params[:local] == false)
 121
 122     with data <- %{
 123            "to" => to,
 124            "cc" => cc,
 125            "type" => "Update",
 126            "actor" => actor,
 127            "object" => object
 128          },
 129          {:ok, activity} <- insert(data, local),
 130          :ok <- maybe_federate(activity) do
 131       {:ok, activity}
 132     end
 133   end
 134
 135   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 136   def like(
 137         %User{ap_id: ap_id} = user,
 138         %Object{data: %{"id" => _}} = object,
 139         activity_id \\ nil,
 140         local \\ true
 141       ) do
 142     with nil <- get_existing_like(ap_id, object),
 143          like_data <- make_like_data(user, object, activity_id),
 144          {:ok, activity} <- insert(like_data, local),
 145          {:ok, object} <- add_like_to_object(activity, object),
 146          :ok <- maybe_federate(activity) do
 147       {:ok, activity, object}
 148     else
 149       %Activity{} = activity -> {:ok, activity, object}
 150       error -> {:error, error}
 151     end
 152   end
 153
 154   def unlike(
 155         %User{} = actor,
 156         %Object{} = object,
 157         activity_id \\ nil,
 158         local \\ true
 159       ) do
 160     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 161          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 162          {:ok, unlike_activity} <- insert(unlike_data, local),
 163          {:ok, _activity} <- Repo.delete(like_activity),
 164          {:ok, object} <- remove_like_from_object(like_activity, object),
 165          :ok <- maybe_federate(unlike_activity) do
 166       {:ok, unlike_activity, like_activity, object}
 167     else
 168       _e -> {:ok, object}
 169     end
 170   end
 171
 172   def announce(
 173         %User{ap_id: _} = user,
 174         %Object{data: %{"id" => _}} = object,
 175         activity_id \\ nil,
 176         local \\ true
 177       ) do
 178     with true <- is_public?(object),
 179          announce_data <- make_announce_data(user, object, activity_id),
 180          {:ok, activity} <- insert(announce_data, local),
 181          {:ok, object} <- add_announce_to_object(activity, object),
 182          :ok <- maybe_federate(activity) do
 183       {:ok, activity, object}
 184     else
 185       error -> {:error, error}
 186     end
 187   end
 188
 189   def unannounce(
 190         %User{} = actor,
 191         %Object{} = object,
 192         activity_id \\ nil,
 193         local \\ true
 194       ) do
 195     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 196          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 197          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 198          :ok <- maybe_federate(unannounce_activity),
 199          {:ok, _activity} <- Repo.delete(announce_activity),
 200          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 201       {:ok, unannounce_activity, announce_activity, object}
 202     else
 203       _e -> {:ok, object}
 204     end
 205   end
 206
 207   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 208     with data <- make_follow_data(follower, followed, activity_id),
 209          {:ok, activity} <- insert(data, local),
 210          :ok <- maybe_federate(activity) do
 211       {:ok, activity}
 212     end
 213   end
 214
 215   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 216     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 217          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 218          {:ok, activity} <- insert(unfollow_data, local),
 219          :ok <- maybe_federate(activity) do
 220       {:ok, activity}
 221     end
 222   end
 223
 224   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 225     user = User.get_cached_by_ap_id(actor)
 226
 227     data = %{
 228       "type" => "Delete",
 229       "actor" => actor,
 230       "object" => id,
 231       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 232     }
 233
 234     with Repo.delete(object),
 235          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 236          {:ok, activity} <- insert(data, local),
 237          :ok <- maybe_federate(activity),
 238          {:ok, _actor} <- User.decrease_note_count(user) do
 239       {:ok, activity}
 240     end
 241   end
 242
 243   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 244     follow_activity = fetch_latest_follow(blocker, blocked)
 245
 246     if follow_activity do
 247       unfollow(blocker, blocked, nil, local)
 248     end
 249
 250     with block_data <- make_block_data(blocker, blocked, activity_id),
 251          {:ok, activity} <- insert(block_data, local),
 252          :ok <- maybe_federate(activity) do
 253       {:ok, activity}
 254     end
 255   end
 256
 257   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 258     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 259          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 260          {:ok, activity} <- insert(unblock_data, local),
 261          :ok <- maybe_federate(activity) do
 262       {:ok, activity}
 263     end
 264   end
 265
 266   def fetch_activities_for_context(context, opts \\ %{}) do
 267     public = ["https://www.w3.org/ns/activitystreams#Public"]
 268
 269     recipients =
 270       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 271
 272     query = from(activity in Activity)
 273
 274     query =
 275       query
 276       |> restrict_blocked(opts)
 277       |> restrict_recipients(recipients, opts["user"])
 278
 279     query =
 280       from(
 281         activity in query,
 282         where:
 283           fragment(
 284             "?->>'type' = ? and ?->>'context' = ?",
 285             activity.data,
 286             "Create",
 287             activity.data,
 288             ^context
 289           ),
 290         order_by: [desc: :id]
 291       )
 292
 293     Repo.all(query)
 294   end
 295
 296   def fetch_public_activities(opts \\ %{}) do
 297     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 298
 299     q
 300     |> restrict_unlisted()
 301     |> Repo.all()
 302     |> Enum.reverse()
 303   end
 304
 305   @valid_visibilities ~w[direct unlisted public private]
 306
 307   defp restrict_visibility(query, %{visibility: "direct"}) do
 308     public = "https://www.w3.org/ns/activitystreams#Public"
 309
 310     from(
 311       activity in query,
 312       join: sender in User,
 313       on: sender.ap_id == activity.actor,
 314       # Are non-direct statuses with no to/cc possible?
 315       where:
 316         fragment(
 317           "not (? && ?)",
 318           [^public, sender.follower_address],
 319           activity.recipients
 320         )
 321     )
 322   end
 323
 324   defp restrict_visibility(_query, %{visibility: visibility})
 325        when visibility not in @valid_visibilities do
 326     Logger.error("Could not restrict visibility to #{visibility}")
 327   end
 328
 329   defp restrict_visibility(query, _visibility), do: query
 330
 331   def fetch_user_activities(user, reading_user, params \\ %{}) do
 332     params =
 333       params
 334       |> Map.put("type", ["Create", "Announce"])
 335       |> Map.put("actor_id", user.ap_id)
 336       |> Map.put("whole_db", true)
 337
 338     recipients =
 339       if reading_user do
 340         ["https://www.w3.org/ns/activitystreams#Public"] ++
 341           [reading_user.ap_id | reading_user.following]
 342       else
 343         ["https://www.w3.org/ns/activitystreams#Public"]
 344       end
 345
 346     fetch_activities(recipients, params)
 347     |> Enum.reverse()
 348   end
 349
 350   defp restrict_since(query, %{"since_id" => since_id}) do
 351     from(activity in query, where: activity.id > ^since_id)
 352   end
 353
 354   defp restrict_since(query, _), do: query
 355
 356   defp restrict_tag(query, %{"tag" => tag}) do
 357     from(
 358       activity in query,
 359       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 360     )
 361   end
 362
 363   defp restrict_tag(query, _), do: query
 364
 365   defp restrict_recipients(query, [], _user), do: query
 366
 367   defp restrict_recipients(query, recipients, nil) do
 368     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 369   end
 370
 371   defp restrict_recipients(query, recipients, user) do
 372     from(
 373       activity in query,
 374       where: fragment("? && ?", ^recipients, activity.recipients),
 375       or_where: activity.actor == ^user.ap_id
 376     )
 377   end
 378
 379   defp restrict_limit(query, %{"limit" => limit}) do
 380     from(activity in query, limit: ^limit)
 381   end
 382
 383   defp restrict_limit(query, _), do: query
 384
 385   defp restrict_local(query, %{"local_only" => true}) do
 386     from(activity in query, where: activity.local == true)
 387   end
 388
 389   defp restrict_local(query, _), do: query
 390
 391   defp restrict_max(query, %{"max_id" => max_id}) do
 392     from(activity in query, where: activity.id < ^max_id)
 393   end
 394
 395   defp restrict_max(query, _), do: query
 396
 397   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 398     from(activity in query, where: activity.actor == ^actor_id)
 399   end
 400
 401   defp restrict_actor(query, _), do: query
 402
 403   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 404     restrict_type(query, %{"type" => [type]})
 405   end
 406
 407   defp restrict_type(query, %{"type" => type}) do
 408     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 409   end
 410
 411   defp restrict_type(query, _), do: query
 412
 413   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 414     from(
 415       activity in query,
 416       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 417     )
 418   end
 419
 420   defp restrict_favorited_by(query, _), do: query
 421
 422   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 423     from(
 424       activity in query,
 425       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 426     )
 427   end
 428
 429   defp restrict_media(query, _), do: query
 430
 431   # Only search through last 100_000 activities by default
 432   defp restrict_recent(query, %{"whole_db" => true}), do: query
 433
 434   defp restrict_recent(query, _) do
 435     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 436
 437     from(activity in query, where: activity.id > ^since)
 438   end
 439
 440   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 441     blocks = info["blocks"] || []
 442     domain_blocks = info["domain_blocks"] || []
 443
 444     from(
 445       activity in query,
 446       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 447       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 448       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 449     )
 450   end
 451
 452   defp restrict_blocked(query, _), do: query
 453
 454   defp restrict_unlisted(query) do
 455     from(
 456       activity in query,
 457       where:
 458         fragment(
 459           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 460           activity.data,
 461           ^["https://www.w3.org/ns/activitystreams#Public"]
 462         )
 463     )
 464   end
 465
 466   def fetch_activities_query(recipients, opts \\ %{}) do
 467     base_query =
 468       from(
 469         activity in Activity,
 470         limit: 20,
 471         order_by: [fragment("? desc nulls last", activity.id)]
 472       )
 473
 474     base_query
 475     |> restrict_recipients(recipients, opts["user"])
 476     |> restrict_tag(opts)
 477     |> restrict_since(opts)
 478     |> restrict_local(opts)
 479     |> restrict_limit(opts)
 480     |> restrict_max(opts)
 481     |> restrict_actor(opts)
 482     |> restrict_type(opts)
 483     |> restrict_favorited_by(opts)
 484     |> restrict_recent(opts)
 485     |> restrict_blocked(opts)
 486     |> restrict_media(opts)
 487     |> restrict_visibility(opts)
 488   end
 489
 490   def fetch_activities(recipients, opts \\ %{}) do
 491     fetch_activities_query(recipients, opts)
 492     |> Repo.all()
 493     |> Enum.reverse()
 494   end
 495
 496   def upload(file) do
 497     data = Upload.store(file)
 498     Repo.insert(%Object{data: data})
 499   end
 500
 501   def user_data_from_user_object(data) do
 502     avatar =
 503       data["icon"]["url"] &&
 504         %{
 505           "type" => "Image",
 506           "url" => [%{"href" => data["icon"]["url"]}]
 507         }
 508
 509     banner =
 510       data["image"]["url"] &&
 511         %{
 512           "type" => "Image",
 513           "url" => [%{"href" => data["image"]["url"]}]
 514         }
 515
 516     locked = data["manuallyApprovesFollowers"] || false
 517     data = Transmogrifier.maybe_fix_user_object(data)
 518
 519     user_data = %{
 520       ap_id: data["id"],
 521       info: %{
 522         "ap_enabled" => true,
 523         "source_data" => data,
 524         "banner" => banner,
 525         "locked" => locked
 526       },
 527       avatar: avatar,
 528       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 529       name: data["name"],
 530       follower_address: data["followers"],
 531       bio: data["summary"]
 532     }
 533
 534     {:ok, user_data}
 535   end
 536
 537   def fetch_and_prepare_user_from_ap_id(ap_id) do
 538     with {:ok, %{status_code: 200, body: body}} <-
 539            @httpoison.get(ap_id, Accept: "application/activity+json"),
 540          {:ok, data} <- Jason.decode(body) do
 541       user_data_from_user_object(data)
 542     else
 543       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 544     end
 545   end
 546
 547   def make_user_from_ap_id(ap_id) do
 548     if _user = User.get_by_ap_id(ap_id) do
 549       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 550     else
 551       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 552         User.insert_or_update_user(data)
 553       else
 554         e -> {:error, e}
 555       end
 556     end
 557   end
 558
 559   def make_user_from_nickname(nickname) do
 560     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 561       make_user_from_ap_id(ap_id)
 562     else
 563       _e -> {:error, "No AP id in WebFinger"}
 564     end
 565   end
 566
 567   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 568
 569   def should_federate?(inbox, public) do
 570     if public do
 571       true
 572     else
 573       inbox_info = URI.parse(inbox)
 574       inbox_info.host not in @quarantined_instances
 575     end
 576   end
 577
 578   def publish(actor, activity) do
 579     followers =
 580       if actor.follower_address in activity.recipients do
 581         {:ok, followers} = User.get_followers(actor)
 582         followers |> Enum.filter(&(!&1.local))
 583       else
 584         []
 585       end
 586
 587     public = is_public?(activity)
 588
 589     remote_inboxes =
 590       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 591       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 592       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 593         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 594       end)
 595       |> Enum.uniq()
 596       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 597
 598     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 599     json = Jason.encode!(data)
 600
 601     Enum.each(remote_inboxes, fn inbox ->
 602       Federator.enqueue(:publish_single_ap, %{
 603         inbox: inbox,
 604         json: json,
 605         actor: actor,
 606         id: activity.data["id"]
 607       })
 608     end)
 609   end
 610
 611   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 612     Logger.info("Federating #{id} to #{inbox}")
 613     host = URI.parse(inbox).host
 614
 615     signature =
 616       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 617
 618     @httpoison.post(
 619       inbox,
 620       json,
 621       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 622       hackney: [pool: :default]
 623     )
 624   end
 625
 626   # TODO:
 627   # This will create a Create activity, which we need internally at the moment.
 628   def fetch_object_from_id(id) do
 629     if object = Object.get_cached_by_ap_id(id) do
 630       {:ok, object}
 631     else
 632       Logger.info("Fetching #{id} via AP")
 633
 634       with true <- String.starts_with?(id, "http"),
 635            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 636              @httpoison.get(
 637                id,
 638                [Accept: "application/activity+json"],
 639                follow_redirect: true,
 640                timeout: 10000,
 641                recv_timeout: 20000
 642              ),
 643            {:ok, data} <- Jason.decode(body),
 644            nil <- Object.get_by_ap_id(data["id"]),
 645            params <- %{
 646              "type" => "Create",
 647              "to" => data["to"],
 648              "cc" => data["cc"],
 649              "actor" => data["attributedTo"],
 650              "object" => data
 651            },
 652            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 653         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 654       else
 655         object = %Object{} ->
 656           {:ok, object}
 657
 658         _e ->
 659           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 660
 661           case OStatus.fetch_activity_from_url(id) do
 662             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 663             e -> e
 664           end
 665       end
 666     end
 667   end
 668
 669   def is_public?(activity) do
 670     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 671                                                          (activity.data["cc"] || []))
 672   end
 673
 674   def visible_for_user?(activity, nil) do
 675     is_public?(activity)
 676   end
 677
 678   def visible_for_user?(activity, user) do
 679     x = [user.ap_id | user.following]
 680     y = activity.data["to"] ++ (activity.data["cc"] || [])
 681     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 682   end
 683 end