git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.{Transmogrifier, MRF}
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   @instance Application.get_env(:pleroma, :instance)
  14
  15   # For Announce activities, we filter the recipients based on following status for any actors
  16   # that match actual users.  See issue #164 for more information about why this is necessary.
  17   def get_recipients(%{"type" => "Announce"} = data) do
  18     recipients = (data["to"] || []) ++ (data["cc"] || [])
  19     actor = User.get_cached_by_ap_id(data["actor"])
  20
  21     recipients
  22     |> Enum.filter(fn recipient ->
  23       case User.get_cached_by_ap_id(recipient) do
  24         nil ->
  25           true
  26
  27         user ->
  28           User.following?(user, actor)
  29       end
  30     end)
  31   end
  32
  33   def get_recipients(data) do
  34     (data["to"] || []) ++ (data["cc"] || [])
  35   end
  36
  37   defp check_actor_is_active(actor) do
  38     if not is_nil(actor) do
  39       with user <- User.get_cached_by_ap_id(actor),
  40            nil <- user.info["deactivated"] do
  41         :ok
  42       else
  43         _e -> :reject
  44       end
  45     else
  46       :ok
  47     end
  48   end
  49
  50   def insert(map, local \\ true) when is_map(map) do
  51     with nil <- Activity.normalize(map),
  52          map <- lazy_put_activity_defaults(map),
  53          :ok <- check_actor_is_active(map["actor"]),
  54          {:ok, map} <- MRF.filter(map),
  55          :ok <- insert_full_object(map) do
  56       {:ok, activity} =
  57         Repo.insert(%Activity{
  58           data: map,
  59           local: local,
  60           actor: map["actor"],
  61           recipients: get_recipients(map)
  62         })
  63
  64       Notification.create_notifications(activity)
  65       stream_out(activity)
  66       {:ok, activity}
  67     else
  68       %Activity{} = activity -> {:ok, activity}
  69       error -> {:error, error}
  70     end
  71   end
  72
  73   def stream_out(activity) do
  74     public = "https://www.w3.org/ns/activitystreams#Public"
  75
  76     if activity.data["type"] in ["Create", "Announce"] do
  77       Pleroma.Web.Streamer.stream("user", activity)
  78       Pleroma.Web.Streamer.stream("list", activity)
  79
  80       if Enum.member?(activity.data["to"], public) do
  81         Pleroma.Web.Streamer.stream("public", activity)
  82
  83         if activity.local do
  84           Pleroma.Web.Streamer.stream("public:local", activity)
  85         end
  86
  87         if activity.data["object"]["attachment"] != [] do
  88           Pleroma.Web.Streamer.stream("public:media", activity)
  89
  90           if activity.local do
  91             Pleroma.Web.Streamer.stream("public:local:media", activity)
  92           end
  93         end
  94       else
  95         if !Enum.member?(activity.data["cc"] || [], public) &&
  96              !Enum.member?(
  97                activity.data["to"],
  98                User.get_by_ap_id(activity.data["actor"]).follower_address
  99              ),
 100            do: Pleroma.Web.Streamer.stream("direct", activity)
 101       end
 102     end
 103   end
 104
 105   def create(%{to: to, actor: actor, context: context, object: object} = params) do
 106     additional = params[:additional] || %{}
 107     # only accept false as false value
 108     local = !(params[:local] == false)
 109     published = params[:published]
 110
 111     with create_data <-
 112            make_create_data(
 113              %{to: to, actor: actor, published: published, context: context, object: object},
 114              additional
 115            ),
 116          {:ok, activity} <- insert(create_data, local),
 117          :ok <- maybe_federate(activity),
 118          {:ok, _actor} <- User.increase_note_count(actor) do
 119       {:ok, activity}
 120     end
 121   end
 122
 123   def accept(%{to: to, actor: actor, object: object} = params) do
 124     # only accept false as false value
 125     local = !(params[:local] == false)
 126
 127     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
 128          {:ok, activity} <- insert(data, local),
 129          :ok <- maybe_federate(activity) do
 130       {:ok, activity}
 131     end
 132   end
 133
 134   def reject(%{to: to, actor: actor, object: object} = params) do
 135     # only accept false as false value
 136     local = !(params[:local] == false)
 137
 138     with data <- %{"to" => to, "type" => "Reject", "actor" => actor, "object" => object},
 139          {:ok, activity} <- insert(data, local),
 140          :ok <- maybe_federate(activity) do
 141       {:ok, activity}
 142     end
 143   end
 144
 145   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
 146     # only accept false as false value
 147     local = !(params[:local] == false)
 148
 149     with data <- %{
 150            "to" => to,
 151            "cc" => cc,
 152            "type" => "Update",
 153            "actor" => actor,
 154            "object" => object
 155          },
 156          {:ok, activity} <- insert(data, local),
 157          :ok <- maybe_federate(activity) do
 158       {:ok, activity}
 159     end
 160   end
 161
 162   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
 163   def like(
 164         %User{ap_id: ap_id} = user,
 165         %Object{data: %{"id" => _}} = object,
 166         activity_id \\ nil,
 167         local \\ true
 168       ) do
 169     with nil <- get_existing_like(ap_id, object),
 170          like_data <- make_like_data(user, object, activity_id),
 171          {:ok, activity} <- insert(like_data, local),
 172          {:ok, object} <- add_like_to_object(activity, object),
 173          :ok <- maybe_federate(activity) do
 174       {:ok, activity, object}
 175     else
 176       %Activity{} = activity -> {:ok, activity, object}
 177       error -> {:error, error}
 178     end
 179   end
 180
 181   def unlike(
 182         %User{} = actor,
 183         %Object{} = object,
 184         activity_id \\ nil,
 185         local \\ true
 186       ) do
 187     with %Activity{} = like_activity <- get_existing_like(actor.ap_id, object),
 188          unlike_data <- make_unlike_data(actor, like_activity, activity_id),
 189          {:ok, unlike_activity} <- insert(unlike_data, local),
 190          {:ok, _activity} <- Repo.delete(like_activity),
 191          {:ok, object} <- remove_like_from_object(like_activity, object),
 192          :ok <- maybe_federate(unlike_activity) do
 193       {:ok, unlike_activity, like_activity, object}
 194     else
 195       _e -> {:ok, object}
 196     end
 197   end
 198
 199   def announce(
 200         %User{ap_id: _} = user,
 201         %Object{data: %{"id" => _}} = object,
 202         activity_id \\ nil,
 203         local \\ true
 204       ) do
 205     with true <- is_public?(object),
 206          announce_data <- make_announce_data(user, object, activity_id),
 207          {:ok, activity} <- insert(announce_data, local),
 208          {:ok, object} <- add_announce_to_object(activity, object),
 209          :ok <- maybe_federate(activity) do
 210       {:ok, activity, object}
 211     else
 212       error -> {:error, error}
 213     end
 214   end
 215
 216   def unannounce(
 217         %User{} = actor,
 218         %Object{} = object,
 219         activity_id \\ nil,
 220         local \\ true
 221       ) do
 222     with %Activity{} = announce_activity <- get_existing_announce(actor.ap_id, object),
 223          unannounce_data <- make_unannounce_data(actor, announce_activity, activity_id),
 224          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 225          :ok <- maybe_federate(unannounce_activity),
 226          {:ok, _activity} <- Repo.delete(announce_activity),
 227          {:ok, object} <- remove_announce_from_object(announce_activity, object) do
 228       {:ok, unannounce_activity, object}
 229     else
 230       _e -> {:ok, object}
 231     end
 232   end
 233
 234   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 235     with data <- make_follow_data(follower, followed, activity_id),
 236          {:ok, activity} <- insert(data, local),
 237          :ok <- maybe_federate(activity) do
 238       {:ok, activity}
 239     end
 240   end
 241
 242   def unfollow(follower, followed, activity_id \\ nil, local \\ true) do
 243     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 244          {:ok, follow_activity} <- update_follow_state(follow_activity, "cancelled"),
 245          unfollow_data <- make_unfollow_data(follower, followed, follow_activity, activity_id),
 246          {:ok, activity} <- insert(unfollow_data, local),
 247          :ok <- maybe_federate(activity) do
 248       {:ok, activity}
 249     end
 250   end
 251
 252   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 253     user = User.get_cached_by_ap_id(actor)
 254
 255     data = %{
 256       "type" => "Delete",
 257       "actor" => actor,
 258       "object" => id,
 259       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 260     }
 261
 262     with Repo.delete(object),
 263          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 264          {:ok, activity} <- insert(data, local),
 265          :ok <- maybe_federate(activity),
 266          {:ok, _actor} <- User.decrease_note_count(user) do
 267       {:ok, activity}
 268     end
 269   end
 270
 271   def block(blocker, blocked, activity_id \\ nil, local \\ true) do
 272     ap_config = Application.get_env(:pleroma, :activitypub)
 273     unfollow_blocked = Keyword.get(ap_config, :unfollow_blocked)
 274     outgoing_blocks = Keyword.get(ap_config, :outgoing_blocks)
 275
 276     with true <- unfollow_blocked do
 277       follow_activity = fetch_latest_follow(blocker, blocked)
 278
 279       if follow_activity do
 280         unfollow(blocker, blocked, nil, local)
 281       end
 282     end
 283
 284     with true <- outgoing_blocks,
 285          block_data <- make_block_data(blocker, blocked, activity_id),
 286          {:ok, activity} <- insert(block_data, local),
 287          :ok <- maybe_federate(activity) do
 288       {:ok, activity}
 289     else
 290       _e -> {:ok, nil}
 291     end
 292   end
 293
 294   def unblock(blocker, blocked, activity_id \\ nil, local \\ true) do
 295     with %Activity{} = block_activity <- fetch_latest_block(blocker, blocked),
 296          unblock_data <- make_unblock_data(blocker, blocked, block_activity, activity_id),
 297          {:ok, activity} <- insert(unblock_data, local),
 298          :ok <- maybe_federate(activity) do
 299       {:ok, activity}
 300     end
 301   end
 302
 303   def fetch_activities_for_context(context, opts \\ %{}) do
 304     public = ["https://www.w3.org/ns/activitystreams#Public"]
 305
 306     recipients =
 307       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 308
 309     query = from(activity in Activity)
 310
 311     query =
 312       query
 313       |> restrict_blocked(opts)
 314       |> restrict_recipients(recipients, opts["user"])
 315
 316     query =
 317       from(
 318         activity in query,
 319         where:
 320           fragment(
 321             "?->>'type' = ? and ?->>'context' = ?",
 322             activity.data,
 323             "Create",
 324             activity.data,
 325             ^context
 326           ),
 327         order_by: [desc: :id]
 328       )
 329
 330     Repo.all(query)
 331   end
 332
 333   def fetch_public_activities(opts \\ %{}) do
 334     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 335
 336     q
 337     |> restrict_unlisted()
 338     |> Repo.all()
 339     |> Enum.reverse()
 340   end
 341
 342   @valid_visibilities ~w[direct unlisted public private]
 343
 344   defp restrict_visibility(query, %{visibility: "direct"}) do
 345     public = "https://www.w3.org/ns/activitystreams#Public"
 346
 347     from(
 348       activity in query,
 349       join: sender in User,
 350       on: sender.ap_id == activity.actor,
 351       # Are non-direct statuses with no to/cc possible?
 352       where:
 353         fragment(
 354           "not (? && ?)",
 355           [^public, sender.follower_address],
 356           activity.recipients
 357         )
 358     )
 359   end
 360
 361   defp restrict_visibility(_query, %{visibility: visibility})
 362        when visibility not in @valid_visibilities do
 363     Logger.error("Could not restrict visibility to #{visibility}")
 364   end
 365
 366   defp restrict_visibility(query, _visibility), do: query
 367
 368   def fetch_user_activities(user, reading_user, params \\ %{}) do
 369     params =
 370       params
 371       |> Map.put("type", ["Create", "Announce"])
 372       |> Map.put("actor_id", user.ap_id)
 373       |> Map.put("whole_db", true)
 374
 375     recipients =
 376       if reading_user do
 377         ["https://www.w3.org/ns/activitystreams#Public"] ++
 378           [reading_user.ap_id | reading_user.following]
 379       else
 380         ["https://www.w3.org/ns/activitystreams#Public"]
 381       end
 382
 383     fetch_activities(recipients, params)
 384     |> Enum.reverse()
 385   end
 386
 387   defp restrict_since(query, %{"since_id" => since_id}) do
 388     from(activity in query, where: activity.id > ^since_id)
 389   end
 390
 391   defp restrict_since(query, _), do: query
 392
 393   defp restrict_tag(query, %{"tag" => tag}) do
 394     from(
 395       activity in query,
 396       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 397     )
 398   end
 399
 400   defp restrict_tag(query, _), do: query
 401
 402   defp restrict_recipients(query, [], _user), do: query
 403
 404   defp restrict_recipients(query, recipients, nil) do
 405     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 406   end
 407
 408   defp restrict_recipients(query, recipients, user) do
 409     from(
 410       activity in query,
 411       where: fragment("? && ?", ^recipients, activity.recipients),
 412       or_where: activity.actor == ^user.ap_id
 413     )
 414   end
 415
 416   defp restrict_limit(query, %{"limit" => limit}) do
 417     from(activity in query, limit: ^limit)
 418   end
 419
 420   defp restrict_limit(query, _), do: query
 421
 422   defp restrict_local(query, %{"local_only" => true}) do
 423     from(activity in query, where: activity.local == true)
 424   end
 425
 426   defp restrict_local(query, _), do: query
 427
 428   defp restrict_max(query, %{"max_id" => max_id}) do
 429     from(activity in query, where: activity.id < ^max_id)
 430   end
 431
 432   defp restrict_max(query, _), do: query
 433
 434   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 435     from(activity in query, where: activity.actor == ^actor_id)
 436   end
 437
 438   defp restrict_actor(query, _), do: query
 439
 440   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 441     restrict_type(query, %{"type" => [type]})
 442   end
 443
 444   defp restrict_type(query, %{"type" => type}) do
 445     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 446   end
 447
 448   defp restrict_type(query, _), do: query
 449
 450   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 451     from(
 452       activity in query,
 453       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 454     )
 455   end
 456
 457   defp restrict_favorited_by(query, _), do: query
 458
 459   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 460     from(
 461       activity in query,
 462       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 463     )
 464   end
 465
 466   defp restrict_media(query, _), do: query
 467
 468   defp restrict_replies(query, %{"exclude_replies" => val}) when val == "true" or val == "1" do
 469     from(
 470       activity in query,
 471       where: fragment("?->'object'->>'inReplyTo' is null", activity.data)
 472     )
 473   end
 474
 475   defp restrict_replies(query, _), do: query
 476
 477   # Only search through last 100_000 activities by default
 478   defp restrict_recent(query, %{"whole_db" => true}), do: query
 479
 480   defp restrict_recent(query, _) do
 481     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 482
 483     from(activity in query, where: activity.id > ^since)
 484   end
 485
 486   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 487     blocks = info["blocks"] || []
 488     domain_blocks = info["domain_blocks"] || []
 489
 490     from(
 491       activity in query,
 492       where: fragment("not (? = ANY(?))", activity.actor, ^blocks),
 493       where: fragment("not (?->'to' \\?| ?)", activity.data, ^blocks),
 494       where: fragment("not (split_part(?, '/', 3) = ANY(?))", activity.actor, ^domain_blocks)
 495     )
 496   end
 497
 498   defp restrict_blocked(query, _), do: query
 499
 500   defp restrict_unlisted(query) do
 501     from(
 502       activity in query,
 503       where:
 504         fragment(
 505           "not (coalesce(?->'cc', '{}'::jsonb) \\?| ?)",
 506           activity.data,
 507           ^["https://www.w3.org/ns/activitystreams#Public"]
 508         )
 509     )
 510   end
 511
 512   def fetch_activities_query(recipients, opts \\ %{}) do
 513     base_query =
 514       from(
 515         activity in Activity,
 516         limit: 20,
 517         order_by: [fragment("? desc nulls last", activity.id)]
 518       )
 519
 520     base_query
 521     |> restrict_recipients(recipients, opts["user"])
 522     |> restrict_tag(opts)
 523     |> restrict_since(opts)
 524     |> restrict_local(opts)
 525     |> restrict_limit(opts)
 526     |> restrict_max(opts)
 527     |> restrict_actor(opts)
 528     |> restrict_type(opts)
 529     |> restrict_favorited_by(opts)
 530     |> restrict_recent(opts)
 531     |> restrict_blocked(opts)
 532     |> restrict_media(opts)
 533     |> restrict_visibility(opts)
 534     |> restrict_replies(opts)
 535   end
 536
 537   def fetch_activities(recipients, opts \\ %{}) do
 538     fetch_activities_query(recipients, opts)
 539     |> Repo.all()
 540     |> Enum.reverse()
 541   end
 542
 543   def upload(file) do
 544     data = Upload.store(file, Application.get_env(:pleroma, :instance)[:dedupe_media])
 545     Repo.insert(%Object{data: data})
 546   end
 547
 548   def user_data_from_user_object(data) do
 549     avatar =
 550       data["icon"]["url"] &&
 551         %{
 552           "type" => "Image",
 553           "url" => [%{"href" => data["icon"]["url"]}]
 554         }
 555
 556     banner =
 557       data["image"]["url"] &&
 558         %{
 559           "type" => "Image",
 560           "url" => [%{"href" => data["image"]["url"]}]
 561         }
 562
 563     locked = data["manuallyApprovesFollowers"] || false
 564     data = Transmogrifier.maybe_fix_user_object(data)
 565
 566     user_data = %{
 567       ap_id: data["id"],
 568       info: %{
 569         "ap_enabled" => true,
 570         "source_data" => data,
 571         "banner" => banner,
 572         "locked" => locked
 573       },
 574       avatar: avatar,
 575       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 576       name: data["name"],
 577       follower_address: data["followers"],
 578       bio: data["summary"]
 579     }
 580
 581     {:ok, user_data}
 582   end
 583
 584   def fetch_and_prepare_user_from_ap_id(ap_id) do
 585     with {:ok, %{status_code: 200, body: body}} <-
 586            @httpoison.get(ap_id, [Accept: "application/activity+json"], follow_redirect: true),
 587          {:ok, data} <- Jason.decode(body) do
 588       user_data_from_user_object(data)
 589     else
 590       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 591     end
 592   end
 593
 594   def make_user_from_ap_id(ap_id) do
 595     if _user = User.get_by_ap_id(ap_id) do
 596       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 597     else
 598       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 599         User.insert_or_update_user(data)
 600       else
 601         e -> {:error, e}
 602       end
 603     end
 604   end
 605
 606   def make_user_from_nickname(nickname) do
 607     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 608       make_user_from_ap_id(ap_id)
 609     else
 610       _e -> {:error, "No AP id in WebFinger"}
 611     end
 612   end
 613
 614   @quarantined_instances Keyword.get(@instance, :quarantined_instances, [])
 615
 616   def should_federate?(inbox, public) do
 617     if public do
 618       true
 619     else
 620       inbox_info = URI.parse(inbox)
 621       inbox_info.host not in @quarantined_instances
 622     end
 623   end
 624
 625   def publish(actor, activity) do
 626     followers =
 627       if actor.follower_address in activity.recipients do
 628         {:ok, followers} = User.get_followers(actor)
 629         followers |> Enum.filter(&(!&1.local))
 630       else
 631         []
 632       end
 633
 634     public = is_public?(activity)
 635
 636     remote_inboxes =
 637       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 638       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 639       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 640         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 641       end)
 642       |> Enum.uniq()
 643       |> Enum.filter(fn inbox -> should_federate?(inbox, public) end)
 644
 645     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 646     json = Jason.encode!(data)
 647
 648     Enum.each(remote_inboxes, fn inbox ->
 649       Federator.enqueue(:publish_single_ap, %{
 650         inbox: inbox,
 651         json: json,
 652         actor: actor,
 653         id: activity.data["id"]
 654       })
 655     end)
 656   end
 657
 658   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 659     Logger.info("Federating #{id} to #{inbox}")
 660     host = URI.parse(inbox).host
 661
 662     digest = "SHA-256=" <> (:crypto.hash(:sha256, json) |> Base.encode64())
 663
 664     signature =
 665       Pleroma.Web.HTTPSignatures.sign(actor, %{
 666         host: host,
 667         "content-length": byte_size(json),
 668         digest: digest
 669       })
 670
 671     @httpoison.post(
 672       inbox,
 673       json,
 674       [
 675         {"Content-Type", "application/activity+json"},
 676         {"signature", signature},
 677         {"digest", digest}
 678       ],
 679       hackney: [pool: :default]
 680     )
 681   end
 682
 683   # TODO:
 684   # This will create a Create activity, which we need internally at the moment.
 685   def fetch_object_from_id(id) do
 686     if object = Object.get_cached_by_ap_id(id) do
 687       {:ok, object}
 688     else
 689       Logger.info("Fetching #{id} via AP")
 690
 691       with true <- String.starts_with?(id, "http"),
 692            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 693              @httpoison.get(
 694                id,
 695                [Accept: "application/activity+json"],
 696                follow_redirect: true,
 697                timeout: 10000,
 698                recv_timeout: 20000
 699              ),
 700            {:ok, data} <- Jason.decode(body),
 701            nil <- Object.normalize(data),
 702            params <- %{
 703              "type" => "Create",
 704              "to" => data["to"],
 705              "cc" => data["cc"],
 706              "actor" => data["attributedTo"],
 707              "object" => data
 708            },
 709            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 710         {:ok, Object.normalize(activity.data["object"])}
 711       else
 712         object = %Object{} ->
 713           {:ok, object}
 714
 715         _e ->
 716           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 717
 718           case OStatus.fetch_activity_from_url(id) do
 719             {:ok, [activity | _]} -> {:ok, Object.normalize(activity.data["object"])}
 720             e -> e
 721           end
 722       end
 723     end
 724   end
 725
 726   def is_public?(activity) do
 727     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 728                                                          (activity.data["cc"] || []))
 729   end
 730
 731   def visible_for_user?(activity, nil) do
 732     is_public?(activity)
 733   end
 734
 735   def visible_for_user?(activity, user) do
 736     x = [user.ap_id | user.following]
 737     y = activity.data["to"] ++ (activity.data["cc"] || [])
 738     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 739   end
 740 end