git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/activity_pub.ex

   1 defmodule Pleroma.Web.ActivityPub.ActivityPub do
   2   alias Pleroma.{Activity, Repo, Object, Upload, User, Notification}
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.WebFinger
   5   alias Pleroma.Web.Federator
   6   alias Pleroma.Web.OStatus
   7   import Ecto.Query
   8   import Pleroma.Web.ActivityPub.Utils
   9   require Logger
  10
  11   @httpoison Application.get_env(:pleroma, :httpoison)
  12
  13   def get_recipients(data) do
  14     (data["to"] || []) ++ (data["cc"] || [])
  15   end
  16
  17   def insert(map, local \\ true) when is_map(map) do
  18     with nil <- Activity.get_by_ap_id(map["id"]),
  19          map <- lazy_put_activity_defaults(map),
  20          :ok <- insert_full_object(map) do
  21       {:ok, activity} =
  22         Repo.insert(%Activity{
  23           data: map,
  24           local: local,
  25           actor: map["actor"],
  26           recipients: get_recipients(map)
  27         })
  28
  29       Notification.create_notifications(activity)
  30       stream_out(activity)
  31       {:ok, activity}
  32     else
  33       %Activity{} = activity -> {:ok, activity}
  34       error -> {:error, error}
  35     end
  36   end
  37
  38   def stream_out(activity) do
  39     if activity.data["type"] in ["Create", "Announce"] do
  40       Pleroma.Web.Streamer.stream("user", activity)
  41
  42       if Enum.member?(activity.data["to"], "https://www.w3.org/ns/activitystreams#Public") do
  43         Pleroma.Web.Streamer.stream("public", activity)
  44
  45         if activity.local do
  46           Pleroma.Web.Streamer.stream("public:local", activity)
  47         end
  48       end
  49     end
  50   end
  51
  52   def create(%{to: to, actor: actor, context: context, object: object} = params) do
  53     additional = params[:additional] || %{}
  54     # only accept false as false value
  55     local = !(params[:local] == false)
  56     published = params[:published]
  57
  58     with create_data <-
  59            make_create_data(
  60              %{to: to, actor: actor, published: published, context: context, object: object},
  61              additional
  62            ),
  63          {:ok, activity} <- insert(create_data, local),
  64          :ok <- maybe_federate(activity) do
  65       {:ok, activity}
  66     end
  67   end
  68
  69   def accept(%{to: to, actor: actor, object: object} = params) do
  70     # only accept false as false value
  71     local = !(params[:local] == false)
  72
  73     with data <- %{"to" => to, "type" => "Accept", "actor" => actor, "object" => object},
  74          {:ok, activity} <- insert(data, local),
  75          :ok <- maybe_federate(activity) do
  76       {:ok, activity}
  77     end
  78   end
  79
  80   def update(%{to: to, cc: cc, actor: actor, object: object} = params) do
  81     # only accept false as false value
  82     local = !(params[:local] == false)
  83
  84     with data <- %{
  85            "to" => to,
  86            "cc" => cc,
  87            "type" => "Update",
  88            "actor" => actor,
  89            "object" => object
  90          },
  91          {:ok, activity} <- insert(data, local),
  92          :ok <- maybe_federate(activity) do
  93       {:ok, activity}
  94     end
  95   end
  96
  97   # TODO: This is weird, maybe we shouldn't check here if we can make the activity.
  98   def like(
  99         %User{ap_id: ap_id} = user,
 100         %Object{data: %{"id" => _}} = object,
 101         activity_id \\ nil,
 102         local \\ true
 103       ) do
 104     with nil <- get_existing_like(ap_id, object),
 105          like_data <- make_like_data(user, object, activity_id),
 106          {:ok, activity} <- insert(like_data, local),
 107          {:ok, object} <- add_like_to_object(activity, object),
 108          :ok <- maybe_federate(activity) do
 109       {:ok, activity, object}
 110     else
 111       %Activity{} = activity -> {:ok, activity, object}
 112       error -> {:error, error}
 113     end
 114   end
 115
 116   def unlike(%User{} = actor, %Object{} = object) do
 117     with %Activity{} = activity <- get_existing_like(actor.ap_id, object),
 118          {:ok, _activity} <- Repo.delete(activity),
 119          {:ok, object} <- remove_like_from_object(activity, object) do
 120       {:ok, object}
 121     else
 122       _e -> {:ok, object}
 123     end
 124   end
 125
 126   def announce(
 127         %User{ap_id: _} = user,
 128         %Object{data: %{"id" => _}} = object,
 129         activity_id \\ nil,
 130         local \\ true
 131       ) do
 132     with true <- is_public?(object),
 133          announce_data <- make_announce_data(user, object, activity_id),
 134          {:ok, activity} <- insert(announce_data, local),
 135          {:ok, object} <- add_announce_to_object(activity, object),
 136          :ok <- maybe_federate(activity) do
 137       {:ok, activity, object}
 138     else
 139       error -> {:error, error}
 140     end
 141   end
 142
 143   def unannounce(%User{} = actor, %Object{} = object, local \\ true) do
 144     with %Activity{} = activity <- get_existing_announce(actor.ap_id, object),
 145          unannounce_data <- make_unannounce_data(actor, object),
 146          {:ok, unannounce_activity} <- insert(unannounce_data, local),
 147          :ok <- maybe_federate(activity),
 148          {:ok, _activity} <- Repo.delete(activity),
 149          {:ok, object} <- remove_announce_from_object(activity, object) do
 150       {:ok, unannounce_activity, activity, object}
 151     else
 152       _e -> {:ok, object}
 153     end
 154   end
 155
 156   def follow(follower, followed, activity_id \\ nil, local \\ true) do
 157     with data <- make_follow_data(follower, followed, activity_id),
 158          {:ok, activity} <- insert(data, local),
 159          :ok <- maybe_federate(activity) do
 160       {:ok, activity}
 161     end
 162   end
 163
 164   def unfollow(follower, followed, local \\ true) do
 165     with %Activity{} = follow_activity <- fetch_latest_follow(follower, followed),
 166          unfollow_data <- make_unfollow_data(follower, followed, follow_activity),
 167          {:ok, activity} <- insert(unfollow_data, local),
 168          :ok,
 169          maybe_federate(activity) do
 170       {:ok, activity}
 171     end
 172   end
 173
 174   def delete(%Object{data: %{"id" => id, "actor" => actor}} = object, local \\ true) do
 175     user = User.get_cached_by_ap_id(actor)
 176
 177     data = %{
 178       "type" => "Delete",
 179       "actor" => actor,
 180       "object" => id,
 181       "to" => [user.follower_address, "https://www.w3.org/ns/activitystreams#Public"]
 182     }
 183
 184     with Repo.delete(object),
 185          Repo.delete_all(Activity.all_non_create_by_object_ap_id_q(id)),
 186          {:ok, activity} <- insert(data, local),
 187          :ok <- maybe_federate(activity) do
 188       {:ok, activity}
 189     end
 190   end
 191
 192   def fetch_activities_for_context(context, opts \\ %{}) do
 193     public = ["https://www.w3.org/ns/activitystreams#Public"]
 194
 195     recipients =
 196       if opts["user"], do: [opts["user"].ap_id | opts["user"].following] ++ public, else: public
 197
 198     query = from(activity in Activity)
 199
 200     query =
 201       query
 202       |> restrict_blocked(opts)
 203       |> restrict_recipients(recipients, opts["user"])
 204
 205     query =
 206       from(
 207         activity in query,
 208         where:
 209           fragment(
 210             "?->>'type' = ? and ?->>'context' = ?",
 211             activity.data,
 212             "Create",
 213             activity.data,
 214             ^context
 215           ),
 216         order_by: [desc: :id]
 217       )
 218
 219     Repo.all(query)
 220   end
 221
 222   # TODO: Make this work properly with unlisted.
 223   def fetch_public_activities(opts \\ %{}) do
 224     q = fetch_activities_query(["https://www.w3.org/ns/activitystreams#Public"], opts)
 225
 226     q
 227     |> Repo.all()
 228     |> Enum.reverse()
 229   end
 230
 231   defp restrict_since(query, %{"since_id" => since_id}) do
 232     from(activity in query, where: activity.id > ^since_id)
 233   end
 234
 235   defp restrict_since(query, _), do: query
 236
 237   defp restrict_tag(query, %{"tag" => tag}) do
 238     from(
 239       activity in query,
 240       where: fragment("? <@ (? #> '{\"object\",\"tag\"}')", ^tag, activity.data)
 241     )
 242   end
 243
 244   defp restrict_tag(query, _), do: query
 245
 246   defp restrict_recipients(query, [], user), do: query
 247
 248   defp restrict_recipients(query, recipients, nil) do
 249     from(activity in query, where: fragment("? && ?", ^recipients, activity.recipients))
 250   end
 251
 252   defp restrict_recipients(query, recipients, user) do
 253     from(
 254       activity in query,
 255       where: fragment("? && ?", ^recipients, activity.recipients),
 256       or_where: activity.actor == ^user.ap_id
 257     )
 258   end
 259
 260   defp restrict_limit(query, %{"limit" => limit}) do
 261     from(activity in query, limit: ^limit)
 262   end
 263
 264   defp restrict_limit(query, _), do: query
 265
 266   defp restrict_local(query, %{"local_only" => true}) do
 267     from(activity in query, where: activity.local == true)
 268   end
 269
 270   defp restrict_local(query, _), do: query
 271
 272   defp restrict_max(query, %{"max_id" => max_id}) do
 273     from(activity in query, where: activity.id < ^max_id)
 274   end
 275
 276   defp restrict_max(query, _), do: query
 277
 278   defp restrict_actor(query, %{"actor_id" => actor_id}) do
 279     from(activity in query, where: activity.actor == ^actor_id)
 280   end
 281
 282   defp restrict_actor(query, _), do: query
 283
 284   defp restrict_type(query, %{"type" => type}) when is_binary(type) do
 285     restrict_type(query, %{"type" => [type]})
 286   end
 287
 288   defp restrict_type(query, %{"type" => type}) do
 289     from(activity in query, where: fragment("?->>'type' = ANY(?)", activity.data, ^type))
 290   end
 291
 292   defp restrict_type(query, _), do: query
 293
 294   defp restrict_favorited_by(query, %{"favorited_by" => ap_id}) do
 295     from(
 296       activity in query,
 297       where: fragment("? <@ (? #> '{\"object\",\"likes\"}')", ^ap_id, activity.data)
 298     )
 299   end
 300
 301   defp restrict_favorited_by(query, _), do: query
 302
 303   defp restrict_media(query, %{"only_media" => val}) when val == "true" or val == "1" do
 304     from(
 305       activity in query,
 306       where: fragment("not (? #> '{\"object\",\"attachment\"}' = ?)", activity.data, ^[])
 307     )
 308   end
 309
 310   defp restrict_media(query, _), do: query
 311
 312   # Only search through last 100_000 activities by default
 313   defp restrict_recent(query, %{"whole_db" => true}), do: query
 314
 315   defp restrict_recent(query, _) do
 316     since = (Repo.aggregate(Activity, :max, :id) || 0) - 100_000
 317
 318     from(activity in query, where: activity.id > ^since)
 319   end
 320
 321   defp restrict_blocked(query, %{"blocking_user" => %User{info: info}}) do
 322     blocks = info["blocks"] || []
 323     from(activity in query, where: fragment("not (? = ANY(?))", activity.actor, ^blocks))
 324   end
 325
 326   defp restrict_blocked(query, _), do: query
 327
 328   def fetch_activities_query(recipients, opts \\ %{}) do
 329     base_query =
 330       from(
 331         activity in Activity,
 332         limit: 20,
 333         order_by: [fragment("? desc nulls last", activity.id)]
 334       )
 335
 336     base_query
 337     |> restrict_recipients(recipients, opts["user"])
 338     |> restrict_tag(opts)
 339     |> restrict_since(opts)
 340     |> restrict_local(opts)
 341     |> restrict_limit(opts)
 342     |> restrict_max(opts)
 343     |> restrict_actor(opts)
 344     |> restrict_type(opts)
 345     |> restrict_favorited_by(opts)
 346     |> restrict_recent(opts)
 347     |> restrict_blocked(opts)
 348     |> restrict_media(opts)
 349   end
 350
 351   def fetch_activities(recipients, opts \\ %{}) do
 352     fetch_activities_query(recipients, opts)
 353     |> Repo.all()
 354     |> Enum.reverse()
 355   end
 356
 357   def upload(file) do
 358     data = Upload.store(file)
 359     Repo.insert(%Object{data: data})
 360   end
 361
 362   def user_data_from_user_object(data) do
 363     avatar =
 364       data["icon"]["url"] &&
 365         %{
 366           "type" => "Image",
 367           "url" => [%{"href" => data["icon"]["url"]}]
 368         }
 369
 370     banner =
 371       data["image"]["url"] &&
 372         %{
 373           "type" => "Image",
 374           "url" => [%{"href" => data["image"]["url"]}]
 375         }
 376
 377     user_data = %{
 378       ap_id: data["id"],
 379       info: %{
 380         "ap_enabled" => true,
 381         "source_data" => data,
 382         "banner" => banner
 383       },
 384       avatar: avatar,
 385       nickname: "#{data["preferredUsername"]}@#{URI.parse(data["id"]).host}",
 386       name: data["name"],
 387       follower_address: data["followers"],
 388       bio: data["summary"]
 389     }
 390
 391     {:ok, user_data}
 392   end
 393
 394   def fetch_and_prepare_user_from_ap_id(ap_id) do
 395     with {:ok, %{status_code: 200, body: body}} <-
 396            @httpoison.get(ap_id, Accept: "application/activity+json"),
 397          {:ok, data} <- Jason.decode(body) do
 398       user_data_from_user_object(data)
 399     else
 400       e -> Logger.error("Could not decode user at fetch #{ap_id}, #{inspect(e)}")
 401     end
 402   end
 403
 404   def make_user_from_ap_id(ap_id) do
 405     if user = User.get_by_ap_id(ap_id) do
 406       Transmogrifier.upgrade_user_from_ap_id(ap_id)
 407     else
 408       with {:ok, data} <- fetch_and_prepare_user_from_ap_id(ap_id) do
 409         User.insert_or_update_user(data)
 410       else
 411         e -> {:error, e}
 412       end
 413     end
 414   end
 415
 416   def make_user_from_nickname(nickname) do
 417     with {:ok, %{"ap_id" => ap_id}} when not is_nil(ap_id) <- WebFinger.finger(nickname) do
 418       make_user_from_ap_id(ap_id)
 419     else
 420       _e -> {:error, "No AP id in WebFinger"}
 421     end
 422   end
 423
 424   def publish(actor, activity) do
 425     followers =
 426       if actor.follower_address in activity.recipients do
 427         {:ok, followers} = User.get_followers(actor)
 428         followers |> Enum.filter(&(!&1.local))
 429       else
 430         []
 431       end
 432
 433     remote_inboxes =
 434       (Pleroma.Web.Salmon.remote_users(activity) ++ followers)
 435       |> Enum.filter(fn user -> User.ap_enabled?(user) end)
 436       |> Enum.map(fn %{info: %{"source_data" => data}} ->
 437         (data["endpoints"] && data["endpoints"]["sharedInbox"]) || data["inbox"]
 438       end)
 439       |> Enum.uniq()
 440
 441     {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 442     json = Jason.encode!(data)
 443
 444     Enum.each(remote_inboxes, fn inbox ->
 445       Federator.enqueue(:publish_single_ap, %{
 446         inbox: inbox,
 447         json: json,
 448         actor: actor,
 449         id: activity.data["id"]
 450       })
 451     end)
 452   end
 453
 454   def publish_one(%{inbox: inbox, json: json, actor: actor, id: id}) do
 455     Logger.info("Federating #{id} to #{inbox}")
 456     host = URI.parse(inbox).host
 457
 458     signature =
 459       Pleroma.Web.HTTPSignatures.sign(actor, %{host: host, "content-length": byte_size(json)})
 460
 461     @httpoison.post(
 462       inbox,
 463       json,
 464       [{"Content-Type", "application/activity+json"}, {"signature", signature}],
 465       hackney: [pool: :default]
 466     )
 467   end
 468
 469   # TODO:
 470   # This will create a Create activity, which we need internally at the moment.
 471   def fetch_object_from_id(id) do
 472     if object = Object.get_cached_by_ap_id(id) do
 473       {:ok, object}
 474     else
 475       Logger.info("Fetching #{id} via AP")
 476
 477       with true <- String.starts_with?(id, "http"),
 478            {:ok, %{body: body, status_code: code}} when code in 200..299 <-
 479              @httpoison.get(
 480                id,
 481                [Accept: "application/activity+json"],
 482                follow_redirect: true,
 483                timeout: 10000,
 484                recv_timeout: 20000
 485              ),
 486            {:ok, data} <- Jason.decode(body),
 487            nil <- Object.get_by_ap_id(data["id"]),
 488            params <- %{
 489              "type" => "Create",
 490              "to" => data["to"],
 491              "cc" => data["cc"],
 492              "actor" => data["attributedTo"],
 493              "object" => data
 494            },
 495            {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 496         {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 497       else
 498         object = %Object{} ->
 499           {:ok, object}
 500
 501         e ->
 502           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
 503
 504           case OStatus.fetch_activity_from_url(id) do
 505             {:ok, [activity | _]} -> {:ok, Object.get_by_ap_id(activity.data["object"]["id"])}
 506             e -> e
 507           end
 508       end
 509     end
 510   end
 511
 512   def is_public?(activity) do
 513     "https://www.w3.org/ns/activitystreams#Public" in (activity.data["to"] ++
 514                                                          (activity.data["cc"] || []))
 515   end
 516
 517   def visible_for_user?(activity, nil) do
 518     is_public?(activity)
 519   end
 520
 521   def visible_for_user?(activity, user) do
 522     x = [user.ap_id | user.following]
 523     y = activity.data["to"] ++ (activity.data["cc"] || [])
 524     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
 525   end
 526 end