git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3   import Ecto.Changeset
   4   alias Pleroma.{Repo, User}
   5
   6   schema "users" do
   7     field :bio, :string
   8     field :email, :string
   9     field :name, :string
  10     field :nickname, :string
  11     field :password_hash, :string
  12     field :password, :string, virtual: true
  13     field :password_confirmation, :string, virtual: true
  14     field :following, { :array, :string }, default: []
  15     field :ap_id, :string
  16     field :avatar, :map
  17
  18     timestamps()
  19   end
  20
  21   def ap_id(%User{nickname: nickname}) do
  22     "#{Pleroma.Web.base_url}/users/#{nickname}"
  23   end
  24
  25   def ap_followers(%User{} = user) do
  26     "#{ap_id(user)}/followers"
  27   end
  28
  29   def follow_changeset(struct, params \\ %{}) do
  30     struct
  31     |> cast(params, [:following])
  32     |> validate_required([:following])
  33   end
  34
  35   def register_changeset(struct, params \\ %{}) do
  36     changeset = struct
  37     |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
  38     |> validate_required([:bio, :email, :name, :nickname, :password, :password_confirmation])
  39     |> validate_confirmation(:password)
  40     |> unique_constraint(:email)
  41     |> unique_constraint(:nickname)
  42
  43     if changeset.valid? do
  44       hashed = Comeonin.Pbkdf2.hashpwsalt(changeset.changes[:password])
  45       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
  46       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
  47       changeset
  48       |> put_change(:password_hash, hashed)
  49       |> put_change(:ap_id, ap_id)
  50       |> put_change(:following, [followers])
  51     else
  52       changeset
  53     end
  54   end
  55
  56   def follow(%User{} = follower, %User{} = followed) do
  57     ap_followers = User.ap_followers(followed)
  58     if following?(follower, followed) do
  59       { :error,
  60         "Could not follow user: #{followed.nickname} is already on your list." }
  61     else
  62       following = [ap_followers | follower.following]
  63       |> Enum.uniq
  64
  65       follower
  66       |> follow_changeset(%{following: following})
  67       |> Repo.update
  68     end
  69   end
  70
  71   def unfollow(%User{} = follower, %User{} = followed) do
  72     ap_followers = User.ap_followers(followed)
  73     if following?(follower, followed) do
  74       following = follower.following
  75       |> List.delete(ap_followers)
  76
  77       follower
  78       |> follow_changeset(%{following: following})
  79       |> Repo.update
  80     else
  81       { :error, "Not subscribed!" }
  82     end
  83   end
  84
  85   def following?(%User{} = follower, %User{} = followed) do
  86     Enum.member?(follower.following, User.ap_followers(followed))
  87   end
  88
  89   def get_cached_by_ap_id(ap_id) do
  90     ConCache.get_or_store(:users, "ap_id:#{ap_id}", fn() ->
  91       # Return false so the cache will store it.
  92       Repo.get_by(User, ap_id: ap_id) || false
  93     end)
  94   end
  95
  96   def get_cached_by_nickname(nickname) do
  97     ConCache.get_or_store(:users, "nickname:#{nickname}", fn() ->
  98       Repo.get_by(User, nickname: nickname) || false
  99     end)
 100   end
 101 end