git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub, OAuth}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     field(:last_refreshed_at, :naive_datetime)
  26     has_many(:notifications, Notification)
  27
  28     timestamps()
  29   end
  30
  31   def avatar_url(user) do
  32     case user.avatar do
  33       %{"url" => [%{"href" => href} | _]} -> href
  34       _ -> "#{Web.base_url()}/images/avi.png"
  35     end
  36   end
  37
  38   def banner_url(user) do
  39     case user.info["banner"] do
  40       %{"url" => [%{"href" => href} | _]} -> href
  41       _ -> "#{Web.base_url()}/images/banner.png"
  42     end
  43   end
  44
  45   def ap_id(%User{nickname: nickname}) do
  46     "#{Web.base_url()}/users/#{nickname}"
  47   end
  48
  49   def ap_followers(%User{} = user) do
  50     "#{ap_id(user)}/followers"
  51   end
  52
  53   def follow_changeset(struct, params \\ %{}) do
  54     struct
  55     |> cast(params, [:following])
  56     |> validate_required([:following])
  57   end
  58
  59   def info_changeset(struct, params \\ %{}) do
  60     struct
  61     |> cast(params, [:info])
  62     |> validate_required([:info])
  63   end
  64
  65   def user_info(%User{} = user) do
  66     oneself = if user.local, do: 1, else: 0
  67
  68     %{
  69       following_count: length(user.following) - oneself,
  70       note_count: user.info["note_count"] || 0,
  71       follower_count: user.info["follower_count"] || 0,
  72       locked: user.info["locked"] || false,
  73       default_scope: user.info["default_scope"] || "public"
  74     }
  75   end
  76
  77   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  78   def remote_user_creation(params) do
  79     changes =
  80       %User{}
  81       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  82       |> validate_required([:name, :ap_id])
  83       |> unique_constraint(:nickname)
  84       |> validate_format(:nickname, @email_regex)
  85       |> validate_length(:bio, max: 5000)
  86       |> validate_length(:name, max: 100)
  87       |> put_change(:local, false)
  88
  89     if changes.valid? do
  90       case changes.changes[:info]["source_data"] do
  91         %{"followers" => followers} ->
  92           changes
  93           |> put_change(:follower_address, followers)
  94
  95         _ ->
  96           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  97
  98           changes
  99           |> put_change(:follower_address, followers)
 100       end
 101     else
 102       changes
 103     end
 104   end
 105
 106   def update_changeset(struct, params \\ %{}) do
 107     struct
 108     |> cast(params, [:bio, :name])
 109     |> unique_constraint(:nickname)
 110     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 111     |> validate_length(:bio, max: 5000)
 112     |> validate_length(:name, min: 1, max: 100)
 113   end
 114
 115   def upgrade_changeset(struct, params \\ %{}) do
 116     params =
 117       params
 118       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 119
 120     struct
 121     |> cast(params, [:bio, :name, :info, :follower_address, :avatar, :last_refreshed_at])
 122     |> unique_constraint(:nickname)
 123     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 124     |> validate_length(:bio, max: 5000)
 125     |> validate_length(:name, max: 100)
 126   end
 127
 128   def password_update_changeset(struct, params) do
 129     changeset =
 130       struct
 131       |> cast(params, [:password, :password_confirmation])
 132       |> validate_required([:password, :password_confirmation])
 133       |> validate_confirmation(:password)
 134
 135     OAuth.Token.delete_user_tokens(struct)
 136     OAuth.Authorization.delete_user_authorizations(struct)
 137
 138     if changeset.valid? do
 139       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 140
 141       changeset
 142       |> put_change(:password_hash, hashed)
 143     else
 144       changeset
 145     end
 146   end
 147
 148   def reset_password(user, data) do
 149     update_and_set_cache(password_update_changeset(user, data))
 150   end
 151
 152   def register_changeset(struct, params \\ %{}) do
 153     changeset =
 154       struct
 155       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 156       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 157       |> validate_confirmation(:password)
 158       |> unique_constraint(:email)
 159       |> unique_constraint(:nickname)
 160       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 161       |> validate_format(:email, @email_regex)
 162       |> validate_length(:bio, max: 1000)
 163       |> validate_length(:name, min: 1, max: 100)
 164
 165     if changeset.valid? do
 166       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 167       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 168       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 169
 170       changeset
 171       |> put_change(:password_hash, hashed)
 172       |> put_change(:ap_id, ap_id)
 173       |> put_change(:following, [followers])
 174       |> put_change(:follower_address, followers)
 175     else
 176       changeset
 177     end
 178   end
 179
 180   def needs_update?(%User{local: true}), do: false
 181
 182   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 183
 184   def needs_update?(%User{local: false} = user) do
 185     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 186   end
 187
 188   def needs_update?(_), do: true
 189
 190   def maybe_direct_follow(%User{} = follower, %User{local: true, info: %{"locked" => true}}) do
 191     {:ok, follower}
 192   end
 193
 194   def maybe_direct_follow(%User{} = follower, %User{local: true} = followed) do
 195     follow(follower, followed)
 196   end
 197
 198   def maybe_direct_follow(%User{} = follower, %User{} = followed) do
 199     if !User.ap_enabled?(followed) do
 200       follow(follower, followed)
 201     else
 202       {:ok, follower}
 203     end
 204   end
 205
 206   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 207     if not following?(follower, followed) do
 208       follow(follower, followed)
 209     else
 210       {:ok, follower}
 211     end
 212   end
 213
 214   def follow(%User{} = follower, %User{info: info} = followed) do
 215     user_config = Application.get_env(:pleroma, :user)
 216     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 217
 218     ap_followers = followed.follower_address
 219
 220     cond do
 221       following?(follower, followed) or info["deactivated"] ->
 222         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 223
 224       deny_follow_blocked and blocks?(followed, follower) ->
 225         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 226
 227       true ->
 228         if !followed.local && follower.local && !ap_enabled?(followed) do
 229           Websub.subscribe(follower, followed)
 230         end
 231
 232         following =
 233           [ap_followers | follower.following]
 234           |> Enum.uniq()
 235
 236         follower =
 237           follower
 238           |> follow_changeset(%{following: following})
 239           |> update_and_set_cache
 240
 241         {:ok, _} = update_follower_count(followed)
 242
 243         follower
 244     end
 245   end
 246
 247   def unfollow(%User{} = follower, %User{} = followed) do
 248     ap_followers = followed.follower_address
 249
 250     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 251       following =
 252         follower.following
 253         |> List.delete(ap_followers)
 254
 255       {:ok, follower} =
 256         follower
 257         |> follow_changeset(%{following: following})
 258         |> update_and_set_cache
 259
 260       {:ok, followed} = update_follower_count(followed)
 261
 262       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 263     else
 264       {:error, "Not subscribed!"}
 265     end
 266   end
 267
 268   def following?(%User{} = follower, %User{} = followed) do
 269     Enum.member?(follower.following, followed.follower_address)
 270   end
 271
 272   def locked?(%User{} = user) do
 273     user.info["locked"] || false
 274   end
 275
 276   def get_by_ap_id(ap_id) do
 277     Repo.get_by(User, ap_id: ap_id)
 278   end
 279
 280   def update_and_set_cache(changeset) do
 281     with {:ok, user} <- Repo.update(changeset) do
 282       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 283       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 284       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 285       {:ok, user}
 286     else
 287       e -> e
 288     end
 289   end
 290
 291   def invalidate_cache(user) do
 292     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 293     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 294   end
 295
 296   def get_cached_by_ap_id(ap_id) do
 297     key = "ap_id:#{ap_id}"
 298     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 299   end
 300
 301   def get_cached_by_nickname(nickname) do
 302     key = "nickname:#{nickname}"
 303     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 304   end
 305
 306   def get_by_nickname(nickname) do
 307     Repo.get_by(User, nickname: nickname)
 308   end
 309
 310   def get_by_nickname_or_email(nickname_or_email) do
 311     case user = Repo.get_by(User, nickname: nickname_or_email) do
 312       %User{} -> user
 313       nil -> Repo.get_by(User, email: nickname_or_email)
 314     end
 315   end
 316
 317   def get_cached_user_info(user) do
 318     key = "user_info:#{user.id}"
 319     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 320   end
 321
 322   def fetch_by_nickname(nickname) do
 323     ap_try = ActivityPub.make_user_from_nickname(nickname)
 324
 325     case ap_try do
 326       {:ok, user} -> {:ok, user}
 327       _ -> OStatus.make_user(nickname)
 328     end
 329   end
 330
 331   def get_or_fetch_by_nickname(nickname) do
 332     with %User{} = user <- get_by_nickname(nickname) do
 333       user
 334     else
 335       _e ->
 336         with [_nick, _domain] <- String.split(nickname, "@"),
 337              {:ok, user} <- fetch_by_nickname(nickname) do
 338           user
 339         else
 340           _e -> nil
 341         end
 342     end
 343   end
 344
 345   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 346     from(
 347       u in User,
 348       where: fragment("? <@ ?", ^[follower_address], u.following),
 349       where: u.id != ^id
 350     )
 351   end
 352
 353   def get_followers(user) do
 354     q = get_followers_query(user)
 355
 356     {:ok, Repo.all(q)}
 357   end
 358
 359   def get_friends_query(%User{id: id, following: following}) do
 360     from(
 361       u in User,
 362       where: u.follower_address in ^following,
 363       where: u.id != ^id
 364     )
 365   end
 366
 367   def get_friends(user) do
 368     q = get_friends_query(user)
 369
 370     {:ok, Repo.all(q)}
 371   end
 372
 373   def get_follow_requests_query(%User{} = user) do
 374     from(
 375       a in Activity,
 376       where:
 377         fragment(
 378           "? ->> 'type' = 'Follow'",
 379           a.data
 380         ),
 381       where:
 382         fragment(
 383           "? ->> 'state' = 'pending'",
 384           a.data
 385         ),
 386       where:
 387         fragment(
 388           "? @> ?",
 389           a.data,
 390           ^%{"object" => user.ap_id}
 391         )
 392     )
 393   end
 394
 395   def get_follow_requests(%User{} = user) do
 396     q = get_follow_requests_query(user)
 397     reqs = Repo.all(q)
 398
 399     users =
 400       Enum.map(reqs, fn req -> req.actor end)
 401       |> Enum.uniq()
 402       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 403       |> Enum.filter(fn u -> !following?(u, user) end)
 404
 405     {:ok, users}
 406   end
 407
 408   def increase_note_count(%User{} = user) do
 409     note_count = (user.info["note_count"] || 0) + 1
 410     new_info = Map.put(user.info, "note_count", note_count)
 411
 412     cs = info_changeset(user, %{info: new_info})
 413
 414     update_and_set_cache(cs)
 415   end
 416
 417   def decrease_note_count(%User{} = user) do
 418     note_count = user.info["note_count"] || 0
 419     note_count = if note_count <= 0, do: 0, else: note_count - 1
 420     new_info = Map.put(user.info, "note_count", note_count)
 421
 422     cs = info_changeset(user, %{info: new_info})
 423
 424     update_and_set_cache(cs)
 425   end
 426
 427   def update_note_count(%User{} = user) do
 428     note_count_query =
 429       from(
 430         a in Object,
 431         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 432         select: count(a.id)
 433       )
 434
 435     note_count = Repo.one(note_count_query)
 436
 437     new_info = Map.put(user.info, "note_count", note_count)
 438
 439     cs = info_changeset(user, %{info: new_info})
 440
 441     update_and_set_cache(cs)
 442   end
 443
 444   def update_follower_count(%User{} = user) do
 445     follower_count_query =
 446       from(
 447         u in User,
 448         where: ^user.follower_address in u.following,
 449         where: u.id != ^user.id,
 450         select: count(u.id)
 451       )
 452
 453     follower_count = Repo.one(follower_count_query)
 454
 455     new_info = Map.put(user.info, "follower_count", follower_count)
 456
 457     cs = info_changeset(user, %{info: new_info})
 458
 459     update_and_set_cache(cs)
 460   end
 461
 462   def get_notified_from_activity_query(to) do
 463     from(
 464       u in User,
 465       where: u.ap_id in ^to,
 466       where: u.local == true
 467     )
 468   end
 469
 470   def get_notified_from_activity(%Activity{recipients: to, data: %{"type" => "Announce"} = data}) do
 471     object = Object.normalize(data["object"])
 472     actor = User.get_cached_by_ap_id(data["actor"])
 473
 474     # ensure that the actor who published the announced object appears only once
 475     to =
 476       if actor.nickname != nil do
 477         to ++ [object.data["actor"]]
 478       else
 479         to
 480       end
 481       |> Enum.uniq()
 482
 483     query = get_notified_from_activity_query(to)
 484
 485     Repo.all(query)
 486   end
 487
 488   def get_notified_from_activity(%Activity{recipients: to}) do
 489     query = get_notified_from_activity_query(to)
 490
 491     Repo.all(query)
 492   end
 493
 494   def get_recipients_from_activity(%Activity{recipients: to}) do
 495     query =
 496       from(
 497         u in User,
 498         where: u.ap_id in ^to,
 499         or_where: fragment("? && ?", u.following, ^to)
 500       )
 501
 502     query = from(u in query, where: u.local == true)
 503
 504     Repo.all(query)
 505   end
 506
 507   def search(query, resolve) do
 508     # strip the beginning @ off if there is a query
 509     query = String.trim_leading(query, "@")
 510
 511     if resolve do
 512       User.get_or_fetch_by_nickname(query)
 513     end
 514
 515     inner =
 516       from(
 517         u in User,
 518         select_merge: %{
 519           search_distance:
 520             fragment(
 521               "? <-> (? || ?)",
 522               ^query,
 523               u.nickname,
 524               u.name
 525             )
 526         },
 527         where: not is_nil(u.nickname)
 528       )
 529
 530     q =
 531       from(
 532         s in subquery(inner),
 533         order_by: s.search_distance,
 534         limit: 20
 535       )
 536
 537     Repo.all(q)
 538   end
 539
 540   def block(blocker, %User{ap_id: ap_id} = blocked) do
 541     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 542     blocker =
 543       if following?(blocker, blocked) do
 544         {:ok, blocker, _} = unfollow(blocker, blocked)
 545         blocker
 546       else
 547         blocker
 548       end
 549
 550     if following?(blocked, blocker) do
 551       unfollow(blocked, blocker)
 552     end
 553
 554     blocks = blocker.info["blocks"] || []
 555     new_blocks = Enum.uniq([ap_id | blocks])
 556     new_info = Map.put(blocker.info, "blocks", new_blocks)
 557
 558     cs = User.info_changeset(blocker, %{info: new_info})
 559     update_and_set_cache(cs)
 560   end
 561
 562   # helper to handle the block given only an actor's AP id
 563   def block(blocker, %{ap_id: ap_id}) do
 564     block(blocker, User.get_by_ap_id(ap_id))
 565   end
 566
 567   def unblock(user, %{ap_id: ap_id}) do
 568     blocks = user.info["blocks"] || []
 569     new_blocks = List.delete(blocks, ap_id)
 570     new_info = Map.put(user.info, "blocks", new_blocks)
 571
 572     cs = User.info_changeset(user, %{info: new_info})
 573     update_and_set_cache(cs)
 574   end
 575
 576   def blocks?(user, %{ap_id: ap_id}) do
 577     blocks = user.info["blocks"] || []
 578     domain_blocks = user.info["domain_blocks"] || []
 579     %{host: host} = URI.parse(ap_id)
 580
 581     Enum.member?(blocks, ap_id) ||
 582       Enum.any?(domain_blocks, fn domain ->
 583         host == domain
 584       end)
 585   end
 586
 587   def block_domain(user, domain) do
 588     domain_blocks = user.info["domain_blocks"] || []
 589     new_blocks = Enum.uniq([domain | domain_blocks])
 590     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 591
 592     cs = User.info_changeset(user, %{info: new_info})
 593     update_and_set_cache(cs)
 594   end
 595
 596   def unblock_domain(user, domain) do
 597     blocks = user.info["domain_blocks"] || []
 598     new_blocks = List.delete(blocks, domain)
 599     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 600
 601     cs = User.info_changeset(user, %{info: new_info})
 602     update_and_set_cache(cs)
 603   end
 604
 605   def local_user_query() do
 606     from(
 607       u in User,
 608       where: u.local == true,
 609       where: not is_nil(u.nickname)
 610     )
 611   end
 612
 613   def moderator_user_query() do
 614     from(
 615       u in User,
 616       where: u.local == true,
 617       where: fragment("?->'is_moderator' @> 'true'", u.info)
 618     )
 619   end
 620
 621   def deactivate(%User{} = user) do
 622     new_info = Map.put(user.info, "deactivated", true)
 623     cs = User.info_changeset(user, %{info: new_info})
 624     update_and_set_cache(cs)
 625   end
 626
 627   def delete(%User{} = user) do
 628     {:ok, user} = User.deactivate(user)
 629
 630     # Remove all relationships
 631     {:ok, followers} = User.get_followers(user)
 632
 633     followers
 634     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 635
 636     {:ok, friends} = User.get_friends(user)
 637
 638     friends
 639     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 640
 641     query = from(a in Activity, where: a.actor == ^user.ap_id)
 642
 643     Repo.all(query)
 644     |> Enum.each(fn activity ->
 645       case activity.data["type"] do
 646         "Create" ->
 647           ActivityPub.delete(Object.normalize(activity.data["object"]))
 648
 649         # TODO: Do something with likes, follows, repeats.
 650         _ ->
 651           "Doing nothing"
 652       end
 653     end)
 654
 655     :ok
 656   end
 657
 658   def html_filter_policy(%User{info: %{"no_rich_text" => true}}) do
 659     Pleroma.HTML.Scrubber.TwitterText
 660   end
 661
 662   def html_filter_policy(_), do: nil
 663
 664   def get_or_fetch_by_ap_id(ap_id) do
 665     user = get_by_ap_id(ap_id)
 666
 667     if !is_nil(user) and !User.needs_update?(user) do
 668       user
 669     else
 670       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 671
 672       case ap_try do
 673         {:ok, user} ->
 674           user
 675
 676         _ ->
 677           case OStatus.make_user(ap_id) do
 678             {:ok, user} -> user
 679             _ -> {:error, "Could not fetch by AP id"}
 680           end
 681       end
 682     end
 683   end
 684
 685   def get_or_create_instance_user do
 686     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 687
 688     if user = get_by_ap_id(relay_uri) do
 689       user
 690     else
 691       changes =
 692         %User{}
 693         |> cast(%{}, [:ap_id, :nickname, :local])
 694         |> put_change(:ap_id, relay_uri)
 695         |> put_change(:nickname, nil)
 696         |> put_change(:local, true)
 697         |> put_change(:follower_address, relay_uri <> "/followers")
 698
 699       {:ok, user} = Repo.insert(changes)
 700       user
 701     end
 702   end
 703
 704   # AP style
 705   def public_key_from_info(%{
 706         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 707       }) do
 708     key =
 709       :public_key.pem_decode(public_key_pem)
 710       |> hd()
 711       |> :public_key.pem_entry_decode()
 712
 713     {:ok, key}
 714   end
 715
 716   # OStatus Magic Key
 717   def public_key_from_info(%{"magic_key" => magic_key}) do
 718     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 719   end
 720
 721   def get_public_key_for_ap_id(ap_id) do
 722     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 723          {:ok, public_key} <- public_key_from_info(user.info) do
 724       {:ok, public_key}
 725     else
 726       _ -> :error
 727     end
 728   end
 729
 730   defp blank?(""), do: nil
 731   defp blank?(n), do: n
 732
 733   def insert_or_update_user(data) do
 734     data =
 735       data
 736       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 737
 738     cs = User.remote_user_creation(data)
 739     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 740   end
 741
 742   def ap_enabled?(%User{local: true}), do: true
 743   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 744   def ap_enabled?(_), do: false
 745
 746   def get_or_fetch(uri_or_nickname) do
 747     if String.starts_with?(uri_or_nickname, "http") do
 748       get_or_fetch_by_ap_id(uri_or_nickname)
 749     else
 750       get_or_fetch_by_nickname(uri_or_nickname)
 751     end
 752   end
 753
 754   # wait a period of time and return newest version of the User structs
 755   # this is because we have synchronous follow APIs and need to simulate them
 756   # with an async handshake
 757   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 758     with %User{} = a <- Repo.get(User, a.id),
 759          %User{} = b <- Repo.get(User, b.id) do
 760       {:ok, a, b}
 761     else
 762       _e ->
 763         :error
 764     end
 765   end
 766
 767   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 768     with :ok <- :timer.sleep(timeout),
 769          %User{} = a <- Repo.get(User, a.id),
 770          %User{} = b <- Repo.get(User, b.id) do
 771       {:ok, a, b}
 772     else
 773       _e ->
 774         :error
 775     end
 776   end
 777 end