git.squeep.com Git - akkoma/blob - lib/pleroma/user.ex

   1 defmodule Pleroma.User do
   2   use Ecto.Schema
   3
   4   import Ecto.{Changeset, Query}
   5   alias Pleroma.{Repo, User, Object, Web, Activity, Notification}
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Web.{OStatus, Websub}
   8   alias Pleroma.Web.ActivityPub.{Utils, ActivityPub}
   9
  10   schema "users" do
  11     field(:bio, :string)
  12     field(:email, :string)
  13     field(:name, :string)
  14     field(:nickname, :string)
  15     field(:password_hash, :string)
  16     field(:password, :string, virtual: true)
  17     field(:password_confirmation, :string, virtual: true)
  18     field(:following, {:array, :string}, default: [])
  19     field(:ap_id, :string)
  20     field(:avatar, :map)
  21     field(:local, :boolean, default: true)
  22     field(:info, :map, default: %{})
  23     field(:follower_address, :string)
  24     field(:search_distance, :float, virtual: true)
  25     field(:last_refreshed_at, :naive_datetime)
  26     has_many(:notifications, Notification)
  27
  28     timestamps()
  29   end
  30
  31   def avatar_url(user) do
  32     case user.avatar do
  33       %{"url" => [%{"href" => href} | _]} -> href
  34       _ -> "#{Web.base_url()}/images/avi.png"
  35     end
  36   end
  37
  38   def banner_url(user) do
  39     case user.info["banner"] do
  40       %{"url" => [%{"href" => href} | _]} -> href
  41       _ -> "#{Web.base_url()}/images/banner.png"
  42     end
  43   end
  44
  45   def ap_id(%User{nickname: nickname}) do
  46     "#{Web.base_url()}/users/#{nickname}"
  47   end
  48
  49   def ap_followers(%User{} = user) do
  50     "#{ap_id(user)}/followers"
  51   end
  52
  53   def follow_changeset(struct, params \\ %{}) do
  54     struct
  55     |> cast(params, [:following])
  56     |> validate_required([:following])
  57   end
  58
  59   def info_changeset(struct, params \\ %{}) do
  60     struct
  61     |> cast(params, [:info])
  62     |> validate_required([:info])
  63   end
  64
  65   def user_info(%User{} = user) do
  66     oneself = if user.local, do: 1, else: 0
  67
  68     %{
  69       following_count: length(user.following) - oneself,
  70       note_count: user.info["note_count"] || 0,
  71       follower_count: user.info["follower_count"] || 0,
  72       locked: user.info["locked"] || false,
  73       default_scope: user.info["default_scope"] || "public"
  74     }
  75   end
  76
  77   @email_regex ~r/^[a-zA-Z0-9.!#$%&'*+\/=?^_`{|}~-]+@[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?(?:\.[a-zA-Z0-9](?:[a-zA-Z0-9-]{0,61}[a-zA-Z0-9])?)*$/
  78   def remote_user_creation(params) do
  79     changes =
  80       %User{}
  81       |> cast(params, [:bio, :name, :ap_id, :nickname, :info, :avatar])
  82       |> validate_required([:name, :ap_id])
  83       |> unique_constraint(:nickname)
  84       |> validate_format(:nickname, @email_regex)
  85       |> validate_length(:bio, max: 5000)
  86       |> validate_length(:name, max: 100)
  87       |> put_change(:local, false)
  88
  89     if changes.valid? do
  90       case changes.changes[:info]["source_data"] do
  91         %{"followers" => followers} ->
  92           changes
  93           |> put_change(:follower_address, followers)
  94
  95         _ ->
  96           followers = User.ap_followers(%User{nickname: changes.changes[:nickname]})
  97
  98           changes
  99           |> put_change(:follower_address, followers)
 100       end
 101     else
 102       changes
 103     end
 104   end
 105
 106   def update_changeset(struct, params \\ %{}) do
 107     struct
 108     |> cast(params, [:bio, :name])
 109     |> unique_constraint(:nickname)
 110     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 111     |> validate_length(:bio, max: 5000)
 112     |> validate_length(:name, min: 1, max: 100)
 113   end
 114
 115   def upgrade_changeset(struct, params \\ %{}) do
 116     params =
 117       params
 118       |> Map.put(:last_refreshed_at, NaiveDateTime.utc_now())
 119
 120     struct
 121     |> cast(params, [:bio, :name, :info, :follower_address, :avatar, :last_refreshed_at])
 122     |> unique_constraint(:nickname)
 123     |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 124     |> validate_length(:bio, max: 5000)
 125     |> validate_length(:name, max: 100)
 126   end
 127
 128   def password_update_changeset(struct, params) do
 129     changeset =
 130       struct
 131       |> cast(params, [:password, :password_confirmation])
 132       |> validate_required([:password, :password_confirmation])
 133       |> validate_confirmation(:password)
 134
 135     if changeset.valid? do
 136       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 137
 138       changeset
 139       |> put_change(:password_hash, hashed)
 140     else
 141       changeset
 142     end
 143   end
 144
 145   def reset_password(user, data) do
 146     update_and_set_cache(password_update_changeset(user, data))
 147   end
 148
 149   def register_changeset(struct, params \\ %{}) do
 150     changeset =
 151       struct
 152       |> cast(params, [:bio, :email, :name, :nickname, :password, :password_confirmation])
 153       |> validate_required([:email, :name, :nickname, :password, :password_confirmation])
 154       |> validate_confirmation(:password)
 155       |> unique_constraint(:email)
 156       |> unique_constraint(:nickname)
 157       |> validate_format(:nickname, ~r/^[a-zA-Z\d]+$/)
 158       |> validate_format(:email, @email_regex)
 159       |> validate_length(:bio, max: 1000)
 160       |> validate_length(:name, min: 1, max: 100)
 161
 162     if changeset.valid? do
 163       hashed = Pbkdf2.hashpwsalt(changeset.changes[:password])
 164       ap_id = User.ap_id(%User{nickname: changeset.changes[:nickname]})
 165       followers = User.ap_followers(%User{nickname: changeset.changes[:nickname]})
 166
 167       changeset
 168       |> put_change(:password_hash, hashed)
 169       |> put_change(:ap_id, ap_id)
 170       |> put_change(:following, [followers])
 171       |> put_change(:follower_address, followers)
 172     else
 173       changeset
 174     end
 175   end
 176
 177   def needs_update?(%User{local: true}), do: false
 178
 179   def needs_update?(%User{local: false, last_refreshed_at: nil}), do: true
 180
 181   def needs_update?(%User{local: false} = user) do
 182     NaiveDateTime.diff(NaiveDateTime.utc_now(), user.last_refreshed_at) >= 86400
 183   end
 184
 185   def needs_update?(_), do: true
 186
 187   def maybe_direct_follow(%User{} = follower, %User{info: info} = followed) do
 188     if !User.ap_enabled?(followed) do
 189       follow(follower, followed)
 190     else
 191       {:ok, follower}
 192     end
 193   end
 194
 195   def maybe_follow(%User{} = follower, %User{info: info} = followed) do
 196     if not following?(follower, followed) do
 197       follow(follower, followed)
 198     else
 199       {:ok, follower}
 200     end
 201   end
 202
 203   def follow(%User{} = follower, %User{info: info} = followed) do
 204     user_config = Application.get_env(:pleroma, :user)
 205     deny_follow_blocked = Keyword.get(user_config, :deny_follow_blocked)
 206
 207     ap_followers = followed.follower_address
 208
 209     cond do
 210       following?(follower, followed) or info["deactivated"] ->
 211         {:error, "Could not follow user: #{followed.nickname} is already on your list."}
 212
 213       deny_follow_blocked and blocks?(followed, follower) ->
 214         {:error, "Could not follow user: #{followed.nickname} blocked you."}
 215
 216       true ->
 217         if !followed.local && follower.local && !ap_enabled?(followed) do
 218           Websub.subscribe(follower, followed)
 219         end
 220
 221         following =
 222           [ap_followers | follower.following]
 223           |> Enum.uniq()
 224
 225         follower =
 226           follower
 227           |> follow_changeset(%{following: following})
 228           |> update_and_set_cache
 229
 230         {:ok, _} = update_follower_count(followed)
 231
 232         follower
 233     end
 234   end
 235
 236   def unfollow(%User{} = follower, %User{} = followed) do
 237     ap_followers = followed.follower_address
 238
 239     if following?(follower, followed) and follower.ap_id != followed.ap_id do
 240       following =
 241         follower.following
 242         |> List.delete(ap_followers)
 243
 244       {:ok, follower} =
 245         follower
 246         |> follow_changeset(%{following: following})
 247         |> update_and_set_cache
 248
 249       {:ok, followed} = update_follower_count(followed)
 250
 251       {:ok, follower, Utils.fetch_latest_follow(follower, followed)}
 252     else
 253       {:error, "Not subscribed!"}
 254     end
 255   end
 256
 257   def following?(%User{} = follower, %User{} = followed) do
 258     Enum.member?(follower.following, followed.follower_address)
 259   end
 260
 261   def locked?(%User{} = user) do
 262     user.info["locked"] || false
 263   end
 264
 265   def get_by_ap_id(ap_id) do
 266     Repo.get_by(User, ap_id: ap_id)
 267   end
 268
 269   def update_and_set_cache(changeset) do
 270     with {:ok, user} <- Repo.update(changeset) do
 271       Cachex.put(:user_cache, "ap_id:#{user.ap_id}", user)
 272       Cachex.put(:user_cache, "nickname:#{user.nickname}", user)
 273       Cachex.put(:user_cache, "user_info:#{user.id}", user_info(user))
 274       {:ok, user}
 275     else
 276       e -> e
 277     end
 278   end
 279
 280   def invalidate_cache(user) do
 281     Cachex.del(:user_cache, "ap_id:#{user.ap_id}")
 282     Cachex.del(:user_cache, "nickname:#{user.nickname}")
 283   end
 284
 285   def get_cached_by_ap_id(ap_id) do
 286     key = "ap_id:#{ap_id}"
 287     Cachex.fetch!(:user_cache, key, fn _ -> get_by_ap_id(ap_id) end)
 288   end
 289
 290   def get_cached_by_nickname(nickname) do
 291     key = "nickname:#{nickname}"
 292     Cachex.fetch!(:user_cache, key, fn _ -> get_or_fetch_by_nickname(nickname) end)
 293   end
 294
 295   def get_by_nickname(nickname) do
 296     Repo.get_by(User, nickname: nickname)
 297   end
 298
 299   def get_by_nickname_or_email(nickname_or_email) do
 300     case user = Repo.get_by(User, nickname: nickname_or_email) do
 301       %User{} -> user
 302       nil -> Repo.get_by(User, email: nickname_or_email)
 303     end
 304   end
 305
 306   def get_cached_user_info(user) do
 307     key = "user_info:#{user.id}"
 308     Cachex.fetch!(:user_cache, key, fn _ -> user_info(user) end)
 309   end
 310
 311   def fetch_by_nickname(nickname) do
 312     ap_try = ActivityPub.make_user_from_nickname(nickname)
 313
 314     case ap_try do
 315       {:ok, user} -> {:ok, user}
 316       _ -> OStatus.make_user(nickname)
 317     end
 318   end
 319
 320   def get_or_fetch_by_nickname(nickname) do
 321     with %User{} = user <- get_by_nickname(nickname) do
 322       user
 323     else
 324       _e ->
 325         with [_nick, _domain] <- String.split(nickname, "@"),
 326              {:ok, user} <- fetch_by_nickname(nickname) do
 327           user
 328         else
 329           _e -> nil
 330         end
 331     end
 332   end
 333
 334   def get_followers_query(%User{id: id, follower_address: follower_address}) do
 335     from(
 336       u in User,
 337       where: fragment("? <@ ?", ^[follower_address], u.following),
 338       where: u.id != ^id
 339     )
 340   end
 341
 342   def get_followers(user) do
 343     q = get_followers_query(user)
 344
 345     {:ok, Repo.all(q)}
 346   end
 347
 348   def get_friends_query(%User{id: id, following: following}) do
 349     from(
 350       u in User,
 351       where: u.follower_address in ^following,
 352       where: u.id != ^id
 353     )
 354   end
 355
 356   def get_friends(user) do
 357     q = get_friends_query(user)
 358
 359     {:ok, Repo.all(q)}
 360   end
 361
 362   def get_follow_requests_query(%User{} = user) do
 363     from(
 364       a in Activity,
 365       where:
 366         fragment(
 367           "? ->> 'type' = 'Follow'",
 368           a.data
 369         ),
 370       where:
 371         fragment(
 372           "? ->> 'state' = 'pending'",
 373           a.data
 374         ),
 375       where:
 376         fragment(
 377           "? @> ?",
 378           a.data,
 379           ^%{"object" => user.ap_id}
 380         )
 381     )
 382   end
 383
 384   def get_follow_requests(%User{} = user) do
 385     q = get_follow_requests_query(user)
 386     reqs = Repo.all(q)
 387
 388     users =
 389       Enum.map(reqs, fn req -> req.actor end)
 390       |> Enum.uniq()
 391       |> Enum.map(fn ap_id -> get_by_ap_id(ap_id) end)
 392       |> Enum.filter(fn u -> !following?(u, user) end)
 393
 394     {:ok, users}
 395   end
 396
 397   def increase_note_count(%User{} = user) do
 398     note_count = (user.info["note_count"] || 0) + 1
 399     new_info = Map.put(user.info, "note_count", note_count)
 400
 401     cs = info_changeset(user, %{info: new_info})
 402
 403     update_and_set_cache(cs)
 404   end
 405
 406   def decrease_note_count(%User{} = user) do
 407     note_count = user.info["note_count"] || 0
 408     note_count = if note_count <= 0, do: 0, else: note_count - 1
 409     new_info = Map.put(user.info, "note_count", note_count)
 410
 411     cs = info_changeset(user, %{info: new_info})
 412
 413     update_and_set_cache(cs)
 414   end
 415
 416   def update_note_count(%User{} = user) do
 417     note_count_query =
 418       from(
 419         a in Object,
 420         where: fragment("?->>'actor' = ? and ?->>'type' = 'Note'", a.data, ^user.ap_id, a.data),
 421         select: count(a.id)
 422       )
 423
 424     note_count = Repo.one(note_count_query)
 425
 426     new_info = Map.put(user.info, "note_count", note_count)
 427
 428     cs = info_changeset(user, %{info: new_info})
 429
 430     update_and_set_cache(cs)
 431   end
 432
 433   def update_follower_count(%User{} = user) do
 434     follower_count_query =
 435       from(
 436         u in User,
 437         where: ^user.follower_address in u.following,
 438         where: u.id != ^user.id,
 439         select: count(u.id)
 440       )
 441
 442     follower_count = Repo.one(follower_count_query)
 443
 444     new_info = Map.put(user.info, "follower_count", follower_count)
 445
 446     cs = info_changeset(user, %{info: new_info})
 447
 448     update_and_set_cache(cs)
 449   end
 450
 451   def get_notified_from_activity_query(to) do
 452     from(
 453       u in User,
 454       where: u.ap_id in ^to,
 455       where: u.local == true
 456     )
 457   end
 458
 459   def get_notified_from_activity(%Activity{recipients: to, data: %{"type" => "Announce"} = data}) do
 460     object = Object.normalize(data["object"])
 461     actor = User.get_cached_by_ap_id(data["actor"])
 462
 463     # ensure that the actor who published the announced object appears only once
 464     to =
 465       if actor.nickname != nil do
 466         to ++ [object.data["actor"]]
 467       else
 468         to
 469       end
 470       |> Enum.uniq()
 471
 472     query = get_notified_from_activity_query(to)
 473
 474     Repo.all(query)
 475   end
 476
 477   def get_notified_from_activity(%Activity{recipients: to}) do
 478     query = get_notified_from_activity_query(to)
 479
 480     Repo.all(query)
 481   end
 482
 483   def get_recipients_from_activity(%Activity{recipients: to}) do
 484     query =
 485       from(
 486         u in User,
 487         where: u.ap_id in ^to,
 488         or_where: fragment("? && ?", u.following, ^to)
 489       )
 490
 491     query = from(u in query, where: u.local == true)
 492
 493     Repo.all(query)
 494   end
 495
 496   def search(query, resolve) do
 497     # strip the beginning @ off if there is a query
 498     query = String.trim_leading(query, "@")
 499
 500     if resolve do
 501       User.get_or_fetch_by_nickname(query)
 502     end
 503
 504     inner =
 505       from(
 506         u in User,
 507         select_merge: %{
 508           search_distance:
 509             fragment(
 510               "? <-> (? || ?)",
 511               ^query,
 512               u.nickname,
 513               u.name
 514             )
 515         },
 516         where: not is_nil(u.nickname)
 517       )
 518
 519     q =
 520       from(
 521         s in subquery(inner),
 522         order_by: s.search_distance,
 523         limit: 20
 524       )
 525
 526     Repo.all(q)
 527   end
 528
 529   def block(blocker, %User{ap_id: ap_id} = blocked) do
 530     # sever any follow relationships to prevent leaks per activitypub (Pleroma issue #213)
 531     blocker =
 532       if following?(blocker, blocked) do
 533         {:ok, blocker, _} = unfollow(blocker, blocked)
 534         blocker
 535       else
 536         blocker
 537       end
 538
 539     if following?(blocked, blocker) do
 540       unfollow(blocked, blocker)
 541     end
 542
 543     blocks = blocker.info["blocks"] || []
 544     new_blocks = Enum.uniq([ap_id | blocks])
 545     new_info = Map.put(blocker.info, "blocks", new_blocks)
 546
 547     cs = User.info_changeset(blocker, %{info: new_info})
 548     update_and_set_cache(cs)
 549   end
 550
 551   # helper to handle the block given only an actor's AP id
 552   def block(blocker, %{ap_id: ap_id}) do
 553     block(blocker, User.get_by_ap_id(ap_id))
 554   end
 555
 556   def unblock(user, %{ap_id: ap_id}) do
 557     blocks = user.info["blocks"] || []
 558     new_blocks = List.delete(blocks, ap_id)
 559     new_info = Map.put(user.info, "blocks", new_blocks)
 560
 561     cs = User.info_changeset(user, %{info: new_info})
 562     update_and_set_cache(cs)
 563   end
 564
 565   def blocks?(user, %{ap_id: ap_id}) do
 566     blocks = user.info["blocks"] || []
 567     domain_blocks = user.info["domain_blocks"] || []
 568     %{host: host} = URI.parse(ap_id)
 569
 570     Enum.member?(blocks, ap_id) ||
 571       Enum.any?(domain_blocks, fn domain ->
 572         host == domain
 573       end)
 574   end
 575
 576   def block_domain(user, domain) do
 577     domain_blocks = user.info["domain_blocks"] || []
 578     new_blocks = Enum.uniq([domain | domain_blocks])
 579     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 580
 581     cs = User.info_changeset(user, %{info: new_info})
 582     update_and_set_cache(cs)
 583   end
 584
 585   def unblock_domain(user, domain) do
 586     blocks = user.info["domain_blocks"] || []
 587     new_blocks = List.delete(blocks, domain)
 588     new_info = Map.put(user.info, "domain_blocks", new_blocks)
 589
 590     cs = User.info_changeset(user, %{info: new_info})
 591     update_and_set_cache(cs)
 592   end
 593
 594   def local_user_query() do
 595     from(
 596       u in User,
 597       where: u.local == true,
 598       where: not is_nil(u.nickname)
 599     )
 600   end
 601
 602   def moderator_user_query() do
 603     from(
 604       u in User,
 605       where: u.local == true,
 606       where: fragment("?->'is_moderator' @> 'true'", u.info)
 607     )
 608   end
 609
 610   def deactivate(%User{} = user) do
 611     new_info = Map.put(user.info, "deactivated", true)
 612     cs = User.info_changeset(user, %{info: new_info})
 613     update_and_set_cache(cs)
 614   end
 615
 616   def delete(%User{} = user) do
 617     {:ok, user} = User.deactivate(user)
 618
 619     # Remove all relationships
 620     {:ok, followers} = User.get_followers(user)
 621
 622     followers
 623     |> Enum.each(fn follower -> User.unfollow(follower, user) end)
 624
 625     {:ok, friends} = User.get_friends(user)
 626
 627     friends
 628     |> Enum.each(fn followed -> User.unfollow(user, followed) end)
 629
 630     query = from(a in Activity, where: a.actor == ^user.ap_id)
 631
 632     Repo.all(query)
 633     |> Enum.each(fn activity ->
 634       case activity.data["type"] do
 635         "Create" ->
 636           ActivityPub.delete(Object.normalize(activity.data["object"]))
 637
 638         # TODO: Do something with likes, follows, repeats.
 639         _ ->
 640           "Doing nothing"
 641       end
 642     end)
 643
 644     :ok
 645   end
 646
 647   def html_filter_policy(%User{info: %{"no_rich_text" => true}}) do
 648     Pleroma.HTML.Scrubber.TwitterText
 649   end
 650
 651   def html_filter_policy(_), do: nil
 652
 653   def get_or_fetch_by_ap_id(ap_id) do
 654     user = get_by_ap_id(ap_id)
 655
 656     if !is_nil(user) and !User.needs_update?(user) do
 657       user
 658     else
 659       ap_try = ActivityPub.make_user_from_ap_id(ap_id)
 660
 661       case ap_try do
 662         {:ok, user} ->
 663           user
 664
 665         _ ->
 666           case OStatus.make_user(ap_id) do
 667             {:ok, user} -> user
 668             _ -> {:error, "Could not fetch by AP id"}
 669           end
 670       end
 671     end
 672   end
 673
 674   def get_or_create_instance_user do
 675     relay_uri = "#{Pleroma.Web.Endpoint.url()}/relay"
 676
 677     if user = get_by_ap_id(relay_uri) do
 678       user
 679     else
 680       changes =
 681         %User{}
 682         |> cast(%{}, [:ap_id, :nickname, :local])
 683         |> put_change(:ap_id, relay_uri)
 684         |> put_change(:nickname, nil)
 685         |> put_change(:local, true)
 686         |> put_change(:follower_address, relay_uri <> "/followers")
 687
 688       {:ok, user} = Repo.insert(changes)
 689       user
 690     end
 691   end
 692
 693   # AP style
 694   def public_key_from_info(%{
 695         "source_data" => %{"publicKey" => %{"publicKeyPem" => public_key_pem}}
 696       }) do
 697     key =
 698       :public_key.pem_decode(public_key_pem)
 699       |> hd()
 700       |> :public_key.pem_entry_decode()
 701
 702     {:ok, key}
 703   end
 704
 705   # OStatus Magic Key
 706   def public_key_from_info(%{"magic_key" => magic_key}) do
 707     {:ok, Pleroma.Web.Salmon.decode_key(magic_key)}
 708   end
 709
 710   def get_public_key_for_ap_id(ap_id) do
 711     with %User{} = user <- get_or_fetch_by_ap_id(ap_id),
 712          {:ok, public_key} <- public_key_from_info(user.info) do
 713       {:ok, public_key}
 714     else
 715       _ -> :error
 716     end
 717   end
 718
 719   defp blank?(""), do: nil
 720   defp blank?(n), do: n
 721
 722   def insert_or_update_user(data) do
 723     data =
 724       data
 725       |> Map.put(:name, blank?(data[:name]) || data[:nickname])
 726
 727     cs = User.remote_user_creation(data)
 728     Repo.insert(cs, on_conflict: :replace_all, conflict_target: :nickname)
 729   end
 730
 731   def ap_enabled?(%User{info: info}), do: info["ap_enabled"]
 732   def ap_enabled?(_), do: false
 733
 734   def get_or_fetch(uri_or_nickname) do
 735     if String.starts_with?(uri_or_nickname, "http") do
 736       get_or_fetch_by_ap_id(uri_or_nickname)
 737     else
 738       get_or_fetch_by_nickname(uri_or_nickname)
 739     end
 740   end
 741
 742   # wait a period of time and return newest version of the User structs
 743   # this is because we have synchronous follow APIs and need to simulate them
 744   # with an async handshake
 745   def wait_and_refresh(_, %User{local: true} = a, %User{local: true} = b) do
 746     with %User{} = a <- Repo.get(User, a.id),
 747          %User{} = b <- Repo.get(User, b.id) do
 748       {:ok, a, b}
 749     else
 750       _e ->
 751         :error
 752     end
 753   end
 754
 755   def wait_and_refresh(timeout, %User{} = a, %User{} = b) do
 756     with :ok <- :timer.sleep(timeout),
 757          %User{} = a <- Repo.get(User, a.id),
 758          %User{} = b <- Repo.get(User, b.id) do
 759       {:ok, a, b}
 760     else
 761       _e ->
 762         :error
 763     end
 764   end
 765 end